mako 0.0.0

data/lib/mako/data/flash_widget_dev_core/src/com/adobe/crypto/SHA224.as

@@ -0,0 +1,226 @@
+/*
+  Copyright (c) 2008, Adobe Systems Incorporated
+  All rights reserved.
+  Redistribution and use in source and binary forms, with or without
+  modification, are permitted provided that the following conditions are
+  met:
+  * Redistributions of source code must retain the above copyright notice,
+    this list of conditions and the following disclaimer.
+  * Redistributions in binary form must reproduce the above copyright
+    notice, this list of conditions and the following disclaimer in the
+    documentation and/or other materials provided with the distribution.
+  * Neither the name of Adobe Systems Incorporated nor the names of its
+    contributors may be used to endorse or promote products derived from
+    this software without specific prior written permission.
+  THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS
+  IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO,
+  THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
+  PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT OWNER OR
+  CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
+  EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
+  PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
+  PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF
+  LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING
+  NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
+  SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
+*/
+package com.adobe.crypto
+{
+	import com.adobe.utils.IntUtil;
+	import flash.utils.ByteArray;
+	import mx.utils.Base64Encoder;
+	/**
+	 * The SHA-224 algorithm
+	 *
+	 * @see http://csrc.nist.gov/publications/fips/fips180-2/fips180-2withchangenotice.pdf
+	 */
+	public class SHA224
+	{
+		public static var digest:ByteArray;
+		/**
+		 *  Performs the SHA224 hash algorithm on a string.
+		 *
+		 *  @param s		The string to hash
+		 *  @return			A string containing the hash value of s
+		 *  @langversion	ActionScript 3.0
+		 *  @playerversion	9.0
+		 *  @tiptext
+		 */
+		public static function hash( s:String ):String {
+			var blocks:Array = createBlocksFromString( s );
+			var byteArray:ByteArray = hashBlocks( blocks );
+			return IntUtil.toHex( byteArray.readInt(), true )
+					+ IntUtil.toHex( byteArray.readInt(), true )
+					+ IntUtil.toHex( byteArray.readInt(), true )
+					+ IntUtil.toHex( byteArray.readInt(), true )
+					+ IntUtil.toHex( byteArray.readInt(), true )
+					+ IntUtil.toHex( byteArray.readInt(), true )
+					+ IntUtil.toHex( byteArray.readInt(), true );
+		}
+		/**
+		 *  Performs the SHA224 hash algorithm on a ByteArray.
+		 *
+		 *  @param data		The ByteArray data to hash
+		 *  @return			A string containing the hash value of data
+		 *  @langversion	ActionScript 3.0
+		 *  @playerversion	9.0
+		 */
+		public static function hashBytes( data:ByteArray ):String
+		{
+			var blocks:Array = createBlocksFromByteArray( data );
+			var byteArray:ByteArray = hashBlocks(blocks);
+			return IntUtil.toHex( byteArray.readInt(), true )
+					+ IntUtil.toHex( byteArray.readInt(), true )
+					+ IntUtil.toHex( byteArray.readInt(), true )
+					+ IntUtil.toHex( byteArray.readInt(), true )
+					+ IntUtil.toHex( byteArray.readInt(), true )
+					+ IntUtil.toHex( byteArray.readInt(), true )
+					+ IntUtil.toHex( byteArray.readInt(), true );
+		}
+		/**
+		 *  Performs the SHA224 hash algorithm on a string, then does
+		 *  Base64 encoding on the result.
+		 *
+		 *  @param s		The string to hash
+		 *  @return			The base64 encoded hash value of s
+		 *  @langversion	ActionScript 3.0
+		 *  @playerversion	9.0
+		 *  @tiptext
+		 */
+		public static function hashToBase64( s:String ):String
+		{
+			var blocks:Array = createBlocksFromString( s );
+			var byteArray:ByteArray = hashBlocks(blocks);
+			// ByteArray.toString() returns the contents as a UTF-8 string,
+			// which we can't use because certain byte sequences might trigger
+			// a UTF-8 conversion.  Instead, we convert the bytes to characters
+			// one by one.
+			var charsInByteArray:String = "";
+			byteArray.position = 0;
+			for (var j:int = 0; j < byteArray.length; j++)
+			{
+				var byte:uint = byteArray.readUnsignedByte();
+				charsInByteArray += String.fromCharCode(byte);
+			}
+			var encoder:Base64Encoder = new Base64Encoder();
+			encoder.encode(charsInByteArray);
+			return encoder.flush();
+		}
+		private static function hashBlocks( blocks:Array ):ByteArray {
+			var h0:int = 0xc1059ed8;
+			var h1:int = 0x367cd507;
+			var h2:int = 0x3070dd17;
+			var h3:int = 0xf70e5939;
+			var h4:int = 0xffc00b31;
+			var h5:int = 0x68581511;
+			var h6:int = 0x64f98fa7;
+			var h7:int = 0xbefa4fa4;
+			var k:Array = new Array(0x428a2f98, 0x71374491, 0xb5c0fbcf, 0xe9b5dba5, 0x3956c25b, 0x59f111f1, 0x923f82a4, 0xab1c5ed5, 0xd807aa98, 0x12835b01, 0x243185be, 0x550c7dc3, 0x72be5d74, 0x80deb1fe, 0x9bdc06a7, 0xc19bf174, 0xe49b69c1, 0xefbe4786, 0x0fc19dc6, 0x240ca1cc, 0x2de92c6f, 0x4a7484aa, 0x5cb0a9dc, 0x76f988da, 0x983e5152, 0xa831c66d, 0xb00327c8, 0xbf597fc7, 0xc6e00bf3, 0xd5a79147, 0x06ca6351, 0x14292967, 0x27b70a85, 0x2e1b2138, 0x4d2c6dfc, 0x53380d13, 0x650a7354, 0x766a0abb, 0x81c2c92e, 0x92722c85, 0xa2bfe8a1, 0xa81a664b, 0xc24b8b70, 0xc76c51a3, 0xd192e819, 0xd6990624, 0xf40e3585, 0x106aa070, 0x19a4c116, 0x1e376c08, 0x2748774c, 0x34b0bcb5, 0x391c0cb3, 0x4ed8aa4a, 0x5b9cca4f, 0x682e6ff3, 0x748f82ee, 0x78a5636f, 0x84c87814, 0x8cc70208, 0x90befffa, 0xa4506ceb, 0xbef9a3f7, 0xc67178f2);
+			var len:int = blocks.length;
+			var w:Array = new Array();
+			// loop over all of the blocks
+			for ( var i:int = 0; i < len; i += 16 ) {
+				var a:int = h0;
+				var b:int = h1;
+				var c:int = h2;
+				var d:int = h3;
+				var e:int = h4;
+				var f:int = h5;
+				var g:int = h6;
+				var h:int = h7;
+				for(var t:int = 0; t < 64; t++) {
+					if ( t < 16 ) {
+						w[t] = blocks[ i + t ];
+						if(isNaN(w[t])) { w[t] = 0; }
+					} else {
+						var ws0:int = IntUtil.ror(w[t-15], 7) ^ IntUtil.ror(w[t-15], 18) ^ (w[t-15] >>> 3);
+						var ws1:int = IntUtil.ror(w[t-2], 17) ^ IntUtil.ror(w[t-2], 19) ^ (w[t-2] >>> 10);
+						w[t] = w[t-16] + ws0 + w[t-7] + ws1;
+					}
+					var s0:int = IntUtil.ror(a, 2) ^ IntUtil.ror(a, 13) ^ IntUtil.ror(a, 22);
+					var maj:int = (a & b) ^ (a & c) ^ (b & c);
+					var t2:int = s0 + maj;
+					var s1:int = IntUtil.ror(e, 6) ^ IntUtil.ror(e, 11) ^ IntUtil.ror(e, 25);
+					var ch:int = (e & f) ^ ((~e) & g);
+					var t1:int = h + s1 + ch + k[t] + w[t];
+					h = g;
+					g = f;
+					f = e;
+					e = d + t1;
+					d = c;
+					c = b;
+					b = a;
+					a = t1 + t2;
+				}
+				//Add this chunk's hash to result so far:
+				h0 += a;
+				h1 += b;
+				h2 += c;
+				h3 += d;
+				h4 += e;
+				h5 += f;
+				h6 += g;
+				h7 += h;
+			}
+			var byteArray:ByteArray = new ByteArray();
+			byteArray.writeInt(h0);
+			byteArray.writeInt(h1);
+			byteArray.writeInt(h2);
+			byteArray.writeInt(h3);
+			byteArray.writeInt(h4);
+			byteArray.writeInt(h5);
+			byteArray.writeInt(h6);
+			byteArray.position = 0;
+			digest = new ByteArray();
+			digest.writeBytes(byteArray);
+			digest.position = 0;
+			return byteArray;
+		}
+		/**
+		 *  Converts a ByteArray to a sequence of 16-word blocks
+		 *  that we'll do the processing on.  Appends padding
+		 *  and length in the process.
+		 *
+		 *  @param data		The data to split into blocks
+		 *  @return			An array containing the blocks into which data was split
+		 */
+		private static function createBlocksFromByteArray( data:ByteArray ):Array
+		{
+			var oldPosition:int = data.position;
+			data.position = 0;
+			var blocks:Array = new Array();
+			var len:int = data.length * 8;
+			var mask:int = 0xFF; // ignore hi byte of characters > 0xFF
+			for( var i:int = 0; i < len; i += 8 )
+			{
+				blocks[ i >> 5 ] |= ( data.readByte() & mask ) << ( 24 - i % 32 );
+			}
+			// append padding and length
+			blocks[ len >> 5 ] |= 0x80 << ( 24 - len % 32 );
+			blocks[ ( ( ( len + 64 ) >> 9 ) << 4 ) + 15 ] = len;
+			data.position = oldPosition;
+			return blocks;
+		}
+		/**
+		 *  Converts a string to a sequence of 16-word blocks
+		 *  that we'll do the processing on.  Appends padding
+		 *  and length in the process.
+		 *
+		 *  @param s	The string to split into blocks
+		 *  @return		An array containing the blocks that s was split into.
+		 */
+		private static function createBlocksFromString( s:String ):Array
+		{
+			var blocks:Array = new Array();
+			var len:int = s.length * 8;
+			var mask:int = 0xFF; // ignore hi byte of characters > 0xFF
+			for( var i:int = 0; i < len; i += 8 ) {
+				blocks[ i >> 5 ] |= ( s.charCodeAt( i / 8 ) & mask ) << ( 24 - i % 32 );
+			}
+			// append padding and length
+			blocks[ len >> 5 ] |= 0x80 << ( 24 - len % 32 );
+			blocks[ ( ( ( len + 64 ) >> 9 ) << 4 ) + 15 ] = len;
+			return blocks;
+		}
+	}
+}

data/lib/mako/data/flash_widget_dev_core/src/com/adobe/crypto/SHA256.as

@@ -0,0 +1,229 @@
+/*
+  Copyright (c) 2008, Adobe Systems Incorporated
+  All rights reserved.
+  Redistribution and use in source and binary forms, with or without
+  modification, are permitted provided that the following conditions are
+  met:
+  * Redistributions of source code must retain the above copyright notice,
+    this list of conditions and the following disclaimer.
+  * Redistributions in binary form must reproduce the above copyright
+    notice, this list of conditions and the following disclaimer in the
+    documentation and/or other materials provided with the distribution.
+  * Neither the name of Adobe Systems Incorporated nor the names of its
+    contributors may be used to endorse or promote products derived from
+    this software without specific prior written permission.
+  THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS
+  IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO,
+  THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
+  PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT OWNER OR
+  CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
+  EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
+  PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
+  PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF
+  LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING
+  NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
+  SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
+*/
+package com.adobe.crypto
+{
+	import com.adobe.utils.IntUtil;
+	import flash.utils.ByteArray;
+	import mx.utils.Base64Encoder;
+	/**
+	 * The SHA-256 algorithm
+	 *
+	 * @see http://csrc.nist.gov/publications/fips/fips180-2/fips180-2withchangenotice.pdf
+	 */
+	public class SHA256
+	{
+		public static var digest:ByteArray;
+		/**
+		 *  Performs the SHA256 hash algorithm on a string.
+		 *
+		 *  @param s		The string to hash
+		 *  @return			A string containing the hash value of s
+		 *  @langversion	ActionScript 3.0
+		 *  @playerversion	9.0
+		 *  @tiptext
+		 */
+		public static function hash( s:String ):String {
+			var blocks:Array = createBlocksFromString( s );
+			var byteArray:ByteArray = hashBlocks( blocks );
+			return IntUtil.toHex( byteArray.readInt(), true )
+					+ IntUtil.toHex( byteArray.readInt(), true )
+					+ IntUtil.toHex( byteArray.readInt(), true )
+					+ IntUtil.toHex( byteArray.readInt(), true )
+					+ IntUtil.toHex( byteArray.readInt(), true )
+					+ IntUtil.toHex( byteArray.readInt(), true )
+					+ IntUtil.toHex( byteArray.readInt(), true )
+					+ IntUtil.toHex( byteArray.readInt(), true );
+		}
+		/**
+		 *  Performs the SHA256 hash algorithm on a ByteArray.
+		 *
+		 *  @param data		The ByteArray data to hash
+		 *  @return			A string containing the hash value of data
+		 *  @langversion	ActionScript 3.0
+		 *  @playerversion	9.0
+		 */
+		public static function hashBytes( data:ByteArray ):String
+		{
+			var blocks:Array = createBlocksFromByteArray( data );
+			var byteArray:ByteArray = hashBlocks(blocks);
+			return IntUtil.toHex( byteArray.readInt(), true )
+					+ IntUtil.toHex( byteArray.readInt(), true )
+					+ IntUtil.toHex( byteArray.readInt(), true )
+					+ IntUtil.toHex( byteArray.readInt(), true )
+					+ IntUtil.toHex( byteArray.readInt(), true )
+					+ IntUtil.toHex( byteArray.readInt(), true )
+					+ IntUtil.toHex( byteArray.readInt(), true )
+					+ IntUtil.toHex( byteArray.readInt(), true );
+		}
+		/**
+		 *  Performs the SHA256 hash algorithm on a string, then does
+		 *  Base64 encoding on the result.
+		 *
+		 *  @param s		The string to hash
+		 *  @return			The base64 encoded hash value of s
+		 *  @langversion	ActionScript 3.0
+		 *  @playerversion	9.0
+		 *  @tiptext
+		 */
+		public static function hashToBase64( s:String ):String
+		{
+			var blocks:Array = createBlocksFromString( s );
+			var byteArray:ByteArray = hashBlocks(blocks);
+			// ByteArray.toString() returns the contents as a UTF-8 string,
+			// which we can't use because certain byte sequences might trigger
+			// a UTF-8 conversion.  Instead, we convert the bytes to characters
+			// one by one.
+			var charsInByteArray:String = "";
+			byteArray.position = 0;
+			for (var j:int = 0; j < byteArray.length; j++)
+			{
+				var byte:uint = byteArray.readUnsignedByte();
+				charsInByteArray += String.fromCharCode(byte);
+			}
+			var encoder:Base64Encoder = new Base64Encoder();
+			encoder.encode(charsInByteArray);
+			return encoder.flush();
+		}
+		private static function hashBlocks( blocks:Array ):ByteArray {
+			var h0:int = 0x6a09e667;
+			var h1:int = 0xbb67ae85;
+			var h2:int = 0x3c6ef372;
+			var h3:int = 0xa54ff53a;
+			var h4:int = 0x510e527f;
+			var h5:int = 0x9b05688c;
+			var h6:int = 0x1f83d9ab;
+			var h7:int = 0x5be0cd19;
+			var k:Array = new Array(0x428a2f98, 0x71374491, 0xb5c0fbcf, 0xe9b5dba5, 0x3956c25b, 0x59f111f1, 0x923f82a4, 0xab1c5ed5, 0xd807aa98, 0x12835b01, 0x243185be, 0x550c7dc3, 0x72be5d74, 0x80deb1fe, 0x9bdc06a7, 0xc19bf174, 0xe49b69c1, 0xefbe4786, 0x0fc19dc6, 0x240ca1cc, 0x2de92c6f, 0x4a7484aa, 0x5cb0a9dc, 0x76f988da, 0x983e5152, 0xa831c66d, 0xb00327c8, 0xbf597fc7, 0xc6e00bf3, 0xd5a79147, 0x06ca6351, 0x14292967, 0x27b70a85, 0x2e1b2138, 0x4d2c6dfc, 0x53380d13, 0x650a7354, 0x766a0abb, 0x81c2c92e, 0x92722c85, 0xa2bfe8a1, 0xa81a664b, 0xc24b8b70, 0xc76c51a3, 0xd192e819, 0xd6990624, 0xf40e3585, 0x106aa070, 0x19a4c116, 0x1e376c08, 0x2748774c, 0x34b0bcb5, 0x391c0cb3, 0x4ed8aa4a, 0x5b9cca4f, 0x682e6ff3, 0x748f82ee, 0x78a5636f, 0x84c87814, 0x8cc70208, 0x90befffa, 0xa4506ceb, 0xbef9a3f7, 0xc67178f2);
+			var len:int = blocks.length;
+			var w:Array = new Array( 64 );
+			// loop over all of the blocks
+			for ( var i:int = 0; i < len; i += 16 ) {
+				var a:int = h0;
+				var b:int = h1;
+				var c:int = h2;
+				var d:int = h3;
+				var e:int = h4;
+				var f:int = h5;
+				var g:int = h6;
+				var h:int = h7;
+				for(var t:int = 0; t < 64; t++) {
+					if ( t < 16 ) {
+						w[t] = blocks[ i + t ];
+						if(isNaN(w[t])) { w[t] = 0; }
+					} else {
+						var ws0:int = IntUtil.ror(w[t-15], 7) ^ IntUtil.ror(w[t-15], 18) ^ (w[t-15] >>> 3);
+						var ws1:int = IntUtil.ror(w[t-2], 17) ^ IntUtil.ror(w[t-2], 19) ^ (w[t-2] >>> 10);
+						w[t] = w[t-16] + ws0 + w[t-7] + ws1;
+					}
+					var s0:int = IntUtil.ror(a, 2) ^ IntUtil.ror(a, 13) ^ IntUtil.ror(a, 22);
+					var maj:int = (a & b) ^ (a & c) ^ (b & c);
+					var t2:int = s0 + maj;
+					var s1:int = IntUtil.ror(e, 6) ^ IntUtil.ror(e, 11) ^ IntUtil.ror(e, 25);
+					var ch:int = (e & f) ^ ((~e) & g);
+					var t1:int = h + s1 + ch + k[t] + w[t];
+					h = g;
+					g = f;
+					f = e;
+					e = d + t1;
+					d = c;
+					c = b;
+					b = a;
+					a = t1 + t2;
+				}
+				//Add this chunk's hash to result so far:
+				h0 += a;
+				h1 += b;
+				h2 += c;
+				h3 += d;
+				h4 += e;
+				h5 += f;
+				h6 += g;
+				h7 += h;
+			}
+			var byteArray:ByteArray = new ByteArray();
+			byteArray.writeInt(h0);
+			byteArray.writeInt(h1);
+			byteArray.writeInt(h2);
+			byteArray.writeInt(h3);
+			byteArray.writeInt(h4);
+			byteArray.writeInt(h5);
+			byteArray.writeInt(h6);
+			byteArray.writeInt(h7);
+			byteArray.position = 0;
+			digest = new ByteArray();
+			digest.writeBytes(byteArray);
+			digest.position = 0;
+			return byteArray;
+		}
+		/**
+		 *  Converts a ByteArray to a sequence of 16-word blocks
+		 *  that we'll do the processing on.  Appends padding
+		 *  and length in the process.
+		 *
+		 *  @param data		The data to split into blocks
+		 *  @return			An array containing the blocks into which data was split
+		 */
+		private static function createBlocksFromByteArray( data:ByteArray ):Array
+		{
+			var oldPosition:int = data.position;
+			data.position = 0;
+			var blocks:Array = new Array();
+			var len:int = data.length * 8;
+			var mask:int = 0xFF; // ignore hi byte of characters > 0xFF
+			for( var i:int = 0; i < len; i += 8 )
+			{
+				blocks[ i >> 5 ] |= ( data.readByte() & mask ) << ( 24 - i % 32 );
+			}
+			// append padding and length
+			blocks[ len >> 5 ] |= 0x80 << ( 24 - len % 32 );
+			blocks[ ( ( ( len + 64 ) >> 9 ) << 4 ) + 15 ] = len;
+			data.position = oldPosition;
+			return blocks;
+		}
+		/**
+		 *  Converts a string to a sequence of 16-word blocks
+		 *  that we'll do the processing on.  Appends padding
+		 *  and length in the process.
+		 *
+		 *  @param s	The string to split into blocks
+		 *  @return		An array containing the blocks that s was split into.
+		 */
+		private static function createBlocksFromString( s:String ):Array
+		{
+			var blocks:Array = new Array();
+			var len:int = s.length * 8;
+			var mask:int = 0xFF; // ignore hi byte of characters > 0xFF
+			for( var i:int = 0; i < len; i += 8 ) {
+				blocks[ i >> 5 ] |= ( s.charCodeAt( i / 8 ) & mask ) << ( 24 - i % 32 );
+			}
+			// append padding and length
+			blocks[ len >> 5 ] |= 0x80 << ( 24 - len % 32 );
+			blocks[ ( ( ( len + 64 ) >> 9 ) << 4 ) + 15 ] = len;
+			return blocks;
+		}
+	}
+}

data/lib/mako/data/flash_widget_dev_core/src/com/adobe/crypto/WSSEUsernameToken.as

@@ -0,0 +1,100 @@
+/*
+  Copyright (c) 2008, Adobe Systems Incorporated
+  All rights reserved.
+  Redistribution and use in source and binary forms, with or without
+  modification, are permitted provided that the following conditions are
+  met:
+  * Redistributions of source code must retain the above copyright notice,
+    this list of conditions and the following disclaimer.
+  * Redistributions in binary form must reproduce the above copyright
+    notice, this list of conditions and the following disclaimer in the
+    documentation and/or other materials provided with the distribution.
+  * Neither the name of Adobe Systems Incorporated nor the names of its
+    contributors may be used to endorse or promote products derived from
+    this software without specific prior written permission.
+  THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS
+  IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO,
+  THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
+  PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT OWNER OR
+  CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
+  EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
+  PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
+  PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF
+  LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING
+  NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
+  SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
+*/
+package com.adobe.crypto
+{
+	import mx.formatters.DateFormatter;
+	import mx.utils.Base64Encoder;
+	/**
+	 * Web Services Security Username Token
+	 *
+	 * Implementation based on algorithm description at
+	 * http://www.oasis-open.org/committees/wss/documents/WSS-Username-02-0223-merged.pdf
+	 */
+	public class WSSEUsernameToken
+	{
+		/**
+		 * Generates a WSSE Username Token.
+		 *
+		 * @param username The username
+		 * @param password The password
+		 * @param nonce A cryptographically random nonce (if null, the nonce
+		 * will be generated)
+		 * @param timestamp The time at which the token is generated (if null,
+		 * the time will be set to the moment of execution)
+		 * @return The generated token
+		 * @langversion ActionScript 3.0
+		 * @playerversion Flash 9.0
+		 * @tiptext
+		 */
+		public static function getUsernameToken(username:String, password:String, nonce:String=null, timestamp:Date=null):String
+		{
+			if (nonce == null)
+			{
+				nonce = generateNonce();
+			}
+			nonce = base64Encode(nonce);
+			var created:String = generateTimestamp(timestamp);
+			var password64:String = getBase64Digest(nonce,
+				created,
+				password);
+			var token:String = new String("UsernameToken Username=\"");
+			token += username + "\", " +
+					 "PasswordDigest=\"" + password64 + "\", " +
+					 "Nonce=\"" + nonce + "\", " +
+					 "Created=\"" + created + "\"";
+			return token;
+		}
+		private static function generateNonce():String
+		{
+			// Math.random returns a Number between 0 and 1.  We don't want our
+			// nonce to contain invalid characters (e.g. the period) so we
+			// strip them out before returning the result.
+			var s:String =  Math.random().toString();
+			return s.replace(".", "");
+		}
+		internal static function base64Encode(s:String):String
+		{
+			var encoder:Base64Encoder = new Base64Encoder();
+			encoder.encode(s);
+			return encoder.flush();
+		}
+		internal static function generateTimestamp(timestamp:Date):String
+		{
+			if (timestamp == null)
+			{
+				timestamp = new Date();
+			}
+			var dateFormatter:DateFormatter = new DateFormatter();
+			dateFormatter.formatString = "YYYY-MM-DDTJJ:NN:SS"
+			return dateFormatter.format(timestamp) + "Z";
+		}
+		internal static function getBase64Digest(nonce:String, created:String, password:String):String
+		{
+			return SHA1.hashToBase64(nonce + created + password);
+		}
+	}
+}

data/lib/mako/data/flash_widget_dev_core/src/com/adobe/effects/SaturationFade.as

@@ -0,0 +1,107 @@
+////////////////////////////////////////////////////////////////////////////////
+//
+// Copyright(c) 2006 Adobe Systems Incorporated. All Rights Reserved.
+//
+////////////////////////////////////////////////////////////////////////////////
+package com.adobe.effects
+{
+import mx.effects.EffectInstance;
+import mx.effects.TweenEffect;
+import mx.effects.IEffectInstance;
+/**
+ *  The SaturationFade effect changes the <code>filters</code> property of a component,
+ *  adding a ColorMatrixFilter to affect it's color saturation level. A saturation
+ *  level of 1.0 indicates the current color saturation level and a saturnation level
+ *  of 0.0 indicates no color saturation (ie. grayscale). A saturation of -1.0 inverts
+ *  the colors of the target.
+ *
+ *  <p>If you omit values for the
+ *  <code>saturationFrom</code> and <code>saturationTo</code> properties,
+ *  the effect automatically transitions from a saturation level of 1.0 to 0.0
+ *
+ *  @mxml
+ *
+ *  <p>The <code>&lt;mx:SaturationFade&gt;</code> tag
+ *  inherits the tag attributes of its superclass,
+ *  and adds the following tag attributes:</p>
+ *
+ *  <pre>
+ *  &lt;mx:SaturationFade
+ *    id="ID"
+ *    saturationFrom="val"
+ *    saturationTo="val"
+ *  /&gt;
+ *  </pre>
+ *
+ *  @see com.adobe.effects.SaturationFadeInstance
+ *
+ */
+public class SaturationFade extends TweenEffect
+{
+   //--------------------------------------------------------------------------
+   //
+   //  Class constants
+   //
+   //--------------------------------------------------------------------------
+   /**
+    *  @private
+    */
+   private static var AFFECTED_PROPERTIES:Array = [ "filters" ];
+   //--------------------------------------------------------------------------
+   //
+   //  Constructor
+   //
+   //--------------------------------------------------------------------------
+   /**
+    *  Constructor.
+    *
+    *  @param target The Object to animate with this effect.
+    */
+   public function SaturationFade( target : Object = null )
+   {
+      super( target );
+      instanceClass = SaturationFadeInstance;
+   }
+   //--------------------------------------------------------------------------
+   //
+   //  Properties
+   //
+   //--------------------------------------------------------------------------
+   [Inspectable(category="General", defaultValue="undefined")]
+	/**
+	 *  Initial saturation level. 0.0 means grayscale, 1.0 means
+	 *  the original saturation level and numbers greater than
+	 *  1.0 increase the saturation beyonds its original level
+	 */
+   public var saturationFrom:Number;
+   [Inspectable(category="General", defaultValue="undefined")]
+	/**
+	 *  Final saturation level. 0.0 means grayscale, 1.0 means
+	 *  the original saturation level and numbers greater than
+	 *  1.0 increase the saturation beyonds its original level
+	 */
+   public var saturationTo:Number;
+   //--------------------------------------------------------------------------
+   //
+   //  Overridden methods
+   //
+   //--------------------------------------------------------------------------
+   /**
+    *  @private
+    */
+   override public function getAffectedProperties():Array /* of String */
+   {
+      return AFFECTED_PROPERTIES;
+   }
+   /**
+    *  @private
+    */
+   override protected function initInstance(instance:IEffectInstance):void
+   {
+      super.initInstance( instance );
+      var saturationInstance:SaturationFadeInstance = SaturationFadeInstance( instance );
+      saturationInstance.saturationFrom = saturationFrom;
+      saturationInstance.saturationTo = saturationTo;
+   }
+}
+}