mako 0.0.0

data/lib/mako/data/flash_widget_dev_core/src/materia/components/questionAnswerDataGrid/TextInputItem.mxml

@@ -0,0 +1,584 @@
+<?xml version = "1.0" encoding = "utf-8"?>
+<mx:Canvas xmlns:mx = "http://www.adobe.com/2006/mxml"
+		   creationComplete="{if(onCompleteCallback != null) { onCompleteCallback.call(this); } }"
+		   verticalScrollPolicy="off" horizontalScrollPolicy="off"
+		   top="0" bottom="0" left="0" right="0" currentState="Expanded"
+		   implements = "mx.managers.IFocusManagerComponent, mx.controls.listClasses.IDropInListItemRenderer, mx.core.IFactory">
+	<mx:states>
+		<mx:State name="Expanded">
+			<mx:SetStyle target="{mainField}" name="bottom" value="22"/>
+		</mx:State>
+		<mx:State name="Normal">
+			<mx:RemoveChild target="{subtitleText}"/>
+			<mx:SetStyle target="{mainField}" name="bottom" value="{fieldPadding}"/>
+			<mx:SetStyle target="{mainField}" name="top" value="{fieldPadding}"/>
+			<mx:SetStyle target="{mainField}" name="right" value="{fieldPadding}"/>
+			<mx:SetStyle target="{mainField}" name="left" value="{fieldPadding}"/>
+			<mx:RemoveChild target="{hbox1}"/>
+		</mx:State>
+		<mx:State name="ShowCharsLeft">
+			<mx:RemoveChild target="{subtitleText}"/>
+			<mx:SetStyle target="{mainField}" name="bottom" value="22"/>
+		</mx:State>
+	</mx:states>
+    <mx:transitions>
+        <mx:Transition id="myTransition" fromState="Normal" toState="ShowCharsLeft">
+            <mx:Parallel id="t1" targets="{[mainField]}">
+                <mx:Move  duration="50"/>
+                <mx:Resize duration="50"/>
+            </mx:Parallel>
+        </mx:Transition>
+        <mx:Transition id="myTransition2" fromState="Normal" toState="ShowCharsLeft">
+            <mx:Parallel id="t2" targets="{[characterCount]}">
+                <mx:Fade alphaFrom="0" alphaTo="1" />
+            </mx:Parallel>
+        </mx:Transition>
+        <mx:Transition id="myTransition3" fromState="ShowCharsLeft" toState="Normal">
+            <mx:Parallel id="t3" targets="{[mainField]}">
+                <mx:Move  duration="50"/>
+                <mx:Resize duration="50"/>
+            </mx:Parallel>
+        </mx:Transition>
+        <mx:Transition id="myTransition4" fromState="ShowCharsLeft" toState="Normal">
+            <mx:Parallel id="t4" targets="{[characterCount]}">
+                <mx:Fade alphaFrom="0" alphaTo="1" />
+            </mx:Parallel>
+        </mx:Transition>
+    </mx:transitions>
+	<mx:TextArea id = "mainField"
+				 creationComplete="{onMainFieldCreationComplete()}"
+				 top = "{fieldPadding}"
+				 bottom = "22"
+				 left = "{fieldPadding}"
+				 right = "{fieldPadding}"
+				 mouseWheel="{onMouseWheel(event)}"
+				 change = "{onChange()}"
+				 textInput="{onTextInput(event)}"
+				 focusIn = "{onFocusIn()}"
+				 focusOut = "{onFocusOut()}"
+				 restrict= "{restrict}"
+				 />
+	<mx:Script>
+		<![CDATA[
+		import com.adobe.utils.StringUtil;
+		import mx.controls.Alert;
+		import mx.controls.TextInput;
+		import mx.controls.dataGridClasses.DataGridListData;
+		import mx.controls.listClasses.BaseListData;
+		import mx.events.FlexEvent;
+		import mx.events.ListEvent;
+		import mx.events.ScrollEvent;
+		import mx.utils.ObjectUtil;
+		/**
+		 * this is the default text that shows up when there is no text
+		 * it dissapears when the user starts editing
+		 */
+		public var explanationText:String;
+		/**
+		 * this is the default text that shows up when acting as a "press to add"
+		 * box.
+		 */
+		public var placeHolderText:String;
+		/**
+		 * To limit the amount of characters for the input
+		 */
+		public var characterLimit:uint;
+		[Bindable]
+		/**
+		 * The padding to be used around the main field
+		 */
+		public var fieldPadding:int = 5;
+		
+		/**
+		 * Tells item renderer which question error filter to use
+		 * Need to include in: <questionAnswerDataGrid:TextInputItem id="blah" errorType="blah" /> 
+		 * AND Extend Question.as to implement custom valid(errorType):Boolean 
+		 **/
+		[Bindable]
+		public var errorType:String;
+			
+		/**
+		 * Restrict newlines if set to false
+		 */
+		public var multiline:Boolean = true;
+		/**
+		 * TextField restrict property
+		 */
+		[Bindable]
+		public var restrict:String = null;
+		/**
+		 * determines weather or not word count is shown
+		 */
+		protected var _showWordCount:Boolean = false;
+		/**
+		 * determines weather or not word count is shown
+		 */
+		protected var _characterLimitVisible:Boolean = true;
+		public var errorColoringEnabled:Boolean = true;
+		/**
+		 * The color of the input field when this question has an error
+		 * Make sure to set this in the initial item renderer.
+		 */
+		public var backgroundColor_error:Number = BGCOLOR_DEFAULT_ERROR;
+		/**
+		 * The color of the input field when this question is normal
+		 * Make sure to set this in the initial item renderer.
+		 */
+		public var backgroundColor_normal:Number = BGCOLOR_DEFAULT_NORMAL;
+		/**
+		 * A background to set for the TextArea.
+		 *
+		 * Usage:
+		 *
+		 * Create an image class by using the embed tag:
+		 *	 [Embed (source="assets/myImage.png")]
+		 *	 public static const MY_IMAGE:Class
+		 *
+		 * Set this equal to that constant
+		 *	 inputItem.backgroundImage = MY_IMAGE;
+		 */
+		public var backgroundImage:Class;
+		/**
+		 * Function called every time this input field is changed or updated
+		 */
+		public var onChangeCallback:Function;
+		/**
+		 * Function called when the creation of this TextInputItem is complete
+		 */
+		public var onCompleteCallback:Function;
+		protected const BGCOLOR_DEFAULT_ERROR:int = 0xFFE9E9;
+		protected const BGCOLOR_DEFAULT_NORMAL:int = 0xFFFFFF;
+		protected const TEXTSTYLE_NORMAL:int = 0;
+		protected const TEXTSTYLE_LIGHT:int = 1;
+		protected var _listData:DataGridListData;
+		protected var _fieldIsEmpty:Boolean;
+		protected var _currentTextStyle:int;
+		protected var _isPlaceholder:Boolean = false;
+		protected var _pendingProperties:Array = new Array();
+		[Bindable]
+		protected var _wordCount:int;
+		public override function set data(value:Object):void
+		{
+			if (parent == null || !(parent.parent is QuestionAnswerDataGrid))
+			{
+				return;
+			}
+			
+			super.data = value;
+			text = String(getData(value));
+
+			if (!mainField.editable)
+			{
+				mainField.selectable = true;
+				mainField.editable = true;
+				updateTextStyle();
+			}
+			
+			// update input style, needed for importing questions
+			updateWordCount();
+			updateCharacterLimit();
+			updateBackgroundColor();
+				
+			//If stealFocus flag is set, take focus and unset it so future text inputs don't try to steal focus also
+			if (data && data.stealFocus)
+			{
+				setFocus();
+				data.stealFocus = false;
+			}
+			
+			//Change appearance if this is the last (placeholder) item
+			var len:int = QuestionAnswerDataGrid(parent.parent).dataProvider.length;
+			if (_isPlaceholder == true)
+			{
+				if (value.rowIndex != len)
+				{
+					_isPlaceholder = false;
+					mainField.setStyle("backgroundAlpha", "1");
+					mainField.setStyle("borderStyle", "solid");
+					mainField.setStyle("textAlign", "left");
+					if (text == '' || text == "null")
+					{
+						mainField.text = (_isPlaceholder) ? placeHolderText : explanationText;
+					}
+					mainField.setSelection(0, mainField.text.length);
+				}
+			}
+			else
+			{
+				if (value.rowIndex == len)
+				{
+					_isPlaceholder = true;
+					mainField.setStyle("backgroundAlpha", "0");
+					mainField.setStyle("borderStyle", "none");
+					mainField.setStyle("textAlign", "center");
+					if (text == '')
+					{
+						mainField.text = placeHolderText;
+					}
+					mainField.setSelection(0, mainField.text.length);
+				}
+			}
+		}
+		/**
+		 * Digests a complex dataField by reading all the periods and brackets
+		 * and following the path as it should be followed. If we were to
+		 * read dataField without this method, a dataField reading
+		 * 'question.answer' have us check for values in data[question.answer]
+		 * including the period as part of the string. We want periods to act
+		 * as separators and brackets to act as array indexes so we need this
+		 * method
+		 */
+		protected function getData(value:Object):Object
+		{
+			var dir:Array = (_listData.dataField as String).split('.');
+			var ret:Object = value;
+			for (var i:int = 0; i < dir.length; i++)
+			{
+				var bracketIndex1:int = String(dir[i]).indexOf('[');
+				var bracketIndex2:int = String(dir[i]).indexOf(']');
+				if (bracketIndex1 == -1)
+				{
+					ret = ret[dir[i]];
+				}
+				else if (bracketIndex2 != -1)
+				{
+					var arr:String = String(dir[i]).substring(0, bracketIndex1);
+					var index:int = int(String(dir[i]).substring(bracketIndex1 + 1, bracketIndex2));
+					ret = Object(ret[arr])[index];
+				}
+			}
+			return ret;
+		}
+		protected function setData(target:Object, content:Object):void
+		{
+			var dir:Array = (_listData.dataField as String).split('.');
+			var ret:Object = target;
+			for (var i:int = 0; i < dir.length - 1; i++)
+			{
+				var bracketIndex1:int = String(dir[i]).indexOf('[');
+				var bracketIndex2:int = String(dir[i]).indexOf(']');
+				if (bracketIndex1 == -1)
+				{
+					if (ret[dir[i]] == null)
+					{
+						ret[dir[i]] = new Object();
+					}
+					ret = ret[dir[i]];
+				}
+				else if (bracketIndex2 != -1)
+				{
+					var arr:String = String(dir[i]).substring(0, bracketIndex1);
+					var index:int = int(String(dir[i]).substring(bracketIndex1 + 1, bracketIndex2));
+					ret = (ret[arr] as Array)[index];
+				}
+			}
+			ret[dir[dir.length - 1]] = content;
+		}
+		/**
+		 *  Gives the text field focus automatically whenever this component receives focus
+		 */
+		public override function setFocus():void
+		{
+			mainField.setFocus();
+		}
+		public override function get data():Object
+		{
+			return super.data;
+		}
+		/**
+		 * Creates a copy of this item. Copies all properties of this instance
+		 * that should be present in all instances.
+		 */
+		public function newInstance():*
+		{
+			var item:TextInputItem = new TextInputItem();
+			this.cloneTo(item);
+			return item;
+		}
+		/**
+		 * Copies important properties from current instance to the target 
+		 */
+		public function cloneTo(target:TextInputItem):void
+		{
+			target.explanationText = explanationText;
+			target.placeHolderText = placeHolderText;
+			target.characterLimit = characterLimit;
+			target.errorColoringEnabled = errorColoringEnabled;
+			target._showWordCount = _showWordCount;
+			target._characterLimitVisible = _characterLimitVisible;
+			target._pendingProperties = _pendingProperties;
+			target.multiline = multiline;
+			target.restrict = restrict;
+			target.backgroundColor_error = backgroundColor_error;
+			target.backgroundColor_normal = backgroundColor_normal;
+			target.backgroundImage = backgroundImage;
+			target.onChangeCallback = onChangeCallback;
+			target.onCompleteCallback = onCompleteCallback;
+			target.fieldPadding = fieldPadding;
+			target.errorType = errorType;
+		}
+		public function set showWordCount(value:Boolean):void
+		{
+			if (value)
+			{
+				currentState = "Expanded";
+			}
+			else if (characterLimit)
+			{
+				currentState = "ShowCharsLeft";
+			}
+			else
+			{
+				currentState = "Normal";
+			}
+			_showWordCount = value;
+		}
+		public function get showWordCount():Boolean
+		{
+			return _showWordCount;
+		}
+		/**
+		 * Whether or not the "characters left" info is shown under
+		 * the input field when focused
+		 */
+		public function get characterLimitVisible():Boolean
+		{
+			return _characterLimitVisible;
+		}
+		public function set characterLimitVisible(value:Boolean):void
+		{
+			_characterLimitVisible = value;
+		}
+		public function set listData(value:BaseListData):void
+		{
+			_listData = DataGridListData(value);
+		}
+		public function get listData():BaseListData
+		{
+			return _listData;
+		}
+		public function set text(value:String):void
+		{
+			//Eliminate newlines if multiline is disabled -- remove carriage returns and returns (\n, \r)
+			if(!multiline)
+			{
+				for (var i:int = value.length - 1; i >= 0; i--)
+				{
+					if (value.charCodeAt(i) == 10 || value.charCodeAt(i) == 13)
+					{
+						value = value.substring(0, i).concat(value.substring(i + 1));
+					}
+				}
+			}
+			
+			if (!value || !value.length || value == "null")
+			{
+				setTextStyle(TEXTSTYLE_LIGHT);
+				if (onChangeCallback != null)
+				{
+					if (mainField.text != explanationText && _isPlaceholder == false && mainField.text != placeHolderText && !_isPlaceholder)
+					{
+						onChangeCallback.call(this);
+					}
+				}
+				mainField.text = (_isPlaceholder) ? placeHolderText : explanationText;
+			}
+			else
+			{
+				if (!text.length)
+				{
+					setTextStyle(TEXTSTYLE_NORMAL);
+				}
+				if (mainField.text != value && onChangeCallback != null)
+				{
+					onChangeCallback.call(this);
+				}
+				mainField.text = value;
+			}
+		}
+		public function get text():String
+		{
+			return (mainField.text == placeHolderText || mainField.text == explanationText) ? '' : mainField.text;
+		}
+		public function get wordCount():int
+		{
+			return _wordCount;
+		}
+		public function set wordCount(value:int):void
+		{
+			_wordCount = value;
+		}
+		public function updateTextStyle():void
+		{
+			var textStyle:int = (!text) ? TEXTSTYLE_LIGHT : TEXTSTYLE_NORMAL; 
+			setTextStyle(textStyle);
+		}
+		public function updateBackgroundColor():void
+		{
+			// if errorType is null, it valid checks both question && answer
+			if(!data.question.valid(errorType) && errorColoringEnabled)
+			{
+				mainField.setStyle('backgroundColor', backgroundColor_error);
+			}
+			else
+			{
+				mainField.setStyle('backgroundColor', backgroundColor_normal);
+			}
+			
+			// set the background image if needed
+			if(backgroundImage != null)
+			{
+				mainField.setStyle('backgroundImage', backgroundImage);
+			}
+		}
+		public function updateCharacterLimit():void
+		{
+			if (characterLimit && this.text.length >= characterLimit)
+			{
+				text = text.substr(0, characterLimit);
+			}
+			wordCount = characterLimit - text.length;
+		}
+		public function hideCharacterLimit():void
+		{
+			currentState = "Normal"
+		}
+		public function showCharacterLimit():void
+		{
+			// Show character limit box if enabled
+			if (characterLimitVisible && characterLimit > 0)
+			{
+				currentState = "ShowCharsLeft"
+			}
+		}
+		protected function updateWordCount():void
+		{
+			var txt:String = StringUtil.trim(text);
+			_wordCount = (txt && txt.length > 0) ? txt.split(/\s+/g).length : 0;
+		}
+		protected function onTextInput(event:TextEvent):void
+		{
+			var str:String = event.text;
+		}
+		protected function onMainFieldCreationComplete():void
+		{
+			for (var i:int = 0; i < _pendingProperties.length; i++)
+			{
+				mainField[_pendingProperties[i].property] = _pendingProperties[i].arg;
+			}
+			// initially hide word and char count
+			hideCharacterLimit();
+		}
+		/**
+		 * Detects mousewheel events and propagates them if there's no scrolling to do
+		 **/
+		public function onMouseWheel(event:MouseEvent):void
+		{
+			if (_isPlaceholder)
+			{
+				dispatchEvent(event);
+				return;
+			}
+			//If scrolling down
+			if (event.delta > 0)
+			{
+				if (mainField.verticalScrollPosition == mainField.maxVerticalScrollPosition)
+				{
+					dispatchEvent(event);
+				}
+			}
+			//If scrolling up
+			else if (event.delta < 0)
+			{
+				if (mainField.verticalScrollPosition == 0)
+				{
+					dispatchEvent(event);
+				}
+			}
+		}
+		public function onChange():void
+		{
+			// update input field
+			setData(data, text);
+			updateWordCount();
+			updateCharacterLimit();
+			updateBackgroundColor();
+			setTextStyle(TEXTSTYLE_NORMAL);
+			dispatchEvent(new Event(Event.CHANGE, true));
+			QuestionAnswerDataGrid(parent.parent).dispatchEvent(new Event(FlexEvent.DATA_CHANGE));
+			if (onChangeCallback != null)
+			{
+				onChangeCallback.call(this);
+			}
+		}
+		public function onFocusIn():void
+		{
+			//If there is sample text, remove it and change to normal font
+			if (!text.length)
+			{
+				mainField.text = "";
+			}
+			// prevent dragging when we might want to be selecting text
+			dispatchEvent(new Event(QuestionAnswerDataGrid.DISABLE_DRAGGING, true));
+			showCharacterLimit();
+		}
+		public function onFocusOut():void
+		{
+			// make sure we can drag again as soon as we click out
+			dispatchEvent(new Event(QuestionAnswerDataGrid.ENABLE_DRAGGING, true));
+			hideCharacterLimit();
+		}
+		/**
+		 * Sets properties in mainField. If mainField has not yet been
+		 * created, property is set on creation complete for mainField.
+		 */
+		public function setTextFieldProperty(property:String, arg:*):void
+		{
+			if (mainField != null)
+			{
+				mainField[property] = arg;
+			}
+			else
+			{
+				_pendingProperties.push({property:property, arg:arg});
+			}
+		}
+		public function setTextStyle(textStyle:int):void
+		{
+			switch (textStyle)
+			{
+				case TEXTSTYLE_NORMAL:
+					if (_currentTextStyle != TEXTSTYLE_NORMAL)
+					{
+						_currentTextStyle = TEXTSTYLE_NORMAL;
+						mainField.setStyle('fontStyle', 'normal');
+						mainField.setStyle('color', '0');
+					}
+					break;
+				case TEXTSTYLE_LIGHT:
+					if (_currentTextStyle != TEXTSTYLE_LIGHT)
+					{
+						_currentTextStyle = TEXTSTYLE_LIGHT;
+						mainField.setStyle('fontStyle', 'normal');
+						mainField.setStyle('color', '0x999999');
+					}
+					break;
+			}
+		}
+		]]>
+	</mx:Script>
+	<mx:HBox bottom = "0"
+			 left = "5"
+			 fontSize = "10"
+			 paddingBottom = "0"
+			 paddingLeft = "0"
+			 paddingRight = "0"
+			 paddingTop = "0" id="hbox1">
+	<mx:Text id = "subtitleText"
+			 text = "{_wordCount} Words"
+			 selectable = "false" />
+	<mx:Text id = "characterCount"
+			 text = "{_wordCount} Characters Remain"
+			 selectable = "false"/>
+	</mx:HBox>
+</mx:Canvas>

data/lib/mako/data/flash_widget_dev_core/src/materia/components/questionAnswerDataGrid/TextInputObject.as

@@ -0,0 +1,28 @@
+package materia.components.questionAnswerDataGrid
+{
+	import materia.questionStorage.Question;
+public dynamic class TextInputObject
+{
+	public var stealFocus:Boolean;
+	[Bindable]
+	public var rowIndex:int;
+	public var question:Question;
+	public var imported:Boolean;
+	public var importModified:Boolean;
+	public function TextInputObject(stealFocus:Boolean, rowIndex:int, question:Question, imported:Boolean, importModified:Boolean)
+	{
+		this.stealFocus = stealFocus;
+		this.rowIndex = rowIndex;
+		this.question = question;
+		this.imported = imported;
+		this.importModified = importModified;
+	}
+	/**
+	 * Override question's valid method in a widget specific extended question class
+	 **/
+	public function hasErrors():Boolean
+	{
+		return !question.valid();
+	}
+}
+}