mako 0.0.0

data/lib/mako/data/flash_widget_dev_core/src/nm/ui/ScrollClip.as

@@ -0,0 +1,468 @@
+/* See the file "LICENSE.txt" for the full license governing this code. */
+package nm.ui{
+	import flash.display.Sprite;
+	import flash.events.Event;
+	import flash.geom.Rectangle;
+	public class ScrollClip extends Component {
+		private var content_mc:Sprite;
+		private var background_mc:Sprite;
+		private var scrollarea_mc:Sprite;
+		private var corner_mc:Sprite;
+		private var vert_sb:ScrollBar;
+		private var horz_sb:ScrollBar;
+		private var maskRect:Rectangle;
+		private var autoHide:Boolean;
+		private var drawVertSb:Boolean;
+		private var drawHorzSb:Boolean;
+		private var mouseWheelEnabled:Boolean;
+		private var stickToBottom:Boolean;
+		private var stickToRight:Boolean;
+		private var _hScrollEnabled:Boolean;
+		private var _vScrollEnabled:Boolean;
+		/**
+		* ScrollClip creates a Sprite and then masks it, as well as adds scrollbars to provide user fuctionality to move the viewing window.
+		* After creating a new ScrollClip object, you should get ScrollClip.clip to get a reference to the content Sprite that is being masked
+		* by ScrollClip.
+		* @param	width		Number. The width of the viewing area window.
+		* @param	height		Number. The height of the viewing area window.
+		* @param	autoRedraw	Boolean. Default false. Auto-calls redraw() on width and height changes.
+		* @param	autoHide	Boolean. Default true. If true, scrollbars are not displayed when not necessary, otherwise, scrollbars are always displayed.
+		*/
+		//function ScrollClip(target_mc:Sprite, instName:String, depth:Number, x:Number, y:Number, width:Number, height:Number, autoRedraw:Boolean, autoHide:Boolean) {
+		public function ScrollClip(width:Number, height:Number, autoRedraw:Boolean, autoHide:Boolean=true)
+		{
+			super(autoRedraw, width, height);
+			////trace("****************SCROLLCLIP CONSTRUCTOR");
+			//addEventListener("mouseMove", function(e:*):void {////trace("MOVED:::");});
+			this.autoHide = autoHide;
+			drawVertSb = drawHorzSb = ! this.autoHide;
+			mouseWheelEnabled = true;
+			content_mc = new Sprite(); // this was in draw,
+			content_mc.addEventListener(Event.ADDED, onAddToClip, false, 0, true);
+			//scroll bars are enabled by default
+			_vScrollEnabled = true;
+			_hScrollEnabled = true;
+			// moving this here so we can add content before draw is called
+			maskRect = new Rectangle(x, y, width, height); // moving this here too
+		}
+		/**
+		* Creates the Sprites needed.  This is automatically called when this class is created.
+		*/
+		public override function draw():void
+		{
+			super.draw();
+			//comp_mc = target_mc.createEmptySprite("comp", depth);
+			background_mc = new Sprite(); addChild(background_mc);//this.createEmptySprite("background", -1);
+			scrollarea_mc = new Sprite(); addChild(scrollarea_mc);//this.createEmptySprite("scrollarea", 0);
+			scrollarea_mc.addChild(content_mc); //scrollarea_mc.createEmptySprite("content", 0);
+			maskRect = new Rectangle(x, y, width, height);
+			drawBackground();
+			drawScrollBars();
+			drawCorner();
+			positionScrollBars();
+			applyMask();
+			redraw();
+		}
+		public function drawBackground():void
+		{
+			background_mc.graphics.clear();
+			//Rect.draw(background_mc, 0, 0, width, height, getStyle("bgFill"), getStyle("bgAlpha"));
+			background_mc.graphics.beginFill(getStyle("bgFill"), getStyle("bgAlpha"));
+			background_mc.graphics.drawRect(0, 0, width, height);
+		}
+		private function drawCorner():void
+		{
+			corner_mc = new Sprite(); addChild(corner_mc);//this.createEmptySprite("corner", 1);
+			var sbWidth:Number  = getStyle("sbWidth")
+			//Rect.draw(corner_mc, 0, 0, sbWidth, sbWidth, vert_sb.getStyle("sliderColor"), 100);
+			corner_mc.graphics.beginFill(vert_sb.getStyle("sliderColor"));
+			corner_mc.graphics.drawRect(0, 0, sbWidth, sbWidth);
+		}
+		private function drawScrollBars():void
+		{
+			var sbWidth:Number = getStyle("sbWidth");
+			vert_sb = new ScrollBar(sbWidth, _height - sbWidth, content_mc.height - sbWidth, maskRect.height - sbWidth, y, false);
+			addChild(vert_sb);
+			horz_sb = new ScrollBar(sbWidth, _width - sbWidth, content_mc.width - sbWidth, maskRect.width - sbWidth, x, true);
+			addChild(horz_sb);
+			vert_sb.wheelEnabled = mouseWheelEnabled;
+			vert_sb.addEventListener("scroll", onVertScroll);
+			horz_sb.addEventListener("scroll", onHorzScroll);
+		}
+		private function positionScrollBars():void
+		{
+			var sbWidth:Number = getStyle("sbWidth")
+			vert_sb.x = width - sbWidth;
+			horz_sb.y = height - sbWidth;
+			horz_sb.x = 0;
+			if(drawVertSb && drawHorzSb) {
+				corner_mc.visible = true;
+				corner_mc.x = width - sbWidth;
+				corner_mc.y = height - sbWidth;
+			} else {
+				corner_mc.visible = false;
+			}
+		}
+		private function onAddToClip(e:Event):void
+		{
+			if(vert_sb != null && stage != null)
+			{
+				update();
+			}
+		}
+		private function onVertScroll(evt:*):void {
+			var p:Number = evt.result;
+			var t:Number = content_mc.height - maskRect.height;
+			if(drawHorzSb) t += getStyle("sbWidth");
+			maskRect.y = t * p / 100;
+			applyMask();
+			dispatchEvent(new Event('vScroll'));//dispatchEvent({type:"vScroll", target:this, result:p});
+		}
+		private function onHorzScroll(evt:*):void {
+			var p:Number = evt.result;
+			var t:Number = content_mc.width - maskRect.width;
+			if(drawVertSb) {
+				t += getStyle("sbWidth");
+				//t += sbWidth * 2;
+			}
+			maskRect.x = t * p / 100;
+			applyMask();
+			dispatchEvent(new Event("hScroll")); //dispatchEvent({type:"hScroll", target:this, result:p});
+		}
+		private function applyMask():void
+		{
+			scrollarea_mc.scrollRect = maskRect;
+		}
+		/**
+		* Resizes the mask window, as well as repositions and resizes the scrollbars.
+		*/
+		public override function redraw():void {
+			// make sure draw was called before redrawing
+			if(background_mc == null) {
+				return;
+			}
+			//redraw background:
+			drawBackground();
+			var vertLen:Number = maskRect.height;
+			var horzLen:Number = maskRect.width;
+			if(drawHorzSb) vertLen -= getStyle("sbWidth");
+			if (drawVertSb) horzLen -= getStyle("sbWidth");
+			if(autoHide) {
+				// check to see if the content is too tall
+				if (vertLen < content_mc.height && _vScrollEnabled == true) {
+					drawVertSb = true;
+					if(vert_sb.visible == false) {
+						vert_sb.wheelEnabled = mouseWheelEnabled;
+						vert_sb.visible = true;
+					}
+				} else {
+					drawVertSb = false;
+					horzLen = maskRect.width;
+					if(vert_sb.visible == true) {
+						vert_sb.wheelEnabled = false;
+						vert_sb.visible = false;
+					}
+				}
+				// check to see if the content is too wide
+				if(horzLen < content_mc.width && _hScrollEnabled == true) {
+					drawHorzSb = true;
+					if(horz_sb.visible == false) horz_sb.visible = true;
+				} else {
+					drawHorzSb = false;
+					if(horz_sb.visible == true) horz_sb.visible = false;
+					vertLen = maskRect.height;
+				}
+			}
+			vert_sb.totalLines = content_mc.height;
+			horz_sb.totalLines = content_mc.width;
+			vert_sb.height = vertLen;
+			horz_sb.height = horzLen;
+			if (horz_sb.visible) vert_sb.height -= getStyle("sbWidth");
+			if (vert_sb.visible) horz_sb.height -=  getStyle("sbWidth");
+			positionScrollBars();
+			applyMask();
+			vert_sb.linesPerPage = vertLen;
+			horz_sb.linesPerPage = horzLen;
+			if(vertLen + maskRect.y >= content_mc.height) {
+				stickToBottom = true;
+			} else {
+				stickToRight = false;
+			}
+			if(horzLen + maskRect.x >= content_mc.width) {
+				stickToRight = true;
+			} else {
+				stickToRight = false;
+			}
+			if(stickToBottom) {
+				maskRect.y = content_mc.height - maskRect.height + (drawHorzSb ? getStyle("sbWidth") : 0);
+				if(vertLen >= content_mc.height) {
+					stickToBottom = false;
+					maskRect.y = 0;
+					vert_sb.scroll = 0;
+				}
+			}
+			if(stickToRight) {
+				maskRect.x = content_mc.width - maskRect.width + (drawVertSb ? getStyle("sbWidth") : 0);
+				if(horzLen >= content_mc.width) {
+					stickToRight = false;
+					maskRect.x = 0;
+					horz_sb.scroll = 0;
+				}
+			}
+		}
+		/*/**
+		* Redraws the content and content mask, but does not draw the scrollbars.
+		*/
+	/*	public function redrawNoScrollBars():void {
+			//redraw background:
+			drawBackground();
+			applyMask();
+		}*/
+		/**
+		* The scrollbars do not automatically update when the contents of the masked Sprite change.
+		* Therefore, you should call update()
+		* when the contents of the Sprite change.
+		*/
+		public function update():void {
+			vert_sb.totalLines = content_mc.height;
+			horz_sb.totalLines = content_mc.width;
+			redraw();
+		}
+		/**
+		 *  Hide scroll bars
+		 */
+		public function hideScrollBars():void {
+			vert_sb.visible = false;
+			horz_sb.visible = false;
+		}
+		/**
+		 *  Unhide scroll bars
+		 */
+		public function showScrollBars():void {
+			vert_sb.visible = true;
+			horz_sb.visible = true;
+		}
+		/**
+		* Sets the x position of the maksed Sprite.
+		* @param	percent		Number. 0 is the far left, 100 is the far right.
+		*/
+		public function setHScroll(percent:Number):void {
+			horz_sb.scroll = percent;
+		}
+		/**
+		* @return	Percentage (0-100) of the x position of the masked Sprite.
+		*/
+		public function getHScroll():Number {
+			if(drawHorzSb) return horz_sb.scroll;
+			return 0;
+		}
+		/**
+		* Sets the y position of the maksed Sprite.
+		* @param	percent		Number. 0 is the top, 100 is the bottom.
+		*/
+		public function setVScroll(percent:Number):void {
+			vert_sb.scroll = percent;
+		}
+		/**
+		* @return	Percentage (0-100) of the y position of the masked Sprite.
+		*/
+		public function getVScroll():Number {
+			if(drawVertSb) return vert_sb.scroll;
+			return 0;
+		}
+		protected override function styleDefaults():void {
+			setStyle("bgFill", 0x9b9b9b);
+			setStyle("bgAlpha", .55);
+			setStyle("sbWidth", 14);
+		}
+		public function objectIsScrollBar(obj:*):Boolean
+		{
+			// returns true if the passed object is part of the scrollbars
+			if (vert_sb == obj) return true;
+			if (horz_sb == obj) return true;
+			if (corner_mc == obj) return true;
+			if (checkChildren(obj, vert_sb)) return true;
+			if (checkChildren(obj, horz_sb)) return true;
+			return false;
+		}
+		private function checkChildren(obj:*, curParent:*):Boolean
+		{
+			for (var i:int = 0; i < curParent.numChildren; i++)
+			{
+				if (curParent.getChildAt(i) == obj){
+					return true;
+				}
+				else if( curParent.getChildAt(i).hasOwnProperty("getChildAt"))
+				{
+					if (containsContent(obj, curParent.getChildAt(i))){
+						return true
+					}
+				}
+			}
+			return false;
+		}
+		public function containsContent(obj:*, p:* = null):Boolean{ // this function will probably not be needed
+			if (p == null) p = clip;
+			if (p == obj) return true;
+			if (checkChildren(obj, p)) return true;
+			return false;
+		}
+		public override function destroy():void
+		{
+			vert_sb.destroy();
+			horz_sb.destroy();
+			super.destroy();
+		}
+		/**
+		* Sets the width of the scrollbars (by default this is 10).
+		* @param	val		Number.
+		*/
+		public function set scrollBarSize(val:Number):void {
+			setStyle("sbWidth", val);
+			vert_sb.width = horz_sb.width = val;
+			positionScrollBars();
+			drawCorner();
+		}
+		/**
+		* @return	Number. Size of scrollbars.
+		*/
+		public function get scrollBarSize():Number {
+			return getStyle("sbWidth");
+		}
+		/**
+		* @return	Number. Size of scrollbars.
+		*/
+		public function get horizScrollBar():Sprite {
+			return horz_sb;
+		}
+		/**
+		* @return	Number. Size of scrollbars.
+		*/
+		public function get vertScrollBar():Sprite {
+			return vert_sb;
+		}
+		/**
+		* @param	val		Boolean. If true then you can use the mouse wheel to move the viewing window vertically.  By default this is false.
+		*/
+		public function set wheelEnabled(val:Boolean):void {
+			vert_sb.wheelEnabled = mouseWheelEnabled = val;
+		}
+		/**
+		* @return	If the mouse wheel is enabled or not for vertical scrolling.
+		*/
+		public function get wheelEnabled():Boolean {
+			return mouseWheelEnabled;
+		}
+		/**
+		* @return vert_sb
+		*/
+		public function get showVertScrollBar():Boolean {
+			return drawVertSb;
+		}
+		/**
+		* @return horz_sb
+		*/
+		public function get showHorizScrollBar():Boolean {
+			return drawHorzSb;
+		}
+		/**
+		* You will need to get this value after creating a new ScrollClip object.
+		* @return	Reference to the content Sprite.
+		*/
+		public function get clip():Sprite {
+			return content_mc;
+		}
+		/**
+		* Sets the width of the viewing window.
+		* @param	val
+		*/
+		public override function set width(val:Number):void {
+			maskRect.width = _width = val;
+			//if(_autoRedraw) redraw();
+			//maskRect.width = val;
+			super.width = val;
+		}
+		/**
+		* Sets the height of the viewing window.
+		* @param	val
+		*/
+		public override function set height(val:Number):void {
+			maskRect.height = _height = val;
+			//if(_autoRedraw) redraw();
+			//maskRect.height = val;
+			super.height = val;
+		}
+		/**
+		* @return	Width of the viewing window.
+		*/
+		public override function get width():Number {
+			return _width;
+		}
+		/**
+		* @return	Height of the viewing window.
+		*/
+		public override function get height():Number {
+			return _height;
+		}
+		/**
+		* Sets the vertical scroll rate.
+		* @param	val			Number. Represents the rate % of scroll per viewing window.  If set to 100, every mouse click will move the window
+		* 						by one viewing-window (Similar effect to PageUp or PageDown on a keyboard).
+		*/
+		public function set vScrollRate(val:Number):void {
+			vert_sb.scrollByPercent = val;
+		}
+		/**
+		* @return	The vertical scroll rate.
+		*/
+		public function get vScrollRate():Number {
+			return vert_sb.scrollByPercent;
+		}
+		/**
+		* Sets the horizontal scroll rate.
+		* @param	val			Number. Represents the rate % of scroll per viewing window.  If set to 100, every mouse click will move the window
+		* 						by one viewing-window (Similar effect to PageUp or PageDown on a keyboard).
+		*/
+		public function set hScrollRate(val:Number):void {
+			horz_sb.scrollByPercent = val;
+		}
+		public function get vScroll():Number {
+			return getVScroll();
+		}
+		public function set vScroll(val:Number):void {
+			setVScroll(val);
+		}
+		public function get hScroll():Number {
+			return getHScroll();
+		}
+		public function set hScroll(val:Number):void {
+			setHScroll(val);
+		}
+		/**
+		* @return	The horizontal scroll rate.
+		*/
+		public function get hScrollRate():Number {
+			return horz_sb.scrollByPercent;
+		}
+		public function get vScrollActive():Boolean {
+			return drawVertSb;
+		}
+		public function get hScrollActive():Boolean {
+			return drawHorzSb;
+		}
+		public function set hScrollEnabled(val:Boolean):void {
+			_hScrollEnabled = val;
+		}
+		public function set vScrollEnabled(val:Boolean):void {
+			_vScrollEnabled = val;
+		}
+		/*public function set _contentArea(w:Number, h:Number){
+		}*/
+		public function get _contentArea():Object
+		{
+			var space:Number = getStyle('borderSpacing');
+			var temp:Object = { w:(width - vert_sb.width), h:(height - horz_sb.width) };
+			return temp;
+		}
+	}
+}

data/lib/mako/data/flash_widget_dev_core/src/nm/ui/ScrollText.as

@@ -0,0 +1,29 @@
+/* See the file "LICENSE.txt" for the full license governing this code. */
+package nm.ui
+{
+	import nm.ui.ScrollText_base
+	import flash.text.TextFormat;
+	public class ScrollText extends ScrollText_base
+	{
+		public function ScrollText(width:Number, height:Number, text:String = "", textFormat:TextFormat = null)
+		{
+			super(width, height, text, textFormat);
+		}
+		protected override function styleDefaults():void{
+			super.styleDefaults();
+			setStyle('bgAlpha', 1);
+			setStyle('bgColor', 0xFFFFFF)
+			setStyle('frameColor', 0x000000);
+		}
+		protected override function drawBG():void
+		{
+			graphics.clear();
+			if(getStyle('showBorder'))
+			{
+				graphics.lineStyle(getStyle('frameW'), getStyle('frameColor'));
+				graphics.beginFill(getStyle('bgColor'), getStyle('bgAlpha'));
+				graphics.drawRect(0, 0, width, height);
+			}
+		}
+	}
+}