mako 0.0.0

data/lib/mako/data/flash_widget_dev_core/src/nm/gameServ/common/Question.as

@@ -0,0 +1,72 @@
+/* See the file "LICENSE.txt" for the full license governing this code. */
+package nm.gameServ.common
+{
+	import nm.util.Objects;
+	public class Question
+	{
+		public static const MC_QUESTION:String = "MC";
+		public static const QA_QUESTION:String = "QA";
+		public static const SO_QUESTION:String = "SO";
+		public var id:Number;
+		public var type:String;
+		public var questions:Array;
+		public var answers:Array;
+		public var options:Object;
+		public var assets:Array = [];
+		public function Question(type:String = QA_QUESTION, options:Object = null, id:Number = 0){
+			this.type = type
+			this.id = id;
+			questions = new Array();
+			answers = new Array();
+			this.options = options == null? new Object() : options;
+		}
+		public function addQItem(text:String, options:Object):void{
+			questions.push(constructNewItem(text, options));
+		}
+		public function addAItem(text:String, options:Object, value:Number = undefined):void{
+			answers.push(constructNewItem(text, options, value));
+		}
+		/*
+		 * TODO: What should be the default value for value
+		 */
+		private function constructNewItem(text:String, options:Object, value:Number = NaN):Object{
+			var newItem:Object = new Object();
+			newItem.options = new Object();
+			for(var i:String in options) newItem.options[i] = options[i];
+			newItem.text = text;
+			if(!isNaN(value)){
+				if(value >= 0 && value <=  100) newItem.value = value
+				else newItem.value = value
+			}
+			return newItem;
+		}
+		public function addOption(name:String, value:Number):void{
+			options[name] = value;
+		}
+		public function clone():Question{
+			var clone:Question = new Question(type, null, id);
+			var i:String;
+			for(i in options){
+				clone.options[i] = options[i];
+			}
+			for(i in answers){
+				clone.answers[i] = answers[i];
+			}
+			for(i in questions){
+				clone.questions[i] = questions[i];
+			}
+			return clone;
+		}
+		public static function convertObject(obj:Object):Question
+		{
+			var q:Question = new Question();
+			if(obj.questions != null) q.questions = obj["questions"];
+			if(obj.answers != null) q.answers = obj["answers"];
+			if( obj["assets"] ) q.assets = Objects.copyArray(obj["assets"]);
+			if( obj["options"] ) q.options = Objects.copyObject(obj["options"]);
+			q.id = obj["id"];
+			q.type = obj["type"];
+			return q;
+		}
+	}
+}

data/lib/mako/data/flash_widget_dev_core/src/nm/gameServ/common/QuestionGroup.as

@@ -0,0 +1,87 @@
+/* See the file "LICENSE.txt" for the full license governing this code. */
+package nm.gameServ.common
+{
+	public class QuestionGroup
+	{
+		public var items:Array
+		public var name:String
+		public var options:Object
+		public var id:Number
+		public var rand:Boolean
+		public var assets:Array = [];
+
+		public function QuestionGroup(name:String, random:Boolean = false, id:Number = 0)
+		{
+			this.name = name
+			items = new Array();
+			options = new Object();
+			this.rand = false;
+			this.id = id
+		}
+
+		public function addGroup(name:*, index:Number):QuestionGroup 
+		{
+			var newGroup:QuestionGroup = (name is QuestionGroup) ? name : new QuestionGroup(name);
+			if(index > 0) items.splice(index, 0, newGroup) // index sent, so splice group into the array
+			else items.push(newGroup); // no index so push onto the array
+			return newGroup;
+		}
+
+		public function removeGroup(index:Number):QuestionGroup
+		{
+			if(items[index] is QuestionGroup) return items.splice(index, 1)[0];
+			return null;
+		}
+
+		public function addQuestion(type:String, Qtext:String, Atext:String, options:Object, Qoptions:Object, Aoptions:Object, index:Number):Question
+		{
+			var q:Question = new Question(type, options);
+			q.addQItem(Qtext, Qoptions)
+			q.addAItem(Atext, Aoptions)
+			items.push(q);
+			return q
+		}
+
+		public function removeQuestion(index:Number):Question
+		{
+			if(items[index] is Question) return items.splice(index, 1)[0];
+			return null;
+		}
+
+		public function getChild(index:Number):Object
+		{
+			return items[index];
+		}
+
+		public function addOption(name:String, value:Number):void
+		{
+			options[name] = value;
+		}
+
+		public static function convertObject(obj:Object):QuestionSet
+		{
+			var qset:QuestionSet = new QuestionSet("", false, 0);
+			qset.name = obj.name;
+			qset.items = obj.items;
+			qset.id = obj.id;
+			qset.options = obj.options;
+			qset.rand = obj.rand;
+			qset.assets = obj.assets;
+			return qset;
+		}
+
+		public function clone():QuestionGroup
+		{
+			var clone:QuestionGroup = new QuestionGroup(name, rand, id);
+			for(var i:String in options)
+			{
+				clone.options[i] = options[i];
+			}
+			for(var j:String in items)
+			{
+				clone.items[j] = items[j].clone();
+			}
+			return clone;
+		}
+	}
+}

data/lib/mako/data/flash_widget_dev_core/src/nm/gameServ/common/QuestionSet.as

@@ -0,0 +1,35 @@
+/* See the file "LICENSE.txt" for the full license governing this code. */
+package nm.gameServ.common
+{
+	public class QuestionSet extends QuestionGroup
+	{
+		public function QuestionSet(name:String = "", random:Boolean = false, id:Number = 0)
+		{
+			super(name, random, id);
+		}
+
+		override public function addQuestion(type:String, Qtext:String, Atext:String, options:Object, Qoptions:Object, Aoptions:Object, index:Number):Question
+		{
+			return null;
+		}
+
+		public static function convertObject(obj:Object):QuestionSet
+		{
+			return QuestionSet(QuestionGroup.convertObject(obj));
+		}
+
+		public override function clone():QuestionGroup
+		{
+			var clone:QuestionSet = new QuestionSet(name, rand, id);
+			for(var i:String in items)
+			{
+				clone.items[i] = items[i].clone();
+			}
+			for(var j:String in options)
+			{
+				clone.options[j] = options[j];
+			}
+			return clone;
+		}
+	}
+}

data/lib/mako/data/flash_widget_dev_core/src/nm/gameServ/common/WidgetSettings.as

@@ -0,0 +1,14 @@
+package nm.gameServ.common {
+	public class WidgetSettings
+	{
+		public var title:String = "";
+		public var scoreType:String;
+		public static function convertFromObject(settings:Object):WidgetSettings
+		{
+			var result:WidgetSettings = new WidgetSettings();
+			if(settings.name) result.title = settings.name;
+			if(settings.widget.score_type) result.scoreType = settings.widget.score_type;
+			return result;
+		}
+	}
+}

data/lib/mako/data/flash_widget_dev_core/src/nm/gameServ/common/coms/ServerEvents.as

@@ -0,0 +1,17 @@
+/* See the file "LICENSE.txt" for the full license governing this code. */
+package nm.gameServ.common.coms
+{
+	public class ServerEvents
+	{
+		public static var ERROR:String = "error";
+		public static var RECEIVE_MESSAGE:String = "onMsg";
+		public static var CHECK_LOGIN:String = "onCheckLogin";
+		//public static var PROCESS_START:String = "procStart";
+		//public static var PROCESS_END:String = "procEnd";
+		public static const PROCESS_START:String = "procStart";
+		public static const PROCESS_END:String = 'procEnd';
+		public function ServerEvents() {
+			//This class is meant to hold static vars only
+		}
+	}
+}

data/lib/mako/data/flash_widget_dev_core/src/nm/gameServ/common/coms/ServerMessageEvent.as

@@ -0,0 +1,31 @@
+/* See the file "LICENSE.txt" for the full license governing this code. */
+// Copyright (c) 2007 rubyamf.org (aaron@rubyamf.org)
+// License - http://www.gnu.org/copyleft/gpl.html
+package nm.gameServ.common.coms
+{
+	import flash.events.Event;
+	/*
+	 * ResultEvent - stores results of a service call
+	 */
+	public class ServerMessageEvent extends Event {
+		public static const SERVER_MESSAGE:String = 'srvMsg';
+		public var message:String;
+		public var messageType:int;
+		/**
+		 *
+		 * @param	message	String Message recieved from server
+		 */
+		public function ServerMessageEvent(message:String, messageType:int=0){
+			super(SERVER_MESSAGE);
+			this.message = message;
+			this.messageType = messageType
+		}
+		/*
+		 * toString - duh
+		 */
+		public override function toString():String
+		{
+			return "nm.gameServ.common.coms.ServerMessageEvent";
+		}
+	}
+}

data/lib/mako/data/flash_widget_dev_core/src/nm/gameServ/common/logging/Log.as

@@ -0,0 +1,92 @@
+/* See the file "LICENSE.txt" for the full license governing this code. */
+/**
+* A basic structure object representing a log item.
+*/
+package nm.gameServ.common.logging
+{
+public class Log
+{
+	/* System Events */
+	public static const GAME_START:int = 1;
+	public static const GAME_END:int = 2;
+	public static const GAME_PAUSE:int = 3;
+	public static const GAME_RESTART:int = 4;
+	public static const ASSET_LOADING:int = 5;
+	public static const ASSET_LOADED:int = 6;
+	public static const FRAMEWORK_INITIALIZE:int = 7;
+	public static const PLAYID_REQUESTED:int = 8;
+	public static const PLAYID_CREATED:int = 9;
+	public static const GAME_UNPAUSED:int = 10;
+	public static const PROCESSING:int = 11;
+	public static const FINISHED_PROCESSING:int = 12;
+	public static const LOGGING_IN:int = 13;
+	public static const APPLYING_THEME:int = 14;
+	public static const GAME_STATE_CHANGED:int = 15;
+	public static const GAME_INITIALIZED:int = 16;
+	/* In-Widget User Events */
+	public static const KEY_PRESSED:int = 500;
+	public static const ITEM_SELECTED:int = 501;
+	public static const ITEM_DRAGGED:int = 502;
+	public static const ITEM_DROPPED:int = 503;
+	public static const TEXT_ENTERED:int = 504;
+	public static const TEXT_EDITED:int = 505;
+	public static const BUTTON_CLICKED:int = 506;
+	public static const VIEW:int = 507;
+	/* Scoring and Reporting */
+	public static const WIDGET_INTERACTION_UNSCORED:int = 1001;
+	public static const FINAL_SCORE_FROM_CLIENT:int = 1002;
+	public static const QUESTION_ANSWERED_UNSCORED:int = 1004;
+	public static const SCORE_FEEDBACK:int = 1008;             // attaches a feedback message to a question (or game if qid is 0)
+	public static const SCORE_ALERT:int = 1009;                // shows a popup at the score screen
+	/*
+	SCORE_ALERT - brigns up popopu
+	SCORE_FEEDBACK - adds bubble to grid view brings up message box
+	*/
+	/* Errors */
+	public static const GENERAL_ERROR:int = 1500;
+	public static const ASSET_NOT_FOUND:int = 1501;
+	public static const LOGIN_FAILURE:int = 1502;
+	public static const SESSION_HIJACK_ATTEMPT:int = 1503;
+	public static const NOT_LOGGED_IN:int = 1504;
+	public static const TIME_OUT:int = 1505;
+	public static const THEME_OJBECT_MISSING:int = 1506;
+	public static const QUESTION_CORRECT_REPORTED_INCORRECTLY:int = 1507;
+	public static const REPORTED_SCORE_DOESNT_MATCH_VERIFIED_SCORE:int = 1508;
+	public static const TIME_VALIDATION_FAILED:int = 1509;
+	public static const QUESTION_NOT_SCORED:int = 1510;
+	public var type:Number
+	public var identity:Number
+	public var text:String
+	public var value:String
+	public var serverTime:Number
+	public var gameTime:Number
+	// this is used to mark this as a log that should be encrypted
+	public var encrypt:Boolean;
+	/**
+	* Create a new log
+	* @param type Numeric type of log
+	* @param text Text descriptor
+	* @param value Value of log
+	* @param gameTime Time stamp of the current game time
+	* @param vis visibility level
+	*/
+	public function Log(type:Number, identity:Number, text:String, value:String, gameTime:Number):void
+	{
+		this.type = type;
+		this.text = text;
+		this.identity = identity;
+		this.value = value;
+		this.gameTime = gameTime;
+		this.encrypt = false;
+	}
+	// return an object with that data needed to send this log to the server
+	public function getObject():Object
+	{
+		return {type:type, identity:identity, text:text, value:value, serverTime:serverTime, gameTime:gameTime};
+	}
+	public function toString():String
+	{
+		return "type: " + type + ' identity: ' + identity + ' text: ' + text + ' value: ' + value + ' gametime: ' + gameTime
+	}
+}
+}

data/lib/mako/data/flash_widget_dev_core/src/nm/gameServ/common/scoring/Scoring.as

@@ -0,0 +1,87 @@
+/* See the file "LICENSE.txt" for the full license governing this code. */
+package nm.gameServ.common.scoring {
+import nm.errors.ScoringError;
+import nm.gameServ.common.logging.Log;
+import nm.gameServ.engines.EngineCore;
+import nm.ui.AlertWindow;
+public class Scoring
+{
+	/**
+	 * A reference to the EngineCore. Used as a channel to send logs to the server.
+	 */
+	private var _core:EngineCore;
+	/**
+	 * The score type for this widget as retrieved from the database table gs_gameregistry->GR_ScoreType
+	 */
+	// private var _scoreType:String;
+	/**
+	 * Constructor for Scoring Class
+	 */
+	public function Scoring(core:EngineCore, scoreType:String):void
+	{
+		_core = core;
+		// _scoreType = scoreType;
+	}
+
+	/**
+	 * Widget interactions are a catch-all category for any (logged) widget activity that isn't
+	 * categorized as an answered question or final score.
+	 * It's up to the score module to make sense of the interaction and grade the widget appropriately.
+	 * Examples include an individual question modifier (hint used, -50%), an overall score modifier (-20% to final score), or more esoteric cases.
+	 *
+	 * @param questionID the ID of the question associated with this interaction, if applicable. The score module can ignore it for cases where it doesn't apply.
+	 * @param interactionType a string identifying what the interaction is, e.g.: 'hint_used', 'attempt_penalty', etc.
+	 * @param value the value of the interaction, if applicable.
+	 */
+
+	public function submitInteractionForScoring(questionID:String, interactionType:String, value:String = ''):void
+	{
+		_core.addLog(Log.WIDGET_INTERACTION_UNSCORED, questionID, interactionType, value);
+	}
+
+	/**
+	 * A final score submission from the client.
+	 * In some situations, a widget may not pass back logs for individual questions/interactions, and only pass back a final score.
+	 * For example, perhaps the widget scores on the client side and only provides the score.
+	 *
+	 * @param questionID if the final score is being determined by an individual question, its ID can be used here. Otherwise, just use 0.
+	 * @param userAnswer if the final score is determined based on a user's answer. Can be an empty string otherwise.
+	 * @param score the final score to return.
+	 */
+
+	public function submitFinalScoreFromClient(questionID:String, userAnswer:String, score:String = ''):void
+	{
+		_core.addLog(Log.FINAL_SCORE_FROM_CLIENT, questionID, userAnswer, score);
+	}
+
+	/**
+	 * An answered question submission.
+	 * This is the most basic log type. Used in most ordinary responses for individual questions.
+	 * @param questionID the ID of the question being answered
+	 * @param userAnswer the response the user provided. This string is matched against the widget's QSET on the server to determine the correct answer.
+	 * @param value the value isn't by default used to determine the score of the question, however it can be used to pass an additional value to be used in scoring.
+	 */
+
+	public function submitQuestionForScoring(questionID:String, userAnswer:String, value:String = ''):void
+	{
+		_core.addLog(Log.QUESTION_ANSWERED_UNSCORED, questionID, userAnswer, value);
+	}
+
+	/**
+	 * Adds a message/feedback to the overall score screen
+	 */
+	public function addGlobalScoreFeedback(msg:String):void
+	{
+		_core.addLog(Log.SCORE_FEEDBACK, '0', msg);
+	}
+	/**
+	 * @private
+	 * Throws an error and shows a popup whenever a function is used out of place
+	 */
+	private function error(fn:String, requiredScoreType:String):void
+	{
+		_core.alert("Scoring Error", "An error has occurred with the scoring of this widget. Please refresh and try again. If the problem persists, notify your instructor or contact an instructional designer.", AlertWindow.OK);
+		// throw new ScoringError("The function " + fn + "() can only be used when GR_ScoreType is set to " + requiredScoreType + " in the gs_gameregistry table of the database.\nGR_ScoreType is currently set to " + _scoreType + ". Please set GR_ScoreType to " + requiredScoreType + " in the database or use another function for scoring.");
+	}
+}
+}

data/lib/mako/data/flash_widget_dev_core/src/nm/gameServ/common/storage/StorageManager.as

@@ -0,0 +1,91 @@
+package nm.gameServ.common.storage
+{
+	import flash.errors.EOFError;
+	import flash.events.EventDispatcher;
+	import nm.errors.StorageError;
+	import org.rubyamf.remoting.ssr.ResultEvent;
+	public class StorageManager extends EventDispatcher
+	{
+		private var _tables:Vector.<StorageTable>
+		/**
+		 * Manages a list of StorageTables for easy access from a Widget Engine
+		 *
+		 * @param core A reference to the engine core
+		 */
+		public function StorageManager()
+		{
+			_tables = new Vector.<StorageTable>;
+		}
+		/**
+		 * Adds a StorageTable to the currently managed list of tables. StorageTables
+		 * are used to store arbitrary information pertaining to a Widget.
+		 *
+		 * @id The name of the table to insert (used to insert to it later)
+		 * @columns The names of the columns for this table
+		 */
+		public function addTable(id:String, ...columns):void
+		{
+			/* Search for a duplicate */
+			var target:StorageTable;
+			for(var i:int = 0; i < _tables.length; i++)
+			{
+				if(_tables[i].id == StorageTable.clean(id))
+				{
+					target = _tables[i];
+					break;
+				}
+			}
+			// Create the table or throw error if duplicate
+			if(target == null) _tables.push(new StorageTable(StorageTable.clean(id), columns));
+			else throw new StorageError("Table \"" + id + "\" already exists");
+		}
+		/**
+		 * Inserts a row into the the table with the given ID. Make sure the number
+		 * of arguments after tableId matches the number of columns that belong to this
+		 * table
+		 *
+		 * @param tableId The name of the table to insert the values to
+		 * @param values The values to insert to the table
+		 */
+		public function insert(tableId:String, ...values):void
+		{
+			/* Search for the Table */
+			var target:StorageTable;
+			for(var i:int = 0; i < _tables.length; i++)
+			{
+				if(_tables[i].id == StorageTable.clean(tableId))
+				{
+					target = _tables[i];
+					break;
+				}
+			}
+			if(target == null) // throw error if not found
+			{
+				throw new StorageError("Data table \"" + tableId + "\" does not exist.");
+				return;
+			}
+			// Insert the row into the appropriate table
+			var result:Object = target.insert.apply(this, values);
+			dispatchEvent(new ResultEvent("sendStorage", false, false, result));
+		}
+		public function getTable(tableID:String):StorageTable
+		{
+			/* Search for the Table */
+			var target:StorageTable;
+			for(var i:int = 0; i < _tables.length; i++)
+			{
+				if(_tables[i].id == StorageTable.clean(tableID))
+				{
+					target = _tables[i];
+					break;
+				}
+			}
+			if(target == null) // throw error if not found
+			{
+				throw new StorageError("Data table \"" + tableID + "\" does not exist.");
+				return null;
+			}
+			return target;
+		}
+	}/* End Class */
+}/* End Package */

data/lib/mako/data/flash_widget_dev_core/src/nm/gameServ/common/storage/StorageTable.as

@@ -0,0 +1,72 @@
+package nm.gameServ.common.storage
+{
+	import com.adobe.protocols.dict.Dict;
+	import flash.utils.Dictionary;
+	import nm.errors.StorageError;
+	import org.rubyamf.remoting.ssr.ResultEvent;
+	public class StorageTable
+	{
+		public var id:String;
+		private var columns:Vector.<String>;
+		private var rows:Vector.<Object>;
+		/**
+		 * Creates a new StorageTable for storing data to the server.
+		 * StorageTables are built to slightly mimic the functionality of database tables.
+		 *
+		 * @param id The name of this StorageTable
+		 * @param columns The names of each of the columns for this table
+		 */
+		public function StorageTable(id:String, columns:Array)
+		{
+			this.id = StorageTable.clean(id);
+			this.columns = new Vector.<String>;
+			this.rows = new Vector.<Object>;
+			for(var i:int = 0; i < columns.length; i++)
+			{
+				this.columns.push(StorageTable.clean(columns[i] as String));
+			}
+		}
+		public static function clean(name:String):String
+		{
+			var cleanName:String = name.replace(/\s/g, '_').replace(/[^\w]/g, '');
+			if(['userName', 'firstName', 'lastName', 'timestamp', 'playID'].indexOf(cleanName) >= 0)
+			{
+				throw new StorageError('Column name "'+name+'" is a protected keyword');
+			}
+			return cleanName;
+		}
+		/**
+		 * Inserts a new row into this table.
+		 *
+		 * @param values The values to insert into the table. Make sure the number
+		 * of arguments passed match the number of columns pertaining to this table.
+		 */
+		public function insert(...values):Object
+		{
+			/* Make sure arguments match number of columns */
+			if(values.length != columns.length)
+			{
+				throw new StorageError('StorageTable "' + id + '" requires ' + columns.length + " value(s) and received " + values.length);
+				return;
+			}
+			/* Create the row to add to the list of rows */
+			var result:Object = new Object();
+			for(var i:int = 0; i < values.length; i++)
+			{
+				result[StorageTable.clean(columns[i])] = String(values[i]);
+			}
+			rows.push(result);
+			/* Send this row to the server */
+			return {name:id, data:result};
+		}
+		public function getValues():Array
+		{
+			var values:Array = new Array();
+			for each(var row:Object in rows)
+			{
+				values.push(row)
+			}
+			return values
+		}
+	}/* End StorageTable Class */
+}/* End Package */