mako 0.0.0

data/lib/mako/data/flash_widget_dev_core/src/materia/PopUpAlert.mxml

@@ -0,0 +1,271 @@
+<?xml version="1.0" encoding="utf-8"?>
+<mx:Canvas xmlns:mx="http://www.adobe.com/2006/mxml"
+	cornerRadius="12"
+	borderStyle="solid"
+	borderThickness="0"
+	creationComplete="{onCreationComplete();}"
+	removedFromStage="{onRemovedFromStage();}"
+	styleName="alertPopup"
+	dropShadowEnabled="true"
+	minWidth="351"
+	>
+	<mx:Number id="minButtonWidth">60</mx:Number>
+	<mx:Text id="titleText" styleName="alertPopupTitle" text="{_title}" right="10"
+		height="42" left="10" top="11" textAlign="center" selectable="false"/>
+	<mx:VBox id="messageArea"
+		right="25"
+		left="25"
+		top="40"
+		bottom="55">
+		<mx:Text id="messageText"
+			width="100%"
+			text="{_message}"
+			textAlign="center"
+			selectable="false"/>
+	</mx:VBox>
+	<mx:HBox id="buttonHolder"
+		height="36" left="9" right="11" bottom="6"
+		horizontalAlign="center">
+	</mx:HBox>
+	<mx:Script>
+		<![CDATA[
+			import mx.controls.Button;
+			import mx.core.Application;
+			import mx.events.CloseEvent;
+			import mx.managers.PopUpManager;
+			protected static var TRACE_STRING:String = "PopUpAlert.mxml";
+			// parallel arrays to store button info
+			protected var _buttonCloseEventDetailsList:Array = null;
+			protected var _buttons:Array = null;
+			protected var _buttonCloseCallbacksList:Array;     // an array of functions called when the associated button is pressed
+			protected var _buttonCloseCallbackArgsList:Array;  // an array that keeps track of the args desired for each callback
+			protected var _indexOfCurrentSelectedButton:int = -1;
+			[Bindable] protected var _title:String = "Text";
+			[Bindable] protected var _message:String = "Text";
+			protected var _originalHeight:Number;
+			protected var _isCreationComplete:Boolean = false;
+			// a list of components to add to the messageArea on creation complete
+			protected var _componentsToInit:Array = null;
+			/// A shortcut for making popup messages with an ok button that dismisses the popup.
+			public static function quickMessagePopup(theTitle:String, theMessage:String, theParentStage:*):void
+			{
+				var p:PopUpAlert = new PopUpAlert();
+				p.title = theTitle;
+				p.message = theMessage;
+				p.addButton("OK",0);
+				p.show(theParentStage);
+			}
+			protected function onCreationComplete():void
+			{
+				_isCreationComplete = true;
+				_originalHeight = height;
+				makeSureButtonListsAreInit();
+				// there could be buttons waiting to be added
+				for(var i:int=0; i< _buttons.length; i++)
+				{
+					buttonHolder.addChild(_buttons[i]);
+				}
+				updateButtonSelection();
+				stage.addEventListener(KeyboardEvent.KEY_DOWN, onKeyDown, false, 0, true);
+				stage.focus = this;
+				if(_componentsToInit != null)
+				{
+					addAdditionalMessageComponents(_componentsToInit);
+				}
+			}
+			protected function onKeyDown(e:KeyboardEvent):void
+			{
+				//trace(TRACE_STRING + "::onKeyDown");
+				if(e.keyCode == Keyboard.ENTER) // press the current selected button
+				{
+					pressCurrentButton();
+				}
+				else if(e.keyCode == Keyboard.LEFT)
+				{
+					moveSelectionLeft();
+				}
+				else if(e.keyCode == Keyboard.RIGHT)
+				{
+					moveSelectionRight();
+				}
+			}
+			protected function onRemovedFromStage():void
+			{
+				//trace(TRACE_STRING + "::onRemovedFromStage");
+				for(var i:int =0; i< _buttons.length; i++)
+				{
+					(_buttons[i] as Button).removeEventListener(MouseEvent.CLICK, onButtonClick);
+				}
+				stage.removeEventListener(KeyboardEvent.KEY_DOWN, onKeyDown);
+			}
+			protected function updateButtonSelection():void
+			{
+				for(var i:int = 0; i< _buttons.length; i++)
+				{
+					if(_indexOfCurrentSelectedButton == i)
+					{
+						(_buttons[i] as Button).styleName = "blueButton";
+					}
+					else
+					{
+						(_buttons[i] as Button).styleName = "DefaultButton";
+					}
+				}
+			}
+			public function set message(message:String):void
+			{
+				_message = message;
+			}
+			public function set title(title:String):void
+			{
+				_title = title;
+			}
+			/**
+			 * Adds a button to the popup.
+			 * Clicking the button will close the popup. And fire a close event with .details = closeEventDetails.
+			 * isDefault will specify if the button will be the defaul selected button for pressing with the enter key.
+			 * */
+			public function addButton(label:String, closeEventDetails:int, isDefault:Boolean = false):void
+			{
+				var b:Button = new Button();
+				b.minWidth = minButtonWidth;
+				b.label = label;
+				makeSureButtonListsAreInit();
+				_buttonCloseEventDetailsList.push(closeEventDetails);
+				_buttonCloseCallbacksList.push(null);
+				_buttonCloseCallbackArgsList.push(null);
+				_buttons.push(b);
+				if(isDefault == true) // make this button the default selected
+				{
+					_indexOfCurrentSelectedButton = _buttons.length -1;
+				}
+				if(buttonHolder != null)
+				{
+					buttonHolder.addChild(b);
+				}
+				b.addEventListener(MouseEvent.CLICK, onButtonClick, false, 0, true);
+			}
+			public function addButtonWithCallback(label:String, closeCallback:Function, isDefault:Boolean = false, callbackArgs:Array = null):void
+			{
+				var b:Button = new Button();
+				b.minWidth = minButtonWidth;
+				b.label = label;
+				makeSureButtonListsAreInit();
+				_buttonCloseEventDetailsList.push(-1);
+				_buttonCloseCallbacksList.push(closeCallback);
+				_buttonCloseCallbackArgsList.push(callbackArgs);
+				_buttons.push(b);
+				if(isDefault == true) // make this button the default selected
+				{
+					_indexOfCurrentSelectedButton = _buttons.length -1;
+				}
+				if(buttonHolder != null)
+				{
+					buttonHolder.addChild(b);
+				}
+				b.addEventListener(MouseEvent.CLICK, onButtonClick, false, 0, true);
+			}
+			public function onButtonClick(e:MouseEvent):void
+			{
+				// get the index of the button
+				var index:int = getButtonIndex(e.currentTarget as Button);
+				mx.managers.PopUpManager.removePopUp(this);
+				if(_buttonCloseCallbacksList[index] != null)
+				{
+					var tt:Function;
+					_buttonCloseCallbacksList[index].apply(this, _buttonCloseCallbackArgsList[index]);
+				}
+				else
+				{
+					dispatchEvent(new CloseEvent(Event.CLOSE, false, false, _buttonCloseEventDetailsList[index]));
+				}
+			}
+			/**
+			 * This will add the componets onto the message are of the popup.
+			 *
+			 */
+			public function addAdditionalMessageComponents(theComponents:Array):void
+			{
+				if(messageArea != null)
+				{
+					function addComponent(item:*, index:int, array:Array):void
+					{
+						messageArea.addChild(item);
+					}
+					theComponents.forEach(addComponent);
+				}
+				else
+				{
+					// these will be initialized after creation complete
+					_componentsToInit = theComponents;
+				}
+			}
+			public function show(parent:*):void
+			{
+				//trace("parent = " + parent);
+				if(parent == null)
+				{
+					//HACKEY but i dont know whats going on yet
+					parent = Application.application;
+				}
+				mx.managers.PopUpManager.addPopUp(this, parent, true);
+				mx.managers.PopUpManager.centerPopUp(this);
+			}
+			protected function getButtonIndex(b:Button):int
+			{
+				var index:int = -1;
+				for(var i:int =0; i< _buttons.length; i++)
+				{
+					if( _buttons[i] == b)
+					{
+						index = i;
+						break;
+					}
+				}
+				return index;
+			}
+			protected function makeSureButtonListsAreInit():void
+			{
+				if(_buttons == null)
+				{
+					_buttons = [];
+				}
+				if(_buttonCloseEventDetailsList == null)
+				{
+					_buttonCloseEventDetailsList = [];
+				}
+				if(_buttonCloseCallbacksList == null)
+				{
+					_buttonCloseCallbacksList = [];
+					_buttonCloseCallbackArgsList = []
+				}
+			}
+			protected function pressCurrentButton():void
+			{
+				if(_indexOfCurrentSelectedButton != -1)
+				{
+					mx.managers.PopUpManager.removePopUp(this);
+					dispatchEvent(new CloseEvent(Event.CLOSE,false,false,_buttonCloseEventDetailsList[_indexOfCurrentSelectedButton]));
+				}
+			}
+			protected function moveSelectionRight():void
+			{
+				_indexOfCurrentSelectedButton++;
+				if(_indexOfCurrentSelectedButton >= _buttons.length)
+				{
+					_indexOfCurrentSelectedButton = _buttons.length-1;
+				}
+				updateButtonSelection();
+			}
+			protected function moveSelectionLeft():void
+			{
+				_indexOfCurrentSelectedButton--;
+				if(_indexOfCurrentSelectedButton < 0)
+				{
+					_indexOfCurrentSelectedButton = 0;
+				}
+				updateButtonSelection();
+			}
+		]]>
+	</mx:Script>
+</mx:Canvas>

data/lib/mako/data/flash_widget_dev_core/src/materia/components/GradientBackground.as

@@ -0,0 +1,41 @@
+package materia.components
+{
+	import mx.skins.ProgrammaticSkin;
+	import flash.geom.Matrix;
+	public class GradientBackground extends ProgrammaticSkin
+	{
+		override public function get measuredWidth():Number
+		{
+			return 45;
+		}
+		override public function get measuredHeight():Number
+		{
+			return 45;
+		}
+		override protected function updateDisplayList(unscaledWidth:Number, unscaledHeight:Number):void
+		{
+			var fillColors:Array = getStyle("fillColors");
+			var fillAlphas:Array = getStyle("fillAlphas");
+			var gradientType:String = getStyle("gradientType");
+			var angle:Number = getStyle("angle");
+			var focalPointRatio:Number = getStyle("focalPointRatio");
+			// Default values, if styles aren’t defined
+			if (fillColors == null)
+			fillColors = [0xEEEEEE, 0x999999];
+			if (fillAlphas == null)
+			fillAlphas = [1, 1];
+			if (gradientType == "" || gradientType == null)
+			gradientType = "linear";
+			if (isNaN(angle))
+			angle = 90;
+			if (isNaN(focalPointRatio))
+			focalPointRatio = 0.5;
+			var matrix:Matrix = new Matrix();
+			matrix.createGradientBox(unscaledWidth, unscaledHeight, angle * Math.PI / 180);
+			graphics.clear();
+			graphics.beginGradientFill(gradientType, fillColors, fillAlphas, [0, 255] , matrix, "pad", "rgb", focalPointRatio);
+			graphics.drawRect(0, 0, unscaledWidth, unscaledHeight);
+			graphics.endFill();
+		}
+	}
+}

data/lib/mako/data/flash_widget_dev_core/src/materia/components/PercentField.mxml

@@ -0,0 +1,104 @@
+<?xml version="1.0" encoding="utf-8"?>
+<mx:Canvas xmlns:mx="http://www.adobe.com/2006/mxml" creationComplete="{onCreationComplete()}"
+	mouseDown="{onMouseDown(event)}" mouseUp="{onMouseUp(event)}">
+	<mx:HBox left="5" right="5" verticalAlign="middle" height="100%">
+		<mx:CheckBox id="checkBox"
+			change="{checkBoxChange()}"
+			scaleX="1.4" scaleY="1.4"/>
+		<mx:TextInput id="textInput"
+			width="100%"
+			focusIn="{onFocusIn()}"
+			focusOut="{textInputChange()}"/>
+	</mx:HBox>
+	<mx:Script>
+		<![CDATA[
+			public override function set data(value:Object):void
+			{
+				super.data = value;
+				if(data.value == undefined)
+				{
+					data.value = 0;
+				}
+				textInput.text = data.value + "%";
+				if(data.value == 0)
+				{
+					checkBox.selected = false;
+					checkBox.alpha = 100;
+				}
+				else
+				{
+					checkBox.selected = true;
+					checkBox.alpha = data.value/100;
+				}
+			}
+			protected function onCreationComplete():void
+			{
+				// NOTE: this will fire for all the item renderers
+				//  that is not too bad? or do something to identify them?
+				stage.addEventListener(KeyboardEvent.KEY_UP, keyDown, false, 0, true);
+			}
+			// stopping mouse down and up event propigation to prevent dragging
+			//  a datagrid item while using this component
+			//  might not be the best way to do this?
+			protected function onMouseDown(e:Event):void
+			{
+				e.stopPropagation();
+			}
+			protected function onMouseUp(e:Event):void
+			{
+				e.stopPropagation();
+			}
+			protected function keyDown(e:KeyboardEvent):void
+			{
+				if( e.keyCode == Keyboard.ENTER)
+				{
+					textInputChange();
+				}
+			}
+			protected function checkBoxChange():void
+			{
+				if(checkBox.selected == true)
+				{
+					data.value = 100;
+				}
+				else
+				{
+					data.value = 0;
+				}
+				checkBox.alpha = 100;
+				textInput.text = data.value + "%";
+			}
+			protected function textInputChange():void
+			{
+				// TODO: i think it is calling this function more than it needs to
+				var text:String = textInput.text.split("%")[0];
+				var n:Number = Number(text);
+				var i:int = Math.floor(n); // Note: this handles when n is NaN
+				if( i > 100 )
+				{
+					i = 100;
+				}
+				else if( i < 0 )
+				{
+					i = 0;
+				}
+				data.value = i;
+				textInput.text = data.value + "%";
+				if(data.value == 0)
+				{
+					checkBox.selected = false;
+					checkBox.alpha = 100;
+				}
+				else
+				{
+					checkBox.selected = true;
+					checkBox.alpha = data.value/100;
+				}
+			}
+			protected function onFocusIn():void
+			{
+				textInput.setSelection(0, textInput.text.length);
+			}
+		]]>
+	</mx:Script>
+</mx:Canvas>