mako 0.0.0

data/lib/mako/data/flash_widget_dev_core/src/nm/ui/TweeningDragDropBankList.as

@@ -0,0 +1,503 @@
+/* See the file "LICENSE.txt" for the full license governing this code. */
+package nm.ui
+{
+	import com.gskinner.motion.GTween;
+	import flash.display.MovieClip;
+import flash.display.Sprite;
+import flash.events.Event;
+	import flash.events.EventDispatcher;
+	public class TweeningDragDropBankList extends EventDispatcher
+	{
+		protected static const TRACE_STRING:String = "TweeningDragDropBankList";
+		// you give this clips, and it stacks them up ( on different pages)
+		// it tweens page changes, tweens adding items,
+		// and tweens making room for adding items
+		// NOTE: is currently a horizontal list
+		protected var _parent:Sprite;
+		public function get items():Array
+		{
+			return _items;
+		}
+		protected var _items:Array = [];
+		// the location on the parent that this list is
+		protected var _x:Number, _y:Number, _width:Number, _height:Number;
+		protected var _paddingBetweenListItems:Number = 8.0; // using this to magic number hack fix
+		protected var _customTween:Function;
+		protected var _tweenTime:Number = 1.6;
+		//protected var _lastPageIndex:int = 0;
+		protected var _currentPage:Number = 0.0; // the current page we are showing
+		// the clips will be shown on pages based on the _width/_height of the area set
+		// NOTE: Should be a Number instead of an int because we are multiplying it with Numbers
+		public function TweeningDragDropBankList(parent:Sprite)
+		{
+			_parent = parent;
+		}
+		public function setTweenStyle(tweenTime:Number, customTweenFunction:Function = null):void
+		{
+			_tweenTime = tweenTime;
+			_customTween = customTweenFunction;
+		}
+		public function setArea(theX:Number, theY:Number, width:Number, height:Number):void
+		{
+			_x = theX;
+			_y = theY;
+			_width = width;
+			_height = height;
+		}
+		public function addItem(clip:MovieClip, animate:Boolean = true):void
+		{
+			//////trace(TRACE_STRING + "::addItem");
+			// NOTE: we will handle the case where the clip is already in items
+			// just re-position it
+			_makingRoomForItem = false;
+			var i:int = _items.indexOf(clip);
+			if( i != -1)
+			{
+				_items.splice(i,1);
+			}
+			_items.splice(0,0,clip);
+//			clip.tabEnabled = false;
+			bubbleDownItemAt(0);
+			moveItemsIntoPosition(animate);
+		}
+		public function itemIsMember(clip:MovieClip):Boolean
+		{
+			return isMember(clip, _items);
+		}
+		public function tryStoppingTweensForClip(clip:MovieClip):void
+		{
+			//////trace(TRACE_STRING + "::tryStoppingTweensForClip");
+			var tweenObject:Object = removeTweenInfo(clip);
+			if(tweenObject != null)
+			{
+				////trace("function tryStoppingTweensForClip, pausing a tween");
+				(tweenObject.tween as GTween).paused = true;
+			}
+		}
+		// our items can have custom fields for telling their height
+		// this sets the field to use as the function to get the item's height
+		protected var _itemHeightFunctionField:String = ""
+		public function setItemHeightFunctionField(field:String):void
+		{
+			_itemHeightFunctionField = field;
+		}
+		protected function getItemHeight(item:*):Number
+		{
+			var result:Number;
+			if(_itemHeightFunctionField != "")
+			{
+				result = (item[_itemHeightFunctionField])();
+			}
+			else
+			{
+				result = item.height;
+			}
+			//trace("height result = " + result);
+			return result;
+		}
+		protected function bubbleDownItemAt(pos:int):int
+		{
+			for(var i:int = pos + 1; i < _items.length; i++)
+			{
+				if( itemY(_items[pos]) > itemY(_items[i]) )
+				{
+					swap(_items, pos, i);
+					pos++;
+				}
+				else
+				{
+					break;
+				}
+			}
+			return pos;
+		}
+		protected function itemY(item:MovieClip):Number
+		{
+			return item.y + getItemHeight(item)/2.0;
+		}
+		protected function swap(arr:Array, index1:int, index2:int):void
+		{
+			var temp:* = arr[index1];
+			arr[index1] = arr[index2];
+			arr[index2] = temp;
+		}
+		protected function moveItemsIntoPosition(animate:Boolean, skipList:Array = null):void
+		{
+			if(skipList == null)
+			{
+				skipList = [];
+			}
+			var lastPage:int = getCurrentLastPage();
+			if( _currentPage > lastPage)
+			{
+				_currentPage = lastPage;
+			}
+			var pageOffset:Number = getPageYOffset(_currentPage);
+			//////trace("pageOffset = " + pageOffset);
+			var curY:Number = _y;
+			for(var i:int =0; i< _items.length; i++)
+			{
+				var item:MovieClip = _items[i];
+				if( ! isMember(item, skipList) )
+				{
+					setItemPosition(item, _x, curY, pageOffset, animate);
+				}
+				// NOTE: doing thise even if they are on the skip list
+				curY += getItemHeight(item) + _paddingBetweenListItems;
+			}
+		}
+		protected function isMember(item:*, list:Array):Boolean
+		{
+			for(var i:int =0; i< list.length; i++)
+			{
+				if( item == list[i])
+				{
+					return true;
+				}
+			}
+			return false;
+		}
+		public function removeItem(clip:MovieClip, animate:Boolean = true):void
+		{
+			//////trace(TRACE_STRING + "::removeItem");
+			_makingRoomForItem = false;
+			for(var i:int =0; i< _items.length; i++)
+			{
+				if( _items[i] == clip)
+				{
+					//////trace("itemFound");
+					var item:MovieClip = _items.splice(i, 1)[0];
+					// stop the tweeing on this item if its goint
+					var tweenInfo:Object = removeTweenInfo(item);
+					if(tweenInfo != null)
+					{
+						////trace("function removeItem, pausing a tween");
+						(tweenInfo.tween as GTween).paused = true;
+					}
+					break;
+				}
+				//////trace("moveItemsIntoPosition, animate = " + animate);
+				moveItemsIntoPosition(animate);
+			}
+		}
+		// set to true when we are making room for an item
+		// it will be set to false after adding, removing, or canceling the make room
+		protected var _makingRoomForItem:Boolean = false;
+		public function makeRoomForItem(clip:MovieClip, animate:Boolean = true):void
+		{
+			// NOTE: clip could already be a member of our clips
+			//   if it is, we would not need to keep its old space?
+			var i:int = _items.indexOf(clip);
+			if(i != -1) // if its already in the _items array
+			{
+				// no need to have room for it twice
+				_items.splice(i,1);
+			}
+			_items.splice(0,0,clip);
+			var newIndex:int = bubbleDownItemAt(0);
+			moveItemsIntoPosition(animate,[clip]);
+			_items.splice(newIndex,1);
+			_makingRoomForItem = true;
+		}
+		public function cancelMakeRoomForItem(animate:Boolean = true):void
+		{
+			if(_makingRoomForItem)
+			{
+				moveItemsIntoPosition(animate);
+				_makingRoomForItem = false;
+			}
+		}
+		protected function getCurrentLastPage():int
+		{
+			//return the index of the last page
+			var pageCount:int = 0;
+			var curPageYAmount:Number = 0;
+			for(var i:int =0; i< _items.length; i++)
+			{
+				var item:MovieClip = _items[i];
+				// NOTE: doing thise even if they are on the skip list
+				curPageYAmount += getItemHeight(item) + _paddingBetweenListItems;
+				if(curPageYAmount > _height)
+				{
+					// this item will be the first item on the next page
+					pageCount++;
+					curPageYAmount = getItemHeight(item) + _paddingBetweenListItems;
+				}
+			}
+			return pageCount;
+		}
+		// get the y offset of a page
+		protected function getPageYOffset(pageNum:int):Number
+		{
+			//////trace("pageNum = " + pageNum);
+			var pageCount:int = 0;
+			var curPageYAmount:Number = 0;
+			var curTotalAmount:Number = 0;
+			var returnValueY:Number = 0;
+			for(var i:int =0; i< _items.length; i++)
+			{
+				if(pageCount == pageNum)
+				{
+					return returnValueY;
+				}
+				var item:MovieClip = _items[i];
+				if(curPageYAmount + getItemHeight(item) > _height)
+				{
+					returnValueY = curTotalAmount;
+					curPageYAmount = 0.0;
+					pageCount++;
+				}
+				var addAmount:Number = getItemHeight(item) + _paddingBetweenListItems;
+				curPageYAmount += addAmount;
+				curTotalAmount += addAmount;
+			}
+			return returnValueY;
+		}
+		public function canGoToNextPage():Boolean
+		{
+			var lastPage:int = getCurrentLastPage();
+			if( _currentPage + 1 <= lastPage)
+			{
+				return true;
+			}
+			return false;
+		}
+		public function canGoToPreviousPage():Boolean
+		{
+			if( _currentPage > 0)
+			{
+				return true;
+			}
+			return false;
+		}
+		public function tryGotoNextPage(animate:Boolean = true):void
+		{
+			_currentPage += 1;
+			moveItemsIntoPosition(animate);
+			// returns true if there was a next page to go to
+			// false if not
+		}
+		public function tryGotoPreviousPage(animate:Boolean = true):void
+		{
+			_currentPage -= 1;
+			if( _currentPage < 0)
+			{
+				_currentPage = 0;
+			}
+			moveItemsIntoPosition(animate);
+		}
+		// scroll to the page that the selected item is on
+		// if its on the current page, do nothing
+		// if it is on another page, only show 1 page move animation
+		public function scrollToItem(item:Object, animate:Boolean = true, force:Boolean = false):void
+		{
+			var newPage:int = getPageForItem(item);
+			if(force || (_currentPage != newPage))
+			{
+				_currentPage = newPage;
+				moveItemsIntoPosition(animate);
+			}
+		}
+		// return the page that the current item is on
+		protected function getPageForItem(theItem:Object):int
+		{
+			var pageCount:int = 0;
+			var curPageYAmount:Number = 0;
+			var curTotalAmount:Number = 0;
+			var returnValueY:Number = 0;
+			//var pageNum:int = 0; // start looking from page 0
+			for(var i:int =0; i< _items.length; i++)
+			{
+				var item:MovieClip = _items[i];
+				if(curPageYAmount + getItemHeight(item) > _height)
+				{
+					returnValueY = curTotalAmount;
+					curPageYAmount = 0.0;
+					pageCount++;
+				}
+				// if we find this item, return the page
+				if( item == theItem)
+				{
+					return pageCount;
+				}
+				var addAmount:Number = getItemHeight(item) + _paddingBetweenListItems;
+				curPageYAmount += addAmount;
+				curTotalAmount += addAmount;
+			}
+			return pageCount;
+		}
+		// where we store all the tween objects
+		// we might need them to cancel tweens
+		//protected var _tweens:Object = {};
+		protected var _tweens:Array = [];
+		// each oject will have {item:, tween:, x:, y:}
+		// x and y are the target locations
+		protected function isTweenStored(item:MovieClip):Boolean
+		{
+			for(var i:int = 0; i< _tweens.length; i++)
+			{
+				if( _tweens[i].item == item)
+				{
+					return true;
+				}
+			}
+			return false;
+		}
+		protected function getTweenInfo(item:MovieClip):Object
+		{
+			for(var i:int = 0; i< _tweens.length; i++)
+			{
+				if( _tweens[i].item == item)
+				{
+					return _tweens[i];
+				}
+			}
+			return null;
+		}
+		protected function removeTweenInfo(item:MovieClip):Object
+		{
+			for(var i:int = 0; i< _tweens.length; i++)
+			{
+				if( _tweens[i].item == item)
+				{
+					return _tweens.splice(i,1)[0];
+				}
+			}
+			return null;
+		}
+		protected function addTweenInfo(item:Object):void
+		{
+			_tweens.push(item);
+		}
+		protected function willClipBeVisible(clip:MovieClip, xDest:Number, yDest:Number):Boolean
+		{
+			// NOTE: currently list is vertical and we only check y coords
+			// dont need offset param
+			var curPageStartY:Number = _y;
+			var curPageEndY:Number = curPageStartY + _height;
+			const ERROR:Number = 3.0;
+			// arg, this ERROR thing is hacky, but its pissing me off so im gonna do it
+			// a clip is being hidden when i dont wat it, so doing this
+			// if it is too high up
+			if(yDest + ERROR < curPageStartY)
+			{
+				return false;
+			}
+			// if it is too far down
+			if( yDest + getItemHeight(clip) > curPageEndY)
+			{
+				return false;
+			}
+			return true;
+		}
+		protected function setItemPosition(item:MovieClip, theX:Number, theY:Number, pageOffset:Number, animate:Boolean = true):void
+		{
+			//  theY gets offset by the current page we are on
+			theY -= pageOffset;
+			if(item.x != theX || item.y != theY)
+			{
+				// cancel any previous tweens
+				var o:Object = removeTweenInfo(item);
+				if(o != null)
+				{
+					//////trace("hello");
+					//var o:Object = getTweenInfo(item);
+					//g = o.tween;
+					//////trace( "theX = " + theX+", theY = "+theY);
+					//////trace( "    o.x = " + o.  x+", o.y = "+o.y);
+					// if the tween is not going where it needs to
+					if( theX != o.x || theY != o.y)
+					{
+						//////trace("hi");
+						//g.end();
+						o.tween.removeEventListener(Event.COMPLETE, tweenComplete);
+						o.tween.paused = true; // not sure if this is needed?
+						//removeTweenInfo(item);//_tweens[item+""] = undefined;
+					}
+					else
+					{
+						// its going to where it needs to go
+						return; // early return
+					}
+				}
+				// Visiblility Check
+				// if it isn't visible, and wont be, no need to animate
+				// if it isnt visible, but will be, make it visible
+				// if it is visible, but wont be later. mark it as to be hidden
+				// if it will be visible at the end
+				var endVisibility:Boolean = willClipBeVisible(item, theX, theY);
+				var startAlpha:Number;
+				var endAlpha:Number;
+				if(endVisibility == true)
+				{
+					if(item.visible == true)
+					{
+						// continue as normal
+						startAlpha = 1.0;
+					}
+					else
+					{
+						// make it visible
+						item.visible = true;
+						startAlpha = 0.0;
+					}
+					endAlpha = 1.0;
+				}
+				else
+				{
+					//item.visible = false;
+					if(item.visible == true)
+					{
+						// endVisibility being false will make it hide later
+						startAlpha = 1.0;
+						endAlpha = 0.0;
+					}
+					else
+					{
+						// be sure not to tween it!
+						// starts invisible, ends invisible
+						animate = false;
+						// wont need to worry about alphas
+					}
+				}
+				if(animate)
+				{
+					var g:GTween;
+					item.alpha = startAlpha;
+					if(_customTween != null)
+					{
+						g = new GTween(item, _tweenTime,
+							{x:theX, y:theY, alpha:endAlpha},
+							{ease:_customTween});
+					}
+					else
+					{
+						g = new GTween(item, _tweenTime,
+							{x:theX, y:theY, alpha:endAlpha});
+					}
+					//////trace("ADDING TWEEN");
+					g.onComplete = tweenComplete;
+//					g.addEventListener(Event.COMPLETE, tweenComplete, false, 0, true);
+					addTweenInfo({item:item, tween:g, x:theX, y:theY, endVisibility:endVisibility});
+				}
+				else
+				{
+					item.x = theX;
+					item.y = theY;
+					item.visible = endVisibility;
+				}
+			}
+		}
+//		protected function tweenComplete(e:Event):void
+		protected function tweenComplete(g:GTween):void
+		{
+			// not longer need to store it
+//			var g:GTween = e.target as GTween; // the listener is added to the tween
+			var tweenInfo:Object = removeTweenInfo(g.target as MovieClip);
+			if(tweenInfo != null)
+			{
+				(g.target).visible = tweenInfo.endVisibility;
+			}
+		}
+	}
+}

data/lib/mako/data/flash_widget_dev_core/src/nm/ui/Window.as

@@ -0,0 +1,144 @@
+/* See the file "LICENSE.txt" for the full license governing this code. */
+package nm.ui
+{
+import flash.filters.DropShadowFilter;
+import flash.geom.Matrix;
+import flash.text.TextFormat;
+import nm.draw.shapes.RectRoundBorder;
+/**
+* Default Style for the Window Component
+*/
+public class Window extends Window_base
+{
+	//--------------------------------------------------------------------------
+	//
+	//  Constructor
+	//
+	//--------------------------------------------------------------------------
+	/**
+	* Creates a window automatically.  The window will take on the x/y coordinates of its parent movie clip.
+	* @param 	x	Number. x coordinate within target to place window's top left corner
+	* @param	y	Number. y coordinate within target to place window's top left corner
+	* @param	w	Number. width of window in pixles
+	* @param	h	Number. Height of window in pixles
+	* @param	title	String. Title text for the window
+	* @param	centered Boolean decides whether or not the window will be centered
+	* @param	isModal	Boolean flag. Optional. Default: false. True will render a background blocking movie clip over the stage
+	* @param	isMovable	Boolean flag. Optional. Defaults: false. True will allow the user to drad and drop the window within it's parent (or within the modal background)
+	*/
+	function Window(w:Number, h:Number, title:String, isModal:Boolean = false, isMovable:Boolean = false)
+	{
+		super(NaN, NaN, w, h, title, isModal, isMovable);
+	}
+	//--------------------------------------------------------------------------
+	//
+	//  Functions
+	//
+	//--------------------------------------------------------------------------
+	//----------------------------------
+	//  styling
+	//----------------------------------
+	/**
+	* Default styles setup
+	*/
+	protected override function styleDefaults():void{
+		super.styleDefaults()
+		/*    BORDERS    */
+		//Border Params
+		setStyle('borderSpacing', 10); // padding from the edges of the window
+		setStyle('borderStroke', 2);// title bar Frame size
+		setStyle('borderColor', 0x377aa6);
+		setStyle('borderCurve', 6);
+		//Bevel Colors (Discontinued)
+		setStyle('wintL', 0xACACAC);
+		setStyle('winbR', 0xACACAC);
+		/*    BODY    */
+		//Body Colors
+		setStyle('winf1', 0x404550);
+		setStyle('winf2', 0x404550);
+		//Body Alpha
+		setStyle('wina', .7);
+		//Body Gradient Direction
+		setStyle('winr', 90);
+		/*    TITLE BAR    */
+		//Title Bar Fill Colors
+		setStyle('tBf1', 0xEEEEEE);
+		setStyle('tBf2', 0xFFFFFF);
+		//Title Bar Border Color?
+		setStyle('tBsC', 0xC1C1C1);
+		//Title Bar Gradient Direction
+		setStyle('tBr', 90);
+		//Title Bar Alpha
+		setStyle('tBa', 0);
+		// Title Bar Height
+		setStyle('titleBarHeight', 30);
+		//Title Bar Font
+		setStyle('titleFormat', new TextFormat("Arial", 16, 0xffffff, true));
+		setStyle('titleEmbedFonts', false);
+		/*    OTHER    */
+		//Modal (Blackout) Color/Alpha
+		setStyle('bgfill', 0x000000);
+		setStyle('bgalpha', .20);
+		//Effects
+		setStyle('dropShadow', new DropShadowFilter(5, 45, 0x000000, 1, 5, 5, .5, 1));
+	}
+	//----------------------------------
+	//  gui drawing functions
+	//----------------------------------
+	/**
+	 *	Draws the body of the window
+	 */
+	protected override function drawBody():void
+	{
+		super.drawBody()
+		//Draw Window Body
+		var colors:Array = [getStyle('winf1'), getStyle('winf2')];
+		var alphas:Array = [getStyle('wina'), getStyle('wina')];
+		var ratios:Array = [0, 0xFF];
+		var matrix:Matrix = new Matrix()
+		matrix.createGradientBox(width, height, (getStyle('winr')/180)*Math.PI)
+		windowBg.graphics.beginGradientFill("linear", colors, alphas, ratios, matrix);
+		windowBg.graphics.drawRoundRect(0, 0, width, height,getStyle('borderCurve'));
+		//Draw Window Border
+		//RectBevel.draw(windowFr, 0, 0, width, height, getStyle('borderStroke'), getStyle('wintL'), getStyle('winbR')); //Draw beveled edge
+		RectRoundBorder.draw(windowFr,0,0,width,height,getStyle('borderStroke'), getStyle('borderCurve'), getStyle('borderColor'), 1);
+		//Apply drop shadow filter
+		windowBg.filters = [getStyle('dropShadow')];
+	}
+	/**
+	 *	Draws the tilte bar
+	 */
+	protected override function drawTitleBar():void
+	{
+		super.drawTitleBar();
+		var stroke:int = getStyle('borderStroke')
+		var tBt:int = getStyle('titleBarHeight');
+		var colors:Array = [getStyle('tBf1'), getStyle('tBf2')];
+		var alphas:Array = [getStyle('tBa'), getStyle('tBa')];
+		var ratios:Array = [0, 0xFF];
+		//var matrix = {matrixType:"box", x:stroke, y:stroke, w:width-(stroke*2), h:tBt, r:(getStyle('tBr')/180)*Math.PI};
+		var matrix:Matrix = new Matrix()
+		matrix.createGradientBox(width-(stroke*2), tBt, (getStyle('tBr')/180)*Math.PI)
+		titleBar.graphics.beginGradientFill("linear", colors, alphas, ratios, matrix);
+		titleBar.graphics.drawRect(stroke, stroke, width - (stroke * 2), tBt);
+		titleBar.graphics.beginFill(getStyle('tBsC'),getStyle('tBa'));
+		titleBar.graphics.drawRect(stroke, stroke+tBt, width - (stroke * 2), stroke);
+	}
+	/**
+	 *	Draws the Background (modal blocking area)
+	 */
+	protected override function drawBg():void
+	{
+		super.drawBg();
+		//Determine parameters for modal (fading background)
+		var rootbound:Boolean = (_modalTarg == root)
+		var bgHeight:Number = (rootbound) ? root.height : _modalTarg.height;
+		var bgWidth:Number = (rootbound) ? root.width : _modalTarg.width;
+		if(modalHeight > 0) bgHeight = modalHeight
+		if(modalWidth > 0) bgWidth = modalWidth
+		//Draw Modal
+		bg.graphics.beginFill(getStyle('bgfill'), getStyle('bgalpha'));
+		bg.graphics.drawRect(0, 0, bgWidth, bgHeight);
+	}
+}
+}