mako 0.0.0

data/lib/mako/data/flash_widget_dev_core/src/nm/ui/ScrollBar_base.as

@@ -0,0 +1,378 @@
+/* See the file "LICENSE.txt" for the full license governing this code. */
+package nm.ui {
+	import flash.display.Sprite;
+	import flash.events.MouseEvent;
+	import flash.events.TimerEvent;
+	import flash.geom.Rectangle;
+	import flash.utils.Timer;
+	import nm.events.StandardEvent;
+	public class ScrollBar_base extends Component
+	{
+		public static const SCROLL:String = "scroll";
+		private const DEBUG_MODE:Boolean = false;
+		protected var uArrow:Sprite
+		protected var dArrow:Sprite
+		protected var scroll_mc:Sprite
+		protected var bg:Sprite
+		protected var slider:Sprite
+		protected var _totalLines:Number
+		protected var _linesPerPage:Number
+		protected var currentScroll:Number
+		protected var sliderSpace:Number
+		protected var _wheelEnabled:Boolean
+		protected var isHoriz:Boolean
+		protected var _percentPerScroll:Number = 2;
+		protected var repeatMoveBy:Number
+		protected var timer:Timer
+		protected var autoHeight:Boolean = false;
+		private var _xHasBeenModified:Boolean = false;
+		private var _hasBeenDrawn:Boolean = false;
+		public function ScrollBar_base(width:int = 15, height:int = -1, totalLines:Number = 100, linesPerPage:Number = 1, currentScroll:Number = 0, isHoriz:Boolean = false)
+		{
+			super(true, width, height);
+			autoHeight = height == -1;
+			_totalLines = totalLines
+			_linesPerPage = linesPerPage
+			this.currentScroll = currentScroll;
+			this.isHoriz = isHoriz;
+			timer = new Timer(getStyle('scrollRate'));
+		}
+		private function print(...args):void
+		{
+			return;
+		}
+		protected override function styleDefaults():void
+		{
+			setStyle('minSliderH', 10);
+			setStyle('staticSliderH', width)
+			setStyle('scrollRate', 100)
+		}
+		public override function draw():void
+		{
+			super.draw();
+			_hasBeenDrawn = true;
+			//Take care of 'automatic' variable values
+			if(autoHeight) _height = parent.height;
+			if(!_xHasBeenModified) x = parent.width - _width;
+			setCurrentScroll(currentScroll)
+			//_wheelEnabled = false
+			wheelEnabled = true;
+			mkArrows();
+			mkBackground(); // need arrow sized before calculation for the background
+			mkSlider();// need background before calculation of this
+			redraw();
+		}
+		protected var beenDrawn:Boolean = false;
+		public override function redraw():void
+		{
+			//Only redraw if compenent has been drawn to begin with
+			if(_hasBeenDrawn == false) return;
+			if(autoHeight) _height = parent.height;
+			drawArrows();
+			drawBackground()
+			drawSlider()
+			syncSlider()
+			uArrow.y = 0;
+			dArrow.y = _height
+			if(isHoriz)
+			{
+				rotation = 270; //rotate
+				scaleX = -1.00; // flip top to bottom
+			}
+		}
+		protected function drawBackground():void
+		{
+			sliderSpace = _height - uArrow.height*2
+		}
+		protected function drawArrows():void{}
+		protected function drawSlider():void{}
+		/****** GUI Creation *********/
+		protected function assignEvents(target:Sprite, name:String):void
+		{
+			print("event added to scrollbar " +name + "Events");
+			var targF:Function = this[name + 'Events'];
+			target.addEventListener(MouseEvent.ROLL_OVER, targF,false,0,true)
+			target.addEventListener(MouseEvent.ROLL_OUT, targF,false,0,true)
+			target.addEventListener(MouseEvent.DOUBLE_CLICK, targF,false,0,true)
+			target.addEventListener(MouseEvent.MOUSE_DOWN, targF,false,0,true)
+			stage.addEventListener(MouseEvent.MOUSE_UP, targF,false,0,true)
+		}
+		protected function mkBackground():void
+		{
+			bg = new Sprite();
+			addChildAt(bg, 0);
+			assignEvents(bg, 'bg');
+		}
+		protected function mkArrows():void
+		{
+			uArrow = new Sprite();
+			uArrow.buttonMode = true;
+			addChild(uArrow)
+			assignEvents(uArrow, 'arrow')
+			dArrow = new Sprite();
+			dArrow.buttonMode = true;
+			addChild(dArrow);
+			assignEvents(dArrow, 'arrow')
+			dArrow.scaleY = -1; // flip the down arrow
+		}
+		protected function mkSlider():void
+		{
+			slider = new Sprite();
+			slider.buttonMode = true;
+			addChild(slider)
+			assignEvents(slider, 'slider')
+		}
+		/****** GUI Interaction ***********/
+		protected function bgEvents(eObj:MouseEvent):void
+		{
+			switch(eObj.type)
+			{
+				case MouseEvent.MOUSE_DOWN:
+					var y:Number = eObj.target.mouseY
+					var moveBy:Number = (y-uArrow.height > slider.y ? 1 : -1)
+					// if we have line data, we want to scroll by a page's full height
+					if(_totalLines > 0 && _linesPerPage > 0)
+					{
+						repeatMoveBy = 100*moveBy
+						timer.addEventListener('timer', bgRepeat,false,0,true);
+						timer.start();
+						scrollPagePercent(repeatMoveBy)
+					}
+					// no line data, so opperate just like the arrow buttons
+					else
+					{
+						repeatMoveBy = _percentPerScroll * moveBy
+						timer.addEventListener('timer', arrowRepeat,false,0,true);
+						timer.start();
+						scrollIncriment(repeatMoveBy)
+					}
+					break;
+				case MouseEvent.MOUSE_UP:
+					timer.removeEventListener('timer', (_totalLines > 0 && _linesPerPage > 0) ? bgRepeat : arrowRepeat);
+					timer.stop()
+			}
+		}
+		protected function arrowEvents(eObj:MouseEvent):void
+		{
+			switch(eObj.type)
+			{
+				case MouseEvent.MOUSE_DOWN:
+					repeatMoveBy = (eObj.target == uArrow ? -1 : 1) * _percentPerScroll
+					timer.addEventListener('timer', arrowRepeat,false,0,true)
+					timer.start();
+					scrollIncriment(repeatMoveBy)
+					break;
+				case MouseEvent.MOUSE_UP:
+					timer.removeEventListener('timer', arrowRepeat)
+					timer.stop();
+			}
+		}
+		protected function arrowRepeat(eObj:TimerEvent):void
+		{
+			scrollIncriment(repeatMoveBy);
+		}
+		protected function bgRepeat(eObj:TimerEvent):void
+		{
+			scrollPagePercent(repeatMoveBy);
+		}
+		protected function sliderEvents(eObj:MouseEvent):void
+		{
+			//////trace("EVENT: " + eObj.type);
+			switch(eObj.type)
+			{
+				case MouseEvent.MOUSE_DOWN:
+					var limitRect:Rectangle = new Rectangle(0,uArrow.height, 0, Math.ceil(sliderSpace - slider.height))
+					slider.startDrag(false, limitRect);
+					dispatchEvent(new StandardEvent('drag', true, true));
+					stage.addEventListener(MouseEvent.MOUSE_MOVE, onSliderMove, false, 0, true);
+					break;
+				case MouseEvent.MOUSE_UP:
+					slider.stopDrag()
+					if(stage) stage.removeEventListener(MouseEvent.MOUSE_MOVE, onSliderMove)
+					setCurrentScroll(((slider.y - uArrow.height)/(sliderSpace-slider.height))*100) // set the scroll without moving the slider
+					dispatchEvent(new StandardEvent('drag', false, true));
+			}
+		}
+		protected function setCurrentScroll(val:Number):void
+		{
+			print("setCurrentScroll");
+			if(isNaN(val)) return; // return if its not a number
+			if(val < 0) val = 0 // keep value above 0
+			if(val > 100) val = 100 // keep value below 100
+			currentScroll = val;
+		}
+		protected function onSliderMove(event:MouseEvent):void
+		{
+			print("onSliderMove");
+			setCurrentScroll((slider.y - uArrow.height) / (sliderSpace - slider.height) * 100)
+			dispatch()
+		}
+		protected function onMouseWheel(mEvent:MouseEvent):void
+		{
+			trace("mousewheel");
+			scrollPagePercent(-mEvent.delta*_percentPerScroll)
+		}
+		/********** UI Actions ****************/
+		protected function setSliderPos(position:Number):void
+		{
+			if(position == currentScroll) return;
+			setCurrentScroll(position)
+			syncSlider();
+			dispatch()
+			print("setSliderPos");
+		}
+		protected function syncSlider():void
+		{
+			print("synchSlider");
+			slider.y = Math.round((currentScroll/100) * (sliderSpace - slider.height) + uArrow.height);  // locate the slider at the correct y location
+		}
+		protected function scrollPagePercent(percent:Number):void
+		{
+			print("scrollPagePercent");
+			if(_totalLines >0 && _linesPerPage > 0)
+			{
+				scrollIncriment((_linesPerPage * (percent/100)) * (100/(_totalLines-_linesPerPage)))
+			}
+		}
+		protected function scrollIncriment(delta:Number):void
+		{
+			setSliderPos(currentScroll + delta);
+			print("scrollIncriment");
+		}
+		protected function dispatch():void
+		{
+			//Dispatches event "scroll"
+			dispatchEvent(new StandardEvent(ScrollBar_base.SCROLL, currentScroll));
+		}
+		public override function destroy():void
+		{
+			slider.removeEventListener(MouseEvent.ROLL_OVER, sliderEvents);
+			slider.removeEventListener(MouseEvent.ROLL_OUT, sliderEvents);
+			slider.removeEventListener(MouseEvent.DOUBLE_CLICK, sliderEvents);
+			slider.removeEventListener(MouseEvent.MOUSE_DOWN, sliderEvents);
+			stage.removeEventListener(MouseEvent.MOUSE_UP, sliderEvents);
+			stage.removeEventListener(MouseEvent.MOUSE_MOVE, onSliderMove)
+			super.destroy();
+		}
+		/********** GETTERS/SETTERS ****************/
+		public function set totalLines(lines:Number):void
+		{
+			if(_totalLines != lines)
+			{
+				_totalLines = lines;
+				if(_linesPerPage >= 0 && stage != null)
+				{
+					drawSlider()
+					syncSlider()
+				}
+			}
+			print("setTotalLines");
+		}
+		public function get totalLines():Number
+		{
+			return _totalLines;
+		}
+		public function set linesPerPage(lines:Number):void
+		{
+			if(_linesPerPage != lines)
+			{
+				_linesPerPage = lines;
+				if(_totalLines >= 0 && stage != null)
+				{
+					drawSlider()
+					syncSlider()
+				}
+			}
+			print("setLinesPerPage");
+		}
+		public function get linesPerPage():Number
+		{
+			return _linesPerPage;
+		}
+		public function set scroll(scroll:Number):void
+		{
+			setSliderPos(scroll)
+			print("setscroll");
+		}
+		public function get scroll():Number
+		{
+			return currentScroll;
+		}
+		public function get wheelEnabled():Boolean
+		{
+			return _wheelEnabled;
+		}
+		public function set wheelEnabled(val:Boolean):void
+		{
+			var target:Sprite = Sprite(parent);
+			if(val && !target.hasEventListener(MouseEvent.MOUSE_WHEEL)) target.addEventListener(MouseEvent.MOUSE_WHEEL, onMouseWheel,false,0,true)
+			else if(!val) target.removeEventListener(MouseEvent.MOUSE_WHEEL, onMouseWheel)
+			_wheelEnabled = val;
+		}
+		public function get numPages():Number
+		{
+			return _totalLines/_linesPerPage;
+		}
+		public function set page(v:Number):void
+		{
+			setSliderPos((v / (numPages - 1)) * 100)
+			print("set page");
+		}
+		public function get page():Number
+		{
+			return Math.round((currentScroll/100)*(numPages-1))
+		}
+		public override function set x(val:Number):void
+		{
+			super.x = val;
+			_xHasBeenModified = true;
+		}
+		public override function set height(v:Number):void
+		{
+			autoHeight = v == -1;
+			_height = v
+			//mkArrows();
+			//mkBackground(); // need arrow sized before calculation for the background
+//			mkSlider();// need background before calculation of this
+			redraw();
+			//x -= width + 10;
+//			if(stage != null)
+//			{
+//				drawBackground()
+//				drawSlider()
+//				syncSlider()
+//				dArrow.y = v
+//			}
+		}
+		public function set scrollByPercent(val:Number):void
+		{
+			_percentPerScroll = val
+			print("scrollByPercent");
+		}
+		public function get scrollByPercent():Number
+		{
+			return _percentPerScroll;
+		}
+		public function set scrollByPagePercent(val:Number):void
+		{
+			if(_totalLines >0 && _linesPerPage > 0)
+			{
+				_percentPerScroll = (_linesPerPage * (val/100)) * (100/(_totalLines-_linesPerPage))
+			}
+			print("scrollByPagePercent");
+		}
+		public function get scrollByPagePercent():Number
+		{
+			return _percentPerScroll;
+		}
+		public function set scrollByLines(val:Number):void
+		{
+			scrollByPagePercent = (1 / _linesPerPage * 100) * val
+			print("scrollByLines");
+		}
+		public function get scrollByLines():Number
+		{
+			return _percentPerScroll/100 * _linesPerPage
+		}
+	}
+}