mako 0.0.0

data/lib/mako/data/flash_widget_dev_core/src/nm/draw/Color.as

@@ -0,0 +1,102 @@
+package nm.draw {
+	public class Color {
+		private var _hex:uint;  // Hex representation for numbers
+		private var _rgb:Array; // Red/Green/Blue
+		private var _hsb:Array; // Hue/Saturation/Brightness
+		public function Color(value:uint) { _hex = value; }
+		//----------------------------------
+		//  Hex (hexadecimal representation of color)
+		//----------------------------------
+		public function get value():uint { return hex; }
+		public function set value(value:uint):void { hex = value }
+		public function get hex():uint { return _hex; }
+		public function set hex(value:uint):void
+		{
+			_hex = value;
+			_rgb = _hsb = null;
+		}
+		//----------------------------------
+		//  RGB (Red-Green-Blue)
+		//----------------------------------
+		public function get rgb():Array
+		{
+			if(_rgb != null) return _rgb;
+			var result:Array = new Array(3);
+			result[0] = _hex >> 16;
+			result[1] = _hex >> 8 & 0xff;
+			result[2] = _hex & 0xff;
+			return result;
+		}
+		public function set rgb(colors:Array):void
+		{
+			_rgb = colors;
+			_hsb = null;
+			_hex = colors[0] << 16 ^ colors[1] << 8 ^ colors[2];
+		}
+		public function get red():int   { return this.rgb[0]; }
+		public function get green():int { return this.rgb[1]; }
+		public function get blue():int  { return this.rgb[2]; }
+		public function set red(val:int):void   { var rgb:Array = this.rgb; this.rgb = new Array(val, rgb[1], rgb[2]); }
+		public function set green(val:int):void { var rgb:Array = this.rgb; this.rgb = new Array(rgb[0], val, rgb[2]); }
+		public function set blue(val:int):void  { var rgb:Array = this.rgb; this.rgb = new Array(rgb[0], rgb[1], val); }
+		//----------------------------------
+		//  HSB (Hue-Saturation-Brightness)
+		//----------------------------------
+		public function get hsb():Array
+		{
+			// re-use any saved objects
+			if(_hsb != null) return _hsb;
+			if(_rgb == null) _rgb = this.rgb;
+			// prepare variables to be used
+			var rgb:Array = [_rgb[0], _rgb[1], _rgb[2]];
+			var x:Number, f:Number, i:Number, hue:int, sat:int, bright:int;
+			rgb[0] /= 255;
+			rgb[1] /= 255;
+			rgb[2] /= 255;
+			// check if shade of gray
+			x = Math.min(rgb[0], rgb[1], rgb[2]);
+			bright = Math.max(rgb[0], rgb[1], rgb[2]);
+			if(x==bright) return new Array(0, 0, bright * 100);
+			// get hue/sat/bright
+			f = (rgb[0] == x) ? rgb[1] - rgb[2] : ((rgb[1] == x) ? rgb[2] - rgb[0] : rgb[0] - rgb[1]);
+			i = (rgb[0] == x) ? 3 : ((rgb[1] == x) ? 5 : 1);
+			hue = Math.floor((i - f / (bright - x)) * 60) % 360;
+			sat = Math.floor(((bright - x) / bright) * 100);
+			bright = Math.floor(bright * 100);
+			return new Array(hue, sat, bright);
+		}
+		public function set hsb(values:Array):void
+		{
+			_hsb = values;
+			var red:Number, green:Number, blue:Number, i:int, f:Number, p:Number, q:Number, t:Number;
+			values[0] %= 360;
+			// check if black
+			if(values[2] == 0) { rgb = new Array(0, 0, 0); return; }
+			values[1] /= 100;
+			values[2] /= 100;
+			values[0] /= 60;
+			i = Math.floor(values[0]);
+			f = values[0] - i;
+			p = values[2] * (1-values[1]);
+			q = hsb[2] * (1-(values[1] * f));
+			t = values[2] * (1 - (values[1] * (1 - f)));
+			if (i == 0) { red = values[2]; green = t; blue = p; }
+			else if (i == 1) { red = q; green = values[2]; blue = p; }
+			else if (i == 2) { red = p; green = values[2]; blue = t; }
+			else if (i == 3) { red = p; green = q; blue = values[2]; }
+			else if (i == 4) { red = t; green = p; blue = values[2]; }
+			else if (i == 5) { red = values[2]; green = p; blue = q; }
+			red = Math.floor(red * 255);
+			green = Math.floor(green * 255);
+			blue = Math.floor(blue * 255);
+			rgb = new Array(red, green, blue);
+			return;
+		}
+		public function get hue():int { return this.hsb[0]; }
+		public function get saturation():int { return this.hsb[1]; }
+		public function get brightness():int { return this.hsb[2]; }
+		public function set hue(val:int):void        { var hsb:Array = this.hsb; this.hsb = new Array(val, hsb[1], hsb[2]); }
+		public function set saturation(val:int):void { var hsb:Array = this.hsb; this.hsb = new Array(hsb[0], val, hsb[2]); }
+		public function set brightness(val:int):void { var hsb:Array = this.hsb; this.hsb = new Array(hsb[0], hsb[1], val); }
+	}
+}

data/lib/mako/data/flash_widget_dev_core/src/nm/draw/Draw.as

@@ -0,0 +1,65 @@
+/* See the file "LICENSE.txt" for the full license governing this code. */
+package nm.draw{
+	import flash.display.DisplayObject;
+	import flash.display.Sprite;
+	public class Draw{
+		static public function drawArray(target:Sprite, cmdArr:Array, color:* = 0, alpha:Number = 1):void{
+			if(target is Sprite){
+				if(color is Number){
+					if(isNaN(alpha)) alpha = 1
+					cmdArr.unshift({t:'SC', c:color, a:alpha});
+				}
+				else if(color is Object){
+					color.t = 'GC';
+					cmdArr.unshift(color);
+				}
+				var len:Number = cmdArr.length;
+				var cmd:Object
+				var i:int;
+				with(target.graphics){
+					lineStyle(null, null, 0);
+					for(i=0; i<len; i++){
+						cmd = cmdArr[i];
+						switch(cmd.t){
+							case 'M':
+								moveTo(cmd.x, cmd.y);
+								break;
+							case 'SC': // Solid Color Change
+								beginFill(cmd.c, cmd.a);
+								break;
+							case 'GC': // Gradient Color Change
+								beginGradientFill(cmd.s, cmd.c, cmd.a, cmd.r, cmd.m);
+								break;
+							case 'LS': // Line Style
+								lineStyle(cmd.s, cmd.c, cmd.a, cmd.ph, cmd.scale, cmd.cap, cmd.j, cmd.m)
+								break;
+							case 'GL': // Gradient Line Style
+								lineGradientStyle(cmd.s, cmd.c, cmd.a, cmd.r, cmd.m);
+								break;
+							case 'C': // curve to
+								curveTo(cmd.cx, cmd.cy, cmd.x, cmd.y);
+								break;
+							// New AS3 Drawing functions
+							case 'R': // Rectangle
+								drawRect(cmd.x, cmd.y, cmd.w, cmd.h);
+								break;
+							case 'RR': // Rounded Rectangle
+								drawRoundRect(cmd.x, cmd.y, cmd.w, cmd.h, cmd.ew, cmd.eh);
+								break;
+							case 'CIR': // Draw Circle
+								drawCircle(cmd.x, cmd.y, cmd.r);
+								break;
+							case 'E': // Draw Ellipse
+								drawEllipse(cmd.x, cmd.y, cmd.w, cmd.h)
+								break;
+							default: // Line to
+								lineTo(cmd.x, cmd.y);
+								break;
+						}
+					}
+					endFill();
+				}
+			}
+		}
+	}
+}

data/lib/mako/data/flash_widget_dev_core/src/nm/draw/lines/Dashed.as

@@ -0,0 +1,48 @@
+/* See the file "LICENSE.txt" for the full license governing this code. */
+package nm.draw.lines{
+	import flash.display.MovieClip;
+	import nm.draw.Draw;
+	public class Dashed{
+		public static function draw(target:MovieClip, startx:Number, starty:Number, endx:Number, endy:Number, len:Number, gap:Number, stroke:Number, fill:Number, alpha:Number):void{
+			target.graphics.lineStyle(stroke, fill, alpha)
+			var dArr:Array = new Array({t:'LS', s:stroke, c:fill, a:alpha, ph:true, scale:'normal', cap:'none', j:'bevel'})
+			// init vars
+			var seglength:Number, deltax:Number, deltay:Number, segs:Number, cx:Number, cy:Number;
+			// calculate the legnth of a segment
+			seglength = len + gap;
+			// calculate the length of the dashed line
+			deltax = endx - startx;
+			deltay = endy - starty;
+			var delta:Number = Math.sqrt((deltax * deltax) + (deltay * deltay));
+			// calculate the number of segments needed
+			segs = Math.floor(Math.abs(delta / seglength));
+			// get the angle of the line in radians
+			var radians:Number = Math.atan2(deltay,deltax);
+			// start the line here
+			cx = startx;
+			cy = starty;
+			// add these to cx, cy to get next seg start
+			deltax = Math.cos(radians)*seglength;
+			deltay = Math.sin(radians)*seglength;
+			// loop through each seg
+			for (var n:int = 0; n < segs; n++) {
+				dArr.push({t:'M', x:cx, y:cy})
+				dArr.push({x:cx+Math.cos(radians)*len,y:cy+Math.sin(radians)*len})
+				cx += deltax;
+				cy += deltay;
+			}
+			// handle last segment as it is likely to be partial
+			dArr.push({t:'M',x:cx, y:cy});
+			//target.moveTo(cx,cy);
+			delta = Math.sqrt((endx-cx)*(endx-cx)+(endy-cy)*(endy-cy));
+			if(delta>len){
+				// segment ends in the gap, so draw a full dash
+				dArr.push({x:cx+Math.cos(radians)*len,y:cy+Math.sin(radians)*len})
+			} else if(delta>0) {
+				dArr.push({x:cx+Math.cos(radians)*delta,y:cy+Math.sin(radians)*delta})
+				// segment is shorter than dash so only draw what is needed
+			}
+			Draw.drawArray(target, dArr, 0, 0);
+		}
+	}
+}

data/lib/mako/data/flash_widget_dev_core/src/nm/draw/lines/Dotted.as

@@ -0,0 +1,83 @@
+/* See the file "LICENSE.txt" for the full license governing this code. */
+/*
+* Code written by Nick Birnbaum
+NewMedia - Course Development & Web Services - University of Central Florida
+*/
+package nm.draw.lines{
+	import flash.display.Graphics;
+	public class Dotted{
+		/**
+		* Draw a dotted line.
+		*
+		* @param	theGraphics	a Sprite's graphics to draw with
+		* @param	startX		the x value of the line start location
+		* @param	startY		the y value of the line start location
+		* @param	endX		the x value of the line end location
+		* @param	endY		the y value of the line end location
+		* @param	size		the lenght of the dashes and spaces in a dotted line
+		*/
+		public static function lineTo(theGraphics:Graphics, startX:Number, startY:Number, endX:Number, endY:Number, size:Number):void
+		{
+			// draw a dotted line on graphics to xPos, yPos with dashes and spaces of lenght size
+			var switched:Boolean = false; // if the end and the beginning were switched to make things work
+			if(endX < startX){
+				switched = true;
+				var tmp:Number;
+				tmp = startX;
+				startX = endX;
+				endX = tmp;
+				tmp = startY;
+				startY = endY;
+				endY = tmp;
+			}
+			var rise:Number = endY - startY;
+			var run:Number = endX - startX;
+			var length:Number = Math.sqrt(rise*rise + run*run);
+			var angle:Number = Math.atan(rise/run);
+			var sizeX:Number = size * Math.cos(angle);
+			var sizeY:Number = size * Math.sin(angle);
+			var curX:Number = startX, curY:Number = startY;
+			theGraphics.moveTo(startX, startY);
+			var rising:Boolean = true;
+			if(curY < endY) rising = false;
+			if(curX == endX){ // vertical line
+				while(curY < endY){
+					curY += sizeY; if( curY > endY) curY = endY;
+					theGraphics.lineTo(curX, curY);
+					curY += sizeY; if( curY > endY) curY = endY;
+					theGraphics.moveTo(curX, curY);
+				}
+			}
+			else{
+			while(curX < endX ){
+				curX+= sizeX;
+				curY+= sizeY;
+				if(curX > endX) curX = endX;
+				if(! rising){ // stop and start line at the right place
+					if(curY > endY) curY = endY;
+				}
+				else{
+					if(curY < endY){
+						curY = endY;
+					}
+				}
+				theGraphics.lineTo(curX,curY); // a dash
+				curX+= sizeX;
+				curY+= sizeY;
+				if(! rising){ //  stop and star the line at the right place
+					if(curY > endY) curY = endY;
+				}
+				else{
+					if(curY < endY){
+						curY = endY;
+					}
+				}
+				theGraphics.moveTo(curX, curY); // a space
+			}
+			}
+			if(switched){
+				theGraphics.moveTo(startX, startY); // this originally was the end, where the next line wants to pick up from
+			}
+		}
+	}
+}

data/lib/mako/data/flash_widget_dev_core/src/nm/draw/shapes/Check.as

@@ -0,0 +1,27 @@
+/* See the file "LICENSE.txt" for the full license governing this code. */
+package nm.draw.shapes {
+import flash.display.MovieClip;
+import flash.display.Sprite;
+	import nm.draw.Draw;
+	public class Check
+	{
+		static public function draw(targ:MovieClip, x:Number, y:Number, w:Number, h:Number, fill:Number, stroke:Number, alpha:Number):void
+		{
+			if(isNaN(alpha)) alpha = 100
+			// make sure the stroke is reasonable
+			if(stroke > h/2 || stroke > w/2) stroke = (h >= w) ? h/2 : w/2
+			// keep the check box inside the bounding box by manipulating x,y,h,w to compensate
+			var hS:Number = stroke/2
+			x = x + hS;
+			y = y + hS;
+			w = w - stroke;
+			h = h - stroke
+			Draw.drawArray(targ,new Array(
+				{t:'LS', s:stroke, c:fill, a:alpha, ph:false, scale:true, cap:"round", j:"round", m:2},
+				{t:'M',x:x,y:y+h/2},
+				{x:x+w/3,y:y+h},
+				{x:w+x,y:y}
+			));
+		}
+	}
+}

data/lib/mako/data/flash_widget_dev_core/src/nm/draw/shapes/Rect.as

@@ -0,0 +1,12 @@
+/* See the file "LICENSE.txt" for the full license governing this code. */
+package nm.draw.shapes{
+	import flash.display.Sprite;
+	import nm.draw.Draw;
+	public class Rect
+	{
+		static public function draw(target:Sprite, x:Number, y:Number, w:Number, h:Number, fill:Number = 0, alpha:Number = 1):void
+		{
+			Draw.drawArray(target, new Array({t:'R', x:x, y:y, w:w, h:h}), fill, alpha);
+		}
+	}
+}

data/lib/mako/data/flash_widget_dev_core/src/nm/draw/shapes/RectBevel.as

@@ -0,0 +1,35 @@
+/* See the file "LICENSE.txt" for the full license governing this code. */
+package nm.draw.shapes{
+	import flash.display.DisplayObject;
+	import flash.display.Sprite
+	import nm.draw.Draw;
+	public class RectBevel{
+		static public function draw(target:Sprite, x:Number, y:Number, w:Number, h:Number, thickness:Number, TopColor:Number, BottomColor:Number):void {
+			w += x;		//Adjust values of w and h to take
+			h += y;		//into acount x and y
+			var p1:Object = {x:w-thickness, y:y+thickness}
+			var p2:Object = {x:w, y:y}
+			var p3:Object = {x:x+thickness, y:h-thickness}
+			var p4:Object = {x:x, y:h}
+			Draw.drawArray(target, new Array(
+					{t:'SC', c:TopColor, a:100},
+					{t:'M',x:x,y:y},
+					p2,
+					p1,
+					{x:x+thickness,y:y+thickness},
+					p3,
+					p4,
+					{x:x,y:y},
+					{t:'SC', c:BottomColor, a:100},
+					{t:'M',x:w,y:h},
+					p2,
+					p1,
+					{x:w-thickness,y:h-thickness},
+					p3,
+					p4,
+					{x:w,y:h}
+				)
+			);
+		}
+	}
+}

data/lib/mako/data/flash_widget_dev_core/src/nm/draw/shapes/RectBorder.as

@@ -0,0 +1,39 @@
+/* See the file "LICENSE.txt" for the full license governing this code. */
+/*
+* Code written by Ian Turgeon
+NewMedia - Course Development & Web Services - University of Central Florida
+newmedia.cdws.ucf.edu  cdws.ucf.edu   ucf.edu
+Unless expicetely given permission, you are prohibited from using this code or any derrivitives of it.
+This code is provided as is and it's creators are not responsible for support or continuing development in any way.
+*/
+package nm.draw.shapes{
+	import nm.draw.Draw
+	import flash.display.Sprite
+	public class RectBorder{
+			/**
+		* Draw a rectangular border
+		* @param	targ[MovieClip]	Target scope to draw on
+		* @param	x[Number]	X coordinate to start drawing the upper left corner at
+		* @param	y[Number]	Y coordinate to start drawwing the upper left corner at
+		* @param	w[Number]	Width of the rectangle
+		* @param	h[Number]	Height of the rectangle
+		* @param	stroke[Number]	Inward pixel width of the border
+		* @param	fill[]	Either a Numeric color or a gradient fill object
+		* @param	alpha[Number]	Alpha to draw the fill at
+		*/
+			static public function draw(targ:Sprite, x:Number, y:Number, w:Number, h:Number, stroke:Number, fill:Number, alpha:Number = 1):void{
+			Draw.drawArray(targ,new Array(
+				{t:'M', x:x, y:y},
+				{x:w+x, y:y},
+				{x:w+x, y:y+h},
+				{x:x, y:y+h},
+				{x:x,y:y},
+				{t:'M', x:x+stroke, y:y+stroke},
+				{x:x+w-stroke, y:y+stroke},
+				{x:x+w-stroke, y:y+h-stroke},
+				{x:x+stroke, y:y+h-stroke},
+				{x:x+stroke, y:y+stroke}
+			) ,fill, alpha);
+		}
+	}
+}

data/lib/mako/data/flash_widget_dev_core/src/nm/draw/shapes/RectRound.as

@@ -0,0 +1,33 @@
+/* See the file "LICENSE.txt" for the full license governing this code. */
+package nm.draw.shapes {
+	import flash.display.Sprite;
+	import nm.draw.Draw;
+	public class RectRound{
+		static public function draw(targ:Sprite, x:Number, y:Number, w:Number,  h:Number, radius:*, fill:Object=0, lineStyle:Array=null, alpha:Number=100):void{
+			var arr:Array = new Array()
+			var r1:Number
+			var r2:Number
+			var r3:Number
+			var r4:Number
+			// if r is a Number, use as3 graphics.drawRoundRect
+			if(radius is Number) {
+				var rNum:Number = Number(radius);
+				arr.push({t:'RR', x:x, y:y, w:w, h:h, ew:rNum*2, eh:rNum*2});
+			}
+			// if r is an array, use each of the four values for each corner
+			else{
+				var rArr:Array = radius as Array;
+				if(lineStyle != null) arr.push({t:'LS', s:lineStyle[0], c:lineStyle[1], a:lineStyle[2] == null ? 1 : lineStyle[2], ph:lineStyle[3], scale:lineStyle[4], cap:lineStyle[5], j:lineStyle[6], m:lineStyle[7]});
+				arr.push({t:'M', x:x, y:y+rArr[0]}) // move to the first point below the top left curve
+				arr.push({t:'C', cx:x, cy:y, x:x+rArr[0], y:y}) // curve the top left corner
+				arr.push({x:x+w-rArr[1], y:y}) // line to the top right corner
+				arr.push({t:'C',cx:x+w, cy:y, x:x+w, y:y+rArr[1]}) // curve for the top right corner
+				arr.push({x:x+w, y:y+h-rArr[2]}) // line to the bottom right
+				arr.push({t:'C', cx:x+w, cy:y+h, x:x+w-rArr[2], y:y+h}) // curve for the botton right
+				arr.push({x:x+rArr[3], y:y+h}) // line to the bottom left corner
+				arr.push({t:'C', cx:x, cy:y+h, x:x, y:y+h-rArr[3]}) // curve for the bottom left
+			}
+			Draw.drawArray(targ, arr, fill, alpha); // send the drawing array to the drawing class
+		}
+	}
+}

data/lib/mako/data/flash_widget_dev_core/src/nm/draw/shapes/RectRoundBorder.as

@@ -0,0 +1,62 @@
+/* See the file "LICENSE.txt" for the full license governing this code. */
+/*
+* Code written by Anthony Reyes
+NewMedia - Course Development & Web Services - University of Central Florida
+newmedia.cdws.ucf.edu  cdws.ucf.edu   ucf.edu
+Unless expicetely given permission, you are prohibited from using this code or any derrivitives of it.
+This code is provided as is and it's creators are not responsible for support or continuing development in any way.
+*/
+package nm.draw.shapes {
+	import flash.display.Sprite;
+	import nm.draw.Draw;
+	public class RectRoundBorder{
+		/**
+		* Draw a rectangular border
+		* @param	targ[MovieClip]	Target scope to draw on
+		* @param	x[Number]	X coordinate to start drawing the upper left corner at
+		* @param	y[Number]	Y coordinate to start drawwing the upper left corner at
+		* @param	w[Number]	Width of the rectangle
+		* @param	h[Number]	Height of the rectangle
+		* @param	stroke[Number]	Inward pixel width of the border
+		* @param	fill[]	Either a Numeric color or a gradient fill object
+		* @param	alpha[Number]	Alpha to draw the fill at
+		*/
+		public static function draw(targ:Sprite, x:Number, y:Number, w:Number, h:Number, stroke:Number, radius:*, fill:Number, alpha:Number):void{
+			var r1:Number
+			var r2:Number
+			var r3:Number
+			var r4:Number
+			var r5:Number
+			// if r is a Number, use that value for all 4 corners
+			if(radius is Number) {
+				var rNum:Number = Number(radius);
+				r2 = r3 = r4 = r1 = rNum;
+			}
+			else{
+				var rArr:Array = radius as Array;
+				r1 = rArr[0] // top left
+				r2 = rArr[1] // top right
+				r3 = rArr[2] // bottom right
+				r4 = rArr[3] // bottom left
+			}
+			Draw.drawArray(targ,new Array(
+				{t:'M', x:x, y:y+r1},
+				{t:'C', cx:x, cy:y, x:x+r1, y:y},
+				{x:x+w-r2, y:y},
+				{t:'C', cx:x+w, cy:y, x:x+w, y:y+r2},
+				{x:x+w, y:y+h-r3},
+				{t:'C', cx:x+w, cy:y+h, x:x+w-r3, y:y+h},
+				{x:x+r4, y:y+h},
+				{t:'C', cx:x, cy:y+h, x:x, y:y+h-r4},
+				{t:'M', x:x+stroke, y:y+r1+stroke}, /* move to the first point below the top left curve */
+				{t:'C', cx:x+stroke, cy:y+stroke, x:x+r1+stroke, y:y+stroke}, /* curve the top left corner */
+				{x:x+w-r2-stroke, y:y+stroke}, /* line to the top right corner */
+				{t:'C', cx:x+w-stroke, cy:y+stroke, x:x+w-stroke, y:y+r2+stroke}, /* curve for the top right corner */
+				{x:x+w-stroke, y:y+h-r3-stroke}, /* line to the bottom right */
+				{t:'C', cx:x+w-stroke, cy:y+h-stroke, x:x+w-r3-stroke, y:y+h-stroke}, /* curve for the botton right */
+				{x:x+r4+stroke, y:y+h-stroke}, /* line to the bottom left corner */
+				{t:'C', cx:x+stroke, cy:y+h-stroke, x:x+stroke, y:y+h-r4-stroke} /* curve for the bottom left */
+			) ,fill, alpha);
+		}
+	}
+}

data/lib/mako/data/flash_widget_dev_core/src/nm/draw/shapes/TriangleEquilateral.as

@@ -0,0 +1,25 @@
+/* See the file "LICENSE.txt" for the full license governing this code. */
+package nm.draw.shapes{
+	import nm.draw.Draw
+	import flash.display.Sprite
+	public class TriangleEquilateral{
+		static public function draw(targ:Sprite, direction:String, x:Number, y:Number, w:Number, h:Number, fill:Number = 0, alpha:Number = 100):void{
+			var arr:Array
+			switch(direction){
+				case 'up':
+					arr = [{t:'M', x:x, y:y+h}, {x:x+w, y:y+h}, {x:x+w/2,y:y}]
+					break;
+				case 'down':
+					arr = [{t:'M', x:x, y:y}, {x:x+w, y:y}, {x:x+w/2,y:y+h}]
+					break;
+				case 'right':
+					arr = [{t:'M', x:x, y:y}, {x:x, y:y+h}, {x:x+w,y:y+h/2}]
+					break;
+				case 'left':
+					arr = [{t:'M', x:x+w, y:y}, {x:x+w, y:y+h}, {x:x,y:y+h/2}]
+					break;
+			}
+			Draw.drawArray(targ,arr, fill, alpha);
+		}
+	}
+}

data/lib/mako/data/flash_widget_dev_core/src/nm/draw/shapes/X.as

@@ -0,0 +1,28 @@
+/* See the file "LICENSE.txt" for the full license governing this code. */
+package nm.draw.shapes {
+import flash.display.MovieClip;
+import flash.display.Sprite;
+import nm.draw.Draw;
+	public class X
+	{
+		static public function draw(targ:MovieClip, x:Number, y:Number, w:Number, h:Number, fill:Number, stroke:Number, alpha:Number):void
+		{
+			if(isNaN(alpha)) alpha = 100
+			// make sure the stroke is reasonable
+			if(stroke > h/2 || stroke > w/2) stroke = (h >= w) ? h/2 : w/2
+			// keep the check box inside the bounding box by manipulating x,y,h,w to compensate
+			var hS:Number = stroke/2
+			x = x + hS;
+			y = y + hS;
+			w = w - stroke;
+			h = h - stroke
+			Draw.drawArray(targ,new Array(
+				{t:'LS', s:stroke, c:fill, a:alpha, ph:false, scale:true, cap:"round", j:"round", m:2},
+				{t:'M',x:x,y:y},
+				{x:x+w,y:y+h},
+				{t:'M',x:x,y:y+h},
+				{x:w+x,y:y}
+			));
+		}
+	}
+}

data/lib/mako/data/flash_widget_dev_core/src/nm/errors/ScoringError.as

@@ -0,0 +1,10 @@
+package nm.errors
+{
+public class ScoringError extends Error
+{
+	public function ScoringError(message:* = "", id:* = 0)
+	{
+		super(message, id);
+	}
+}
+}

data/lib/mako/data/flash_widget_dev_core/src/nm/errors/StorageError.as

@@ -0,0 +1,10 @@
+package nm.errors
+{
+public class StorageError extends Error
+{
+	public function StorageError(message:* = "", id:* = 0)
+	{
+		super(message, id);
+	}
+}
+}

data/lib/mako/data/flash_widget_dev_core/src/nm/events/ButtonEvent.as

@@ -0,0 +1,25 @@
+/* See the file "LICENSE.txt" for the full license governing this code. */
+package nm.events
+{
+import flash.events.Event;
+/**
+ * Handles events sent by the Button_base class
+ * @author Anthony Reyes
+ */
+public class ButtonEvent extends Event
+{
+	public static var PRESSED:String = "button-pressed";
+	public function ButtonEvent(type:String, bubbles:Boolean=false, cancelable:Boolean=false)
+	{
+		super(type, bubbles, cancelable);
+	}
+	public override function clone():Event
+	{
+		return new ButtonEvent(type, bubbles, cancelable);
+	}
+	public override function toString():String
+	{
+		return formatToString("ButtonEvent", "type", "bubbles", "cancelable", "eventPhase");
+	}
+}
+}

data/lib/mako/data/flash_widget_dev_core/src/nm/events/PayloadEvent.as

@@ -0,0 +1,14 @@
+/* See the file "LICENSE.txt" for the full license governing this code. */
+package nm.events
+{
+	import flash.events.Event;
+	public class PayloadEvent extends Event
+	{
+		public var payload:Object
+		public function PayloadEvent(type:String, payload:Object, bubbles:Boolean=false, cancelable:Boolean=false)
+		{
+			super(type, bubbles, cancelable);
+			this.payload = payload
+		}
+	}
+}

data/lib/mako/data/flash_widget_dev_core/src/nm/events/StandardEvent.as

@@ -0,0 +1,26 @@
+/* See the file "LICENSE.txt" for the full license governing this code. */
+package nm.events
+{
+	import flash.events.Event;
+	/**
+	* ...
+	* @author Luis Estrada
+	*/
+	public class StandardEvent extends Event
+	{
+		public var result:*;
+		public function StandardEvent(type:String, result:*, bubbles:Boolean=false, cancelable:Boolean=false)
+		{
+			super(type, bubbles, cancelable);
+			this.result = result;
+		}
+		public override function clone():Event
+		{
+			return new StandardEvent(type, result, bubbles, cancelable);
+		}
+		public override function toString():String
+		{
+			return formatToString("StandardEvent2", "type", "result", "bubbles", "cancelable", "eventPhase");
+		}
+	}
+}