mako 0.0.0

data/lib/mako/data/flash_widget_dev_core/src/nm/gameServ/engines/EngineCore.as

@@ -0,0 +1,222 @@
+/* See the file "LICENSE.txt" for the full license governing this code. */
+package nm.gameServ.engines
+{
+	import flash.display.Loader;
+	import flash.display.LoaderInfo;
+	import flash.display.MovieClip;
+	import flash.display.Sprite;
+	import flash.display.StageAlign;
+	import flash.display.StageScaleMode;
+	import flash.events.Event;
+	import flash.external.ExternalInterface;
+	import flash.net.URLRequest;
+	import flash.system.Security;
+	import flash.system.LoaderContext;
+	import nm.gameServ.common.QuestionSet;
+	import nm.gameServ.common.logging.Log;
+	import nm.gameServ.common.scoring.Scoring;
+	import nm.gameServ.common.storage.StorageManager;
+	import nm.ui.AlertWindow;
+	import nm.ui.layout.WindowManager;
+	import org.rubyamf.remoting.ssr.ResultEvent;
+
+	public class EngineCore extends Sprite
+	{
+		public static var qSetData:QuestionSet;
+		public static var qSetVersion:String;
+		public var inst:Object;
+		public var widget:Object;
+		public var scoring:Scoring;
+		public var storage:StorageManager;
+		private var _gameEndSent:Boolean = false;
+		private var _showScoreScreenOnEnd:Boolean = true;
+		private var _inst_id:String;
+		private var _webroot:String;
+		private var _assetUrl:String;
+		protected var _loadingItemLoaders:Array = [];
+		protected var _loadingItemData:Array = [];
+		protected var _loadingItemCallbacks:Array = [];
+		protected var _windowManager:WindowManager;
+		protected var _windowManagerStage:MovieClip;
+
+		public function EngineCore():void
+		{
+			trace('Engine Core v2')
+			// set appropriate scaling and alignment
+			stage.scaleMode = StageScaleMode.NO_SCALE;
+			stage.align = StageAlign.TOP_LEFT;
+			// load variables passed in through JS wrapper
+			loadFlashvars();
+			// allow compatability with obojobo
+			Security.allowDomain('https://obojobo.ucf.edu');
+			Security.allowInsecureDomain('http://obo');
+			Security.loadPolicyFile(_webroot+'crossdomain.xml');
+			// allow static files to be hosted from subdomain and still talk to materia
+			if (_webroot.indexOf('https'))
+			{
+				Security.allowDomain(_webroot);
+			}
+			else
+			{
+				Security.allowInsecureDomain(_webroot);
+			}
+			// create the window manager
+			_windowManagerStage = new MovieClip();
+			_windowManager = new WindowManager(_windowManagerStage);
+			stage.addChild(_windowManagerStage);
+			stage.setChildIndex(_windowManagerStage, stage.numChildren - 1);
+			ExternalInterface.addCallback("initWidget", initWidget);
+			// make sure stage is added beore taking any action
+			if(stage == null) addEventListener(Event.ADDED_TO_STAGE, onEngineCoreReady, false, 0, true);
+			else onEngineCoreReady();
+		}
+
+		public function onEngineCoreReady(e:Event = null):void
+		{
+			// remove added to stage listener
+			if(this.hasEventListener(Event.ADDED_TO_STAGE)) removeEventListener(Event.ADDED_TO_STAGE, onEngineCoreReady);
+			// let JS wrapper know engine is ready for qset
+			ExternalInterface.call("__materia_onWidgetReady");
+		}
+
+		private function initWidget(qset:Object, instance:Object):void
+		{
+			EngineCore.qSetData = QuestionSet.convertObject(qset.data);
+			EngineCore.qSetVersion = qset.version
+			this.inst = instance
+			this.widget = instance.widget
+			scoring = new Scoring(this, widget.score_type); // initialize scoring helper class
+			storage = new StorageManager();
+			storage.addEventListener('sendStorage', onSendStorage);
+			addLog(Log.GAME_INITIALIZED);
+			startEngine();
+		}
+
+		protected function onSendStorage(event:ResultEvent):void
+		{
+			ExternalInterface.call("__materia_sendStorage", event.result);
+		}
+
+		protected function startEngine():void
+		{
+			// should be overriden in the engine
+		}
+
+		public function loadFlashvars():void
+		{
+			var params:Object = LoaderInfo(this.root.loaderInfo).parameters;
+			_inst_id = getFlashvar(params, 'inst_id');
+			_webroot = getFlashvar(params, 'URL_WEB');
+			_assetUrl = getFlashvar(params, 'URL_GET_ASSET');
+		}
+
+		public function getFlashvar(params:Object, expectedParam:String, required:Boolean=true):*
+		{
+			if(params.hasOwnProperty(expectedParam)) return params[expectedParam];
+			else if(required) throw new Error("Required param "+expectedParam+" not recieved.");
+		}
+
+		/**
+		* Log an event (logs get saved to the server periodically
+		* @param	type		Number indicating the logType this event is associated with (see the GameServ documentation (nm.gameServ.common.logging.Log.as) for the different log types)
+		* @param	identity	Number id of the item the log is associated with, for instance if the log is a question answer event, this would be the ID of the question
+		* @param	text		* text or description of the event, for instance when a score modified message is sent, this is where you could indicate what the user did to cause the modification
+		* @param	value		* typically this is a numeric or string value for the log, say its a question answer partial credit event, this would be the credit recieved for that event
+		*/
+		public function addLog(type:Number, id:String = '0', text:* = "", value:* = ""):void
+		{
+			ExternalInterface.call("__materia_addLog", {type:type, item_id:id, text:text, value:value});
+		}
+
+		/**
+		* Request a system level alert box
+		* @param	title  String   title to show in the window title bar
+		* @param	msg	   String   message to show in the content of the alert window.
+		* @param	type   int      Constant from AlertWindow class depicting the type of alert
+		*/
+		public function alert(title:String, msg:String, type:Number = 2):MovieClip
+		{
+			var a:AlertWindow = new AlertWindow(title, msg, type);
+			a._modalTarg = stage;
+			stage.setChildIndex(_windowManagerStage, stage.numChildren - 1);
+			return _windowManager.addWindow(a, false);
+		}
+
+		/**
+		 * Loads the asset with the given assetId from the server and
+		 * returns it in the given callback function.
+		 *
+		 *
+		 * @param assetId The ID of the asset to be loaded
+		 * @param callback The function to send the newly loaded sprite to. Must
+		 * accept a sprite as the first parameter and can accept the given data
+		 * object as the second parameter
+		 * @param data Data to be relayed to the callback function as the second
+		 * parameter. Allows multiple images to be loaded concurrently.
+		 */
+		protected function getImageAssetSprite(assetId:String, callback:Function, data:Object = null):void
+		{
+			var context:LoaderContext = new LoaderContext();
+			context.checkPolicyFile = true;
+			var newLoader:Loader = new Loader();
+			newLoader.contentLoaderInfo.addEventListener(Event.COMPLETE, imageLoaded, false, 0, true);
+			var request:URLRequest = new URLRequest(getImageAssetUrl(assetId));
+			_loadingItemLoaders.push(newLoader);
+			_loadingItemData.push(data);
+			_loadingItemCallbacks.push(callback);
+			newLoader.load(request, context);
+		}
+
+		public function getImageAssetUrl(assetId:String):String
+		{
+			return _webroot + _assetUrl + assetId;
+		}
+
+		protected function imageLoaded(e:Event):void
+		{
+			var index:int;
+			for(index = 0; index < _loadingItemLoaders.length; index++)
+			{
+				var l:Loader = _loadingItemLoaders[index];
+				if(l.contentLoaderInfo == e.currentTarget)
+				{
+					break;
+				}
+			}
+			var callbackFunc:* = _loadingItemCallbacks[index];
+			var loader:* = _loadingItemLoaders[index];
+			var data:* = _loadingItemData[index];
+			if( data != null )
+			{
+				callbackFunc( loader, data );
+			}
+			else
+			{
+				callbackFunc( loader );
+			}
+			_loadingItemCallbacks.splice(index, 1);
+			_loadingItemData.splice(index, 1);
+			_loadingItemLoaders.splice(index, 1);
+		}
+
+		/**
+		 * Finalizes the score, sends end game log to server and brings user
+		 * to the score screen to view results
+		 *
+		 * @param showScoreScreen Shows the score screen only if this is set to true
+		 * @param feedback Optional feedback or comments to give user about widget
+		 */
+		public function end(showScoreScreen:Boolean = true, feedback:String = null):void
+		{
+			// make sure this function can only be called once
+			if(_gameEndSent) return;
+			// save logs needed to end the game
+
+			if(feedback != null) { addLog(Log.SCORE_FEEDBACK, '0', feedback); }
+			addLog(Log.GAME_END);
+			ExternalInterface.call("__materia_end", showScoreScreen);
+
+			_gameEndSent = true;
+		}
+	}
+}

data/lib/mako/data/flash_widget_dev_core/src/nm/geom/Dimension.as

@@ -0,0 +1,76 @@
+/* See the file "LICENSE.txt" for the full license governing this code. */
+////////////////////////////////////////////////////////////////////////////////
+//
+//  UCF COURSE DEVELOPMENT AND WEB SERVICES
+//  Copyright 2010 UCF Course Development and Web Services
+//  All Rights Reserved.
+//
+//  NOTICE: Course Development and Webservices prohibits the use of the
+//  following code without explicit permission.  Permission can be obtained
+//  from the New Media team at <newmedia@mail.ucf.edu>.
+//
+////////////////////////////////////////////////////////////////////////////////
+package nm.geom
+{
+/**
+ * Stores a dimension for any 2D object.
+ *
+ * This is useful for keeping track of width/height of components
+ * because DisplayObjects in Actionscript don't have static width/heights.
+ * (Their height is determined by what's contained in them)
+ */
+public class Dimension
+{
+	/**
+	 * The width of this dimension
+	 */
+	public var width:Number;
+	/**
+	 * The height of this dimension
+	 */
+	public var height:Number;
+	/**
+	 * Creates a dimension with the specified width/height
+	 * @param width the width of this dimension
+	 * @param height the height of this dimension
+	 */
+	public function Dimension(width:Number, height:Number)
+	{
+		setDimension(width, height);
+	}
+	/**
+	 * Gets the area of this dimension
+	 * @return width * height of this dimension
+	 */
+	public function get area():Number
+	{
+		return width * height;
+	}
+	/**
+	 * Sets this dimension to the given width and height
+	 * @param width the width to set this dimension to
+	 * @param height the height to set this dimension to
+	 */
+	public function setDimension(width:Number, height:Number):void
+	{
+		this.width = width;
+		this.height = height;
+	}
+	/**
+	 * Creates a dimension with the same properties as this dimension
+	 * @return Dimension a copy of this dimension
+	 */
+	public function clone():Dimension
+	{
+		return new Dimension(width, height);
+	}
+	/**
+	 * Returns this dimension in string form [widthxheight]
+	 * @return String a dimension in string form
+	 */
+	public function toString():String
+	{
+		return "[" + width + "x" + height + "]"
+	}
+}
+}