mako 0.0.0

data/lib/mako/data/flash_widget_dev_core/src/nm/util/Printer.as

@@ -0,0 +1,548 @@
+/* See the file "LICENSE.txt" for the full license governing this code. */
+package nm.util
+{
+import flash.display.Bitmap;
+import flash.display.BitmapData;
+import flash.display.BlendMode;
+import flash.display.PixelSnapping;
+import flash.display.Sprite;
+import flash.geom.Matrix;
+import flash.geom.Rectangle;
+import flash.printing.PrintJob;
+import flash.printing.PrintJobOptions;
+import flash.text.TextField;
+import flash.text.TextFormat;
+import jac.image.ImageUtils;
+import nm.ui.layout.CenterScale;
+//import .CrosswordSpace;
+/**
+* A class that handles all printing in Flash so you don't have to.
+*
+* @author	Scott Rapp
+*/
+public class Printer
+{
+	//--------------------------------------------------------------------------
+	//
+	//  Variables
+	//
+	//--------------------------------------------------------------------------
+	/**
+	 *  Keeps track of updates between previewing. Keeps buffer preview up to date when printing occurs.
+	 */
+	private var hasPreviewed:Boolean;
+	//----------------------------------
+	//  References
+	//----------------------------------
+	private var headerMC:Sprite;
+	private var footerMC:Sprite;
+	//----------------------------------
+	//  Virtual Page Dimensions
+	//----------------------------------
+	private var PAGEWIDTH:Number;
+	private var PAGEHEIGHT:Number;
+	private var bitmapResolution:Number = 2880;
+	//----------------------------------
+	//  data storage
+	//----------------------------------
+	/**
+	 *  References to the sprites requested to be printed
+	 */
+	private var sourcePages:Array;
+	/**
+	 *  holder sprites generated by the preview function,
+	 *  used for output to the printer, contains a content clip where the bitmap is drawn
+	 */
+	private var renderedPages:Array;
+	//private var bitmapData:Array;
+	/**
+	 *  Array of bitmapData objects for each page
+	 */
+	private var bitmapDataPages:Array;
+	//----------------------------------
+	//  margin sizes
+	//----------------------------------
+	/**
+	 *  NOT the actual margins. Used in temporary margin calculation and storage.
+	 *  This is because someone can ditch the footer or header and the margin should not reset to zero.
+	 */
+	private var topMargin:Number;
+	private var bottomMargin:Number;
+	/**
+	 *  These are the ACTUAL margin sizes
+	 */
+	private var topPgMargin:Number;
+	private var bottomPgMargin:Number;
+	private var leftPgMargin:Number;
+	private var rightPgMargin:Number;
+	//----------------------------------
+	//  set/update margins
+	//----------------------------------
+	private var headerMargin:Number;
+	private var headerHeight:Number;
+	private var footerMargin:Number;
+	private var footerHeight:Number;
+	//--------------------------------------------------------------------------
+	//
+	//  Constructor
+	//
+	//--------------------------------------------------------------------------
+	/**
+	 * Creates the printer object and sets custom heights and widths for a virtual page used as a reference.
+	 *
+	 * @usage   var Printer:printer = new printer (printArea, 0, 1100, 800);
+	 * @param   print_mc     Sprite. This is a Sprite that will be used to create all printing BitmapData on.
+	 * @param   depthNum     Number. A free depth in the print_mc to create the BitmapData.
+	 * @param   customHeight Number. Optional. Send a custom height to the printer class, changing the height of the virtual page.
+	 * @param   customWidth  Number. Optional. Send a custom width to the printer class, changing the width of the virtual page.
+	 */
+	public function Printer(pageWidth:Number = 612, pageHeight:Number = 792)
+	{
+		//Initialization.
+		this.pageWidth  = pageWidth;
+		this.pageHeight = pageHeight;
+		reset();
+	}
+	//--------------------------------------------------------------------------
+	//
+	//  Member Functions
+	//
+	//--------------------------------------------------------------------------
+	/**
+	 * This function correctly disposes of BitmapData, clears the arrays of Sprites and BitmapData, resets the margins and previews, and calls resetPrintingData.
+	 *
+	 * @usage   Printer.resetBuffer();
+	 */
+	public function reset():void
+	{
+		//reset all variables
+		cleanUp();
+		sourcePages = new Array();
+		topPgMargin = bottomPgMargin = leftPgMargin = rightPgMargin = 0;
+		topMargin = bottomMargin = 0;
+		headerMargin = headerHeight = footerMargin = footerHeight = 0;
+	}
+	/**
+	 * Special internal function that clears the Printing bitmap data after each printing.
+	 */
+	public function cleanUp():void
+	{
+		for(var i:* in bitmapDataPages) bitmapDataPages[i].dispose();
+		bitmapDataPages = new Array();
+		for(var j:* in renderedPages) removeSprite(renderedPages[i]);
+		renderedPages = new Array();
+		hasPreviewed = false;
+	}
+	/**
+	 * This function sets the margins to any width in pixels. The default is 0.
+	 * A top and bottom margin may not be smaller than the header or footer, and is automatically resized.
+	 * All margins tend to be accurate except when both sets of opposing margins do not match:
+	 * Ex. 30, 40, 50, 60. Unknown, but negligable, errors seem to occur.
+	 *
+	 * @usage   Printer.setMargins(20, 20, 10, 10);
+	 * @param   top    Number. Optional. The pixel amount of the Top Margin.
+	 * @param   bottom Number. Optional. The pixel amount of the Bottom Margin.
+	 * @param   left   Number. Optional. The pixel amount of the Left Margin.
+	 * @param   right  Number. Optional. The pixel amount of the Right Margin.
+	 */
+	public function setMargins(top:Number = 0, bottom:Number = 0, left:Number = 0, right:Number = 0):void
+	{
+		topMargin = top;
+		bottomMargin = bottom;
+		leftPgMargin = left;
+		rightPgMargin = right;
+		//topMargin and bottomMargin stored in case header or footer is destroyed later
+		topPgMargin = topMargin;
+		bottomPgMargin = bottomMargin;
+		var txt:TextField;
+		//redraw header
+		if(headerMC)
+		{
+			txt = TextField(headerMC.getChildByName('txt'));
+			setHeader(headerHeight, headerMargin, txt.text, txt.getTextFormat());
+		}
+		//redraw footer
+		if(footerMC)
+		{
+			txt = TextField(footerMC.getChildByName('txt'));
+			setFooter(footerHeight, footerMargin, txt.text, txt.getTextFormat());
+		}
+		hasPreviewed = false;
+	}
+	/**
+	 *  Removes the given sprite from its parent
+	 */
+	public function removeSprite(mc:Sprite):Sprite
+	{
+		if(mc && mc.parent) mc.parent.removeChild(mc);
+		return mc;
+	}
+	/**
+	 * This places a header on the printing page, and automatically makes the top margin large enough to hold it.
+	 * The text and format are not necessary, and creating a new header destroys the old one.
+	 * Margin is the width from the top the header is moved down, while size is the size of the text field.
+	 *
+	 * @usage   Printer.setHeader ( 25, 10, "Created by New Media.", headerFormat);
+	 * @param   size       Number. The total size of the header in pixels.
+	 * @param   margin     Number. The amount of space in pixels from the top of the header the text begins.
+	 * @param   text       String. Optional. The text to appear in the header.
+	 * @param   textFormat TextFormat. Optional. A special format for the text in the header.
+	 */
+	public function setHeader(height:Number, margin:Number, text:String, textFormat:TextFormat):void
+	{
+		headerHeight = height;
+		headerMargin = margin;
+		if(height + margin > topPgMargin) topPgMargin = margin + height;
+		else topPgMargin = topMargin;
+		if(headerMC != null)
+		{
+			removeSprite(headerMC);
+			headerMC = null;
+		}
+		if(text.length > 0)
+		{
+			headerMC = new Sprite();
+			headerMC.name = "header";
+			var txt:TextField = new TextField();
+			txt.name = "txt";
+			txt.x = leftPgMargin;
+			txt.y = margin;
+			txt.width = PAGEWIDTH - rightPgMargin - leftPgMargin;
+			txt.height = height;
+			if(textFormat) txt.defaultTextFormat = textFormat;
+			txt.text = text;
+			headerMC.addChild(txt);
+		}
+		hasPreviewed = false;
+	}
+	/**
+	 * This places a footer on the printing page, and automatically makes the bottom margin large enough to hold it.
+	 * The text and format are not necessary, and creating a new footer destroys the old one.
+	 * Margin is the width from the top the footer is moved down, while size is the size of the text field.
+	 *
+	 * @usage   Printer.setFooter ( 25, 10, "Created by New Media.", footerFormat);
+	 * @param   size       Number. The total size of the footer in pixels.
+	 * @param   margin     Number. The amount of space in pixels from the top of the footer the text begins.
+	 * @param   text       String. Optional. The text to appear in the footer.
+	 * @param   textFormat TextFormat. Optional. A special format for the text in the footer.
+	 */
+	public function setFooter(height:Number, margin:Number, text:String, textFormat:TextFormat):void
+	{
+		footerHeight = height;
+		footerMargin = margin;
+		if(margin + height > bottomPgMargin) bottomPgMargin = margin + height;
+		else bottomPgMargin = bottomMargin;
+		if(footerMC != null)
+		{
+			removeSprite(footerMC);
+			footerMC = null;
+		}
+		if(text.length > 0)
+		{
+			//create the footer
+			footerMC = new Sprite();
+			footerMC.name = "footer";
+			//Add a text field to the footer
+			var txt:TextField = new TextField();
+			txt.name = "txt";
+			txt.x = leftPgMargin;
+			txt.y = PAGEHEIGHT - height;
+			txt.width = PAGEWIDTH - rightPgMargin - leftPgMargin;
+			txt.height = height;
+			if(textFormat) txt.defaultTextFormat = textFormat;
+			txt.text = "";
+			txt.text = text;
+			footerMC.addChild(txt);
+		}
+		hasPreviewed = false;
+	}
+	/**
+	 * Returns how many pages the sent sprite will take up
+	 *
+	 * @usage   var myMCpages:Number = Printer.howManyPages(myMC);
+	 * @param   mc Sprite. This is a reference to a Sprite whose dimensions vs. the virtual page determine the number of pages needed.
+	 * @return  Number. The number of pages this sprite will take to print based off the current virtual page.
+	 */
+	public function calcNumPages(mc:Sprite):Number
+	{
+		return (Math.ceil(mc.height/PAGEHEIGHT)*Math.ceil(mc.width/PAGEWIDTH));
+	}
+	/**
+	 * Returns how many pages are in the buffer.
+	 *
+	 * @usage   var totalPages:Number = Printer.pageTotal();
+	 * @return  Number. The number of pages in the entire buffer.
+	 */
+	public function pageTotal():Number
+	{
+		var count:Number = 0;
+		var numSourcePages:Number = sourcePages.length;
+		for(var i:Number = 0; i < numSourcePages; i++)
+		{
+			count += calcNumPages(sourcePages[i]);
+		}
+		return count;
+	}
+	/**
+	 * Adds the sprite to the sprite array for printing. Any changes to the sprite will be reflected at printing.
+	 *
+	 * @usage   Printer.addPage(page3_mc);
+	 * @param   mc_page Sprite. This is a reference to the Sprite that is to be added to the buffer.
+	 */
+	public function addPage(mc_page:Sprite):void
+	{
+		////trace('adding page ' + mc_page)
+		sourcePages.push(mc_page);
+		hasPreviewed = false;
+	}
+	/**
+	 * Removes the specified sprite from buffer. If no sprite is specified, the last page is removed.
+	 *
+	 * @usage   Printer.removePage(2);
+	 * @param   i Number. Optional. The number of the buffer page to be removed, starting at 0.
+	 */
+	public function removePage(index:Number):void
+	{
+		if(index) index = sourcePages.length-1;
+		sourcePages.splice(index,1);
+		hasPreviewed = false;
+	}
+	/**
+	 * Returns a specific page from the buffer. If no page is specified, the entire buffer Array is returned.
+	 *
+	 * @usage   var sixthPage:Sprite = Printer.viewPage(5);
+	 * @param   i Number. Optional. The number of the page in the buffer you want a reference to.
+	 * @return  Number or Array. If i is defined, that Sprite is returned as a reference. If not, an Array of all the references is returned.
+	 */
+	public function getPage(index:Number):Sprite
+	{
+		if(index) return sourcePages[index];
+		else return new Sprite();
+	}
+	/**
+	 * The preview function is automatically called by the print function if it is not called. The preview function sets up
+	 * the BitmapData and final printing pages for the print function. In addition, the preview function can be called at
+	 * any time with an object called preOb. This optional variable contains an array with information about sending a copy
+	 * of the Bitmap Data to any sprite you would like as a print preview of each page buffered. Be wary
+	 * of using this function for large print jobs too far ahead of the print function, as every page in the
+	 * buffer has a BitmapData cached for it which is not removed until resetBuffer or print functions are called.
+	 *
+	 * @usage   Printer.preview(previewInfo);
+	 */
+	public function preview():void
+	{
+		cleanUp();
+		//All of the sprites are made into bitmap data for resizing, and the BitmapData size is maxed out
+		//and scaled back down for higher resolution.
+		var scaler:Number;
+		var bodyScale:Number;
+		var mPage:Matrix = new Matrix();
+		var xCenter:Number = leftPgMargin;
+		var yCenter:Number = topPgMargin;
+		//Used for scaling down
+		var bodyH:Number = PAGEHEIGHT + topPgMargin + bottomPgMargin;
+		var bodyW:Number = PAGEWIDTH + leftPgMargin + rightPgMargin;
+		//Used for scaling up
+		var maxH:Number = PAGEHEIGHT - (topPgMargin + bottomPgMargin);
+		var maxW:Number = PAGEWIDTH -  (rightPgMargin + leftPgMargin);
+		//The highest level If statement determines whether the page's height or width is longer.
+		//The nested If statement determines whether the determines whether the difference between
+		//the page width and body width (size of page once margins are subtracted) or the page height
+		//and body height is greater. A ratio is then determined for scaling up and down successfully,
+		//thus faking margins when the process is complete and the bitmap is copied.
+		if(PAGEHEIGHT < PAGEWIDTH)
+		{ // tall page
+			scaler = bitmapResolution / PAGEWIDTH;
+			if((PAGEHEIGHT/maxH) < (PAGEWIDTH/maxW))
+			{
+				bodyScale = bitmapResolution/bodyW;
+				yCenter = (((maxH-(maxH*(maxW/PAGEWIDTH)))-(topPgMargin+bottomPgMargin))/2)+topPgMargin;
+			}
+			else{
+				bodyScale = bitmapResolution / ((PAGEWIDTH*PAGEHEIGHT)/maxH);
+				xCenter = (((PAGEWIDTH-(PAGEWIDTH*(bodyScale/scaler)))-(rightPgMargin+leftPgMargin))/2)+leftPgMargin;
+			}
+		}
+		else
+		{ // wide page
+			scaler = bitmapResolution / PAGEHEIGHT;
+			if((PAGEHEIGHT/maxH) < (PAGEWIDTH/maxW))
+			{
+				bodyScale = bitmapResolution/((PAGEWIDTH*PAGEHEIGHT)/maxW);
+				yCenter = (((PAGEHEIGHT-(PAGEHEIGHT*(bodyScale/scaler)))-(topPgMargin+bottomPgMargin))/2)+topPgMargin;
+			}
+			else
+			{
+				bodyScale = bitmapResolution/bodyH;
+				xCenter = (((maxW-(maxW*(maxH/PAGEHEIGHT)))-(rightPgMargin+leftPgMargin))/2)+leftPgMargin;
+			}
+		}
+		//Sets up the scaling/translating done to the header, footer, and body.
+		var mHeader:Matrix
+		if(headerMC)
+		{
+			mHeader = new Matrix();
+			mHeader.scale(scaler, scaler);
+		}
+		mPage.scale(bodyScale, bodyScale);
+		mPage.translate(xCenter*scaler, yCenter*scaler);
+		var mFooter:Matrix;
+		if(footerMC)
+		{
+			mFooter = new Matrix();
+			mFooter.scale(scaler, scaler);
+		}
+		//This is used to split a larger sprite into smaller ones to print on multiple pages
+		var rectClip:Rectangle = new Rectangle(xCenter*scaler, yCenter*scaler, maxW*scaler, maxH*scaler);
+		var numPages:Number = sourcePages.length
+		for(var i:Number = 0; i < numPages; i++)
+		{
+			//The first two for loops are used to determine how many pages each clip will take up, and creates them
+			//seperately.
+			var pagesHigh:Number = Math.ceil(sourcePages[i].height/PAGEHEIGHT)
+			var pagesWide:Number = Math.ceil(sourcePages[i].width/PAGEWIDTH)
+			// loop through pages high
+			for(var j:Number = 0; j < pagesHigh; j++)
+			{
+				// loop through pages wide
+				for(var k:Number = 0; k < pagesWide; k++)
+				{
+					var index:Number = bitmapDataPages.length
+					var bitmapObject:Bitmap = new Bitmap(new BitmapData(PAGEWIDTH*scaler, PAGEHEIGHT*scaler, false), PixelSnapping.NEVER, true);
+					//Create holder for the new bitmap
+					var holder:Sprite = new Sprite()
+					holder.name = "printingPage";
+					//printing_mc.addChild(holder);
+					//Create the new bitmap
+					var content:Sprite = new Sprite();
+					content.name = "content";
+					holder.addChild(content);
+					//push this page onto the printing data array
+					bitmapDataPages.push(bitmapObject.bitmapData);
+					//push a reference to the holder
+					renderedPages.push(holder);
+					content.addChild(bitmapObject)
+					//Header, footer, and body are all drawn onto the same page
+					if(headerMC != null)
+					{
+						bitmapObject.bitmapData.draw(headerMC, mHeader, null, BlendMode.NORMAL, null, true); // draw header onto the bitmapdata
+					}
+					mPage.translate(-(k*maxW)*scaler, -(j*maxH)*scaler);
+					bitmapObject.bitmapData.draw(sourcePages[i], mPage, null, BlendMode.NORMAL, rectClip, true); // draw page onto the bitmapdata
+//					content.graphics.lineStyle(5,0xff0000);
+//					content.graphics.moveTo(0,0);
+//					content.graphics.lineTo(500,500);
+					if(footerMC != null)
+					{
+						bitmapObject.bitmapData.draw(footerMC, mFooter, null, BlendMode.NORMAL, null, true); // draw footer onto the bitmapdata
+					}
+					//Scaling down
+					content.width /= scaler;
+					content.height /= scaler;
+					bitmapObject.smoothing = true;
+				}
+			}
+		}
+		hasPreviewed = true;
+	}
+	public function renderPreviewPage(pageNum:Number, height:Number, width:Number):Sprite
+	{
+		var ret:Sprite = new Sprite();
+		if(!hasPreviewed)
+		{
+			preview();
+		}
+		if(renderedPages[pageNum])
+		{
+			var scalled:BitmapData = ImageUtils.resizeImage(bitmapDataPages[pageNum], width, height, "constrainProportions")
+			ret.addChild(new Bitmap(scalled, PixelSnapping.NEVER, true))
+			//ret.addChild(new Bitmap(bitmapDataPages[pageNum], PixelSnapping.NEVER, true));
+			//CenterScale.scale(ret, height, width);
+		}
+		return ret;
+	}
+	/**
+	 * Prints all pages in the buffer and clears the temperary printing buffer. The buffer with the pages in it remains intact.
+	 *
+	 * @usage   Printer.print();
+	 */
+	public function print():void
+	{
+		//This creates a preview if one has not been created. The preview is what is sent to the printer.
+		if(!hasPreviewed)
+		{
+			preview();
+		}
+		//Set up variables
+		var widthUsed:Number = PAGEWIDTH;
+		var heightUsed:Number = PAGEHEIGHT;
+		var scaled:Number = 1;
+		var printJob:PrintJob = new PrintJob();
+		//If user selects a printer and confirms print (printJob.start() opens print dialog)
+		if(printJob.start())
+		{
+			//Check for Portrait or Landscape to use as much of the page as possible.
+			if((printJob.orientation == "landscape" && widthUsed < heightUsed) || (printJob.orientation == "portrait" && widthUsed > heightUsed))
+			{
+				var temp:Number = widthUsed;
+				widthUsed = heightUsed;
+				heightUsed = temp;
+			}
+			//Checks to see if the height and width are larger than the printer's printable area.
+			if(heightUsed > printJob.pageHeight || widthUsed > printJob.pageWidth)
+			{
+				if((heightUsed/printJob.pageHeight) > (widthUsed/printJob.pageWidth)) scaled = (printJob.pageHeight/heightUsed);
+				else scaled = (printJob.pageWidth/widthUsed);
+				heightUsed *= scaled;
+				widthUsed *= scaled;
+			}
+			//Goes through the buffer printing the pages and scaling them if the printer has its own margins.
+			var pages:Number = renderedPages.length
+			for(var i:Number = 0; i < pages; i++)
+			{
+				var backgroundSprite:Sprite = new Sprite();
+				var jj:Sprite = new Sprite();
+				jj.addChild(renderedPages[i]);
+				backgroundSprite.addChild(jj);
+				printJob.addPage(backgroundSprite, new Rectangle(0,0,PAGEWIDTH, PAGEHEIGHT), new PrintJobOptions(false));
+			}
+			printJob.send();
+			//The buffer is then cleared.
+			cleanUp();
+		}
+	}
+	public function set pageHeight(val:Number):void
+	{
+		if(!isNaN(val))
+		{
+			var prevVal:Number = PAGEHEIGHT
+			PAGEHEIGHT = val
+			if(prevVal != val) hasPreviewed = false;
+		}
+	}
+	public function get pageHeight():Number
+	{
+		return PAGEHEIGHT;
+	}
+	public function set pageWidth(val:Number):void
+	{
+		if(!isNaN(val)){
+			var prevVal:Number = PAGEWIDTH;
+			PAGEWIDTH = val
+			if(prevVal != val) hasPreviewed = false
+		}
+	}
+	public function get pageWidth():Number
+	{
+		return PAGEWIDTH;
+	}
+	public function get contentHeight():Number
+	{
+		return PAGEHEIGHT - headerMargin - headerHeight - footerMargin - footerHeight
+	}
+	public function get contentWidth():Number
+	{
+		return PAGEWIDTH - leftPgMargin - rightPgMargin;
+	}
+}
+}

data/lib/mako/data/flash_widget_dev_core/src/nm/util/StringUtil.as

@@ -0,0 +1,12 @@
+/* See the file "LICENSE.txt" for the full license governing this code. */
+package nm.util
+{
+	public class StringUtil
+	{
+		static public function trim(text:String):String
+		{
+			if (text == null) return "";
+			return text.replace(/^\s+|\s+$/g, "");
+		}
+	}
+}

data/lib/mako/data/flash_widget_dev_core/src/org/rubyamf/remoting/ssr/FaultEvent.as

@@ -0,0 +1,37 @@
+// Copyright (c) 2007 rubyamf.org (aaron@rubyamf.org)
+// License - http://www.gnu.org/copyleft/gpl.html
+package org.rubyamf.remoting.ssr
+{
+	import flash.events.ErrorEvent;
+	import flash.events.Event;
+	public class FaultEvent extends ErrorEvent
+	{
+		public static const FAULT:String = "FAULT";
+		public static const CONNECTION_ERROR:String = "CONNECTION_ERROR";
+		public static const AUTHENTICATION_FAILED:String = "AUTHENTICATION_FAILED";
+		public var fault:Object;
+		/*
+		 * Constructor
+		 * @param type:String
+		 * @param bubbles:Boolean
+		 * @param cancelable:Boolean
+		 * @param result:Object
+		 */
+		public function FaultEvent(type:String, bubbles:Boolean, cancelable:Boolean, fault:Object)
+		{
+			super(type, bubbles, cancelable, "");
+			this.fault = fault;
+		}
+		/*
+		 * toString - duh
+		 */
+		public override function toString():String
+		{
+			return "org.rubyamf.remoting.ssr.FaultEvent";
+		}
+		public override function clone():Event
+		{
+			return new FaultEvent(type, bubbles, cancelable, fault);
+		}
+	}
+}