mako 0.0.0

data/lib/mako/data/flash_widget_dev_core/src/nm/respondus/Respondus.as

@@ -0,0 +1,612 @@
+/* See the file "LICENSE.txt" for the full license governing this code. */
+package nm.respondus
+{
+	import mx.controls.Text;
+	public class Respondus
+	{
+		public static const PUNCTUATION_PERIOD:String = ".";
+		public static const PUNCTUATION_PAREN:String = ")";
+		//Consistant: Mult choice, T/F, Matching ('' and 'MT').
+		//
+		//		Netural		WebCT 3/4/Vista		Angel	Blackbrd	Desire2Learn	eCollege	IMS QTI
+		//E:	E			P					E		E			E				E			E
+		//P:	E			P					E		E			E				E			E
+		//SA:	E			P					E		E			E				SA			E
+		//F:	F			S					F		F			S				F			F
+		//S:	F			S					F		F			S				F			F
+		//MR:	MR			MR					MS		MA			MR				MA			MR
+		//MS:	MR			MR					MS		MA			MR				MA			MR
+		//MA:	MR			MR					MS		MA			MR				MA			MR
+		private static const typeTable:Object =
+			{
+				E: {
+					Netural:		TYPE_ESSAY,
+					WebCT34:		TYPE_PARAGRAPH,
+					WebCTVista:		TYPE_PARAGRAPH,
+					ANGEL:			TYPE_ESSAY,
+					Blackboard:		TYPE_ESSAY,
+					Desire2Learn:	TYPE_ESSAY,
+					eCollege:		TYPE_ESSAY,
+					IMSQTI:			TYPE_ESSAY
+				},
+				P: {
+					Netural:		TYPE_ESSAY,
+					WebCT34:		TYPE_PARAGRAPH,
+					WebCTVista:		TYPE_PARAGRAPH,
+					ANGEL:			TYPE_ESSAY,
+					Blackboard:		TYPE_ESSAY,
+					Desire2Learn:	TYPE_ESSAY,
+					eCollege:		TYPE_ESSAY,
+					IMSQTI:			TYPE_ESSAY
+				},
+				SA: {
+					Netural:		TYPE_ESSAY,
+					WebCT34:		TYPE_PARAGRAPH,
+					WebCTVista:		TYPE_PARAGRAPH,
+					ANGEL:			TYPE_ESSAY,
+					Blackboard:		TYPE_ESSAY,
+					Desire2Learn:	TYPE_ESSAY,
+					eCollege:		TYPE_SHORT_ANSWER_ECOLLEGE,
+					IMSQTI:			TYPE_ESSAY
+				},
+				F: {
+					Netural:		TYPE_FILL_IN_THE_BLANK,
+					WebCT34:		TYPE_SHORT_ANSWER,
+					WebCTVista:		TYPE_SHORT_ANSWER,
+					ANGEL:			TYPE_FILL_IN_THE_BLANK,
+					Blackboard:		TYPE_FILL_IN_THE_BLANK,
+					Desire2Learn:	TYPE_SHORT_ANSWER,
+					eCollege:		TYPE_FILL_IN_THE_BLANK,
+					IMSQTI:			TYPE_FILL_IN_THE_BLANK
+				},
+				S: {
+					Netural:		TYPE_FILL_IN_THE_BLANK,
+					WebCT34:		TYPE_SHORT_ANSWER,
+					WebCTVista:		TYPE_SHORT_ANSWER,
+					ANGEL:			TYPE_FILL_IN_THE_BLANK,
+					Blackboard:		TYPE_FILL_IN_THE_BLANK,
+					Desire2Learn:	TYPE_SHORT_ANSWER,
+					eCollege:		TYPE_FILL_IN_THE_BLANK,
+					IMSQTI:			TYPE_FILL_IN_THE_BLANK
+				},
+				MR: {
+					Netural:		TYPE_MULTIPLE_RESPONSE,
+					WebCT34:		TYPE_MULTIPLE_RESPONSE,
+					WebCTVista:		TYPE_MULTIPLE_RESPONSE,
+					ANGEL:			TYPE_MULTIPLE_SELECT,
+					Blackboard:		TYPE_MULTIPLE_ANSWER,
+					Desire2Learn:	TYPE_MULTIPLE_RESPONSE,
+					eCollege:		TYPE_MULTIPLE_ANSWER,
+					IMSQTI:			TYPE_MULTIPLE_RESPONSE
+				},
+				MS: {
+					Netural:		TYPE_MULTIPLE_RESPONSE,
+					WebCT34:		TYPE_MULTIPLE_RESPONSE,
+					WebCTVista:		TYPE_MULTIPLE_RESPONSE,
+					ANGEL:			TYPE_MULTIPLE_SELECT,
+					Blackboard:		TYPE_MULTIPLE_ANSWER,
+					Desire2Learn:	TYPE_MULTIPLE_RESPONSE,
+					eCollege:		TYPE_MULTIPLE_ANSWER,
+					IMSQTI:			TYPE_MULTIPLE_RESPONSE
+				},
+				MA: {
+					Netural:		TYPE_MULTIPLE_RESPONSE,
+					WebCT34:		TYPE_MULTIPLE_RESPONSE,
+					WebCTVista:		TYPE_MULTIPLE_RESPONSE,
+					ANGEL:			TYPE_MULTIPLE_SELECT,
+					Blackboard:		TYPE_MULTIPLE_ANSWER,
+					Desire2Learn:	TYPE_MULTIPLE_RESPONSE,
+					eCollege:		TYPE_MULTIPLE_ANSWER,
+					IMSQTI:			TYPE_MULTIPLE_RESPONSE
+				}
+			};
+		public static const TYPE_MULTIPLE_CHOICE:String = '';
+		public static const TYPE_ESSAY:String = 'E';
+		public static const TYPE_FILL_IN_THE_BLANK:String = 'F';
+		public static const TYPE_MATCHING:String = 'MT';
+		public static const TYPE_MULTIPLE_RESPONSE:String = 'MR';
+		public static const TYPE_PARAGRAPH:String = 'P'; //WebCT alias for 'E'.
+		public static const TYPE_SHORT_ANSWER:String = 'S'; //WebCT alias for 'F'.
+		public static const TYPE_MULTIPLE_SELECT:String = 'MS' //Angle alias for 'MR'.
+		public static const TYPE_MULTIPLE_ANSWER:String = 'MA' //Blackboard alias for 'MR'.
+		public static const TYPE_SHORT_ANSWER_ECOLLEGE:String = 'SA' //eCollege alias for 'E'.
+		public static const PERSONALITY_NETURAL:String = 'Netural';
+		public static const PERSONALITY_WEBCT_34:String = 'WebCT34';
+		public static const PERSONALITY_WEBCT_VISTA:String = 'WebCTVista';
+		public static const PERSONALITY_ANGEL:String = 'ANGEL';
+		public static const PERSONALITY_BLACKBOARD:String = 'Blackboard';
+		public static const PERSONALITY_DESIRE2LEARN:String = 'Desire2Learn';
+		public static const PERSONALITY_ECOLLEGE:String = 'eCollege';
+		public static const PERSONALITY_IMS_QTI:String = 'IMSQTI';
+		private static const BLANK_LINE:String = "";
+		private static const TYPE:String = "type";
+		private static const TITLE:String = "title";
+		private static const QUESTION:String = "question";
+		private static const ANSWER:String = "answer";
+		private static const FEEDBACK:String = "feedback";
+		private static const BLACKBOARD_CORRECT_FEEDBACK:String = 'blackboardCorrectFeedback';
+		private static const ERROR:String = "error";
+		private static const ANSWER_LIST:String = "answers";
+		public function Respondus() { }
+		/*
+		public static function getNewLineChar():String
+		{
+			switch(Capabilities.os.substr(0, 1).toLowerCase())
+			{
+				case "w": //Windows
+					return "\r";
+				default: //Mac, Linux
+					return "\r";
+			}
+		}*/
+		public static function textToQuiz(quizText:String):Array
+		{
+			////trace'input:\n=====');
+			////tracequizText);
+			////trace'===');
+			//Convert all newlines to '\r', which is what flash likes.
+			var r1:RegExp = /\n/g;
+			var r2:RegExp = /\r\r/g;
+			quizText = quizText.replace(r1, '\r');
+			quizText = quizText.replace(r2, '\r');
+			var r3:RegExp = /\r/g;
+			var qt:String = quizText.replace(r3, '[R]').replace(r1, '[N]');
+			////trace'import_:\n======');
+			////tracequizText);
+			////trace'=====');
+			////traceqt);
+			var questions:Array = [];
+			var NEW_LINE:String = '\r';
+			var lines:Array = quizText.split(NEW_LINE);
+			cleanWhitespace(lines);
+			var answerListIndex:int = -1;
+			var curQ:RespondusQuestion = null;
+			var curA:RespondusAnswer = null;
+			var questionTextSet:Boolean;
+			var curLine:String;
+			var curLineType:String;
+			var numCorrectAnswers:int;
+			var t:String
+			for(var i:int = 0; i < lines.length; i++)
+			{
+				curLine = lines[i];
+				////tracei + '[' + curLine + ']');
+				curLineType = getLineType(curLine);
+				if(curLineType == ANSWER_LIST)
+				{
+					answerListIndex = i;
+					break;
+				}
+				if(curLineType == BLANK_LINE)
+				{
+					//Do nothing.
+				}
+				else if(curLineType == TYPE)
+				{
+					if(curA != null || curQ == null)
+					{
+						curA = null;
+						curQ = new RespondusQuestion();
+					}
+					t = getSubstring(curLine, i + 1).toUpperCase();
+					if(isValidType(t)) curQ.type = t;
+				}
+				else if(curLineType == TITLE)
+				{
+					if(curA != null || curQ == null)
+					{
+						curA = null;
+						curQ = new RespondusQuestion();
+					}
+					curQ.title = getSubstring(curLine, i + 1);
+				}
+				else if(curLineType == QUESTION)
+				{
+					if(curA != null || curQ == null)
+					{
+						curA = null;
+						curQ = new RespondusQuestion();
+					}
+					questions.push(curQ);
+					numCorrectAnswers = 0;
+					curQ.questionText = getSubstring(curLine, i + 1);
+					questionTextSet = true;
+					var j:int = i + 1;
+					//Look ahead.  Skipping blanks and feedback, if the next line is not an answer begin a new question.
+					while(lines.length > j)
+					{
+						t = getLineType(lines[j]);
+						if(t != BLANK_LINE && t != FEEDBACK && t != BLACKBOARD_CORRECT_FEEDBACK)
+						{
+							if(t != ANSWER) curQ = null;
+							break;
+						}
+						j++;
+					}
+				}
+				else if(curLineType == FEEDBACK)
+				{
+					if(curA != null)
+					{
+						curA.feedbackText = getSubstring(curLine, i + 1);
+					}
+					else
+					{
+						if(curQ.correctFeedback.length == 0)
+						{
+							curQ.generalFeedback = getSubstring(curLine, i + 1);
+						}
+						else
+						{
+							curQ.incorrectFeedback = getSubstring(curLine, i + 1);
+						}
+					}
+				}
+				else if(curLineType == BLACKBOARD_CORRECT_FEEDBACK)
+				{
+					curQ.correctFeedback = getSubstring(curLine, i + 1);
+					//If this question has general feedback, change it to incorrect feedback
+					//since we now know this question is using blackboard correct/incorrect general feedback.
+					if(curQ.generalFeedback.length > 0)
+					{
+						curQ.incorrectFeedback = curQ.generalFeedback;
+						curQ.generalFeedback = '';
+					}
+				}
+				else if(curLineType == ANSWER)
+				{
+					if(curQ == null)
+					{
+						numCorrectAnswers = 0;
+						curQ = new RespondusQuestion();
+						questions.push(curQ);
+					}
+					curA = new RespondusAnswer();
+					if(curQ.type != TYPE_MATCHING && (curLine.charAt(0) == "*" || isLongAnswerType(curQ.type)))
+					{
+						numCorrectAnswers++;
+						curA.correct = true;
+					}
+					//Switch type to 'MR' if there is more than one correct answer
+					if(curQ.type != TYPE_FILL_IN_THE_BLANK && curQ.type != TYPE_SHORT_ANSWER && numCorrectAnswers > 1)
+					{
+						curQ.type = TYPE_MULTIPLE_RESPONSE;
+					}
+					curA.answerText = getSubstring(curLine, i + 1);
+					curQ.answers.push(curA);
+				}
+				else
+				{
+					//Handle error
+					throw(new RespondusError("Invalid Respondus formatting at line " + String(i + 1) + ": '" + lines[i] + "'.", i + 1, lines[i], RespondusError.PARSE_ERROR));
+				}
+			}
+			if(answerListIndex != -1) processAnswerList(questions, lines.slice(answerListIndex + 1, lines.length), answerListIndex);
+			return questions;
+		}
+		/*
+		1. A
+		2. B
+		3. T (For True = A)
+		4. Bob
+		4. Bob Joe
+		4. Bob Joe Sue (Multiple 4s for a SA)
+		5. B D (MR)
+		6. B,D (MR)
+		7. B, D (MR)
+		9. C (No 8 since 8 was a Paragraph - Paragraph answer is optional)
+		10. D
+		11. This is a response to a Paragraph question.
+		*/
+		//Note: Type MT (Matching) questions cannot have answers in the answer list.
+		private static function processAnswerList(questions:Array, list:Array, startingLineNumber:int):void
+		{
+			var len:int = list.length;
+			var curNum:int;
+			var lastNum:int = -1;
+			var curLine:String;
+			var temp:String;
+			var curAnsText:String;
+			var curQ:Object;
+			var curA:int;
+			for(var i:int = 0; i < len; i++)
+			{
+				curLine = eatLeadingWhitespace(list[i]);
+				if(curLine.length > 0)
+				{
+					temp = curLine.substring(0, curLine.indexOf(' '));
+					curNum = int(temp.substring(0, temp.length - 1));
+					if(curNum > 0 && curNum <= questions.length)
+					{
+						curAnsText = getSubstring(curLine, startingLineNumber + i + 2);
+						var a:RespondusAnswer;
+						curQ = questions[int(curNum) - 1];
+						if(curQ.type == TYPE_MATCHING)
+						{
+							//Ignore these.  The respondus format does not allow for matching questions
+							//to be placed at the bottom of the list.
+						}
+						if(curQ.type == TYPE_ESSAY || curQ.type == TYPE_PARAGRAPH || curQ.type == TYPE_SHORT_ANSWER_ECOLLEGE)
+						{
+							a = new RespondusAnswer();
+							a.answerText = curAnsText;
+							a.correct = true;
+							curQ.answers = [a];
+						}
+						else if(curQ.type == TYPE_FILL_IN_THE_BLANK || curQ.type == TYPE_SHORT_ANSWER)
+						{
+							a = new RespondusAnswer();
+							a.answerText = curAnsText;
+							a.correct = true;
+							curQ.answers.push(a);
+						}
+						else if(curAnsText.indexOf(",") == -1)
+						{
+							//Assume it is a choice letter ('A', 'B', ...) or a 'T'/'F'.
+							temp = curAnsText.toLowerCase();
+							if(temp == 't')
+							{
+								curA = 0;
+							}
+							else if(temp == 'f')
+							{
+								curA = 1;
+							}
+							else
+							{
+								curA = temp.charCodeAt(0) - 97;
+							}
+							if(curA >= 0 && curA < curQ.answers.length) curQ.answers[curA].correct = true;
+						}
+						else
+						{
+							//Assume it is a MR list ('A, B, C')
+							curAnsText = curAnsText.replace(' ', '');
+							var correct:Array = curAnsText.split(',');
+							for each(var ans:String in correct)
+							{
+								curA = ans.toLowerCase().charCodeAt(0) - 97;
+								curQ.answers[curA].correct = true;
+							}
+						}
+					}
+				}
+			}
+		}
+		private static function getSubstring(s:String, lineNumber:int):String
+		{
+			var i:int = s.indexOf(' ');
+			if(i == -1) throw(new RespondusError("Missing space on line " + String(lineNumber) + ": '" + s + "'.", lineNumber, s, RespondusError.MISSING_SPACE));
+			return s.substring(i + 1, s.length);
+		}
+		private static function cleanWhitespace(array:Array):void
+		{
+			var len:int = array.length;
+			for(var i:int = 0; i < len; i++)
+			{
+				array[i] = eatLeadingWhitespace(array[i]);
+			}
+		}
+		private static function isValidType(type:String):Boolean
+		{
+			return 	type == TYPE_ESSAY || type == TYPE_FILL_IN_THE_BLANK || type == TYPE_MATCHING ||
+					type == TYPE_MULTIPLE_ANSWER || type == TYPE_MULTIPLE_CHOICE || type == TYPE_MULTIPLE_RESPONSE ||
+					type == TYPE_MULTIPLE_SELECT || type == TYPE_PARAGRAPH || type == TYPE_SHORT_ANSWER ||
+					type == TYPE_SHORT_ANSWER_ECOLLEGE;
+		}
+		private static function getLineType(line:String):String
+		{
+			var r:String;
+			var l:String = line.toLowerCase();
+			if(l.length == 0)
+			{
+				r = BLANK_LINE;
+			}
+			else if(l.indexOf('type:') == 0)
+			{
+				r = TYPE;
+			}
+			else if(l.indexOf('title:') == 0)
+			{
+				r = TITLE;
+			}
+			else if(l.indexOf('@') == 0)
+			{
+				r = FEEDBACK;
+			}
+			else if(l.indexOf('~') == 0)
+			{
+				r = BLACKBOARD_CORRECT_FEEDBACK;
+			}
+			else if(l.indexOf('answers:') == 0)
+			{
+				r = ANSWER_LIST;
+			}
+			else
+			{
+				var matchQuestion:RegExp = /[0-9]+[\.\)]/;
+				var matchAnswer:RegExp = /\*?[a-z][\.\)]/;
+				if(l.search(matchQuestion) == 0)
+				{
+					r = QUESTION;
+				}
+				else if(l.search(matchAnswer) == 0)
+				{
+					r = ANSWER;
+				}
+				else
+				{
+					r = ERROR;
+				}
+			}
+			return r;
+		}
+		//Given: '  ABC' returns 'ABC';
+		private static function eatLeadingWhitespace(string:String):String
+		{
+			for(var i:int = 0; i < string.length; i++)
+			{
+				if(string.charAt(i) == ' ')
+				{
+					string = string.substr(1, string.length);
+				}
+				else
+				{
+					break;
+				}
+			}
+			return string;
+		}
+		//Given a personality will output the correct Type label.
+		private static function getTypeAlias(personality:String, type:String):String
+		{
+			if(type == TYPE_MULTIPLE_CHOICE || type == TYPE_MATCHING) return type;
+			return typeTable[type][personality];
+		}
+		public static function quizToText(	quizArray:Array,
+											personality:String = PERSONALITY_NETURAL,
+											asterixNotation:Boolean = true,
+											blankLineAfterTitle:Boolean = false,
+											blankLineAfterQuestion:Boolean = true,
+											questionListPunctuation:String = PUNCTUATION_PAREN,
+											answerListPunctuation:String = PUNCTUATION_PERIOD
+										):String
+		{
+			////trace'quizToText newline');
+			var NEW_LINE:String = '\n'; //getNewLineChar();
+			var quizText:String = "";
+			var qc:int = 1; //Question counter
+			var ac:int; //Answer counter
+			var noTypeOrTitle:Boolean;
+			//var correctAnswers:Array;
+			var q:Object;
+			var a:Object;
+			for each(q in quizArray)
+			{
+				noTypeOrTitle = true;
+				//Write type:
+				if(q.type != '')
+				{
+					noTypeOrTitle = false;
+					quizText += "Type: " + getTypeAlias(personality, q.type) + NEW_LINE;
+				}
+				//Write title:
+				if(q.title != '')
+				{
+					noTypeOrTitle = false;
+					quizText += "Title: " + q.title + NEW_LINE;
+				}
+				if(!noTypeOrTitle && blankLineAfterTitle) quizText += NEW_LINE;
+				//Write question:
+				quizText += String(qc) + questionListPunctuation + " " + q.questionText + NEW_LINE;
+				//Write feedback:
+				if(q.generalFeedback != '')
+				{
+					quizText += "@ " + q.generalFeedback + NEW_LINE;
+				}
+				else
+				{
+					if(q.correctFeedback != '')
+					{
+						quizText += "~ " + q.correctFeedback + NEW_LINE;
+					}
+					if(q.incorrectFeedback != '')
+					{
+						quizText += "@ " + q.incorrectFeedback + NEW_LINE;
+					}
+				}
+				//Write answers:
+				//Special case 1: Don't write answer for Essay or Fill in the blank questions if asterixNotation == false.
+				//Special case 2: Must write matching questions in asterix notation even if asterixNotation == false.
+				if(q.type == TYPE_MATCHING || !(!asterixNotation && isLongAnswerType(q.type)))
+				{
+					ac = 0;
+					var answerText:String = '';
+					for each(a in q.answers)
+					{
+						answerText += (asterixNotation && a.correct && !isLongAnswerType(q.type) && q.type != TYPE_MATCHING ? '*' : '') + String.fromCharCode(ac + 97) + answerListPunctuation + " " + a.answerText + NEW_LINE;
+						if(a.feedbackText != '') answerText += '@ ' + a.feedbackText + NEW_LINE;
+						ac++;
+					}
+					//If there were any answers, add the new line, then the answer text..
+					if(ac > 0)
+					{
+						if(blankLineAfterQuestion) quizText += NEW_LINE;
+						quizText += answerText + NEW_LINE;
+					}
+					else
+					{
+						quizText += NEW_LINE;
+					}
+					//quizText += NEW_LINE;
+				}
+				else
+				{
+					quizText += NEW_LINE;
+				}
+				qc++;
+			}
+			//Write list answer format:
+			if(!asterixNotation)
+			{
+				quizText += 'Answers:' + NEW_LINE;
+				var i:int = 0;
+				var j:int = 0;
+				var correct:Array;
+				for each(q in quizArray)
+				{
+					correct = [];
+					j = 0;
+					for each(a in q.answers)
+					{
+						if(a.correct)
+						{
+							if(isLongAnswerType(q.type))
+							{
+								correct.push(a.answerText);
+							}
+							else
+							{
+								correct.push(j);
+							}
+						}
+						j++;
+					}
+					var len:int = correct.length;
+					if(len > 0)
+					{
+						var c:int;
+						//Print out answers depending on type:
+						if(isLongAnswerType(q.type))
+						{
+							//1. Answer one
+							//1. Answer two
+							for(c = 0; c < len; c++)
+							{
+								quizText += (i + 1) + '. ' + correct[c] + NEW_LINE;
+							}
+						}
+						else
+						{
+							//1. A, B
+							quizText += (i + 1) + '. ';
+							for(c = 0; c < len; c++)
+							{
+								quizText += String.fromCharCode(correct[c] + 65);
+								if(c < len - 1) quizText += ', ';
+							}
+							quizText += NEW_LINE;
+						}
+					}
+					i++;
+				}
+			}
+			return quizText;
+		}
+		//Returns true if question is of type Essay or Fill-in-the-blank.
+		private static function isLongAnswerType(type:String):Boolean
+		{
+			return type == TYPE_FILL_IN_THE_BLANK || type == TYPE_SHORT_ANSWER || type == TYPE_ESSAY || type == TYPE_PARAGRAPH || type == TYPE_SHORT_ANSWER_ECOLLEGE;
+		}
+	}
+}

data/lib/mako/data/flash_widget_dev_core/src/nm/respondus/RespondusAnswer.as

@@ -0,0 +1,11 @@
+/* See the file "LICENSE.txt" for the full license governing this code. */
+package nm.respondus
+{
+	public class RespondusAnswer
+	{
+		public var answerText:String = '';
+		public var feedbackText:String = '';
+		public var correct:Boolean = false;
+		public function RespondusAnswer() { }
+	}
+}

data/lib/mako/data/flash_widget_dev_core/src/nm/respondus/RespondusError.as

@@ -0,0 +1,18 @@
+/* See the file "LICENSE.txt" for the full license governing this code. */
+package nm.respondus
+{
+	public class RespondusError extends Error
+	{
+		public static const GENERIC_ERROR:int = 0;
+		public static const PARSE_ERROR:int = 1;
+		public static const MISSING_SPACE:int = 2;
+		public var lineNumber:int;
+		public var line:String;
+		public function RespondusError(message:String = '', lineNumber:int = 0, line:String = '', id:int = 0)
+		{
+			super(message, id);
+			this.lineNumber = lineNumber;
+			this.line = line;
+		}
+	}
+}

data/lib/mako/data/flash_widget_dev_core/src/nm/respondus/RespondusQuestion.as

@@ -0,0 +1,43 @@
+/* See the file "LICENSE.txt" for the full license governing this code. */
+package nm.respondus
+{
+	public class RespondusQuestion
+	{
+		public var title:String = '';
+		public var type:String = '';
+		public var questionText:String = '';
+		public var generalFeedback:String = '';
+		public var correctFeedback:String = '';
+		public var incorrectFeedback:String = '';
+		public var answers:Array = [];
+		public function RespondusQuestion() { }
+		public function addAnswer(text:String, isCorrect:Boolean = false, feedback:String = ''):RespondusAnswer
+		{
+			var a:RespondusAnswer = new RespondusAnswer();
+			a.answerText = text;
+			a.correct = isCorrect;
+			a.feedbackText = feedback;
+			answers.push(a);
+			return a;
+		}
+		public function addAnswerAt(index:int, text:String, isCorrect:Boolean = false, feedback:String = ''):RespondusAnswer
+		{
+			var a:RespondusAnswer = new RespondusAnswer();
+			a.answerText = text;
+			a.correct = isCorrect;
+			a.feedbackText = feedback;
+			answers.splice(index, 0, a);
+			return a;
+		}
+		public function swapAnswers(index1:int, index2:int):void
+		{
+			var tmp:Object = answers[index1];
+			answers[index1] = answers[index2];
+			answers[index2] = tmp;
+		}
+		public function getAnswerAt(index:int):RespondusAnswer
+		{
+			return answers[index];
+		}
+	}
+}