mako 0.0.0

data/lib/mako/data/flash_widget_dev_core/src/materia/components/toolTips/KogneatoToolTip.as

@@ -0,0 +1,196 @@
+package materia.components.toolTips
+{
+	import flash.display.Sprite;
+	import flash.filters.DropShadowFilter;
+	import flash.text.TextField;
+	import flash.text.TextFieldAutoSize;
+	import flash.text.TextFormat;
+	import mx.core.UIComponent;
+	public class KogneatoToolTip extends UIComponent
+	{
+		//Components:
+		protected var bg:Sprite;
+		protected var tf:TextField;
+		//Properties:
+		protected var _text:String;
+		//Flags:
+		protected var _bTextChanged:Boolean;
+		//Statics:
+		protected var DEFAULT_POINTER_ORIENTATION:String = "down"; //@TODO: How do I do this?
+		protected var DEFAULT_MIN_TF_WIDTH:int = 50;
+		protected var DEFAULT_MAX_TF_WIDTH:int = 300;
+		protected var DEFAULT_PTR_SIZE:int = 10;
+		protected var DEFAULT_PADDING:int = 7;
+		public function KogneatoToolTip()
+		{
+			super();
+			mouseEnabled = mouseChildren = false;
+		}
+		public function set text(val:String):void
+		{
+			_text = val;
+			_bTextChanged = true;
+			invalidateProperties();
+		}
+		public function get text():String
+		{
+			return _text;
+		}
+		protected override function createChildren():void
+		{
+			super.createChildren();
+			if(!bg)
+			{
+				bg = new Sprite();
+				addChild(bg);
+			}
+			if(!tf)
+			{
+				tf = new TextField();
+				//tf.text = 'XXXXXXXXXXXXXXXXX';
+				//tf.width = 300;
+				//tf.height = 1;
+				//tf.width = 1;
+				tf.autoSize = TextFieldAutoSize.LEFT;
+				//tf.multiline = tf.wordWrap = true;
+				//tf.setStyle('textAlign', 'center');
+				//tf.maxWidth = DEFAULT_MAX_TF_WIDTH;
+				addChild(tf);
+			}
+		}
+		protected override function commitProperties():void
+		{
+			super.commitProperties();
+			if(_bTextChanged)
+			{
+				_bTextChanged = false;
+				tf.text = _text;
+				tf.setTextFormat(new TextFormat('Verdana', 12, 0xFFFFFF, false, false, false, null, null, 'center'));
+				if(tf.width > DEFAULT_MAX_TF_WIDTH)
+				{
+					tf.width = DEFAULT_MAX_TF_WIDTH;
+					tf.multiline = tf.wordWrap = true;
+				}
+				else if(tf.width < DEFAULT_MIN_TF_WIDTH)
+				{
+					tf.autoSize = TextFieldAutoSize.NONE;
+					tf.width = DEFAULT_MIN_TF_WIDTH;
+				}
+				invalidateDisplayList();
+			}
+		}
+		/*
+		public override function get height():Number
+		{
+			return bg.height;
+		}*/
+		protected override function measure():void
+		{
+			super.measure();
+			measuredWidth = bg.width;
+			measuredHeight = bg.height;
+			measuredMinWidth = 50;
+			measuredMinHeight = 30;
+		}
+		protected override function updateDisplayList(unscaledWidth:Number, unscaledHeight:Number):void
+		{
+			super.updateDisplayList(unscaledWidth, unscaledHeight);
+			var pointerOrientation:String = getStyle("pointerOrientation");
+			var padding:int = DEFAULT_PADDING;
+			var strokeWidth:int = 4;
+			var ptrOffset:int = getStyle("pointerOffset");
+			//trace('DRAWING');
+			var tw:int = padding * 2 + tf.width; //tip width
+			var th:int = padding * 2 + tf.height; //tip height
+			var twh:int = tw / 2;
+			var thh:int = th / 2;
+			var ps:int = DEFAULT_PTR_SIZE;
+			var psh:int = ps / 2;
+			var cr:int = 4; //radius
+			bg.graphics.clear();
+			bg.graphics.lineStyle(strokeWidth, 0xFFFFFF, 0.3, true);
+			//Draw bubble with pointer oriented down
+			bg.graphics.beginFill(0x232323, .95);//0xe6e2d1
+			bg.graphics.moveTo(cr, 0);
+			bg.graphics.curveTo(0, 0, 0, cr);
+			bg.graphics.lineTo(0, th - cr);
+			bg.graphics.curveTo(0, th, cr, th);
+			bg.graphics.lineTo(twh - ps + ptrOffset, th);
+			bg.graphics.lineTo(twh + ptrOffset, th + ps);
+			bg.graphics.lineTo(twh + ps + ptrOffset, th);
+			bg.graphics.lineTo(tw - cr, th);
+			bg.graphics.curveTo(tw, th, tw, th - cr);
+			bg.graphics.lineTo(tw, cr);
+			bg.graphics.curveTo(tw, 0, tw - cr, 0);
+			bg.graphics.lineTo(cr, 0);
+			if(pointerOrientation == 'up')
+			{
+				bg.scaleY = -1;
+				//@TODO @HACK SUPER SUPER HACK ATTACK
+				if(ptrOffset == 0)
+				{
+					bg.y += bg.height - strokeWidth;
+				}
+				tf.x = padding;
+				tf.y = ps + padding;
+			}
+			else //down
+			{
+				tf.x = padding;
+				tf.y = padding;
+			}
+			/*
+			switch(pointerOrientation)
+			{
+				case 'up':
+					tf.x = -twh + padding;
+					tf.y = ps + padding;
+					bg.graphics.beginFill(0xe6e2d1, .95);
+					bg.graphics.moveTo(-ps + ptrOffset, ps);
+					bg.graphics.lineTo(ptrOffset, 0);
+					bg.graphics.lineTo(ps + ptrOffset, ps);
+					bg.graphics.lineTo(twh - cr, ps);
+					bg.graphics.curveTo(twh, ps, twh, ps + cr);
+					var topY:int = ps + th;
+					bg.graphics.lineTo(twh, topY - cr);
+					bg.graphics.curveTo(twh, topY, twh - cr, topY);
+					bg.graphics.lineTo(-twh + cr, topY);
+					bg.graphics.curveTo(-twh, topY, -twh, topY - cr);
+					bg.graphics.lineTo(-twh, ps + cr);
+					bg.graphics.curveTo(-twh, ps, -twh + cr, ps);
+					bg.graphics.lineTo(-ps + ptrOffset, ps);
+					bg.graphics.endFill();
+					break;
+				case 'down':
+				default:
+					tf.x = -twh + padding;
+					tf.y = -ps - padding - tf.height;
+					bg.graphics.beginFill(0xe6e2d1, .95);
+					bg.graphics.moveTo(-ps + ptrOffset, -ps);
+					bg.graphics.lineTo(ptrOffset, 0);
+					bg.graphics.lineTo(ps + ptrOffset, -ps);
+					bg.graphics.lineTo(twh - cr, -ps);
+					bg.graphics.curveTo(twh, -ps, twh, -ps - cr);
+					var topY:int = -ps - th;
+					bg.graphics.lineTo(twh, topY + cr);
+					bg.graphics.curveTo(twh, topY, twh - cr, topY);
+					bg.graphics.lineTo(-twh + cr, topY);
+					bg.graphics.curveTo(-twh, topY, -twh, topY + cr);
+					bg.graphics.lineTo(-twh, -ps - cr);
+					bg.graphics.curveTo(-twh, -ps, -twh + cr, -ps);
+					bg.graphics.lineTo(-ps + ptrOffset, -ps);
+					bg.graphics.endFill();
+					break;
+			}*/
+			//graphics.beginFill(0xFF0000, 0.2);
+			//graphics.drawRect(0, 0, bg.width, bg.height);
+			//graphics.endFill();
+			bg.filters = [new DropShadowFilter(3, 90, 0x0, 0.6, 2, 2, 1, 3)];
+			//bg.x = twh;
+			//bg.y = padding * 2 + th + ps;
+			//trace('ok so height is ' + bg.height);
+			setActualSize(bg.width, bg.height);
+			//measure();
+		}
+	}
+}

data/lib/mako/data/flash_widget_dev_core/src/materia/components/toolTips/TipManager.as

@@ -0,0 +1,150 @@
+package materia.components.toolTips
+{
+	import flash.display.DisplayObject;
+	import flash.events.Event;
+	import flash.events.MouseEvent;
+	import flash.events.TimerEvent;
+	import flash.geom.Point;
+	import flash.utils.Timer;
+	import mx.core.Application;
+	import mx.core.UIComponent;
+	import mx.effects.Fade;
+	import mx.events.FlexEvent;
+	import mx.managers.PopUpManager;
+	import mx.managers.PopUpManagerChildList;
+	public class TipManager
+	{
+		protected static var curToolTip:KogneatoToolTip;
+		protected static var curTipTarget:UIComponent;
+		protected static var _enabled:Boolean = true;
+		protected static var _removeTimer:Timer;
+		protected static const REMOVE_DELAY:int = 10;
+		public function TipManager()
+		{
+		}
+		public static function set enabled(val:Boolean):void
+		{
+			_enabled = val;
+		}
+		public static function get enabled():Boolean
+		{
+			return _enabled;
+		}
+		public static function removeTip():void
+		{
+			_removeTimer = new Timer(REMOVE_DELAY, 1);
+			_removeTimer.addEventListener(TimerEvent.TIMER_COMPLETE, handleRemoveTimerComplete);
+			_removeTimer.start();
+			if(curTipTarget)
+			{
+				curTipTarget.removeEventListener(MouseEvent.MOUSE_OUT, handleTargetMouseOut);
+			}
+		}
+		protected static function handleRemoveTimerComplete(event:TimerEvent = null):void
+		{
+			if(_removeTimer)
+			{
+				_removeTimer.removeEventListener(TimerEvent.TIMER_COMPLETE, handleRemoveTimerComplete);
+				_removeTimer = null;
+			}
+			PopUpManager.removePopUp(curToolTip);
+			curToolTip = null;
+			curTipTarget = null;
+		}
+		public static function showTip(targetUIComponent:Object, tipText:String = '', orientation:String = '', addRemoveListener:Boolean = true):void
+		{
+			if(curToolTip)
+			{
+				if(curToolTip.text == tipText)
+				{
+					//Cancel the remove timer
+					if(_removeTimer)
+					{
+						_removeTimer.stop();
+						_removeTimer.removeEventListener(TimerEvent.TIMER_COMPLETE, handleRemoveTimerComplete);
+						_removeTimer = null;
+					}
+					if(addRemoveListener)
+					{
+						curTipTarget.addEventListener(MouseEvent.MOUSE_OUT, handleTargetMouseOut);
+					}
+					return;
+				}
+				else
+				{
+					handleRemoveTimerComplete();
+				}
+			}
+			if(_enabled && tipText && tipText.length > 0)
+			{
+				curTipTarget = UIComponent(targetUIComponent);
+				if(addRemoveListener)
+				{
+					curTipTarget.addEventListener(MouseEvent.MOUSE_OUT, handleTargetMouseOut);
+				}
+				curToolTip = new KogneatoToolTip();
+				curToolTip.addEventListener(FlexEvent.UPDATE_COMPLETE, handleToolTipUpdateComplete);
+				if(orientation.length > 0)
+				{
+					switch(orientation)
+					{
+						case 'above':
+							curToolTip.setStyle("pointerOrientation", 'down');
+							break;
+						case 'below':
+							curToolTip.setStyle("pointerOrientation", 'up');
+					}
+				}
+				curToolTip.alpha = 0;
+				curToolTip.text = tipText;
+				PopUpManager.addPopUp(curToolTip, DisplayObject(Application.application), false, PopUpManagerChildList.POPUP);
+			}
+		}
+		protected static function handleToolTipUpdateComplete(event:Event):void
+		{
+			if(curToolTip)
+			{
+				if(curToolTip.width > 0 && curToolTip.height > 0)
+				{
+					curToolTip.removeEventListener(FlexEvent.UPDATE_COMPLETE, handleToolTipUpdateComplete);
+					var p:Point = UIComponent(curTipTarget).localToGlobal(new Point());
+					var pointerOrientation:String = curToolTip.getStyle('pointerOrientation');
+					//trace('pointer orientation is ' + pointerOrientation);
+					if(pointerOrientation == 'down' || (pointerOrientation == null && p.y - curToolTip.height > 0))
+					{
+						curToolTip.move(p.x - (curToolTip.width / 2) + (curTipTarget.width / 2), p.y - curToolTip.height);
+					}
+					else
+					{
+						curToolTip.setStyle('pointerOrientation', 'up');
+						curToolTip.move(p.x - (curToolTip.width / 2) + (curTipTarget.width / 2), p.y + curTipTarget.height);
+					}
+					var unfixedXPos:Number = curToolTip.x;
+					if(curToolTip.x + curToolTip.width + 10 > Application.application.stage.stageWidth)
+					{
+						curToolTip.x = Application.application.stage.stageWidth - 10 - curToolTip.width;
+						curToolTip.setStyle("pointerOffset", unfixedXPos - curToolTip.x + 2);
+					}
+					else if(curToolTip.x < 0)
+					{
+						curToolTip.x = 10;
+						curToolTip.setStyle("pointerOffset", unfixedXPos - curToolTip.x + 2);
+					}
+					var f:Fade = new Fade(curToolTip);
+					f.alphaFrom = 0.0;
+					f.alphaTo = 1.0;
+					f.duration = 100;
+					f.play();
+				}
+			}
+		}
+		protected static function handleTargetMouseOut(event:MouseEvent):void
+		{
+			if(curTipTarget)
+			{
+				curTipTarget.removeEventListener(MouseEvent.MOUSE_OUT, handleTargetMouseOut);
+			}
+			removeTip();
+		}
+	}
+}

data/lib/mako/data/flash_widget_dev_core/src/materia/help/HelpBubble.mxml

@@ -0,0 +1,245 @@
+<?xml version = "1.0" encoding = "utf-8"?>
+<mx:Canvas xmlns:mx = "http://www.adobe.com/2006/mxml"
+		   visible = "false"
+		   width = "242"
+		   tabEnabled = "false"
+		   styleName="transparentModal"
+		   creationComplete = "init()">
+	<mx:Script>
+		<![CDATA[
+			import mx.controls.Alert;
+			import mx.core.Application;
+			import mx.managers.PopUpManager;
+			import mx.managers.PopUpManagerChildList;
+			private const ARROW_SPACING_H:int = 9;
+			private const PADDING_H:int = 8;
+			private const SPACING_H:int = 5;
+			private const SPACING_V:int = 6;
+			private const MAX_CENTER_HEIGHT:int = 150;
+			[Bindable]
+			public var helpTitle:String = '';
+			[Bindable]
+			public var helpText:String = '';
+			public var target:DisplayObject;
+			public var showArrow:Boolean;
+			public var verticalAlign:int = -1;
+			public var horizontalAlign:int = -1;
+			private var resizeTimer:Timer;
+			public var continueFunction:Function;
+			public var stopFunction:Function;
+			private function init():void
+			{
+				//Timer waits until after bubble is resized to become visible
+				callLater(show);
+				//Listen to resize events if attached to an object
+				if(target != null)
+				{
+					target.stage.addEventListener(Event.RESIZE, onResize, false, 0, true);
+				}
+			}
+			public override function setFocus():void
+			{
+				//Do nothing!
+			}
+			private function show():void
+			{
+				//If this is giving you an error, you need the latest version of flex sdk :(
+				//http://opensource.adobe.com/wiki/display/flexsdk/Download+Flex+3
+				this.visible = true;
+			}
+			public function position(centerHelp:Boolean = false):void
+			{
+				var center:Point;
+				var targetBounds:Rectangle;
+				if(target == null)
+				{
+					var _stage:Canvas = Application.application.canvasMainContainer;
+					x = _stage.width / 2 - width / 2;
+					y = _stage.height / 2 - height / 2 - 150;
+					return;
+				}
+				//Find what quadrant the target object is in
+				center = this.target.localToGlobal(new Point(target.width / 2, target.height / 2));
+				var targetPoint:Point = this.target.localToGlobal(new Point(0, 0));
+				targetBounds = new Rectangle(targetPoint.x, targetPoint.y, target.width, target.height);
+				var pos:Point = new Point();
+				//---------- find y position for bubble ----------
+				if ((verticalAlign == HelpObject.V_ALIGN_AUTO && center.y <= screen.height / 2) ||
+					verticalAlign == HelpObject.V_ALIGN_BOTTOM) // for components on top half of screen
+				{
+					pos.y = targetBounds.y - SPACING_V;
+					positionArrowV('top');
+				}
+				else // for components on bottom half of screen
+				{
+					this.validateNow(); //needed for this.height to return accurate measure
+					pos.y = targetBounds.y + targetBounds.height - this.height + SPACING_V;
+					positionArrowV('bottom');
+				}
+				//---------- find x position for bubble ----------
+				if ((horizontalAlign == HelpObject.H_ALIGN_AUTO && center.x <= screen.width / 2) ||
+					horizontalAlign == HelpObject.H_ALIGN_RIGHT) //components on left
+				{
+					pos.x = targetBounds.x + targetBounds.width + SPACING_H;
+					positionArrowH(true);
+				}
+				else //components on right
+				{
+					pos.x = targetBounds.x - this.width - SPACING_H;
+					positionArrowH(false);
+				}
+				//Validate x-position
+				if(pos.x < 0)
+				{
+					pos.x = 0;
+				}
+				//Validate y-position
+				if(pos.y < 0)
+				{
+					pos.y = 0;
+				}
+				move(pos.x, pos.y);
+			}
+			private function positionArrowH(left:Boolean):void
+			{
+				arrowLeft.visible = showArrow && left;
+				arrowRight.visible = showArrow && !left;
+			}
+			private function positionArrowV(position:String):void
+			{
+				if(position == 'top')
+				{
+					arrowLeft.setStyle('top', ARROW_SPACING_H);
+					arrowLeft.setStyle('bottom', null);
+					arrowRight.setStyle('top', ARROW_SPACING_H);
+					arrowRight.setStyle('bottom', null);
+				}
+				else if(position == 'bottom')
+				{
+					arrowLeft.setStyle('top', null);
+					arrowLeft.setStyle('bottom', ARROW_SPACING_H);
+					arrowRight.setStyle('top', null);
+					arrowRight.setStyle('bottom', ARROW_SPACING_H);
+				}
+				else if(position == 'center')
+				{
+				}
+			}
+			public static function create(helpObject:HelpObject, stopFunction:Function = null, continueFunction:Function = null, visibleModalBackground:Boolean = false):HelpBubble
+			{
+				//Create and Initialize popup
+				var popup:HelpBubble = new HelpBubble();
+				if(visibleModalBackground)
+				{
+					popup.styleName = '';
+				}
+				popup.target = helpObject.targetComponent;
+				popup.continueFunction = (continueFunction == null)? stopFunction:continueFunction;
+				popup.stopFunction = stopFunction;
+				popup.showArrow = helpObject.showArrow;
+				popup.verticalAlign= helpObject.verticalAlign;
+				popup.horizontalAlign = helpObject.horizontalAlign;
+				popup.width = helpObject.width;
+				//Display popup using popup manager
+				PopUpManager.addPopUp(popup, DisplayObject(Application.application), true,
+					PopUpManagerChildList.POPUP);
+				//Update popup information and position (we do it after it appears so size updates properly)
+				popup.helpText = helpObject.message;
+				popup.helpTitle = helpObject.title;
+				popup.position(helpObject.horizontalAlign == HelpObject.V_ALIGN_CENTER);
+				//Hide continue button if there is no continue function
+				if(continueFunction == null)
+				{
+					popup.btnContinue.visible = false;
+					popup.btnDismiss.label = "Close";
+				}
+				return popup;
+			}
+			/**
+			 *  called whenever resize event is fired.
+			 *  this function is combined with a timer to avoid excessive
+			 *  repositioning and to add a small delay that is needed for
+			 *  the maximize resize event to work properly
+			 */
+			private function onResize(event:Event):void
+			{
+				//Create resize timer if not created yet
+				if(resizeTimer == null)
+				{
+					resizeTimer = new Timer(100, 1);
+					resizeTimer.addEventListener(TimerEvent.TIMER_COMPLETE, onResizeUpdate);
+				}
+				//Only start timer if timer isn't already running
+				if(resizeTimer.running == false)
+				{
+					resizeTimer.start();
+				}
+			}
+			private function onResizeUpdate(event:Event):void
+			{
+				position();
+			}
+			private function onContinue():void
+			{
+				if(continueFunction != null)
+				{
+					continueFunction.call(this);
+				}
+				destroy();
+			}
+			private function onDismiss():void
+			{
+				if(continueFunction != null)
+				{
+					stopFunction.call(this);
+				}
+				destroy();
+			}
+			public function destroy():void
+			{
+				if(target != null)
+				{
+					if(target.stage != null && target.stage.hasEventListener(Event.RESIZE))
+					{
+						target.stage.removeEventListener(Event.RESIZE, onResize);
+					}
+					target = null;
+				}
+				if(resizeTimer != null)
+				{
+					if(resizeTimer.hasEventListener(TimerEvent.TIMER_COMPLETE))
+					{
+						resizeTimer.removeEventListener(TimerEvent.TIMER_COMPLETE, onResize);
+					}
+					resizeTimer = null;
+				}
+				PopUpManager.removePopUp(this);
+			}
+		]]>
+	</mx:Script>
+	<mx:Canvas id = "innerCanvas"
+			   styleName = "helpBubble"
+			   fontSize = "14"
+			   fontFamily = "Arial"
+			   left = "{PADDING_H}"
+			   right = "{PADDING_H + 1}">
+		<mx:VBox id="vbContent" bottom = "45" top = "10" left = "10" right = "10">
+			<mx:Label fontFamily = "Arial Rounded MT Bold" fontWeight="normal" fontSize = "16" text = "{helpTitle}" color = "#393939" />
+			<mx:Text text = "{helpText}" selectable = "false" fontSize = "12" width = "100%" />
+		</mx:VBox>
+		<mx:LinkButton id="btnClose" styleName="popupButton" toolTip="close" click="{onDismiss()}" buttonMode="false" top="10" right="10">
+			<mx:icon>@Embed(source='/assets/materia/images/close-x.png')</mx:icon>
+		</mx:LinkButton>
+		<mx:LinkButton id="btnDismiss" styleName="popupButton" label="Dismiss Help" click="{onDismiss()}" visible="false" height="25" bottom="10" left="10"/>
+		<mx:LinkButton id="btnContinue" styleName="popupButton" label="Continue" click="{onContinue()}" fontSize="16" height="25" bottom="10" right="10" color="#14144C"/>
+	</mx:Canvas>
+	<mx:Image id = "arrowLeft" visible = "false" source = "@Embed(source='/assets/materia/swf/helpBubble.swf#leftArrow')" top="ARROW_SPACING_H"/>
+	<mx:Image id = "arrowRight"
+			  visible = "false"
+			  source = "@Embed(source='/assets/materia/swf/helpBubble.swf#rightArrow')"
+			  bottom="ARROW_SPACING_H"
+			  x = "{width - arrowLeft.width}" />
+	<mx:filters>
+		<mx:DropShadowFilter angle = "90" quality = "3" alpha = ".5" />
+	</mx:filters>
+</mx:Canvas>

data/lib/mako/data/flash_widget_dev_core/src/materia/help/HelpDot.mxml

@@ -0,0 +1,21 @@
+<?xml version="1.0" encoding="utf-8"?>
+<mx:Image creationComplete="handleCreationComplete()" xmlns:mx="http://www.adobe.com/2006/mxml" width="13" height="13"
+          source="@Embed(source='/assets/materia/swf/kogneatoSymbols.swf#DarkHelpDot')">
+	<mx:Script>
+		<![CDATA[
+		import materia.toolTips.TipManager;
+		import mx.managers.ToolTipManager;
+		[Bindable]
+		public var toolTipOrientation:String = '';
+		public function handleCreationComplete():void
+		{
+			ToolTipManager.enabled = false;
+			addEventListener(MouseEvent.MOUSE_OVER, handleMouseOver, false, 0, true);
+		}
+		protected function handleMouseOver(event:MouseEvent):void
+		{
+			TipManager.showTip(this, toolTip, toolTipOrientation);
+		}
+		]]>
+	</mx:Script>
+</mx:Image>

data/lib/mako/data/flash_widget_dev_core/src/materia/help/HelpManager.as

@@ -0,0 +1,92 @@
+package materia.help
+{
+	import mx.core.Application;
+	import mx.core.UIComponent;
+	public class HelpManager
+	{
+		private const DISMISS_MESSAGE_ID:String = "DissmissMessage";
+		private static var _instance:HelpManager;
+		private static var _kogneato:Application;
+		private var _targetScreen:UIComponent;
+		private var _helpSequence:Array;
+		private var _helpStep:int;
+		private var _continueFunction:Function;
+		private var _stopFunction:Function;
+		private var _currentBubble:HelpBubble;
+		public function HelpManager(targetScreen:UIComponent, helpSequence:Array, continueFunction:Function = null, stopFunction:Function = null)
+		{
+			_targetScreen = targetScreen;
+			_helpSequence = helpSequence;
+			_continueFunction = (continueFunction == null)? continueTour:continueFunction;
+			_stopFunction = (stopFunction == null)? stopTour:stopFunction;
+		}
+		public static function init(targetScreen:UIComponent, helpSequence:Array, customContinueFunction:Function = null, customStopFunction:Function = null):void
+		{
+			if(_instance != null)
+			{
+				_instance.destroy();
+			}
+			_instance = new HelpManager(targetScreen, helpSequence, customContinueFunction, customStopFunction);
+			_instance.beginTour();
+		}
+		public function beginTour():void
+		{
+			_helpStep = 0;
+			continueTour();
+		}
+		public function continueTour():void
+		{
+			//Avoid stepping out of range of the help sequence array
+			if(_helpStep >= _helpSequence.length)
+			{
+				onTourForPageComplete();
+				return;
+			}
+			//Create the bubble and increment the step
+			_currentBubble = HelpBubble.create(HelpObject(_helpSequence[_helpStep]), _stopFunction, _continueFunction);
+			//Actions to take for the last bubble on this page
+			if(_helpStep == _helpSequence.length - 1)
+			{
+//				if(_kogneato.helpStep < _kogneato.numPagesInTour - 1)
+//				{
+//					_currentBubble.btnContinue.label = "Next Page";
+//				}
+//				else
+//				{
+//					_currentBubble.btnContinue.label = "Finish";
+//				}
+			}
+			_helpStep++;
+		}
+		public function onTourForPageComplete():void
+		{
+//			_kogneato.continueTour();
+		}
+		public function stopTour():void
+		{
+			_currentBubble = null;
+			//Save preference to dismiss help for this page
+			_helpStep = _helpSequence.length;
+		}
+		public function destroy():void
+		{
+			if(_currentBubble != null)
+			{
+				_currentBubble.destroy();
+				_currentBubble = null;
+			}
+		}
+		public static function setKogneatoReference(kogneato:Application):void
+		{
+			_kogneato = kogneato;
+		}
+		public static function clear():void
+		{
+			if(_instance != null)
+			{
+				_instance.destroy();
+				_instance = null;
+			}
+		}
+	}
+}