@crossbind/port-gdal-wasi 2.0.0-beta.50

package/dist/prebuilt/wasi-wasm32-st-release/lib/cmake/gdal/packages/FindOracle.cmake

@@ -0,0 +1,230 @@
+#.rst:
+# FindOracle
+# ----------
+#
+# Configure Oracle libraries
+#
+# ORACLE_FOUND - system has Oracle OCI
+# ORACLE_INCLUDE_DIRS - where to find oci.h
+# ORACLE_LIBRARIES - the libraries to link against to use Oracle OCI
+#
+# Components: CLNTSH, CLNTST, OCCI, XML, OCIEI
+# CLNTSH is enabled by default
+# for example: FIND_PACKAGE(Oracle REQUIRED CLNTSH OCCI)
+#
+# This module will set the following variables in your project:
+#
+# ``ORACLE_FOUND``
+#   Oracle installation detected (InstantClient or "thick" client)
+# ``ORACLE_INCLUDE_DIRS``
+#   Oracle include directory (where oci.h resides)
+# ``ORACLE_CLNTSH_LIBRARY``
+#   Library libclntsh.so.*
+# ``ORACLE_CLNTST_LIBRARY``
+#   Library libclntst??.a (not present in InstantClient, must be generated by executing genclntst)
+# ``ORACLE_OCCI_LIBRARY``
+#   OCCI C++ client library
+# ``ORACLE_XML_LIBRARY``
+#   Oracle XMLTYPE library libxml?.a (usually static, only present in thick client)
+# ``ORACLE_LIBRARIES``
+#   All Oracle libraries detected libclntsh.so.*, libociei.so.8 libxml.a ....
+# ``ORACLE_OCI_VERSION``
+#   This is set to 8i, 9i, 10g, 11g, 12c
+
+# TOra Project: Configure Oracle libraries
+#
+# Copyright (c) 2007 Petr Vanek <petr@yarpen.cz>
+# Copyright (c) 2016 Ivan Brezina <ibre5041@ibrezina.net>
+# Redistribution and use is allowed according to the terms of the BSD license.
+#
+
+# Port to GDAL
+# Copyright (c) 2018 Hiroshi Miura
+#
+
+if(DEFINED Oracle_ROOT)
+    set(ORACLE_HOME "${Oracle_ROOT}")
+elseif(DEFINED ORACLE_ROOT)
+    set(ORACLE_HOME "${ORACLE_ROOT}")
+else()
+    file(TO_CMAKE_PATH "$ENV{ORACLE_HOME}" ORACLE_HOME)
+endif()
+get_filename_component(XE_HOME "[HKEY_LOCAL_MACHINE\\SOFTWARE\\ORACLE\\KEY_XE;ORACLE_HOME]" ABSOLUTE CACHE)
+mark_as_advanced(XE_HOME)
+
+set(ORACLE_INCLUDES_LOCATION
+        ${ORACLE_HOME}/rdbms/public
+        ${ORACLE_HOME}/include
+        # xdk
+        ${ORACLE_HOME}/xdk/include
+        # sdk
+        ${ORACLE_HOME}/sdk/include/
+        # xe on windows
+        ${ORACLE_HOME}/OCI/include/
+        # instant client from rpm
+        /usr/include/oracle/11.2/client${LIB_SUFFIX}/
+        /usr/include/oracle/12.1/client${LIB_SUFFIX}/
+        # instantclient on OS X from macports
+        /opt/local/lib/oracle/sdk/include/
+        # Oracle XE Windows
+        ${XE_HOME}/oci/include/
+   )
+
+find_path(Oracle_INCLUDE_DIR oci.h
+          PATHS ${ORACLE_INCLUDES_LOCATION}
+          HINTS ${ORACLE_PATH_LIB}
+          NO_DEFAULT_PATH NO_CMAKE_ENVIRONMENT_PATH NO_CMAKE_PATH NO_SYSTEM_ENVIRONMENT_PATH NO_CMAKE_SYSTEM_PATH
+)
+
+# guess OCI version
+#   we need it before lib checking because of OS X bugs in instant client (see below)
+if (NOT DEFINED ORACLE_OCI_VERSION AND ORACLE_INCLUDES)
+  try_run(OCIVER_TYPE OCIVER_COMPILED
+          ${PROJECT_BINARY_DIR}
+          ${PROJECT_SOURCE_DIR}/cmake/modules/OCIVersion.c
+          CMAKE_FLAGS "-DINCLUDE_DIRECTORIES:STRING=${ORACLE_INCLUDES}"
+          OUTPUT_VARIABLE OCIVER)
+
+  if(${OCIVER_TYPE} GREATER "120")
+    set(ORACLE_OCI_VERSION "12C")
+  elseif(${OCIVER_TYPE} GREATER "110")
+    set(ORACLE_OCI_VERSION "11G")
+  elseif(${OCIVER_TYPE} EQUAL "102")
+    set(ORACLE_OCI_VERSION "10G_R2")
+  elseif(${OCIVER_TYPE} EQUAL "101")
+    set(ORACLE_OCI_VERSION "10G")
+  elseif(${OCIVER_TYPE} EQUAL "91")
+    set(ORACLE_OCI_VERSION "9")
+  elseif(${OCIVER_TYPE} EQUAL "92")
+    set(ORACLE_OCI_VERSION "9")
+  elseif(NOT ${OCIVER_TYPE} GREATER "90")
+    set(ORACLE_OCI_VERSION "8I")
+  else(${OCIVER_TYPE} GREATER "110")
+    set(ORACLE_OCI_VERSION "10G_R2")
+  endif ()
+
+  message(STATUS "Guessed ORACLE_OCI_VERSION value: ${ORACLE_OCI_VERSION} for ${OCIVER_TYPE}")
+
+  if(APPLE)
+    if(${OCIVER_TYPE} LESS 110)
+        list(FIND Oracle_FIND_COMPONENTS "OCIEI" _nextcomp)
+        if(_nextcomp EQUAL -1)
+            list(APPEND Oracle_FIND_COMPONENTS OCIEI)
+            message(STATUS "    APPLE requires libociei for instantclient < 11, enforcing ociei")
+        endif()
+    endif()
+  endif()
+endif()
+
+set(ORACLE_LIB_LOCATION
+        # TODO add 32/64bit version here (lib32/lib64 on some platforms)
+        ${ORACLE_HOME}/lib
+        # xe on windows
+        ${ORACLE_HOME}/OCI/lib/MSVC/
+        ${ORACLE_HOME}
+        # InstantClient on WinXP
+        ${ORACLE_HOME}/sdk/lib/msvc/
+        # Instant client from rpm
+        /usr/lib${LIB_SUFFIX}/
+        /usr/lib/oracle/11.2/client${LIB_SUFFIX}/lib/
+        /usr/lib/oracle/12.1/client${LIB_SUFFIX}/lib/
+        # instant client on OS X from macports
+        /opt/local/lib/oracle/
+        # Oracle XE Windows
+        ${XE_HOME}/oci/lib/MSVC/
+    )
+
+# The NO_DEFAULT_PATH is necessary here in the case there is Oracle DB
+# *and* instant client installed. The order is given in ORACLE_LIB_LOCATION.
+# See above.
+find_library(Oracle_LIBRARY
+             NAMES oci
+             PATHS ${ORACLE_LIB_LOCATION}
+             HINTS ${ORACLE_PATH_LIBS}
+             NO_DEFAULT_PATH
+             )
+
+# Oracle InstantClient 12.1 has no liboci. It seems we just need libclntsh
+# for the GDAL drivers.
+if( Oracle_CAN_USE_CLNTSH_AS_MAIN_LIBRARY AND "${Oracle_FIND_COMPONENTS}" STREQUAL "")
+    set(Oracle_FIND_COMPONENTS CLNTSH)
+endif()
+
+foreach(_comp IN LISTS Oracle_FIND_COMPONENTS)
+  set(Oracle_${_comp}_FOUND FALSE)
+endforeach()
+
+set(Oracle_known_components CLNTSH CLNTST OCCI XML OCIEI)
+
+set(Oracle_CLNTSH_lib libclntsh clntsh)
+set(Oracle_CLNTST_lib libclntst libclntst9 libclntst10 libclntst11 libclntst12 clntst clntst9 clntst10 clntst11 clntst12)
+set(Oracle_OCCI_lib libocci occi)
+set(Oracle_XML_lib
+    libxml xml libxml10 xml10 libxml11 xml11 oraxml10 oraxml11)
+set(Oracle_XML_header xml.h)
+set(Oracle_OCIEI_lib libociei ociei)
+
+foreach(_comp IN LISTS Oracle_known_components)
+    list(FIND Oracle_FIND_COMPONENTS "${_comp}" _nextcomp)
+    if(_nextcomp GREATER -1)
+        find_library(Oracle_${_comp}_LIBRARY
+                     NAMES ${Oracle_${_comp}_lib}
+                     NAMES_PER_DIR
+                     PATHS ${ORACLE_LIB_LOCATION}
+                     NO_DEFAULT_PATH
+        )
+        if(Oracle_${_comp}_LIBRARY)
+            set(Oracle_${_comp}_FOUND TRUE)
+        endif()
+        mark_as_advanced(Oracle_${_comp}_LIBRARY)
+        if(Oracle_${_comp}_header)
+            find_path(Oracle_${_comp}_INCLUDE_DIR
+                      NAMES ${Oracle_${_comp}_header}
+                      PATHS ${ORACLE_INCLUDES_LOCATION}
+                      NO_DEFAULT_PATH)
+            mark_as_advanced(Oracle_${_comp}_INCLUDE_DIR)
+        endif()
+    endif()
+endforeach()
+
+if( NOT Oracle_LIBRARY AND Oracle_CAN_USE_CLNTSH_AS_MAIN_LIBRARY AND Oracle_CLNTSH_LIBRARY )
+    set(Oracle_LIBRARY "${Oracle_CLNTSH_LIBRARY}")
+endif()
+
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(Oracle
+                                  FOUND_VAR Oracle_FOUND
+                                  REQUIRED_VARS Oracle_LIBRARY Oracle_INCLUDE_DIR
+                                  VERSION_VAR ORACLE_OCI_VERSION
+                                  HANDLE_COMPONENTS)
+mark_as_advanced(Oracle_INCLUDE_DIR Oracle_LIBRARY)
+
+IF(Oracle_FOUND)
+    set(Oracle_INCLUDE_DIRS "${Oracle_INCLUDE_DIR}")
+    set(Oracle_LIBRARIES "${Oracle_LIBRARY}")
+    if(Oracle_XML_INCLUDE_DIR AND Oracle_XML_LIBRARY)
+        list(APPEND Oracle_INCLUDE_DIRS "${Oracle_XML_INCLUDE_DIR}")
+    endif()
+    if(NOT TARGET Oracle::OCI)
+        add_library(Oracle::OCI UNKNOWN IMPORTED)
+        set_target_properties(Oracle::OCI PROPERTIES
+                              INTERFACE_INCLUDE_DIRECTORIES "${Oracle_INCLUDE_DIR}"
+                              IMPORTED_LINK_INTERFACE_LANGUAGES "C"
+                              IMPORTED_LOCATION "${Oracle_LIBRARY}"
+                              )
+        foreach(tgt IN LISTS Oracle_known_components)
+            if(Oracle_${tgt}_FOUND)
+                add_library(Oracle::${tgt} UNKNOWN IMPORTED)
+                set_target_properties(Oracle::${tgt} PROPERTIES
+                                      IMPORTED_LINK_INTERFACE_LANGUAGES "C"
+                                      IMPORTED_LOCATION "${Oracle_${tgt}_LIBRARY}")
+            endif()
+        endforeach()
+        if(Oracle_XML_INCLUDE_DIR)
+            if(TARGET Oracle::XML)
+                set_property(Oracle::XML APPEND PROPERTY
+                             INTERFACE_INCLUDE_DIRECTORIES "${Oracle_XML_INCLUDE_DIR}")
+            endif()
+        endif()
+    endif()
+endif()

package/dist/prebuilt/wasi-wasm32-st-release/lib/cmake/gdal/packages/FindPCRE.cmake

@@ -0,0 +1,28 @@
+# Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
+# file COPYING-CMAKE-SCRIPTS or https://cmake.org/licensing for details.
+
+#.rst
+# FindPCRE
+# ~~~~~~~~~
+# Copyright (C) 2017-2018, Hiroshi Miura
+#
+# Find the native PCRE headers and libraries.
+
+find_path(PCRE_INCLUDE_DIR NAMES pcre.h)
+find_library(PCRE_LIBRARY NAMES pcre)
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(PCRE
+                                  FOUND_VAR PCRE_FOUND
+                                  REQUIRED_VARS PCRE_LIBRARY PCRE_INCLUDE_DIR)
+mark_as_advanced(PCRE_INCLUDE_DIR PCRE_LIBRARY)
+if(PCRE_FOUND)
+    set(PCRE_LIBRARIES "${PCRE_LIBRARY}")
+    set(PCRE_INCLUDE_DIRS "${PCRE_INCLUDE_DIR}")
+    if(NOT TARGET PCRE::PCRE)
+        add_library(PCRE::PCRE UNKNOWN IMPORTED)
+        set_target_properties(PCRE::PCRE PROPERTIES
+                              INTERFACE_INCLUDE_DIRECTORIES "${PCRE_INCLUDE_DIR}"
+                              IMPORTED_LINK_INTERFACE_LANGUAGES "C"
+                              IMPORTED_LOCATION "${PCRE_LIBRARY}")
+    endif()
+endif()

package/dist/prebuilt/wasi-wasm32-st-release/lib/cmake/gdal/packages/FindPCRE2.cmake

@@ -0,0 +1,27 @@
+# Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
+# file COPYING-CMAKE-SCRIPTS or https://cmake.org/licensing for details.
+
+#.rst
+# FindPCRE2
+# ~~~~~~~~~
+# Copyright (C) 2017-2018, Hiroshi Miura
+#
+# Find the native PCRE2 headers and libraries.
+
+find_path(PCRE2_INCLUDE_DIR NAMES pcre2.h)
+find_library(PCRE2-8_LIBRARY NAMES pcre2-8 pcre2-8d pcre2-8-static pcre2-8-staticd NAMES_PER_DIR)
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(PCRE2
+                                  REQUIRED_VARS PCRE2-8_LIBRARY PCRE2_INCLUDE_DIR)
+mark_as_advanced(PCRE2_INCLUDE_DIR PCRE2-8_LIBRARY)
+if(PCRE2_FOUND)
+    list(APPEND PCRE2_LIBRARIES "${PCRE2-8_LIBRARY}")
+    set(PCRE2_INCLUDE_DIRS "${PCRE2_INCLUDE_DIR}")
+    if(NOT TARGET PCRE2::PCRE2-8)
+        add_library(PCRE2::PCRE2-8 UNKNOWN IMPORTED)
+        set_target_properties(PCRE2::PCRE2-8 PROPERTIES
+                              INTERFACE_INCLUDE_DIRECTORIES "${PCRE2_INCLUDE_DIR}"
+                              IMPORTED_LINK_INTERFACE_LANGUAGES "C"
+                              IMPORTED_LOCATION "${PCRE2-8_LIBRARY}")
+    endif()
+endif()

package/dist/prebuilt/wasi-wasm32-st-release/lib/cmake/gdal/packages/FindPROJ.cmake

@@ -0,0 +1,91 @@
+# Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
+# file COPYING-CMAKE-SCRIPTS or https://cmake.org/licensing for details.
+
+#[=======================================================================[.rst:
+FindPROJ
+---------
+
+CMake module to search for PROJ(PROJ.4 and PROJ) library
+
+On success, the macro sets the following variables:
+``PROJ_FOUND``
+  if the library found
+
+``PROJ_LIBRARIES``
+  full path to the library
+
+``PROJ_INCLUDE_DIRS``
+  where to find the library headers
+
+``PROJ_VERSION_STRING``
+  version string of PROJ
+
+Copyright (c) 2009 Mateusz Loskot <mateusz@loskot.net>
+Copyright (c) 2015 NextGIS <info@nextgis.com>
+Copyright (c) 2018 Hiroshi Miura
+
+#]=======================================================================]
+
+find_path(PROJ_INCLUDE_DIR proj.h
+          PATHS ${PROJ_ROOT}/include
+          DOC "Path to PROJ library include directory")
+
+set(PROJ_NAMES ${PROJ_NAMES} proj proj_i)
+set(PROJ_NAMES_DEBUG ${PROJ_NAMES_DEBUG} projd proj_d)
+
+if(NOT PROJ_LIBRARY)
+  find_library(PROJ_LIBRARY_RELEASE NAMES ${PROJ_NAMES} NAMES_PER_DIR)
+  find_library(PROJ_LIBRARY_DEBUG NAMES ${PROJ_NAMES_DEBUG} NAMES_PER_DIR)
+  include(SelectLibraryConfigurations)
+  select_library_configurations(PROJ)
+  mark_as_advanced(PROJ_LIBRARY_RELEASE PROJ_LIBRARY_DEBUG)
+endif()
+
+unset(PROJ_NAMES)
+unset(PROJ_NAMES_DEBUG)
+
+if(PROJ_INCLUDE_DIR)
+    file(READ "${PROJ_INCLUDE_DIR}/proj.h" PROJ_H_CONTENTS)
+    string(REGEX REPLACE "^.*PROJ_VERSION_MAJOR +([0-9]+).*$" "\\1" PROJ_VERSION_MAJOR "${PROJ_H_CONTENTS}")
+    string(REGEX REPLACE "^.*PROJ_VERSION_MINOR +([0-9]+).*$" "\\1" PROJ_VERSION_MINOR "${PROJ_H_CONTENTS}")
+    string(REGEX REPLACE "^.*PROJ_VERSION_PATCH +([0-9]+).*$" "\\1" PROJ_VERSION_PATCH "${PROJ_H_CONTENTS}")
+    unset(PROJ_H_CONTENTS)
+    set(PROJ_VERSION_STRING "${PROJ_VERSION_MAJOR}.${PROJ_VERSION_MINOR}.${PROJ_VERSION_PATCH}")
+endif ()
+
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(PROJ
+                                  REQUIRED_VARS PROJ_LIBRARY PROJ_INCLUDE_DIR
+                                  VERSION_VAR PROJ_VERSION_STRING)
+mark_as_advanced(PROJ_INCLUDE_DIR PROJ_LIBRARY)
+
+if(PROJ_FOUND)
+  set(PROJ_LIBRARIES "${PROJ_LIBRARY}")
+  set(PROJ_INCLUDE_DIRS "${PROJ_INCLUDE_DIR}")
+  if(NOT TARGET PROJ::proj)
+    add_library(PROJ::proj UNKNOWN IMPORTED)
+    set_target_properties(PROJ::proj PROPERTIES
+                          INTERFACE_INCLUDE_DIRECTORIES "${PROJ_INCLUDE_DIR}"
+                          IMPORTED_LINK_INTERFACE_LANGUAGES "C")
+    if(EXISTS "${PROJ_LIBRARY}")
+      set_target_properties(PROJ::proj PROPERTIES
+        IMPORTED_LINK_INTERFACE_LANGUAGES "C"
+        IMPORTED_LOCATION "${PROJ_LIBRARY}")
+    endif()
+    if(EXISTS "${PROJ_LIBRARY_RELEASE}")
+      set_property(TARGET PROJ::proj APPEND PROPERTY
+        IMPORTED_CONFIGURATIONS RELEASE)
+      set_target_properties(PROJ::proj PROPERTIES
+        IMPORTED_LINK_INTERFACE_LANGUAGES_RELEASE "C"
+        IMPORTED_LOCATION_RELEASE "${PROJ_LIBRARY_RELEASE}")
+    endif()
+    if(EXISTS "${PROJ_LIBRARY_DEBUG}")
+      set_property(TARGET PROJ::proj APPEND PROPERTY
+        IMPORTED_CONFIGURATIONS DEBUG)
+      set_target_properties(PROJ::proj PROPERTIES
+        IMPORTED_LINK_INTERFACE_LANGUAGES_DEBUG "C"
+        IMPORTED_LOCATION_DEBUG "${PROJ_LIBRARY_DEBUG}")
+    endif()
+  endif()
+endif()
+

package/dist/prebuilt/wasi-wasm32-st-release/lib/cmake/gdal/packages/FindPodofo.cmake

@@ -0,0 +1,94 @@
+# Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
+# file COPYING-CMAKE-SCRIPTS or https://cmake.org/licensing for details.
+
+#[=======================================================================[.rst:
+FindPODOFO
+-----------
+
+Copyright (c) 2017, Hiroshi Miura <miurahr@linux.com>
+
+Find the PODOFO headers and libraries.
+
+IMPORTED Targets
+^^^^^^^^^^^^^^^^
+
+This module defines :prop_tgt:`IMPORTED` target ``PODOFO::PODOFO``, if
+PODOFO has been found.
+
+Result Variables
+^^^^^^^^^^^^^^^^
+
+This module defines the following variables:
+
+``PODOFO_FOUND``
+  True if PODOFO found.
+
+``PODOFO_INCLUDE_DIRS``
+  where to find podofo/POFDoc.h, etc.
+
+``PODOFO_LIBRARIES``
+  List of podofo libraries to link.
+
+``PODOFO_VERSION_STRING``
+  Version of podofo library defined in podofo/base/podofo_config.h
+
+#]=======================================================================]
+
+find_package(PkgConfig QUIET)
+if(PKG_CONFIG_FOUND)
+  pkg_check_modules(PC_PODOFO QUIET podofo)
+endif()
+
+find_path(PODOFO_INCLUDE_DIR
+          NAMES podofo.h
+          HINTS ${PC_PODOFO_INCLUDE_DIRS}
+          PATH_SUFFIXES podofo)
+
+find_library(PODOFO_LIBRARY
+             NAMES podofo libpodofo
+             NAMES_PER_DIR
+             HINTS ${PC_PODOFO_LIBRARY_DIRS})
+
+mark_as_advanced(PODOFO_INCLUDE_DIR PODOFO_LIBRARY)
+
+if(PODOFO_INCLUDE_DIR)
+  set(version_hdr "${PODOFO_INCLUDE_DIR}/base/podofo_config.h")
+  if(NOT EXISTS ${version_hdr})
+    # PoDoFo >= 0.10
+    set(version_hdr "${PODOFO_INCLUDE_DIR}/auxiliary/podofo_config.h")
+  endif()
+  if(EXISTS ${version_hdr})
+    file(STRINGS ${version_hdr} _contents REGEX "^[ \t]*#define PODOFO_VERSION_.*")
+    if(_contents)
+        string(REGEX REPLACE ".*#define PODOFO_VERSION_MAJOR[ \t]+([0-9]+).*" "\\1" PODOFO_VERSION_MAJOR "${_contents}")
+        string(REGEX REPLACE ".*#define PODOFO_VERSION_MINOR[ \t]+([0-9]+).*" "\\1" PODOFO_VERSION_MINOR "${_contents}")
+        string(REGEX REPLACE ".*#define PODOFO_VERSION_PATCH[ \t]+([0-9]+).*" "\\1" PODOFO_VERSION_PATCH "${_contents}")
+    endif()
+    set(PODOFO_VERSION_STRING  ${PODOFO_VERSION_MAJOR}.${PODOFO_VERSION_MINOR}.${PODOFO_VERSION_PATCH})
+  endif()
+endif()
+
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(Podofo
+                                  FOUND_VAR PODOFO_FOUND
+                                  REQUIRED_VARS PODOFO_LIBRARY PODOFO_INCLUDE_DIR
+                                  VERSION_VAR PODOFO_VERSION_STRING)
+
+if(PODOFO_FOUND)
+  get_filename_component(PODOFO_PARENT_INCLUDE_DIR ${PODOFO_INCLUDE_DIR} DIRECTORY)
+  set(PODOFO_INCLUDE_DIRS "${PODOFO_INCLUDE_DIR};${PODOFO_PARENT_INCLUDE_DIR}")
+  set(PODOFO_LIBRARIES "${PDOFO_LIBRARY}")
+  if(NOT TARGET PODOFO::Podofo)
+    add_library(PODOFO::Podofo UNKNOWN IMPORTED)
+    set_target_properties(PODOFO::Podofo PROPERTIES
+                          INTERFACE_INCLUDE_DIRECTORIES "${PODOFO_INCLUDE_DIRS}"
+                          IMPORTED_LINK_INTERFACE_LANGUAGES "C"
+                          IMPORTED_LOCATION "${PODOFO_LIBRARY}")
+  endif()
+endif()
+
+include(FeatureSummary)
+set_package_properties(PODOFO PROPERTIES
+                       DESCRIPTION "a free, portable C++ library which includes classes to parse PDF files and modify their contents into memory."
+                       URL "http://podofo.sourceforge.net/"
+)

package/dist/prebuilt/wasi-wasm32-st-release/lib/cmake/gdal/packages/FindPoppler.cmake

@@ -0,0 +1,182 @@
+# Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
+# file COPYING-CMAKE-SCRIPTS or https://cmake.org/licensing for details.
+
+#[=======================================================================[.rst:
+FindPoppler
+--------
+
+Find the Poppler headers and libraries.
+
+This is a component-based find module, which makes use of the COMPONENTS
+and OPTIONAL_COMPONENTS arguments to find_package.  The following components
+are available::
+
+  Cpp  Qt5  Qt4  Glib
+
+Copyright (c) 2017,2019, Hiroshi Miura <miurahr@linux.com>
+Copyright (c) 2015, Alex Richardson <arichardson.kde@gmail.com>
+
+IMPORTED Targets
+^^^^^^^^^^^^^^^^
+
+This module defines :prop_tgt:`IMPORTED` target ``Poppler::Poppler``, if
+curl has been found.
+
+Result Variables
+^^^^^^^^^^^^^^^^
+
+This module defines the following variables:
+
+``Poppler_FOUND``
+  True if Poppler found.
+
+``Poppler_INCLUDE_DIRS``
+  where to find poppler/poppler-config.h, etc.
+
+``Poppler_LIBRARIES``
+  List of libraries when using Poppler.
+
+``Poppler_VERSION_STRING``
+  The version of Poppler found.
+#]=======================================================================]
+
+find_package(PkgConfig QUIET)
+if(PKG_CONFIG_FOUND)
+  pkg_check_modules(PC_Poppler QUIET poppler)
+  if(PC_Poppler_VERSION)
+    set(Poppler_VERSION_STRING ${PC_Poppler_VERSION})
+  endif()
+endif()
+find_path(Poppler_INCLUDE_DIR NAMES "poppler-config.h" "cpp/poppler-version.h" "qt5/poppler-qt5.h" "qt4/poppler-qt4.h"
+          "glib/poppler.h"
+          HINTS ${PC_Poppler_INCLUDE_DIRS}
+          PATH_SUFFIXES poppler)
+
+find_library(Poppler_LIBRARY NAMES poppler HINTS ${PC_Poppler_LIBRARY_DIRS})
+
+set(Poppler_known_components Cpp Qt4 Qt5 Glib )
+foreach(_comp IN LISTS Poppler_known_components)
+  string(TOLOWER "${_comp}" _lc_comp)
+  set(Poppler_${_comp}_pkg_config "poppler-${_lc_comp}")
+  set(Poppler_${_comp}_lib "poppler-${_lc_comp}")
+  set(Poppler_${_comp}_header_subdir "poppler/${_lc_comp}")
+endforeach()
+set(Poppler_known_components Core ${Poppler_known_components})
+
+# poppler-config.h header is only installed with --enable-xpdf-headers
+# fall back to using any header from a submodule with a path to make it work in that case too
+set(Poppler_Cpp_header "poppler-version.h")
+set(Poppler_Qt5_header "poppler-qt5.h")
+set(Poppler_Qt4_header "poppler-qt4.h")
+set(Poppler_Glib_header "poppler.h")
+
+foreach(_comp IN LISTS Poppler_FIND_COMPONENTS)
+  set(Poppler_${_comp}_FOUND FALSE)
+endforeach()
+
+foreach(_comp IN LISTS Poppler_known_components)
+  list(FIND Poppler_FIND_COMPONENTS "${_comp}" _nextcomp)
+  if(_nextcomp GREATER -1)
+    find_path(Poppler_${_comp}_INCLUDE_DIR
+              NAMES ${Poppler_${_comp}_header}
+              PATH_SUFFIXES poppler
+              HINTS ${PC_Poppler_${_comp}_INCLUDE_DIRS})
+    find_library(Poppler_${_comp}_LIBRARY
+            NAMES ${Poppler_${_comp}_lib}
+            HINTS ${PC_Poppler_${_comp}_LIBRARY_DIRS})
+  endif()
+endforeach()
+
+if(NOT Poppler_VERSION_STRING)
+  find_file(Poppler_VERSION_HEADER
+            NAMES "poppler-config.h" "cpp/poppler-version.h"
+            HINTS ${Poppler_INCLUDE_DIR}
+            PATH_SUFFIXES poppler
+            )
+  #if(Poppler_VERSION_HEADER)
+  #  file(READ ${Poppler_VERSION_HEADER} _poppler_version_header_contents)
+  #  string(REGEX REPLACE
+  #         "^.*[ \t]+POPPLER_VERSION_MAJOR[ \t]+([0-9]+).*$"
+  #         "\\1"
+  #         Poppler_VERSION_MAJOR
+  #         "${_poppler_version_header_contents}"
+  #         )
+  #  string(REGEX REPLACE
+  #         "^.*[ \t]+POPPLER_VERSION_MINOR[ \t]+([0-9]+).*$"
+  #         "\\1"
+  #         Poppler_VERSION_MINOR
+  #         "${_poppler_version_header_contents}"
+  #         )
+  #  string(REGEX REPLACE
+  #         "^.*[ \t]+POPPLER_VERSION_MICRO[ \t]+([0-9]+).*$"
+  #         "\\1"
+  #         Poppler_VERSION_MICRO
+  #         "${_poppler_version_header_contents}"
+  #         )
+  #  unset(_poppler_version_header_contents)
+  #  set(Poppler_VERSION_STRING "${Poppler_VERSION_MAJOR}.${Poppler_VERSION_MINOR}.${Poppler_VERSION_MICRO}")
+  #endif()
+  if(Poppler_VERSION_HEADER)
+    file(STRINGS "${Poppler_VERSION_HEADER}" _poppler_version_str REGEX "^#define[\t ]+POPPLER_VERSION[\t ]+\".*\"")
+    string(REGEX REPLACE "^#define[\t ]+POPPLER_VERSION[\t ]+\"([^\"]*)\".*" "\\1" Poppler_VERSION_STRING "${_poppler_version_str}")
+    if(NOT ${Poppler_VERSION_STRING} MATCHES "[0-9]+\\.[0-9]+\\.[0-9]+")
+      message(WARNING "POPPLER_VERSION (${Poppler_VERSION_STRING}) doesn't match *.*.* form")
+    endif()
+    unset(_poppler_version_str)
+  endif()
+endif()
+
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(Poppler
+                                  FOUND_VAR Poppler_FOUND
+                                  REQUIRED_VARS Poppler_LIBRARY Poppler_INCLUDE_DIR
+                                  VERSION_VAR  Poppler_VERSION_STRING
+                                  HANDLE_COMPONENTS)
+mark_as_advanced(Poppler_INCLUDE_DIR Poppler_LIBRARY)
+
+if(Poppler_FOUND)
+  if (NOT EXISTS "${Poppler_INCLUDE_DIR}/Object.h")
+    message(WARNING "Poppler private headers not found. Make sure you build Poppler with -DENABLE_UNSTABLE_API_ABI_HEADERS")
+    unset(Poppler_FOUND)
+    unset(POPPLER_FOUND)
+  endif()
+endif()
+
+if(Poppler_FOUND)
+  set(Poppler_INCLUDE_DIRS "${Poppler_INCLUDE_DIR}")
+  if(Poppler_INCLUDE_DIR MATCHES ".*/poppler" OR Poppler_INCLUDE_DIR MATCHES ".*\\poppler")
+      # poppler/splash/SplashBitmap.h unfortunately has a #include "poppler/GfxState.h"
+      # which obliges us to add the parent directory of Poppler_INCLUDE_DIR
+      get_filename_component(_poppler_upper_include_dir "${Poppler_INCLUDE_DIR}" DIRECTORY)
+      list(APPEND Poppler_INCLUDE_DIRS "${_poppler_upper_include_dir}")
+  endif()
+  set(Poppler_LIBRARIES "${Poppler_LIBRARY}")
+  if(NOT TARGET Poppler::Poppler)
+    add_library(Poppler::Poppler UNKNOWN IMPORTED)
+    set(POPPLER_EXTRA_TARGETS)
+    foreach(_lib IN LISTS POPPLER_EXTRA_LIBRARIES)
+        add_library(Poppler::Poppler_${INCR} UNKNOWN IMPORTED)
+        set_target_properties(Poppler::Poppler_${INCR} PROPERTIES
+                              IMPORTED_LINK_INTERFACE_LANGUAGES "C"
+                              IMPORTED_LOCATION "${_lib}")
+        list(APPEND POPPLER_EXTRA_TARGETS Poppler::Poppler_${INCR})
+        math(EXPR INCR "${INCR}+1")
+    endforeach()
+    set_target_properties(Poppler::Poppler PROPERTIES
+                          INTERFACE_INCLUDE_DIRECTORIES "${Poppler_INCLUDE_DIRS}"
+                          IMPORTED_LINK_INTERFACE_LANGUAGES "C"
+                          INTERFACE_LINK_LIBRARIES "${POPPLER_EXTRA_TARGETS}"
+                          IMPORTED_LOCATION "${Poppler_LIBRARY}")
+    foreach(tgt IN LISTS Poppler_known_components)
+      add_library(Poppler::${tgt} UNKNOWN IMPORTED)
+      set_target_properties(Poppler::${tgt} PROPERTIES
+                            INTERFACE_INCLUDE_DIRECTORIES "${Poppler_${tgt}_INCLUDE_DIR}"
+                            IMPORTED_LINK_INTERFACE_LANGUAGES "C"
+                            IMPORTED_LOCATION "${POPPLER_${tgt}_LIBRARY}")
+    endforeach()
+  endif()
+endif()
+
+include(FeatureSummary)
+set_package_properties(Poppler PROPERTIES
+                       DESCRIPTION "A PDF rendering library" URL "http://poppler.freedesktop.org")