@crossbind/port-gdal-wasi 2.0.0-beta.50

package/dist/prebuilt/wasi-wasm32-st-release/lib/cmake/gdal/packages/FindMRSID.cmake

@@ -0,0 +1,66 @@
+# Distributed under the GDAL/OGR MIT style License.  See accompanying
+# file LICENSE.TXT.
+
+#[=======================================================================[.rst:
+configure
+---------
+
+#]=======================================================================]
+# Find the MRSID library - Multi-resolution Seamless Image Database.
+#
+# Copyright (C) 2017,2018 Hiroshi Miura
+# Copyright (c) 2015 NextGIS <info@nextgis.com>
+#
+# Sets
+#   MRSID_FOUND.
+#   MRSID_INCLUDE_DIRS
+#   MRSID_LIBRARIES
+#
+
+find_path(MRSID_INCLUDE_DIR NAMES lt_base.h)
+
+if( MRSID_INCLUDE_DIR )
+  find_library( MRSID_LIBRARY NAMES lti_dsdk ltidsdk NAMES_PER_DIR)
+endif()
+
+if(MRSID_INCLUDE_DIR AND MRSID_LIBRARY)
+  set(MAJOR_VERSION 0)
+  set(MINOR_VERSION 0)
+  set(SRV_VERSION 0)
+  set(BLD_VERSION 0)
+  if(EXISTS "${MRSID_INCLUDE_DIR}/lti_version.h")
+    file(READ "${MRSID_INCLUDE_DIR}/lti_version.h" VERSION_H_CONTENTS)
+    string(REGEX MATCH "LTI_SDK_MAJOR[ \t]+([0-9]+)"
+      MAJOR_VERSION ${VERSION_H_CONTENTS})
+    string (REGEX MATCH "([0-9]+)"
+      MAJOR_VERSION ${MAJOR_VERSION})
+    string(REGEX MATCH "LTI_SDK_MINOR[ \t]+([0-9]+)"
+      MINOR_VERSION ${VERSION_H_CONTENTS})
+    string (REGEX MATCH "([0-9]+)"
+      MINOR_VERSION ${MINOR_VERSION})
+    string(REGEX MATCH "LTI_SDK_REV[ \t]+([0-9]+)"
+      REV_VERSION ${VERSION_H_CONTENTS})
+    string (REGEX MATCH "([0-9]+)"
+      REV_VERSION ${REV_VERSION})
+    unset(VERSION_H_CONTENTS)
+  endif()
+  set(MRSID_VERSION_STRING "${MAJOR_VERSION}.${MINOR_VERSION}.${REV_VERSION}")
+endif()
+mark_as_advanced(MRSID_INCLUDE_DIR MRSID_LIBRARY MRSID_VERSION_STRING)
+
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(MRSID FOUND_VAR MRSID_FOUND
+                                  REQUIRED_VARS MRSID_LIBRARY MRSID_INCLUDE_DIR
+                                  VERSION_VAR MRSID_VERSION_STRING)
+
+# Copy the results to the output variables.
+if(MRSID_FOUND)
+  set(MRSID_LIBRARIES ${MRSID_LIBRARY})
+  set(MRSID_INCLUDE_DIRS ${MRSID_INCLUDE_DIR})
+  if(NOT TARGET MRSID::MRSID)
+    add_library(MRSID::MRSID UNKNOWN IMPORTED)
+    set_target_properties(MRSID::MRSID PROPERTIES
+                          INTERFACE_INCLUDE_DIRECTORIES "${MRSID_INCLUDE_DIR}"
+                          IMPORTED_LOCATION "${MRSID_LIBRARY}")
+  endif()
+endif()

package/dist/prebuilt/wasi-wasm32-st-release/lib/cmake/gdal/packages/FindMSSQL_NCLI.cmake

@@ -0,0 +1,86 @@
+# Find MSSQL Native Client
+# ~~~~~~~~~~~~~~~~~~~~~~~~
+#
+# Copyright (c) 2021 Even Rouault <even.rouault@spatialys.com>
+# Redistribution and use is allowed according to the terms of the BSD license.
+# For details see the accompanying COPYING-CMAKE-SCRIPTS file.
+#
+
+#[=======================================================================[.rst:
+FindMSSQL_NCLI
+--------------
+
+Find the MSSQL Native Client includes and library.
+
+IMPORTED Targets
+^^^^^^^^^^^^^^^^
+
+This module defines :prop_tgt:`IMPORTED` target ``MSSQL_NCLI::MSSQL_NCLI``, if
+MSSQL_NCLI has been found.
+
+Result Variables
+^^^^^^^^^^^^^^^^
+
+This module defines the following variables:
+
+::
+
+  MSSQL_NCLI_INCLUDE_DIRS   - where to find sqlncli.h, etc.
+  MSSQL_NCLI_LIBRARIES      - List of libraries when using MSSQL_NCLI.
+  MSSQL_NCLI_FOUND          - True if MSSQL_NCLI found.
+  MSSQL_NCLI_VERSION        - Major Version (11, 10, ...). Can be a input variable too
+
+#]=======================================================================]
+
+if(NOT WIN32)
+    return()
+endif()
+
+if(NOT DEFINED MSSQL_NCLI_VERSION)
+    set(MSSQL_NCLI_VERSION_CANDIDATES 11 10)
+    foreach(_vers IN LISTS MSSQL_NCLI_VERSION_CANDIDATES)
+      set(_dir "C:/Program Files/Microsoft SQL Server/${_vers}0/SDK")
+      if(EXISTS "${_dir}")
+        set(MSSQL_NCLI_VERSION "${_vers}")
+        break()
+      endif()
+    endforeach()
+endif()
+
+if(NOT DEFINED MSSQL_NCLI_ROOT)
+    set(MSSQL_NCLI_ROOT "C:/Program Files/Microsoft SQL Server/${MSSQL_NCLI_VERSION}0/SDK")
+endif()
+
+find_path(MSSQL_NCLI_INCLUDE_DIR NAMES sqlncli.h
+          PATHS "${MSSQL_NCLI_ROOT}/Include")
+mark_as_advanced(MSSQL_NCLI_INCLUDE_DIR)
+
+if("${CMAKE_SIZEOF_VOID_P}" EQUAL "8")
+    set(MSSQL_NCLI_DIR_ARCH x64)
+else()
+    set(MSSQL_NCLI_DIR_ARCH x86)
+endif()
+
+find_library(MSSQL_NCLI_LIBRARY NAMES "sqlncli${MSSQL_NCLI_VERSION}.lib"
+             PATHS "${MSSQL_NCLI_ROOT}/Lib/${MSSQL_NCLI_DIR_ARCH}")
+mark_as_advanced(MSSQL_NCLI_LIBRARY)
+
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(MSSQL_NCLI
+                                  FOUND_VAR MSSQL_NCLI_FOUND
+                                  VERSION_VAR MSSQL_NCLI_VERSION
+                                  REQUIRED_VARS MSSQL_NCLI_LIBRARY MSSQL_NCLI_INCLUDE_DIR MSSQL_NCLI_VERSION)
+
+if(MSSQL_NCLI_FOUND)
+    set(MSSQL_NCLI_LIBRARIES ${MSSQL_NCLI_LIBRARY})
+    set(MSSQL_NCLI_INCLUDE_DIRS ${MSSQL_NCLI_INCLUDE_DIR})
+    if(NOT TARGET MSSQL_NCLI::MSSQL_NCLI)
+        add_library(MSSQL_NCLI::MSSQL_NCLI UNKNOWN IMPORTED)
+        set_target_properties(MSSQL_NCLI::MSSQL_NCLI PROPERTIES
+                              INTERFACE_INCLUDE_DIRECTORIES "${MSSQL_NCLI_INCLUDE_DIRS}"
+                              INTERFACE_COMPILE_DEFINITIONS "SQLNCLI_VERSION=${MSSQL_NCLI_VERSION};MSSQL_BCP_SUPPORTED=1"
+                              IMPORTED_LINK_INTERFACE_LANGUAGES "C"
+                              IMPORTED_LOCATION "${MSSQL_NCLI_LIBRARY}")
+    endif()
+endif()
+

package/dist/prebuilt/wasi-wasm32-st-release/lib/cmake/gdal/packages/FindMSSQL_ODBC.cmake

@@ -0,0 +1,113 @@
+# Find MSSQL ODBC driver
+# ~~~~~~~~~~~~~~~~~~~~~~
+#
+# Copyright (c) 2021 Even Rouault <even.rouault@spatialys.com>
+# Redistribution and use is allowed according to the terms of the BSD license.
+# For details see the accompanying COPYING-CMAKE-SCRIPTS file.
+#
+
+#[=======================================================================[.rst:
+FindMSSQL_ODBC
+--------------
+
+Find the MSSQL ODBC driver includes and library.
+
+IMPORTED Targets
+^^^^^^^^^^^^^^^^
+
+This module defines :prop_tgt:`IMPORTED` target ``MSSQL_ODBC::MSSQL_ODBC``, if
+MSSQL_ODBC has been found.
+
+Result Variables
+^^^^^^^^^^^^^^^^
+
+This module defines the following variables:
+
+::
+
+  MSSQL_ODBC_INCLUDE_DIRS   - where to find msodbcsql.h, etc.
+  MSSQL_ODBC_LIBRARIES      - List of libraries when using MSSQL_ODBC.
+  MSSQL_ODBC_FOUND          - True if MSSQL_ODBC found.
+  MSSQL_ODBC_VERSION        - Major Version (18, 17, 13, ...). Can be a input variable too
+
+#]=======================================================================]
+
+if(NOT DEFINED MSSQL_ODBC_ROOT AND DEFINED CMAKE_FIND_USE_CMAKE_SYSTEM_PATH AND NOT CMAKE_FIND_USE_CMAKE_SYSTEM_PATH)
+    return()
+endif()
+
+if(WIN32)
+    if(NOT DEFINED MSSQL_ODBC_VERSION)
+        set(MSSQL_ODBC_VERSION_CANDIDATES 18 17 13)
+        foreach(_vers IN LISTS MSSQL_ODBC_VERSION_CANDIDATES)
+          set(_dir "C:/Program Files/Microsoft SQL Server/Client SDK/ODBC/${_vers}0/SDK")
+          if(EXISTS "${_dir}")
+            set(MSSQL_ODBC_VERSION "${_vers}")
+            break()
+          endif()
+        endforeach()
+    endif()
+
+    if(NOT DEFINED MSSQL_ODBC_ROOT)
+        set(MSSQL_ODBC_ROOT "C:/Program Files/Microsoft SQL Server/Client SDK/ODBC/${MSSQL_ODBC_VERSION}0/SDK")
+    endif()
+
+    find_path(MSSQL_ODBC_INCLUDE_DIR NAMES msodbcsql.h
+              PATHS "${MSSQL_ODBC_ROOT}/Include")
+    mark_as_advanced(MSSQL_ODBC_INCLUDE_DIR)
+
+    if("${CMAKE_SIZEOF_VOID_P}" EQUAL "8")
+        set(MSSQL_ODBC_DIR_ARCH x64)
+    else()
+        set(MSSQL_ODBC_DIR_ARCH x86)
+    endif()
+
+    find_library(MSSQL_ODBC_LIBRARY NAMES "msodbcsql${MSSQL_ODBC_VERSION}.lib"
+                 PATHS "${MSSQL_ODBC_ROOT}/Lib/${MSSQL_ODBC_DIR_ARCH}")
+    mark_as_advanced(MSSQL_ODBC_LIBRARY)
+else()
+    if(NOT DEFINED MSSQL_ODBC_VERSION)
+        set(MSSQL_ODBC_VERSION_CANDIDATES 18 17 13)
+        foreach(_vers IN LISTS MSSQL_ODBC_VERSION_CANDIDATES)
+          set(_dir "/opt/microsoft/msodbcsql${_vers}")
+          if(EXISTS "${_dir}")
+            set(MSSQL_ODBC_VERSION "${_vers}")
+            break()
+          endif()
+        endforeach()
+    endif()
+
+    if(NOT DEFINED MSSQL_ODBC_ROOT)
+        set(MSSQL_ODBC_ROOT "/opt/microsoft/msodbcsql${MSSQL_ODBC_VERSION}")
+    endif()
+
+    find_path(MSSQL_ODBC_INCLUDE_DIR NAMES msodbcsql.h
+              PATHS "${MSSQL_ODBC_ROOT}/include")
+    mark_as_advanced(MSSQL_ODBC_INCLUDE_DIR)
+
+    file(GLOB _libs "${MSSQL_ODBC_ROOT}/lib*/libmsodbc*")
+    list(LENGTH _libs _libs_length)
+    if(_libs_length EQUAL "1")
+        set(MSSQL_ODBC_LIBRARY ${_libs})
+    endif()
+    mark_as_advanced(MSSQL_ODBC_LIBRARY)
+endif()
+
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(MSSQL_ODBC
+                                  FOUND_VAR MSSQL_ODBC_FOUND
+                                  VERSION_VAR MSSQL_ODBC_VERSION
+                                  REQUIRED_VARS MSSQL_ODBC_LIBRARY MSSQL_ODBC_INCLUDE_DIR MSSQL_ODBC_VERSION)
+
+if(MSSQL_ODBC_FOUND)
+    set(MSSQL_ODBC_LIBRARIES ${MSSQL_ODBC_LIBRARY})
+    set(MSSQL_ODBC_INCLUDE_DIRS ${MSSQL_ODBC_INCLUDE_DIR})
+    if(NOT TARGET MSSQL_ODBC::MSSQL_ODBC)
+        add_library(MSSQL_ODBC::MSSQL_ODBC UNKNOWN IMPORTED)
+        set_target_properties(MSSQL_ODBC::MSSQL_ODBC PROPERTIES
+                              INTERFACE_INCLUDE_DIRECTORIES "${MSSQL_ODBC_INCLUDE_DIRS}"
+                              INTERFACE_COMPILE_DEFINITIONS "MSODBCSQL_VERSION=${MSSQL_ODBC_VERSION};MSSQL_BCP_SUPPORTED=1"
+                              IMPORTED_LINK_INTERFACE_LANGUAGES "C"
+                              IMPORTED_LOCATION "${MSSQL_ODBC_LIBRARY}")
+    endif()
+endif()

package/dist/prebuilt/wasi-wasm32-st-release/lib/cmake/gdal/packages/FindMySQL.cmake

@@ -0,0 +1,83 @@
+# Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
+# file COPYING-CMAKE-SCRIPTS or https://cmake.org/licensing for details.
+
+#.rst
+# Get from http://www.cmake.org/Wiki/CMakeUserFindMySQL
+# - Find mysqlclient
+# Find the native MySQL includes and library
+#
+#  MYSQL_INCLUDE_DIRS- where to find mysql.h, etc.
+#  MYSQL_LIBRARIES   - List of libraries when using MySQL.
+#  MYSQL_FOUND       - True if MySQL found.
+
+find_path(MYSQL_INCLUDE_DIR
+          NAMES mysql.h
+          PATH_SUFFIXES mysql
+          DOC "MySQL Client library includes")
+
+if( MYSQL_INCLUDE_DIR AND EXISTS "${MYSQL_INCLUDE_DIR}/mysql_version.h" )
+    file( STRINGS "${MYSQL_INCLUDE_DIR}/mysql_version.h"
+          MYSQL_VERSION_H REGEX "^#define[ \t]+MYSQL_SERVER_VERSION[ \t]+\"[^\"]+\".*$" )
+    string( REGEX REPLACE
+            "^.*MYSQL_SERVER_VERSION[ \t]+\"([^\"]+)\".*$" "\\1" MYSQL_VERSION_STRING
+            "${MYSQL_VERSION_H}" )
+endif()
+
+find_library(MYSQL_LIBRARY NAMES mysqlclient mysqlclient_r NAMES_PER_DIR)
+
+if( NOT CMAKE_C_COMPILER_LOADED )
+    message(AUTHOR_WARNING "C language not enabled: Skipping detection of extra link libraries.")
+elseif( MYSQL_INCLUDE_DIR AND MYSQL_LIBRARY )
+    # On Conda, mysqlclient is a static lib that requires explicit linking to zlib and zstd
+    function(check_mysql_test_program_links)
+        include(CheckCSourceCompiles)
+        include(CMakePushCheckState)
+        cmake_push_check_state(RESET)
+        set(CMAKE_REQUIRED_QUIET "yes")
+        set(CMAKE_REQUIRED_INCLUDES ${MYSQL_INCLUDE_DIR})
+        set(CMAKE_REQUIRED_LIBRARIES ${MYSQL_LIBRARY})
+        check_c_source_compiles("#include <mysql.h>\n; int main () {mysql_library_end (); return 0;}" MYSQL_TEST_PROGRAM_LINKS)
+        cmake_pop_check_state()
+    endfunction()
+
+    check_mysql_test_program_links()
+    if(NOT MYSQL_TEST_PROGRAM_LINKS)
+       find_library(_MYSQL_ZLIB_LIBRARY NAMES zlib)
+       find_library(_MYSQL_ZSTD_LIBRARY NAMES zstd)
+       if(_MYSQL_ZLIB_LIBRARY AND _MYSQL_ZSTD_LIBRARY)
+            function(check_mysql_test_program_links_with_zlib_and_zstd)
+                include(CheckCSourceCompiles)
+                include(CMakePushCheckState)
+                cmake_push_check_state(RESET)
+                set(CMAKE_REQUIRED_QUIET "yes")
+                set(CMAKE_REQUIRED_INCLUDES ${MYSQL_INCLUDE_DIR})
+                set(CMAKE_REQUIRED_LIBRARIES ${MYSQL_LIBRARY} ${_MYSQL_ZSTD_LIBRARY} ${_MYSQL_ZLIB_LIBRARY})
+                check_c_source_compiles("#include <mysql.h>\n;int main () {mysql_library_end (); return 0;}" MYSQL_TEST_PROGRAM_LINKS_WITH_ZLIB_AND_ZSTD)
+                cmake_pop_check_state()
+            endfunction()
+
+            check_mysql_test_program_links_with_zlib_and_zstd()
+            if(MYSQL_TEST_PROGRAM_LINKS_WITH_ZLIB_AND_ZSTD)
+              set(MYSQL_ZSTD_LIBRARY ${_MYSQL_ZSTD_LIBRARY})
+              set(MYSQL_ZLIB_LIBRARY ${_MYSQL_ZLIB_LIBRARY})
+            endif()
+       endif()
+    endif()
+endif()
+
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(MySQL
+                                  FOUND_VAR MYSQL_FOUND
+                                  REQUIRED_VARS MYSQL_LIBRARY MYSQL_INCLUDE_DIR
+                                  VERSION_VAR MYSQL_VERSION_STRING)
+include(FeatureSummary)
+set_package_properties(MYSQL PROPERTIES
+                       DESCRIPTION "MySQL Client library"
+                       URL "https://dev.mysql.com/downloads/c-api/"
+                       )
+
+mark_as_advanced(MYSQL_LIBRARY MYSQL_INCLUDE_DIR)
+
+set(MYSQL_LIBRARIES ${MYSQL_LIBRARY} ${MYSQL_ZSTD_LIBRARY} ${MYSQL_ZLIB_LIBRARY})
+set(MYSQL_INCLUDE_DIRS ${MYSQL_INCLUDE_DIR})
+

package/dist/prebuilt/wasi-wasm32-st-release/lib/cmake/gdal/packages/FindNetCDF.cmake

@@ -0,0 +1,209 @@
+# Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
+# file Copyright.txt or https://cmake.org/licensing for details.
+
+#.rst:
+# FindNetCDF
+# ---------
+#
+# Find the native NetCDF includes and library
+#
+#  NETCDF_INCLUDE_DIR  - user modifiable choice of where netcdf headers are
+#  NETCDF_LIBRARY      - user modifiable choice of where netcdf libraries are
+#
+# Your package can require certain interfaces to be FOUND by setting these
+#
+#  NETCDF_CXX         - require the C++ interface and link the C++ library
+#  NETCDF_F77         - require the F77 interface and link the fortran library
+#  NETCDF_F90         - require the F90 interface and link the fortran library
+#
+# Or equivalently by calling FindNetCDF with a COMPONENTS argument containing one or
+# more of "CXX;F77;F90".
+#
+# When interfaces are requested the user has access to interface specific hints:
+#
+#  NETCDF_${LANG}_INCLUDE_DIR - where to search for interface header files
+#  NETCDF_${LANG}_LIBRARY     - where to search for interface libraries
+#
+# This module returns these variables for the rest of the project to use.
+#
+#  NETCDF_FOUND          - True if NetCDF found including required interfaces (see below)
+#  NETCDF_LIBRARIES      - All netcdf related libraries.
+#  NETCDF_INCLUDE_DIRS   - All directories to include.
+#  NETCDF_HAS_INTERFACES - Whether requested interfaces were found or not.
+#  NETCDF_${LANG}_INCLUDE_DIRS/NETCDF_${LANG}_LIBRARIES - C/C++/F70/F90 only interface
+#
+# Normal usage would be:
+#  set (NETCDF_F90 "YES")
+#  find_package (NetCDF REQUIRED)
+#  target_link_libraries (uses_everthing ${NETCDF_LIBRARIES})
+#  target_link_libraries (only_uses_f90 ${NETCDF_F90_LIBRARIES})
+#
+# It detect NetCDF configurations and set configurations in variable
+#
+# NETCDF_HAS_NC2
+# NETCDF_HAS_NC4
+# NETCDF_HAS_HDF4
+# NETCDF_HAS_HDF5
+# NETCDF_HAS_DAP
+# NETCDF_HAS_MEM
+#
+
+#search starting from user editable cache var
+if (NETCDF_INCLUDE_DIR AND NETCDF_LIBRARY)
+    # Already in cache, be silent
+    set (NETCDF_FIND_QUIETLY TRUE)
+endif ()
+find_program(NC_CONFIG NAMES nc-config DOC "NetCDF config command")
+mark_as_advanced(NC_CONFIG)
+
+if(NC_CONFIG)
+    execute_process(COMMAND ${NC_CONFIG} --includedir
+                    RESULT_VARIABLE nc_res
+                    OUTPUT_VARIABLE NETCDF_INCLUDE_PATH
+                    ERROR_QUIET
+                    OUTPUT_STRIP_TRAILING_WHITESPACE)
+    execute_process(COMMAND ${NC_CONFIG} --prefix
+                    RESULT_VARIABLE nc_res
+                    OUTPUT_VARIABLE NETCDF_PREFIX_DIR
+                    ERROR_QUIET
+                    OUTPUT_STRIP_TRAILING_WHITESPACE)
+endif()
+
+find_path(NETCDF_INCLUDE_DIR netcdf.h
+          PATHS "${NETCDF_DIR}/include"
+          HINTS ${NETCDF_INCLUDE_PATH})
+
+find_library (NETCDF_LIBRARY NAMES netcdf
+        PATHS "${NETCDF_DIR}/lib"
+              "${NETCDF_INCLUDE_DIR}/../lib"
+        HINTS "${NETCDF_PREFIX_DIR}/lib")
+
+if(NETCDF_INCLUDE_DIR AND NETCDF_LIBRARY)
+    set (NETCDF_C_INCLUDE_DIRS ${NETCDF_INCLUDE_DIR})
+    set (NETCDF_C_LIBRARIES ${NETCDF_LIBRARY})
+
+    find_file(NETCDF_MEM_H
+             NAMES "netcdf_mem.h"
+             HINTS ${NETCDF_INCLUDE_DIR})
+    mark_as_advanced(NETCDF_MEM_H)
+    # Ubuntu 16.04 netCDFConfig.cmake declares netCDF_HAS_DISKLESS but doesn't include netcdf_mem.h
+    unset(netCDF_HAS_DISKLESS)
+    if(NETCDF_MEM_H)
+        set(NETCDF_HAS_MEM ON)
+    endif()
+
+    function(GET_NC_CONFIG _conf)
+        if(_conf STREQUAL "c++")
+            set(_key "CXX")
+        else()
+            string(TOUPPER ${_conf} _key)
+        endif()
+        execute_process(COMMAND ${NC_CONFIG} --has-${_conf}
+                        RESULT_VARIABLE nc_res
+                        OUTPUT_VARIABLE nc_has_${_conf}
+                        ERROR_QUIET
+                        OUTPUT_STRIP_TRAILING_WHITESPACE)
+        if(nc_has_${_conf} STREQUAL "yes")
+            set(NETCDF_HAS_${_key} ON  PARENT_SCOPE)
+        else()
+            set(NETCDF_HAS_${_key} OFF PARENT_SCOPE)
+        endif()
+    endfunction()
+
+    if(NC_CONFIG AND NOT WIN32)
+        GET_NC_CONFIG(dap)
+        GET_NC_CONFIG(nc2)
+        GET_NC_CONFIG(nc4)
+        GET_NC_CONFIG(hdf4)
+        GET_NC_CONFIG(hdf5)
+    else()
+        # Detect internal NC4_create symbol as a hint that NC4 support is enabled
+        # Fragile...
+        function(detect_NC4_create)
+            include(CheckCSourceCompiles)
+            include(CMakePushCheckState)
+            cmake_push_check_state(RESET)
+            set(CMAKE_REQUIRED_QUIET "yes")
+            set(CMAKE_REQUIRED_LIBRARIES ${NETCDF_LIBRARY})
+            check_c_source_compiles("int NC4_create ();int main () {return NC4_create ();}" HAVE_NC4_CREATE)
+            cmake_pop_check_state()
+        endfunction()
+
+        detect_NC4_create()
+        if(HAVE_NC4_CREATE)
+            set(NETCDF_HAS_NC4 ON)
+        endif()
+    endif()
+
+    macro(NetCDF_DETECT_COMPONENT _comp)
+        list (FIND NetCDF_FIND_COMPONENTS "${_comp}" _nextcomp)
+        if (_nextcomp GREATER -1)
+            set (NETCDF_${_comp} 1)
+        endif ()
+    endmacro()
+    NetCDF_DETECT_COMPONENT("CXX")
+    NetCDF_DETECT_COMPONENT("F77")
+    NetCDF_DETECT_COMPONENT("F90")
+
+    #start finding requested language components
+    set (NetCDF_libs "")
+    set (NetCDF_includes "${NETCDF_INCLUDE_DIR}")
+    get_filename_component (NetCDF_lib_dirs "${NETCDF_LIBRARY}" PATH)
+    set (NETCDF_HAS_INTERFACES "YES") # will be set to NO if we're missing any interfaces
+    macro (NetCDF_check_interface lang header libs)
+        if (NETCDF_${lang})
+            #search starting from user modifiable cache var
+            find_path (NETCDF_${lang}_INCLUDE_DIR NAMES ${header}
+                    HINTS "${NETCDF_INCLUDE_DIR}"
+                    HINTS "${NETCDF_${lang}_ROOT}/include"
+                    ${USE_DEFAULT_PATHS})
+
+            find_library (NETCDF_${lang}_LIBRARY NAMES ${libs}
+                    HINTS "${NetCDF_lib_dirs}"
+                    HINTS "${NETCDF_${lang}_ROOT}/lib"
+                    ${USE_DEFAULT_PATHS})
+
+            mark_as_advanced (NETCDF_${lang}_INCLUDE_DIR NETCDF_${lang}_LIBRARY)
+
+            #export to internal varS that rest of project can use directly
+            set (NETCDF_${lang}_LIBRARIES ${NETCDF_${lang}_LIBRARY})
+            set (NETCDF_${lang}_INCLUDE_DIRS ${NETCDF_${lang}_INCLUDE_DIR})
+
+            if (NETCDF_${lang}_INCLUDE_DIR AND NETCDF_${lang}_LIBRARY)
+                list (APPEND NetCDF_libs ${NETCDF_${lang}_LIBRARY})
+                list (APPEND NetCDF_includes ${NETCDF_${lang}_INCLUDE_DIR})
+            else ()
+                set (NETCDF_HAS_INTERFACES "NO")
+                message (STATUS "Failed to find NetCDF interface for ${lang}")
+            endif ()
+        endif ()
+    endmacro ()
+
+    NetCDF_check_interface (CXX netcdfcpp.h netcdf_c++)
+    NetCDF_check_interface (F77 netcdf.inc  netcdff)
+    NetCDF_check_interface (F90 netcdf.mod  netcdff)
+
+    #export accumulated results to internal vars that rest of project can depend on
+    list (APPEND NetCDF_libs "${NETCDF_C_LIBRARIES}")
+    set (NETCDF_LIBRARIES ${NetCDF_libs})
+    set (NETCDF_INCLUDE_DIRS ${NetCDF_includes})
+endif()
+mark_as_advanced(NETCDF_LIBRARY NETCDF_INCLUDE_DIR)
+
+include (FindPackageHandleStandardArgs)
+find_package_handle_standard_args (NetCDF
+                                   FOUND_VAR NETCDF_FOUND
+                                   REQUIRED_VARS NETCDF_LIBRARY NETCDF_INCLUDE_DIR
+                                   VERSION_VAR NETCDF_VERSION
+                                   )
+
+if(NETCDF_FOUND)
+    if(NOT TARGET NETCDF::netCDF)
+        add_library(NETCDF::netCDF UNKNOWN IMPORTED)
+        set_target_properties(NETCDF::netCDF PROPERTIES
+            INTERFACE_INCLUDE_DIRECTORIES "${NETCDF_INCLUDE_DIRS}")
+        set_target_properties(NETCDF::netCDF PROPERTIES
+            IMPORTED_LINK_INTERFACE_LANGUAGES "C;CXX"
+            IMPORTED_LOCATION "${NETCDF_LIBRARIES}")
+    endif()
+endif()