bioroebe 0.10.80

data/lib/bioroebe/perl/local_to_global.pl

@@ -0,0 +1,694 @@
+#!/usr/bin/perl
+# =========================================================================== #
+# This script will convert local coords from within a transcript into
+# a global (e.g. genomic) coordinates - and vice versa.
+# =========================================================================== #
+
+use strict;
+use warnings;
+use Getopt::Long;
+use AnnotUtil;
+use Pod::Usage;
+
+# =========================================================================== #
+# Command line options:
+# =========================================================================== #
+my $exon_in;    # exon gtf file
+my $data_in;    # data to be converted
+
+my $exon_type;  # annotation type of exon file
+my $data_type;  # annotation type of data file
+
+my $txID_exon;  # specify txID of exon file to be used
+my $txID_data;  # specify txID of data file to be used
+
+my $loc2glob;   # convert local to global coordinates
+my $glob2loc;   # convert global tp local coordinates
+
+my $v;          # verbose mode
+
+my $show_help;
+my $man;
+
+GetOptions(
+  'exon|e=s'      => \$exon_in,
+  'data|dat|d:s'  => \$data_in,
+  'etype|et:s'    => \$exon_type,
+  'dtype|dt:s'    => \$data_type,
+  'exonID|eid:s'  => \$txID_exon,
+  'dataID|did:s'  => \$txID_data,
+  'g2l|glob2loc'  => \$glob2loc,
+  'l2g|loc2glob'  => \$loc2glob,
+  'verbose|v'     => \$v,
+  'help|h'        => \$show_help,
+  'man'           => \$man
+);
+
+pod2usage(1) if $show_help;
+pod2usage(-verbose => 2) if $man;
+
+# =========================================================================== #
+# Known file types.
+# =========================================================================== #
+my %known_types = (bed  => 1,
+                   gtf  => 2,
+                   gff3 => 3);
+
+# =========================================================================== #
+# Auto detect file types
+# =========================================================================== #
+unless (defined($exon_type)){
+  $exon_type = $1 if $exon_in =~ /\.(\w+)$/;
+}
+
+# =========================================================================== #
+unless (defined($data_type)){
+# =========================================================================== #
+  $data_type = $1 if $data_in =~ /\.(\w+)$/;
+}
+
+
+die "\nplease specify the exon file type: -et|-etype [bed, gtf, gff3]\n\n" unless defined($exon_type) && exists($known_types{$exon_type});
+die "\nplease specify the data file type: -dt|-dtype [bed, gtf, gff3]\n\n" unless defined($data_type) && exists($known_types{$data_type});
+
+# field that holds transcript id
+my %txID_field = (bed  => "name",
+                  gtf  => "transcript_id",
+                  gff3 => "ID");
+
+$txID_exon = $txID_field{$exon_type} unless (defined($txID_exon));
+$txID_data = $txID_field{$data_type} unless (defined($txID_data));
+
+print "txID_exon $txID_exon\n" if $v;
+print "txID_data $txID_data\n" if $v;
+
+# Read exon gtf file
+# ------------------------------------------------------------
+
+my %exons = ();  # Reference to the entire %hash.
+
+my $fh_exon;
+
+if ($exon_in =~ /\.gz$/){
+  open($fh_exon, "zcat $exon_in |") || die "could not open gzipped exon annotation file $!\n";
+}
+else{
+  open($fh_exon, "<$exon_in") || die "could not open exon annotation file $!\n";
+}
+
+while(<$fh_exon>){
+#  chomp;
+  my $id;
+
+  if ($exon_type eq "gtf"){
+    my($fields, $attribs) = splitGtfLine($_);
+    $id = $attribs->{$txID_exon}->[0];
+    $id =~ s/[";]//g;
+    push(@{$exons{$id}},$fields);
+    print "exon id: $id\n" if $v;
+    next;
+  }
+
+  if ($exon_type eq "gff3"){
+    my($fields, $attribs) = splitGff3Line($_);
+    $id = $attribs->{$txID_exon}->{$txID_exon};
+    $id =~ s/[";]//g;
+    push(@{$exons{$id}},$fields);
+    next;
+  }
+
+  if ($exon_type eq "bed"){
+    my($fields) = splitBedLine($_);
+    next unless exists($fields->{strand});
+    $id = $fields->{$txID_exon};
+    push(@{$exons{$id}},$fields);
+    next;
+  }
+  
+}
+close($fh_exon);
+print STDERR "done reading exon table\n" if $v;
+
+# -----------------------------------------------------------
+# Calculate local coordinates
+# -----------------------------------------------------------
+
+my ($g2l) = &genomeLocalTAB(\%exons);
+
+# Read data file
+# and convert local coordinates to genomic coodinates
+# --------------------------------------------------
+
+my $fh_data;
+
+if ($data_in =~ /\.gz$/){
+  open($fh_data, "zcat $data_in |") || die "could not open gzipped data gtf file $!\n";
+}
+else{
+  open($fh_data, "<$data_in") || die "could not open data annotation file $!\n";
+}
+
+while(<$fh_data>){
+  chomp;
+  my($fields, $attribs, $txID);
+
+  # the id field is the tx_id in the global data file
+  # when converting global2local!
+
+  if ($data_type eq "gtf"){
+    ($fields, $attribs) = splitGtfLine($_);
+    $txID = $attribs->{$txID_data}->[0];
+    $txID =~ s/[";]//g;
+  }
+  
+  if ($data_type eq "gff3"){
+    ($fields, $attribs) = splitGff3Line($_);
+    $txID = $attribs->{$txID_data}->{$txID_data};
+    $txID =~ s/[";]//g;
+#    print "data txID $txID\n";
+  }
+
+  if ($data_type eq "bed"){
+    $fields = splitBedLine($_);
+    next unless exists($fields->{strand});
+    $txID = $fields->{$txID_data};
+  }
+
+  # the id field is the chromosome in the local data file
+  # when converting local2glbal!
+  $txID = $fields->{chr} if $loc2glob;
+  
+  next unless defined($txID) ;
+  $txID =~ s/[";]//g;
+
+  # check if txID exists in g2l lookup table
+  next unless exists($g2l->{$txID});
+  print STDERR "data txID exists in lookup table $txID\n" if $v;
+  
+  my $data_start  = $fields->{start};
+  my $data_end    = $fields->{end};
+  
+  # global2local
+  # --------------------------------------------------
+  # calculate local coordinates of global features
+  my $data;
+  
+  $data = &global2local2(\%exons, $g2l,$txID,$data_start,$data_end) if $glob2loc;
+
+  # local2global
+  # --------------------------------------------------
+  # calculate global coordinates of local features
+
+  $data = &local2global2(\%exons, $g2l,$txID,$data_start,$data_end) if $loc2glob;
+
+  # Print results
+
+  # the chromosome field was the txID and is now the chr
+  $fields->{chr}    = $exons{$txID}->[0]->{chr}    if $loc2glob;
+
+  # get the strand right
+  # g2l
+  # if exon is on + and data is on + => stands are equal => local = +
+  # if exon is on - and data is on - => stands are equal => local = +
+  # if exon is on + and data is on - => stands are NOT equal => local = -
+  # if exon is on - and data is on + => stands are NOT equal => local = -
+
+  if ($glob2loc){
+    ($exons{$txID}->[0]->{strand} eq $fields->{strand}) ? ($fields->{strand} = "+") : ($fields->{strand} = "-");
+    
+#    $fields->{strand} = "+", next if $exons{$txID}->[0]->{strand} eq $fields->{strand};
+#    $fields->{strand} = "-", next if $exons{$txID}->[0]->{strand} ne $fields->{strand};
+  }
+
+  # l2g
+  # if exon is on + and data is on + => global stands are equal => global = +
+  # if exon is on - and data is on - => global stands are equal => global = -
+  # => strand global is strand exon
+  # if exon is on + and data is on - => global stands are NOT equal => global = -
+  # if exon is on - and data is on + => global stands are NOT equal => global = +
+  # => strand global is strand data => nothing to be done
+
+  if ($loc2glob){
+    $fields->{strand} = $exons{$txID}->[0]->{strand} if $exons{$txID}->[0]->{strand} eq $fields->{strand};
+  }
+
+  
+  $fields->{strand} = $exons{$txID}->[0]->{strand} if $loc2glob;
+
+  # the chromosome field was the chr and is now the txID
+  $fields->{chr} = $txID if $glob2loc;
+    
+  for my $i (0..$#$data){
+
+#    foreach my $k (sort keys %{$data->[$i]} ){
+#      print "$txID $k $data->[$i]->{$k}\n"
+#    }
+    if ($glob2loc){
+      $fields->{start} = $data->[$i]->{lstart};
+      $fields->{end}   = $data->[$i]->{lend};
+    }
+
+    if ($loc2glob){
+      $fields->{start} = $data->[$i]->{gstart};
+      $fields->{end}   = $data->[$i]->{gend};
+    }
+
+    
+    printGtfFields($fields, *STDOUT) if $data_type eq "gtf" || $data_type eq "gff3";
+    printBedLine($fields)            if $data_type eq "bed";
+  }
+  
+#  print "main l2g  $txID  " if $loc2glob;
+#  print "main g2l  $txID  " if $glob2loc;
+#  print "main global: ",$data->[0]->{gstart}," ",$data->[0]->{gend},"  ";
+#  print "main local $data->[0]->{lstart} $data->[0]->{lend}\n";
+}
+close($fh_data);
+
+# --------------------------------------------------
+# Subfunctions
+# --------------------------------------------------
+sub genomeLocalTAB {
+  my ($exons) = @_;
+
+  my %g2l = ();
+
+  foreach my $txID (sort keys %$exons ){
+
+    # sort exons if plus strand
+    if ($exons->{$txID}->[0]->{strand} eq "+"){
+      @{$exons->{$txID}} = sort(MySort2 @{$exons->{$txID}});
+    }
+
+    # reverse sort exons if minus strand
+    if ($exons->{$txID}->[0]->{strand} eq "-"){
+      @{$exons->{$txID}} = sort(RevMySort2 @{$exons->{$txID}});
+    }
+
+    # for the first exon it's simple :)
+    my $firstex_start = $exons->{$txID}->[0]->{start};
+    my $firstex_end   = $exons->{$txID}->[0]->{end};
+
+    $g2l{$txID}->[0]->{lstart} = 1;
+    $g2l{$txID}->[0]->{lend}   = 1+ ($firstex_end - $firstex_start +1) -1;
+    $g2l{$txID}->[0]->{gstart} = $exons->{$txID}->[0]->{start};
+    $g2l{$txID}->[0]->{gend}   = $exons->{$txID}->[0]->{end};
+
+    # convert coordinates for exons 1-n
+    for my $i (1..$#{$exons->{$txID}}){
+      my $tmp_start = $exons->{$txID}->[$i]->{start};
+      my $tmp_end   = $exons->{$txID}->[$i]->{end};
+
+      my $tmp_length = $tmp_end - $tmp_start +1;
+      $g2l{$txID}->[$i]->{lstart} = $g2l{$txID}->[$i-1]->{lend}+1;
+      $g2l{$txID}->[$i]->{lend}   = $g2l{$txID}->[$i]->{lstart} + $tmp_length -1;
+      $g2l{$txID}->[$i]->{gstart} = $exons->{$txID}->[$i]->{start};
+      $g2l{$txID}->[$i]->{gend}   = $exons->{$txID}->[$i]->{end};
+    }
+  }
+  return(\%g2l);
+}
+
+# --------------------------------------------------
+
+# Convert Global coordinates to local coordinates
+# example: cds exons within transcript exons
+
+sub global2local2{
+  my ($exons,$g2l,$ID,$data_gstart,$data_gend) = @_;
+  
+  my $data_length = $data_gend - $data_gstart + 1;
+
+  # exons on plus strand and local feature on plus strand
+  if ($exons->{$ID}->[0]->{strand} eq "+"){
+    @{$g2l->{$ID}} = sort(MySortGlobal @{$g2l->{$ID}});
+
+    my @data = ();
+
+    for my $i (0..$#{$g2l->{$ID}}){
+      my $ex_gstart = $g2l->{$ID}->[$i]->{gstart};
+      my $ex_gend   = $g2l->{$ID}->[$i]->{gend};
+      my $ex_lstart = $g2l->{$ID}->[$i]->{lstart};
+      my $ex_lend   = $g2l->{$ID}->[$i]->{lend};
+
+      # feature starts in exon and must end in exon!
+      next unless (($data_gstart >= $ex_gstart) && ($data_gend <= $ex_gend));
+
+      my %tmp = ();
+
+      # calculate local start coordinate
+      my $start_shift = $data_gstart - $ex_gstart +1;
+      $tmp{lstart}    = $ex_lstart  + $start_shift -1;
+      $tmp{gstart}    = $data_gstart;
+
+      # calculate local end coordinate
+      # feature must be included in exon!
+      $tmp{lend}  = $tmp{lstart} + $data_length -1;
+      $tmp{gend}  = $data_gend;
+      push(@data,\%tmp);
+      last;
+    }
+    return(\@data);
+  }
+
+  # exons on minus strand
+  if ($exons->{$ID}->[0]->{strand} eq "-"){
+    @{$g2l->{$ID}} = sort(MySortGlobal @{$g2l->{$ID}});
+
+    my @data = ();
+
+    for my $i (0..$#{$g2l->{$ID}}){
+      my $ex_gstart = $g2l->{$ID}->[$i]->{gstart};
+      my $ex_gend   = $g2l->{$ID}->[$i]->{gend};
+      my $ex_lstart = $g2l->{$ID}->[$i]->{lstart};
+      my $ex_lend   = $g2l->{$ID}->[$i]->{lend};
+      
+      # feature starts in exon and must end in exon!
+      next unless (($data_gstart >= $ex_gstart) && ($data_gend <= $ex_gend));
+
+#      print "$data_gstart $data_gend $i\n";
+      my %tmp = ();
+
+      # feature is included in exon
+      # exon_global   s<<<<<<<<<<<<e
+      # data_global     s<<<<<<<<<e
+      # local           e<<<<<<<<<s
+      # shift          --
+
+      # calculate local end coordinate
+      my $start_shift = $data_gstart - $ex_gstart   +1;
+      $tmp{lend}      = $ex_lend     - $start_shift +1;
+      $tmp{gstart}    = $data_gstart;
+
+      # calculate local start coordinate
+      # feature must be included in exon!
+      $tmp{lstart}  = $tmp{lend} - $data_length +1;
+      $tmp{gend}  = $data_gend;
+      push(@data,\%tmp);
+      last;
+    }
+    return(\@data);
+  }
+}
+
+# =========================================================================== #
+# === local2global2
+#
+# Convert local coordinates to global coordinates
+# example: RNA secondary structure element in transcript
+# where RNALfold was run on transcript sequences.
+# here, the feature need not be included in an exon
+# and may cross exon junctions
+# =========================================================================== #
+sub local2global2 {
+  my ($exons,$g2l,$ID,$data_lstart,$data_lend) = @_;
+
+  my $data_length = $data_lend - $data_lstart + 1;
+  # print "data coords: ls $data_lstart le $data_lend length $data_length\n";
+
+  # exons on plus strand 
+  if ($exons->{$ID}->[0]->{strand} eq "+"){
+    @{$g2l->{$ID}} = sort(MySortLocal @{$g2l->{$ID}});
+
+    my @data = ();
+
+    for my $i (0..$#{$g2l->{$ID}}){
+      my $ex_gstart = $g2l->{$ID}->[$i]->{gstart};
+      my $ex_gend   = $g2l->{$ID}->[$i]->{gend};
+      my $ex_lstart = $g2l->{$ID}->[$i]->{lstart};
+      my $ex_lend   = $g2l->{$ID}->[$i]->{lend};
+
+      # feature starts in exon
+      next unless ($data_lstart >= $ex_lstart) && ($data_lstart <= $ex_lend);
+
+      my %tmp = ();
+      # calculate global start coordinate
+      my $start_shift = $data_lstart - $ex_lstart +1;
+      $tmp{gstart}    = $ex_gstart  + $start_shift -1;
+      $tmp{lstart}    = $data_lstart;
+
+#      print "exon $i\n exon coords: gs $ex_gstart ge $ex_gend ls $ex_lstart le $ex_lend length ",($ex_lend-$ex_lstart+1),"\n";
+
+    # calculate global end coordinate
+    # feature is included in exon -> we are done here
+    if ($data_lend <= $ex_lend){
+#  $tmp{gend} = $tmp{gstart} + $data_length -1 ;
+  $tmp{gend} = $tmp{gstart} + ($data_lend-$tmp{lstart}+1 ) -1 ;
+  $tmp{lend} = $data_lend;
+
+#  print("data $i included\n data coords: gs $tmp{gstart} ge $tmp{gend} ls $tmp{lstart} le $tmp{lend} glength ",($tmp{gend}-$tmp{gstart}+1)," llength ",($tmp{lend}-$tmp{lstart}+1),"\n\n");
+
+  push(@data,\%tmp);
+  last;
+      }
+
+      # feature goes beyond exon and reaches into following exons
+      if ($data_lend > $ex_lend){
+  $tmp{gend} = $ex_gend;
+  $tmp{lend} = $ex_lend;
+#  print("data $i part\n data coords: gs $tmp{gstart} ge $tmp{gend} ls $tmp{lstart} le $tmp{lend}  glength ",($tmp{gend}-$tmp{gstart}+1)," llength ",($tmp{lend}-$tmp{lstart}+1),"\n\n");
+  push(@data,\%tmp);
+    # new start coordinate for next loop
+    $data_lstart = $ex_lend + 1;
+    next;
+      }
+    }
+    return(\@data);
+  }
+
+  # exons on minus strand 
+  if ($exons->{$ID}->[0]->{strand} eq "-"){
+    @{$g2l->{$ID}} = sort(MySortLocal @{$g2l->{$ID}});
+
+    my @data = ();
+
+    for my $i (0..$#{$g2l->{$ID}}){
+      my $ex_gstart = $g2l->{$ID}->[$i]->{gstart};
+      my $ex_gend   = $g2l->{$ID}->[$i]->{gend};
+      my $ex_lstart = $g2l->{$ID}->[$i]->{lstart};
+      my $ex_lend   = $g2l->{$ID}->[$i]->{lend};
+
+      # feature starts in exon
+      next unless ($data_lstart >= $ex_lstart) && ($data_lstart <= $ex_lend);
+
+      my %tmp = ();
+
+      # calculate GLOBAL END coordinate = local start
+      # --------------------------------------------------
+
+      my $start_shift = $data_lstart - $ex_lstart +1;
+      $tmp{gend}      = $ex_gend  - $start_shift +1;
+      $tmp{lstart}    = $data_lstart;
+      
+      # calculate GLOBAL START coordinate = local end
+      # --------------------------------------------------
+      # feature is included in exon -> we are done here
+      # global s>>>>>>>>>>>>e
+      # local    e<<<<<<s
+      # shift           ----
+      if ($data_lend <= $ex_lend){
+        $tmp{gstart} = $tmp{gend} - ($data_lend-$tmp{lstart}+1 ) +1 ;
+        $tmp{lend}   = $data_lend;
+        push(@data,\%tmp);
+        last;
+      }
+
+      # feature goes beyond exon and reaches into following exons
+      # global s>>>>>e    s>>>>>>>>>>>>e
+      # local    e<<<......<<<<s
+      # shift                  --------
+      if ($data_lend > $ex_lend){
+  $tmp{gstart} = $ex_gstart;
+  $tmp{lend}   = $ex_lend;
+  push(@data,\%tmp);
+
+  # new start coordinate for next loop
+  $data_lstart = $ex_lend + 1;
+  next;
+      }
+    }
+    return(\@data);
+  }
+}
+
+# --------------------------------------------------
+
+sub MySort2 {
+  if(${$a}{start} < ${$b}{start})
+  { return -1; }
+  elsif(${$a}{start} == ${$b}{start})
+  { return 0; }
+  else
+  { return 1; }
+}
+
+sub RevMySort2 {
+  if(${$a}{end} > ${$b}{end})
+  { return -1; }
+  elsif(${$a}{end} == ${$b}{end})
+  { return 0; }
+  else
+  { return 1; }
+}
+
+sub MySortGlobal {
+  if(${$a}{gstart} < ${$b}{gstart})
+  { return -1; }
+  elsif(${$a}{gstart} == ${$b}{gstart})
+  { return 0; }
+  else
+  { return 1; }
+}
+
+sub RevMySortGlobal {
+  if(${$a}{gend} > ${$b}{gend})
+  { return -1; }
+  elsif(${$a}{gend} == ${$b}{gend})
+  { return 0; }
+  else
+  { return 1; }
+}
+
+sub MySortLocal {
+  if(${$a}{lstart} < ${$b}{lstart})
+  { return -1; }
+  elsif(${$a}{lstart} == ${$b}{lstart})
+  { return 0; }
+  else
+  { return 1; }
+}
+
+sub RevMySortLocal{
+  if(${$a}{lend} > ${$b}{lend})
+  { return -1; }
+  elsif(${$a}{lend} == ${$b}{lend})
+  { return 0; }
+  else
+  { return 1; }
+}
+
+__END__
+=head1 NAME
+
+local2global.pl
+
+=head1 SYNOPSIS
+
+local2global.pl [options] [file]
+
+=head1 OPTIONS
+
+=over 8
+
+=item B<-exon, -e>
+
+name of exon annotation file
+
+=item B<-etype, -et>
+
+type of exon annotation file; possible types: gtf, gff3, bed; default: autodetect via suffix of input file
+
+=item B<-exonID, -eid>
+
+field to use as transcript ID;
+
+defaults
+
+    for gtf: attribute "transcript_id"
+
+    for gff3: attribute "ID"
+
+    for bed: ID (=field 4)
+
+=item B<-data, -d>
+
+name of data annotation file
+
+=item B<-dtype, -dt>
+
+type of data annotation file; possible types: gtf, gff3, bed; default: autodetect via suffix of input file
+
+=item B<-dataID, -did>
+
+field to use as transcript ID;
+
+defaults
+
+    for gtf: attribute "transcript_id"
+
+    for gff3: attribute "ID"
+
+    for bed: ID (=field 4)
+
+=item B<-g2l>
+
+covert global coordinates (e.g. genomic coordinates) of features
+in data file to local coordinates relative to the respective
+features in the exon annotation file
+
+=item B<-l2g>
+
+covert local coordinates (e.g. within a spliced transcript) of
+features in the data file to global coordinates (e.g. genomic
+coordinates) relative to the respective features in the exon
+annotation file
+
+=item B<-help>
+
+Print a brief help message and exit
+
+=item B<-man>
+
+Print full man page and exit
+
+=head1 DESCRIPTION
+
+local2global.pl converts coordinates of a sub-feature within a
+feature to genomic coordinates and vice versa. It requires two
+annotation files: the features are listed in the "exon" file
+and the sub-features contained in these features are in the
+"data" file. Annotation formats are "gtf", "gff3" and "bed".
+
+The identifier, based on which subfeatures are assigned to
+features, can be specified.
+
+B<Example 1: conversion local to global>
+
+You analysed structural motifs in spliced transcript sequences and
+want to know the genomic position of these structures. The "data"
+file contains the positions of your RNA structures within a
+transcript, the "exon" file is the exon annotation of your
+transcripts. Let us assume you are using gtf files.
+
+In this case, you would create gtf annotation files for all
+your RNA structures, use the "gene_id" attribute to reference
+the transcripts these structures belong to and assign each
+structure a unique "transcript_id". In the chromosome fields
+put the same id as in the "gene_id" attribute, since the
+coordinates are relative to the transcript. The exon file
+is the annotation file you retreived from some gene annotation
+repository, e.g. ensembl. The output would then be genomic
+coordinates of your structures, in the chromosome filed you
+will find the chromosome the transcript resides on.
+Structures spanning exon-exon junctions are split into
+multiple intervals (i.e. "exons").
+    
+  local2global.pl -e exon.gtf -et gtf -eid transcript_id -d structure.gtf -dt gtf -did gene_id -l2g > structure.global.gtf
+
+B<Example 2: conversion global to local>
+
+Say that you wish to know the position of the coding exons
+within a spliced transcript. In this case, your "data"
+file is the CDS annotation file with genomic coordinates
+of the CDS exons, the "exon" file is again the "exon"
+annotation file. Both were downloaded from a database,
+e.g. ensembl. Note, that here the identifyer of the
+CDS exons is the "transcript_id". The output in this
+case are coordinates of the CDS exons realtive to
+the spliced transcript, i.e. local coordinates,
+and thus you will find the transcript_id the in
+the chromosome field. 
+
+  local2global.pl -e exon.gtf -et gtf -eid transcript_id -d CDS.gtf -dt gtf -did transcript_id -g2l > CDS.local.gtf    
+
+=cut