basic101 0.1.0

data/test/integration/tests/basic_computer_games/queen.bas

@@ -0,0 +1,168 @@
+1 PRINT TAB(33);"QUEEN"
+2 PRINT TAB(15);"CREATIVE COMPUTING  MORRISTOWN, NEW JERSEY"
+3 PRINT:PRINT:PRINT
+10 DIM S(64)
+11 FOR I=1 TO 64
+12 READ S(I)
+13 NEXT I
+14 DATA  81,  71,  61,  51,  41,  31,  21,  11
+15 DATA  92,  82,  72,  62,  52,  42,  32,  22
+16 DATA 103,  93,  83,  73,  63,  53,  43,  33
+17 DATA 114, 104,  94,  84,  74,  64,  54,  44
+18 DATA 125, 115, 105,  95,  85,  75,  65,  55
+19 DATA 136, 126, 116, 106,  96,  86,  76,  66
+20 DATA 147, 137, 127, 117, 107,  97,  87,  77
+21 DATA 158, 148, 138, 128, 118, 108,  98,  88
+22 INPUT "DO YOU WANT INSTRUCTIONS";W$
+23 IF W$="NO" THEN 30
+24 IF W$="YES" THEN 28
+25 PRINT "PLEASE ANSWER 'YES' OR 'NO'."
+26 GOTO 22
+28 GOSUB 5000
+29 GOTO 100
+30 GOSUB 5160
+90 REM     ERROR CHECKS
+100 PRINT "WHERE WOULD YOU LIKE TO START";
+110 INPUT M1
+115 IF M1=0 THEN 232
+120 T1=INT(M1/10)
+130 U1=M1-10*T1
+140 IF U1=1 THEN 200
+150 IF U1=T1 THEN 200
+160 PRINT "PLEASE READ THE DIRECTIONS AGAIN."
+170 PRINT "YOU HAVE BEGUN ILLEGALLY."
+175 PRINT
+180 GOTO 100
+200 GOSUB 2000
+210 PRINT "COMPUTER MOVES TO SQUARE";M
+215 IF M=158 THEN 3400
+220 PRINT "WHAT IS YOUR MOVE";
+230 INPUT M1
+231 IF M1<>0 THEN 239
+232 PRINT
+233 PRINT "IT LOOKS LIKE I HAVE WON BY FORFEIT."
+234 PRINT
+235 GOTO 4000
+239 IF M1<=M THEN 3200
+240 T1=INT(M1/10)
+250 U1=M1-10*T1
+260 P=U1-U
+270 IF P<>0 THEN 300
+280 L=T1-T
+290 IF L<=0 THEN 3200
+295 GOTO 200
+300 IF T1-T <>P THEN 320
+310 GOTO 200
+320 IF T1-T <>2*P THEN 3200
+330 GOTO 200
+1990 REM     LOCATE MOVE FOR COMPUTER
+2000 IF M1=41 THEN 2180
+2010 IF M1=44 THEN 2180
+2020 IF M1=73 THEN 2180
+2030 IF M1=75 THEN 2180
+2040 IF M1=126 THEN 2180
+2050 IF M1=127 THEN 2180
+2060 IF M1=158 THEN 3300
+2065 C=0
+2070 FOR K=7 TO 1 STEP -1
+2080 U=U1
+2090 T=T1+K
+2100 GOSUB 3500
+2105 IF C=1 THEN 2160
+2110 U=U+K
+2120 GOSUB 3500
+2125 IF C=1 THEN 2160
+2130 T=T+K
+2140 GOSUB 3500
+2145 IF C=1 THEN 2160
+2150 NEXT K
+2155 GOTO 2180
+2160 C=0
+2170 RETURN
+2180 GOSUB 3000
+2190 RETURN
+2990 REM     RANDOM MOVE
+3000 Z=RND(1)
+3010 IF Z>.6 THEN 3110
+3020 IF Z>.3 THEN 3070
+3030 U=U1
+3040 T=T1+1
+3050 M=10*T+U
+3060 RETURN
+3070 U=U1+1
+3080 T=T1+2
+3090 M=10*T+U
+3100 RETURN
+3110 U=U1+1
+3120 T=T1+1
+3130 M=10*T+U
+3140 RETURN
+3190 REM     ILLEGAL MOVE MESSAGE
+3200 PRINT
+3210 PRINT "Y O U   C H E A T . . .  TRY AGAIN";
+3220 GOTO 230
+3290 REM     PLAYER WINS
+3300 PRINT
+3310 PRINT "C O N G R A T U L A T I O N S . . ."
+3320 PRINT 
+3330 PRINT "YOU HAVE WON--VERY WELL PLAYED."
+3340 PRINT "IT LOOKS LIKE I HAVE MET MY MATCH."
+3350 PRINT "THANKS FOR PLAYING---I CAN'T WIN ALL THE TIME."
+3360 PRINT
+3370 GOTO 4000
+3390 REM     COMPUTER WINS
+3400 PRINT
+3410 PRINT "NICE TRY, BUT IT LOOKS LIKE I HAVE WON."
+3420 PRINT "THANKS FOR PLAYING."
+3430 PRINT
+3440 GOTO 4000
+3490 REM     TEST FOR COMPUTER MOVE
+3500 M=10*T+U
+3510 IF M=158 THEN 3570
+3520 IF M=127 THEN 3570
+3530 IF M=126 THEN 3570
+3540 IF M=75 THEN 3570
+3550 IF M=73 THEN 3570
+3560 RETURN
+3570 C=1
+3580 GOTO 3560
+3990 REM     ANOTHER GAME???
+4000 PRINT "ANYONE ELSE CARE TO TRY";
+4010 INPUT Q$
+4020 PRINT
+4030 IF Q$="YES" THEN 30 
+4040 IF Q$="NO" THEN 4050
+4042 PRINT "PLEASE ANSWER 'YES' OR 'NO'."
+4045 GOTO 4000
+4050 PRINT:PRINT "OK --- THANKS AGAIN."
+4060 STOP
+4990 REM     DIRECTIONS
+5000 PRINT "WE ARE GOING TO PLAY A GAME BASED ON ONE OF THE CHESS"
+5010 PRINT "MOVES.  OUR QUEEN WILL BE ABLE TO MOVE ONLY TO THE LEFT,"
+5020 PRINT "DOWN, OR DIAGONALLY DOWN AND TO THE LEFT."
+5030 PRINT
+5040 PRINT "THE OBJECT OF THE GAME IS TO PLACE THE QUEEN IN THE LOWER"
+5050 PRINT "LEFT HAND SQUARE BY ALTERNATING MOVES BETWEEN YOU AND THE"
+5060 PRINT "COMPUTER.  THE FIRST ONE TO PLACE THE QUEEN THERE WINS."
+5070 PRINT
+5080 PRINT "YOU GO FIRST AND PLACE THE QUEEN IN ANY ONE OF THE SQUARES"
+5090 PRINT "ON THE TOP ROW OR RIGHT HAND COLUMN."
+5100 PRINT "THAT WILL BE YOUR FIRST MOVE."
+5110 PRINT "WE ALTERNATE MOVES."
+5120 PRINT "YOU MAY FORFEIT BY TYPING '0' AS YOUR MOVE."
+5130 PRINT "BE SURE TO PRESS THE RETURN KEY AFTER EACH RESPONSE."
+5140 PRINT
+5150 PRINT
+5160 PRINT
+5170 FOR A=0 TO 7
+5180 FOR B=1 TO 8
+5185 I=8*A+B
+5190 PRINT S(I);
+5200 NEXT B
+5210 PRINT
+5220 PRINT
+5230 PRINT
+5240 NEXT A
+5250 PRINT
+5260 RETURN
+9999 END

data/test/integration/tests/basic_computer_games/queen.input

@@ -0,0 +1,10 @@
+YES
+11
+YES
+21
+137
+YES
+31
+97
+137
+NO

data/test/integration/tests/basic_computer_games/queen.output

@@ -0,0 +1,133 @@
+                                 QUEEN
+               CREATIVE COMPUTING  MORRISTOWN, NEW JERSEY
+
+
+
+DO YOU WANT INSTRUCTIONS? YES
+WE ARE GOING TO PLAY A GAME BASED ON ONE OF THE CHESS
+MOVES.  OUR QUEEN WILL BE ABLE TO MOVE ONLY TO THE LEFT,
+DOWN, OR DIAGONALLY DOWN AND TO THE LEFT.
+
+THE OBJECT OF THE GAME IS TO PLACE THE QUEEN IN THE LOWER
+LEFT HAND SQUARE BY ALTERNATING MOVES BETWEEN YOU AND THE
+COMPUTER.  THE FIRST ONE TO PLACE THE QUEEN THERE WINS.
+
+YOU GO FIRST AND PLACE THE QUEEN IN ANY ONE OF THE SQUARES
+ON THE TOP ROW OR RIGHT HAND COLUMN.
+THAT WILL BE YOUR FIRST MOVE.
+WE ALTERNATE MOVES.
+YOU MAY FORFEIT BY TYPING '0' AS YOUR MOVE.
+BE SURE TO PRESS THE RETURN KEY AFTER EACH RESPONSE.
+
+
+
+ 81  71  61  51  41  31  21  11 
+
+
+ 92  82  72  62  52  42  32  22 
+
+
+ 103  93  83  73  63  53  43  33 
+
+
+ 114  104  94  84  74  64  54  44 
+
+
+ 125  115  105  95  85  75  65  55 
+
+
+ 136  126  116  106  96  86  76  66 
+
+
+ 147  137  127  117  107  97  87  77 
+
+
+ 158  148  138  128  118  108  98  88 
+
+
+
+WHERE WOULD YOU LIKE TO START? 11
+COMPUTER MOVES TO SQUARE 158 
+
+NICE TRY, BUT IT LOOKS LIKE I HAVE WON.
+THANKS FOR PLAYING.
+
+ANYONE ELSE CARE TO TRY? YES
+
+
+ 81  71  61  51  41  31  21  11 
+
+
+ 92  82  72  62  52  42  32  22 
+
+
+ 103  93  83  73  63  53  43  33 
+
+
+ 114  104  94  84  74  64  54  44 
+
+
+ 125  115  105  95  85  75  65  55 
+
+
+ 136  126  116  106  96  86  76  66 
+
+
+ 147  137  127  117  107  97  87  77 
+
+
+ 158  148  138  128  118  108  98  88 
+
+
+
+WHERE WOULD YOU LIKE TO START? 21
+COMPUTER MOVES TO SQUARE 126 
+WHAT IS YOUR MOVE? 137
+COMPUTER MOVES TO SQUARE 158 
+
+NICE TRY, BUT IT LOOKS LIKE I HAVE WON.
+THANKS FOR PLAYING.
+
+ANYONE ELSE CARE TO TRY? YES
+
+
+ 81  71  61  51  41  31  21  11 
+
+
+ 92  82  72  62  52  42  32  22 
+
+
+ 103  93  83  73  63  53  43  33 
+
+
+ 114  104  94  84  74  64  54  44 
+
+
+ 125  115  105  95  85  75  65  55 
+
+
+ 136  126  116  106  96  86  76  66 
+
+
+ 147  137  127  117  107  97  87  77 
+
+
+ 158  148  138  128  118  108  98  88 
+
+
+
+WHERE WOULD YOU LIKE TO START? 31
+COMPUTER MOVES TO SQUARE 75 
+WHAT IS YOUR MOVE? 97
+COMPUTER MOVES TO SQUARE 127 
+WHAT IS YOUR MOVE? 137
+COMPUTER MOVES TO SQUARE 158 
+
+NICE TRY, BUT IT LOOKS LIKE I HAVE WON.
+THANKS FOR PLAYING.
+
+ANYONE ELSE CARE TO TRY? NO
+
+
+OK --- THANKS AGAIN.
+Break in line 4060

data/test/integration/tests/basic_computer_games/reverse.bas

@@ -0,0 +1,62 @@
+10 PRINT TAB(32);"REVERSE"
+20 PRINT TAB(15);"CREATIVE COMPUTING  MORRISTOWN, NEW JERSEY"
+30 PRINT:PRINT:PRINT
+100 PRINT "REVERSE -- A GAME OF SKILL": PRINT
+130 DIM A(20)
+140 REM *** N=NUMBER OF NUMBERS
+150 N=9
+160 PRINT "DO YOU WANT THE RULES";
+170 INPUT A$
+180 IF A$="NO" THEN 210
+190 GOSUB 710
+200 REM *** MAKE A RANDOM LIST A(1) TO A(N)
+210 A(1)=INT((N-1)*RND(1)+2)
+220 FOR K=2 TO N
+230 A(K)=INT(N*RND(1)+1)
+240 FOR J=1 TO K-1
+250 IF A(K)=A(J) THEN 230
+260 NEXT J:NEXT K
+280 REM *** PRINT ORIGINAL LIST AND START GAME
+290 PRINT: PRINT "HERE WE GO ... THE LIST IS:"
+310 T=0
+320 GOSUB 610
+330 PRINT "HOW MANY SHALL I REVERSE";
+340 INPUT R
+350 IF R=0 THEN 520
+360 IF R<=N THEN 390
+370 PRINT "OOPS! TOO MANY! I CAN REVERSE AT MOST";N:GOTO 330
+390 T=T+1
+400 REM *** REVERSE R NUMBERS AND PRINT NEW LIST
+410 FOR K=1 TO INT(R/2)
+420 Z=A(K)
+430 A(K)=A(R-K+1)
+440 A(R-K+1)=Z
+450 NEXT K
+460 GOSUB 610
+470 REM *** CHECK FOR A WIN
+480 FOR K=1 TO N
+490 IF A(K)<>K THEN 330
+500 NEXT K
+510 PRINT "YOU WON IT IN";T;"MOVES!!!":PRINT
+520 PRINT
+530 PRINT "TRY AGAIN (YES OR NO)";
+540 INPUT A$
+550 IF A$="YES" THEN 210
+560 PRINT: PRINT "O.K. HOPE YOU HAD FUN!!":GOTO 999
+600 REM *** SUBROUTINE TO PRINT LIST
+610 PRINT:FOR K=1 TO N:PRINT A(K);:NEXT K
+650 PRINT:PRINT:RETURN
+700 REM *** SUBROUTINE TO PRINT THE RULES
+710 PRINT:PRINT "THIS IS THE GAME OF 'REVERSE'.  TO WIN, ALL YOU HAVE"
+720 PRINT "TO DO IS ARRANGE A LIST OF NUMBERS (1 THROUGH";N;")"
+730 PRINT "IN NUMERICAL ORDER FROM LEFT TO RIGHT.  TO MOVE, YOU"
+740 PRINT "TELL ME HOW MANY NUMBERS (COUNTING FROM THE LEFT) TO"
+750 PRINT "REVERSE.  FOR EXAMPLE, IF THE CURRENT LIST IS:"
+760 PRINT:PRINT "2 3 4 5 1 6 7 8 9"
+770 PRINT:PRINT "AND YOU REVERSE 4, THE RESULT WILL BE:"
+780 PRINT:PRINT "5 4 3 2 1 6 7 8 9"
+790 PRINT:PRINT "NOW IF YOU REVERSE 5, YOU WIN!"
+800 PRINT:PRINT "1 2 3 4 5 6 7 8 9":PRINT
+810 PRINT "NO DOUBT YOU WILL LIKE THIS GAME, BUT"
+820 PRINT "IF YOU WANT TO QUIT, REVERSE 0 (ZERO).":PRINT: RETURN
+999 END

data/test/integration/tests/basic_computer_games/reverse.input

@@ -0,0 +1,12 @@
+YES
+5
+9
+4
+8
+3
+7
+4
+6
+5
+3
+NO

data/test/integration/tests/basic_computer_games/reverse.output

@@ -0,0 +1,79 @@
+                                REVERSE
+               CREATIVE COMPUTING  MORRISTOWN, NEW JERSEY
+
+
+
+REVERSE -- A GAME OF SKILL
+
+DO YOU WANT THE RULES? YES
+
+THIS IS THE GAME OF 'REVERSE'.  TO WIN, ALL YOU HAVE
+TO DO IS ARRANGE A LIST OF NUMBERS (1 THROUGH 9 )
+IN NUMERICAL ORDER FROM LEFT TO RIGHT.  TO MOVE, YOU
+TELL ME HOW MANY NUMBERS (COUNTING FROM THE LEFT) TO
+REVERSE.  FOR EXAMPLE, IF THE CURRENT LIST IS:
+
+2 3 4 5 1 6 7 8 9
+
+AND YOU REVERSE 4, THE RESULT WILL BE:
+
+5 4 3 2 1 6 7 8 9
+
+NOW IF YOU REVERSE 5, YOU WIN!
+
+1 2 3 4 5 6 7 8 9
+
+NO DOUBT YOU WILL LIKE THIS GAME, BUT
+IF YOU WANT TO QUIT, REVERSE 0 (ZERO).
+
+
+HERE WE GO ... THE LIST IS:
+
+ 6  7  5  4  9  8  1  2  3 
+
+HOW MANY SHALL I REVERSE? 5
+
+ 9  4  5  7  6  8  1  2  3 
+
+HOW MANY SHALL I REVERSE? 9
+
+ 3  2  1  8  6  7  5  4  9 
+
+HOW MANY SHALL I REVERSE? 4
+
+ 8  1  2  3  6  7  5  4  9 
+
+HOW MANY SHALL I REVERSE? 8
+
+ 4  5  7  6  3  2  1  8  9 
+
+HOW MANY SHALL I REVERSE? 3
+
+ 7  5  4  6  3  2  1  8  9 
+
+HOW MANY SHALL I REVERSE? 7
+
+ 1  2  3  6  4  5  7  8  9 
+
+HOW MANY SHALL I REVERSE? 4
+
+ 6  3  2  1  4  5  7  8  9 
+
+HOW MANY SHALL I REVERSE? 6
+
+ 5  4  1  2  3  6  7  8  9 
+
+HOW MANY SHALL I REVERSE? 5
+
+ 3  2  1  4  5  6  7  8  9 
+
+HOW MANY SHALL I REVERSE? 3
+
+ 1  2  3  4  5  6  7  8  9 
+
+YOU WON IT IN 10 MOVES!!!
+
+
+TRY AGAIN (YES OR NO)? NO
+
+O.K. HOPE YOU HAD FUN!!

data/test/integration/tests/basic_computer_games/rocket.bas

@@ -0,0 +1,71 @@
+10 PRINT TAB(30); "ROCKET"
+20 PRINT TAB(15);"CREATIVE COMPUTING  MORRISTOWN, NEW JERSEY"
+30 PRINT:PRINT:PRINT
+70 PRINT "LUNAR LANDING SIMULATION"
+80 PRINT "----- ------- ----------": PRINT
+100 INPUT "DO YOU WANT INSTRUCTIONS (YES OR NO)";A$
+110 IF A$="NO" THEN 390
+160 PRINT
+200 PRINT"YOU ARE LANDING ON THE MOON AND AND HAVE TAKEN OVER MANUAL"
+210 PRINT"CONTROL 1000 FEET ABOVE A GOOD LANDING SPOT. YOU HAVE A DOWN-"
+220 PRINT"WARD VELOCITY OF 50 FEET/SEC. 150 UNITS OF FUEL REMAIN."
+225 PRINT
+230 PRINT"HERE ARE THE RULES THAT GOVERN YOUR APOLLO SPACE-CRAFT:": PRINT
+240 PRINT"(1) AFTER EACH SECOND THE HEIGHT, VELOCITY, AND REMAINING FUEL"
+250 PRINT"    WILL BE REPORTED VIA DIGBY YOUR ON-BOARD COMPUTER."
+260 PRINT"(2) AFTER THE REPORT A '?' WILL APPEAR. ENTER THE NUMBER"
+270 PRINT"    OF UNITS OF FUEL YOU WISH TO BURN DURING THE NEXT"
+280 PRINT"    SECOND. EACH UNIT OF FUEL WILL SLOW YOUR DESCENT BY"
+290 PRINT"    1 FOOT/SEC."
+310 PRINT"(3) THE MAXIMUM THRUST OF YOUR ENGINE IS 30 FEET/SEC/SEC"
+320 PRINT"    OR 30 UNITS OF FUEL PER SECOND."
+330 PRINT"(4) WHEN YOU CONTACT THE LUNAR SURFACE. YOUR DESCENT ENGINE"
+340 PRINT"    WILL AUTOMATICALLY SHUT DOWN AND YOU WILL BE GIVEN A"
+350 PRINT"    REPORT OF YOUR LANDING SPEED AND REMAINING FUEL."
+360 PRINT"(5) IF YOU RUN OUT OF FUEL THE '?' WILL NO LONGER APPEAR"
+370 PRINT"    BUT YOUR SECOND BY SECOND REPORT WILL CONTINUE UNTIL"
+380 PRINT"    YOU CONTACT THE LUNAR SURFACE.":PRINT
+390 PRINT"BEGINNING LANDING PROCEDURE..........":PRINT
+400 PRINT"G O O D  L U C K ! ! !"
+420 PRINT:PRINT
+430 PRINT"SEC  FEET      SPEED     FUEL     PLOT OF DISTANCE"
+450 PRINT
+455 T=0:H=1000:V=50:F=150
+490 PRINT T;TAB(6);H;TAB(16);V;TAB(26);F;TAB(35);"I";TAB(H/15);"*"
+500 INPUT B
+510 IF B<0 THEN 650
+520 IF B>30 THEN B=30
+530 IF B>F THEN B=F
+540 V1=V-B+5
+560 F=F-B
+570 H=H- .5*(V+V1)
+580 IF H<=0 THEN 670
+590 T=T+1
+600 V=V1
+610 IF F>0 THEN 490
+615 IF B=0 THEN 640
+620 PRINT"**** OUT OF FUEL ****"
+640 PRINT T;TAB(4);H;TAB(12);V;TAB(20);F;TAB(29);"I";TAB(H/12+29);"*"
+650 B=0
+660 GOTO 540
+670 PRINT"***** CONTACT *****"
+680 H=H+ .5*(V1+V)
+690 IF B=5 THEN 720
+700 D=(-V+SQR(V*V+H*(10-2*B)))/(5-B)
+710 GOTO 730
+720 D=H/V
+730 V1=V+(5-B)*D
+760 PRINT"TOUCHDOWN AT";T+D;"SECONDS."
+770 PRINT"LANDING VELOCITY=";V1;"FEET/SEC."
+780 PRINT F;"UNITS OF FUEL REMAINING."
+790 IF V1<>0 THEN 810
+800 PRINT"CONGRATULATIONS! A PERFECT LANDING!!"
+805 PRINT"YOUR LICENSE WILL BE RENEWED.......LATER."
+810 IF ABS(V1)<2 THEN 840
+820 PRINT"***** SORRY, BUT YOU BLEW IT!!!!"
+830 PRINT"APPROPRIATE CONDOLENCES WILL BE SENT TO YOUR NEXT OF KIN."
+840 PRINT:PRINT:PRINT
+850 INPUT "ANOTHER MISSION";A$
+860 IF A$="YES" THEN 390
+870 PRINT: PRINT "CONTROL OUT.": PRINT
+999 END

data/test/integration/tests/basic_computer_games/rocket.input

@@ -0,0 +1,42 @@
+YES
+0
+0
+0
+0
+0
+0
+30
+5
+5
+5
+5
+5
+5
+5
+5
+5
+5
+YES
+0
+0
+0
+0
+0
+0
+0
+0
+0
+30
+30
+20
+20
+5
+5
+5
+5
+5
+5
+10
+5
+5
+NO