basic101 0.1.0

data/test/integration/tests/basic_computer_games/mastrmnd.bas

@@ -0,0 +1,232 @@
+2 PRINT TAB(30);"MASTERMIND"
+4 PRINT TAB(15);"CREATIVE COMPUTING  MORRISTOWN, NEW JERSEY"
+6 PRINT: PRINT: PRINT
+10 REM
+20 REM     MASTERMIND II
+30 REM     STEVE NORTH
+40 REM     CREATIVE COMPUTING
+50 REM     PO BOX 789-M MORRISTOWN NEW JERSEY 07960
+60 REM
+70 REM
+80 INPUT "NUMBER OF COLORS";C9
+90 IF C9>8 THEN PRINT "NO MORE THAN 8, PLEASE!":GOTO 80
+100 INPUT "NUMBER OF POSITIONS";P9
+110 INPUT "NUMBER OF ROUNDS";R9
+120 P=C9^P9
+130 PRINT "TOTAL POSSIBILITIES =";P
+140 H=0:C=0
+150 DIM Q(P9),S(10,2),S$(10),A$(P9),G$(P9),I(P),H$(P9)
+160 L$="BWRGOYPT"
+170 PRINT
+180 PRINT
+190 PRINT "COLOR     LETTER"
+200 PRINT "=====     ======"
+210 FOR X=1 TO C9
+220 READ X$
+230 PRINT X$;TAB(13);MID$(L$,X,1)
+240 NEXT X
+250 PRINT
+260 FOR R=1 TO R9
+270 PRINT 
+280 PRINT "ROUND NUMBER";R;"----"
+290 PRINT
+300 PRINT "GUESS MY COMBINATION.":PRINT
+310 REM     GET A COMBINATION
+320 A=INT(P*RND(1)+1)
+330 GOSUB 3000
+340 FOR X=1 TO A
+350 GOSUB 3500
+360 NEXT X
+370 FOR M=1 TO 10
+380 PRINT "MOVE # ";M;" GUESS ";:INPUT X$
+390 IF X$="BOARD" THEN 2000
+400 IF X$="QUIT" THEN 2500
+410 IF LEN(X$)<>P9 THEN PRINT "BAD NUMBER OF POSITIONS.":GOTO 380
+420 REM     UNPACK X$ INTO G$(1-P9)
+430 FOR X=1 TO P9
+440 FOR Y=1 TO C9
+450 IF MID$(X$,X,1)=MID$(L$,Y,1) THEN 480
+460 NEXT Y
+470 PRINT "'"; MID$(X$,X,1); "' IS UNRECOGNIZED.":GOTO 380
+480 G$(X)=MID$(X$,X,1)
+490 NEXT X
+500 REM     NOW WE CONVERT Q(1-P9) INTO A$(1-P9) [ACTUAL GUESS]
+510 GOSUB 4000
+520 REM     AND GET NUMBER OF BLACKS AND WHITES
+530 GOSUB 4500
+540 IF B=P9 THEN 630
+550 REM     TELL HUMAN RESULTS
+560 PRINT "YOU HAVE ";B;" BLACKS AND ";W;" WHITES."
+570 REM     SAVE ALL THIS STUFF FOR BOARD PRINTOUT LATER
+580 S$(M)=X$
+590 S(M,1)=B
+600 S(M,2)=W
+610 NEXT M
+620 PRINT "YOU RAN OUT OF MOVES!  THAT'S ALL YOU GET!":GOTO 640
+622 GOSUB 4000
+623 PRINT "THE ACTUAL COMBINATION WAS: ";
+624 FOR X=1 TO P9
+625 PRINT A$(X);
+626 NEXT X
+627 PRINT
+630 PRINT "YOU GUESSED IT IN ";M;" MOVES!"
+640 H=H+M
+650 GOSUB 5000
+660 REM
+670 REM     NOW COMPUTER GUESSES
+680 REM
+690 FOR X=1 TO P
+700 I(X)=1
+710 NEXT X
+720 PRINT "NOW I GUESS.  THINK OF A COMBINATION."
+730 INPUT "HIT RETURN WHEN READY:";X$
+740 FOR M=1 TO 10
+750 GOSUB 3000
+760 REM     FIND A GUESS
+770 G=INT(P*RND(1)+1)
+780 IF I(G)=1 THEN 890
+790 FOR X=G TO P
+800 IF I(X)=1 THEN 880
+810 NEXT X
+820 FOR X=1 TO G
+830 IF I(X)=1 THEN 880
+840 NEXT X
+850 PRINT "YOU HAVE GIVEN ME INCONSISTENT INFORMATION."
+860 PRINT "TRY AGAIN, AND THIS TIME PLEASE BE MORE CAREFUL."
+870 GOTO 660
+880 G=X
+890 REM     NOW WE CONVERT GUESS #G INTO G$
+900 FOR X=1 TO G
+910 GOSUB 3500
+920 NEXT X
+930 GOSUB 6000
+940 PRINT "MY GUESS IS: ";
+950 FOR X=1 TO P9
+960 PRINT H$(X);
+970 NEXT X
+980 INPUT "  BLACKS, WHITES ";B1,W1
+990 IF B1=P9 THEN 1120
+1000 GOSUB 3000
+1010 FOR X=1 TO P
+1020 GOSUB 3500
+1030 IF I(X)=0 THEN 1070
+1035 GOSUB 6500
+1040 GOSUB 4000
+1050 GOSUB 4500
+1060 IF B1<>B OR W1<>W THEN I(X)=0
+1070 NEXT X
+1080 NEXT M
+1090 PRINT "I USED UP ALL MY MOVES!"
+1100 PRINT "I GUESS MY CPU IS JUST HAVING AN OFF DAY."
+1110 GOTO 1130
+1120 PRINT "I GOT IT IN ";M;" MOVES!"
+1130 C=C+M
+1140 GOSUB 5000
+1150 NEXT R
+1160 PRINT "GAME OVER"
+1170 PRINT "FINAL SCORE:"
+1180 GOSUB 5040
+1190 STOP
+2000 REM
+2010 REM     BOARD PRINTOUT ROUTINE
+2020 REM
+2025 PRINT
+2030 PRINT "BOARD"
+2040 PRINT "MOVE     GUESS          BLACK     WHITE"
+2050 FOR Z=1 TO M-1
+2060 PRINT Z;TAB(9);S$(Z);TAB(25);S(Z,1);TAB(35);S(Z,2)
+2070 NEXT Z
+2075 PRINT
+2080 GOTO 380
+2500 REM
+2510 REM     QUIT ROUTINE
+2520 REM
+2530 PRINT "QUITTER!  MY COMBINATION WAS: ";
+2535 GOSUB 4000
+2540 FOR X=1 TO P9
+2550 PRINT A$(X);
+2560 NEXT X
+2565 PRINT
+2570 PRINT "GOOD BYE"
+2580 STOP
+3000 REM
+3010 REM     INITIALIZE Q(1-P9) TO ZEROS
+3020 REM
+3030 FOR S=1 TO P9
+3040 Q(S)=0
+3050 NEXT S
+3060 RETURN
+3500 REM
+3510 REM     INCREMENT Q(1-P9)
+3520 REM
+3522 IF Q(1)>0 THEN 3530
+3524 REM  IF ZERO, THIS IS OUR FIRST INCREMENT: MAKE ALL ONES
+3526 FOR S=1 TO P9
+3527 Q(S)=1
+3528 NEXT S
+3529 RETURN
+3530 Q=1
+3540 Q(Q)=Q(Q)+1
+3550 IF Q(Q)<=C9 THEN RETURN
+3560 Q(Q)=1
+3570 Q=Q+1
+3580 GOTO 3540
+4000 REM
+4010 REM     CONVERT Q(1-P9) TO A$(1-P9)
+4020 REM
+4030 FOR S=1 TO P9
+4040 A$(S)=MID$(L$,Q(S),1)
+4050 NEXT S
+4060 RETURN
+4500 REM
+4510 REM     GET NUMBER OF BLACKS (B) AND WHITES (W)
+4520 REM     MASHES G$ AND A$ IN THE PROCESS
+4530 REM
+4540 B=0:W=0:F=0
+4550 FOR S=1 TO P9
+4560 IF G$(S)<>A$(S) THEN 4620
+4570 B=B+1
+4580 G$(S)=CHR$(F)
+4590 A$(S)=CHR$(F+1)
+4600 F=F+2
+4610 GOTO 4660
+4620 FOR T=1 TO P9
+4630 IF G$(S)<>A$(T) THEN 4650
+4640 IF G$(T)=A$(T) THEN 4650
+4645 W=W+1:A$(T)=CHR$(F):G$(S)=CHR$(F+1):F=F+2:GOTO 4660
+4650 NEXT T
+4660 NEXT S
+4670 RETURN
+5000 REM
+5010 REM     PRINT SCORE
+5020 REM
+5030 PRINT "SCORE:"
+5040 PRINT "     COMPUTER ";C
+5050 PRINT "     HUMAN    ";H
+5060 PRINT
+5070 RETURN
+5500 REM
+5510 REM     CONVERT Q(1-P9) INTO G$(1-P9)
+5520 REM
+5530 FOR S=1 TO P9
+5540 G$(S)=MID$(L$,Q(S),1)
+5550 NEXT S
+5560 RETURN
+6000 REM
+6010 REM     CONVERT Q(1-P9) TO H$(1-P9)
+6020 REM
+6030 FOR S=1 TO P9
+6040 H$(S)=MID$(L$,Q(S),1)
+6050 NEXT S
+6060 RETURN
+6500 REM
+6510 REM     COPY H$ INTO G$
+6520 REM
+6530 FOR S=1 TO P9
+6540 G$(S)=H$(S)
+6550 NEXT S
+6560 RETURN
+8000 REM     PROGRAM DATA FOR COLOR NAMES
+8010 DATA BLACK,WHITE,RED,GREEN,ORANGE,YELLOW,PURPLE,TAN
+9998 REM   ...WE'RE SORRY BUT IT'S TIME TO GO...
+9999 END

data/test/integration/tests/basic_computer_games/mastrmnd.input

@@ -0,0 +1,18 @@
+6
+4
+12
+BBBB
+WWWW
+RRRR
+GGGG
+OOOO
+WBBB
+BWBB
+BBWB
+GGWO
+GOWG
+
+1,0
+0,0
+0,0
+4,0

data/test/integration/tests/basic_computer_games/mastrmnd.output

@@ -0,0 +1,67 @@
+                              MASTERMIND
+               CREATIVE COMPUTING  MORRISTOWN, NEW JERSEY
+
+
+
+NUMBER OF COLORS? 6
+NUMBER OF POSITIONS? 4
+NUMBER OF ROUNDS? 12
+TOTAL POSSIBILITIES = 1296 
+
+
+COLOR     LETTER
+=====     ======
+BLACK        B
+WHITE        W
+RED          R
+GREEN        G
+ORANGE       O
+YELLOW       Y
+
+
+ROUND NUMBER 1 ----
+
+GUESS MY COMBINATION.
+
+MOVE #  1  GUESS ? BBBB
+YOU HAVE  0  BLACKS AND  0  WHITES.
+MOVE #  2  GUESS ? WWWW
+YOU HAVE  1  BLACKS AND  0  WHITES.
+MOVE #  3  GUESS ? RRRR
+YOU HAVE  0  BLACKS AND  0  WHITES.
+MOVE #  4  GUESS ? GGGG
+YOU HAVE  2  BLACKS AND  0  WHITES.
+MOVE #  5  GUESS ? OOOO
+YOU HAVE  1  BLACKS AND  0  WHITES.
+MOVE #  6  GUESS ? WBBB
+YOU HAVE  0  BLACKS AND  1  WHITES.
+MOVE #  7  GUESS ? BWBB
+YOU HAVE  0  BLACKS AND  1  WHITES.
+MOVE #  8  GUESS ? BBWB
+YOU HAVE  1  BLACKS AND  0  WHITES.
+MOVE #  9  GUESS ? GGWO
+YOU HAVE  2  BLACKS AND  2  WHITES.
+MOVE #  10  GUESS ? GOWG
+YOU GUESSED IT IN  10  MOVES!
+SCORE:
+     COMPUTER  0 
+     HUMAN     10 
+
+NOW I GUESS.  THINK OF A COMBINATION.
+HIT RETURN WHEN READY:? 
+MY GUESS IS: ROWO  BLACKS, WHITES ? 1,0
+MY GUESS IS: GOGG  BLACKS, WHITES ? 0,0
+MY GUESS IS: RBBY  BLACKS, WHITES ? 0,0
+MY GUESS IS: WWWW  BLACKS, WHITES ? 4,0
+I GOT IT IN  4  MOVES!
+SCORE:
+     COMPUTER  4 
+     HUMAN     10 
+
+
+ROUND NUMBER 2 ----
+
+GUESS MY COMBINATION.
+
+MOVE #  1  GUESS ? 
+Error on line 380: No more input

data/test/integration/tests/basic_computer_games/mathdice.bas

@@ -0,0 +1,60 @@
+10 PRINT TAB(31);"MATH DICE"
+20 PRINT TAB(15);"CREATIVE COMPUTING  MORRISTOWN, NEW JERSEY"
+30 PRINT:PRINT:PRINT
+40 PRINT "THIS PROGRAM GENERATES SUCCESIVE PICTURES OF TWO DICE."
+50 PRINT "WHEN TWO DICE AND AN EQUAL SIGN FOLLOWED BY A QUESTION"
+60 PRINT "MARK HAVE BEEN PRINTED, TYPE YOUR ANSWER AND THE RETURN KEY."
+70 PRINT "TO CONCLUDE THE LESSON, TYPE CONTROL-C AS YOUR ANSWER."
+80 PRINT
+90 PRINT
+100 N=N+1
+110 D=INT(6*RND(1)+1)
+120 PRINT" ----- "
+130 IF D=1 THEN 200
+140 IF D=2 THEN 180
+150 IF D=3 THEN 180
+160 PRINT "I * * I"
+170 GOTO 210
+180 PRINT "I *   I"
+190 GOTO 210
+200 PRINT "I     I"
+210 IF D=2 THEN 260
+220 IF D=4 THEN 260
+230 IF D=6 THEN 270
+240 PRINT "I  *  I"
+250 GOTO 280
+260 PRINT "I     I"
+265 GOTO 280
+270 PRINT "I * * I"
+280 IF D=1 THEN 350
+290 IF D=2 THEN 330
+300 IF D=3 THEN 330
+310 PRINT "I * * I"
+320 GOTO 360
+330 PRINT "I   * I"
+340 GOTO 360
+350 PRINT "I     I"
+360 PRINT " ----- "
+370 PRINT
+375 IF N=2 THEN 500
+380 PRINT "   +"
+381 PRINT
+400 A=D
+410 GOTO 100
+500 T=D+A
+510 PRINT "      =";
+520 INPUT T1
+530 IF T1=T THEN 590
+540 PRINT "NO, COUNT THE SPOTS AND GIVE ANOTHER ANSWER."
+541 PRINT "      =";
+550 INPUT T2
+560 IF T2=T THEN 590
+570 PRINT "NO, THE ANSWER IS";T
+580 GOTO 600
+590 PRINT "RIGHT!"
+600 PRINT
+601 PRINT "THE DICE ROLL AGAIN..."
+610 PRINT
+615 N=0
+620 GOTO 100
+999 END

data/test/integration/tests/basic_computer_games/mathdice.input

@@ -0,0 +1,4 @@
+9
+8
+1
+7

data/test/integration/tests/basic_computer_games/mathdice.output

@@ -0,0 +1,86 @@
+                               MATH DICE
+               CREATIVE COMPUTING  MORRISTOWN, NEW JERSEY
+
+
+
+THIS PROGRAM GENERATES SUCCESIVE PICTURES OF TWO DICE.
+WHEN TWO DICE AND AN EQUAL SIGN FOLLOWED BY A QUESTION
+MARK HAVE BEEN PRINTED, TYPE YOUR ANSWER AND THE RETURN KEY.
+TO CONCLUDE THE LESSON, TYPE CONTROL-C AS YOUR ANSWER.
+
+
+ ----- 
+I * * I
+I     I
+I * * I
+ ----- 
+
+   +
+
+ ----- 
+I * * I
+I  *  I
+I * * I
+ ----- 
+
+      =? 9
+RIGHT!
+
+THE DICE ROLL AGAIN...
+
+ ----- 
+I * * I
+I     I
+I * * I
+ ----- 
+
+   +
+
+ ----- 
+I * * I
+I     I
+I * * I
+ ----- 
+
+      =? 8
+RIGHT!
+
+THE DICE ROLL AGAIN...
+
+ ----- 
+I *   I
+I  *  I
+I   * I
+ ----- 
+
+   +
+
+ ----- 
+I * * I
+I     I
+I * * I
+ ----- 
+
+      =? 1
+NO, COUNT THE SPOTS AND GIVE ANOTHER ANSWER.
+      =? 7
+RIGHT!
+
+THE DICE ROLL AGAIN...
+
+ ----- 
+I *   I
+I  *  I
+I   * I
+ ----- 
+
+   +
+
+ ----- 
+I * * I
+I * * I
+I * * I
+ ----- 
+
+      =? 
+Error on line 520: No more input

data/test/integration/tests/basic_computer_games/mugwump.bas

@@ -0,0 +1,56 @@
+1 PRINT TAB(33);"MUGWUMP"
+2 PRINT TAB(15);"CREATIVE COMPUTING  MORRISTOWN, NEW JERSEY"
+3 PRINT:PRINT:PRINT
+4 REM     COURTESY PEOPLE'S COMPUTER COMPANY
+10 DIM P(4,2)
+20 PRINT "THE OBJECT OF THIS GAME IS TO FIND FOUR MUGWUMPS"
+30 PRINT "HIDDEN ON A 10 BY 10 GRID.  HOMEBASE IS POSITION 0,0."
+40 PRINT "ANY GUESS YOU MAKE MUST BE TWO NUMBERS WITH EACH"
+50 PRINT "NUMBER BETWEEN 0 AND 9, INCLUSIVE.  FIRST NUMBER"
+60 PRINT "IS DISTANCE TO RIGHT OF HOMEBASE AND SECOND NUMBER"
+70 PRINT "IS DISTANCE ABOVE HOMEBASE."
+80 PRINT
+90 PRINT "YOU GET 10 TRIES.  AFTER EACH TRY, I WILL TELL"
+100 PRINT "YOU HOW FAR YOU ARE FROM EACH MUGWUMP."
+110 PRINT
+240 GOSUB 1000
+250 T=0
+260 T=T+1
+270 PRINT
+275 PRINT
+290 PRINT "TURN NO.";T;"-- WHAT IS YOUR GUESS";
+300 INPUT M,N
+310 FOR I=1 TO 4
+320 IF P(I,1)=-1 THEN 400
+330 IF P(I,1)<>M THEN 380
+340 IF P(I,2)<>N THEN 380
+350 P(I,1)=-1
+360 PRINT "YOU HAVE FOUND MUGWUMP";I
+370 GOTO 400
+380 D=SQR((P(I,1)-M)^2+(P(I,2)-N)^2)
+390 PRINT "YOU ARE";(INT(D*10))/10;"UNITS FROM MUGWUMP";I
+400 NEXT I
+410 FOR J=1 TO 4
+420 IF P(J,1)<>-1 THEN 470
+430 NEXT J
+440 PRINT
+450 PRINT "YOU GOT THEM ALL IN";T;"TURNS!"
+460 GOTO 580
+470 IF T<10 THEN 260
+480 PRINT
+490 PRINT "SORRY, THAT'S 10 TRIES.  HERE IS WHERE THEY'RE HIDING:"
+540 FOR I=1 TO 4
+550 IF P(I,1)=-1 THEN 570
+560 PRINT "MUGWUMP";I;"IS AT (";P(I,1);",";P(I,2);")"
+570 NEXT I
+580 PRINT
+600 PRINT "THAT WAS FUN! LET'S PLAY AGAIN......."
+610 PRINT "FOUR MORE MUGWUMPS ARE NOW IN HIDING."
+630 GOTO 240
+1000 FOR J=1 TO 2
+1010 FOR I=1 TO 4
+1020 P(I,J)=INT(10*RND(1))
+1030 NEXT I
+1040 NEXT J
+1050 RETURN
+1099 END

data/test/integration/tests/basic_computer_games/mugwump.input

@@ -0,0 +1,16 @@
+0,0
+10,0
+5,4
+7,6
+6,4
+5,8
+1,1
+2,2
+3,3
+4,4
+5,5
+6,6
+7,7
+8,8
+9,9
+10,10

data/test/integration/tests/basic_computer_games/mugwump.output

@@ -0,0 +1,139 @@
+                                 MUGWUMP
+               CREATIVE COMPUTING  MORRISTOWN, NEW JERSEY
+
+
+
+THE OBJECT OF THIS GAME IS TO FIND FOUR MUGWUMPS
+HIDDEN ON A 10 BY 10 GRID.  HOMEBASE IS POSITION 0,0.
+ANY GUESS YOU MAKE MUST BE TWO NUMBERS WITH EACH
+NUMBER BETWEEN 0 AND 9, INCLUSIVE.  FIRST NUMBER
+IS DISTANCE TO RIGHT OF HOMEBASE AND SECOND NUMBER
+IS DISTANCE ABOVE HOMEBASE.
+
+YOU GET 10 TRIES.  AFTER EACH TRY, I WILL TELL
+YOU HOW FAR YOU ARE FROM EACH MUGWUMP.
+
+
+
+TURN NO. 1 -- WHAT IS YOUR GUESS? 0,0
+YOU ARE 6.4 UNITS FROM MUGWUMP 1 
+YOU ARE 9.2 UNITS FROM MUGWUMP 2 
+YOU ARE 7.2 UNITS FROM MUGWUMP 3 
+YOU ARE 9.4 UNITS FROM MUGWUMP 4 
+
+
+TURN NO. 2 -- WHAT IS YOUR GUESS? 10,0
+YOU ARE 6.4 UNITS FROM MUGWUMP 1 
+YOU ARE 6.7 UNITS FROM MUGWUMP 2 
+YOU ARE 5.6 UNITS FROM MUGWUMP 3 
+YOU ARE 9.4 UNITS FROM MUGWUMP 4 
+
+
+TURN NO. 3 -- WHAT IS YOUR GUESS? 5,4
+YOU HAVE FOUND MUGWUMP 1 
+YOU ARE 2.8 UNITS FROM MUGWUMP 2 
+YOU ARE 1 UNITS FROM MUGWUMP 3 
+YOU ARE 4 UNITS FROM MUGWUMP 4 
+
+
+TURN NO. 4 -- WHAT IS YOUR GUESS? 7,6
+YOU HAVE FOUND MUGWUMP 2 
+YOU ARE 2.2 UNITS FROM MUGWUMP 3 
+YOU ARE 2.8 UNITS FROM MUGWUMP 4 
+
+
+TURN NO. 5 -- WHAT IS YOUR GUESS? 6,4
+YOU HAVE FOUND MUGWUMP 3 
+YOU ARE 4.1 UNITS FROM MUGWUMP 4 
+
+
+TURN NO. 6 -- WHAT IS YOUR GUESS? 5,8
+YOU HAVE FOUND MUGWUMP 4 
+
+YOU GOT THEM ALL IN 6 TURNS!
+
+THAT WAS FUN! LET'S PLAY AGAIN.......
+FOUR MORE MUGWUMPS ARE NOW IN HIDING.
+
+
+TURN NO. 1 -- WHAT IS YOUR GUESS? 1,1
+YOU ARE 8.9 UNITS FROM MUGWUMP 1 
+YOU ARE 8.2 UNITS FROM MUGWUMP 2 
+YOU ARE 6 UNITS FROM MUGWUMP 3 
+YOU ARE 4.1 UNITS FROM MUGWUMP 4 
+
+
+TURN NO. 2 -- WHAT IS YOUR GUESS? 2,2
+YOU ARE 7.6 UNITS FROM MUGWUMP 1 
+YOU ARE 7 UNITS FROM MUGWUMP 2 
+YOU ARE 5.3 UNITS FROM MUGWUMP 3 
+YOU ARE 3.6 UNITS FROM MUGWUMP 4 
+
+
+TURN NO. 3 -- WHAT IS YOUR GUESS? 3,3
+YOU ARE 6.3 UNITS FROM MUGWUMP 1 
+YOU ARE 6 UNITS FROM MUGWUMP 2 
+YOU ARE 5 UNITS FROM MUGWUMP 3 
+YOU ARE 3.6 UNITS FROM MUGWUMP 4 
+
+
+TURN NO. 4 -- WHAT IS YOUR GUESS? 4,4
+YOU ARE 5 UNITS FROM MUGWUMP 1 
+YOU ARE 5 UNITS FROM MUGWUMP 2 
+YOU ARE 5 UNITS FROM MUGWUMP 3 
+YOU ARE 4.1 UNITS FROM MUGWUMP 4 
+
+
+TURN NO. 5 -- WHAT IS YOUR GUESS? 5,5
+YOU ARE 4 UNITS FROM MUGWUMP 1 
+YOU ARE 4.4 UNITS FROM MUGWUMP 2 
+YOU ARE 5.3 UNITS FROM MUGWUMP 3 
+YOU ARE 5 UNITS FROM MUGWUMP 4 
+
+
+TURN NO. 6 -- WHAT IS YOUR GUESS? 6,6
+YOU ARE 3.1 UNITS FROM MUGWUMP 1 
+YOU ARE 4.2 UNITS FROM MUGWUMP 2 
+YOU ARE 6 UNITS FROM MUGWUMP 3 
+YOU ARE 6 UNITS FROM MUGWUMP 4 
+
+
+TURN NO. 7 -- WHAT IS YOUR GUESS? 7,7
+YOU ARE 2.8 UNITS FROM MUGWUMP 1 
+YOU ARE 4.4 UNITS FROM MUGWUMP 2 
+YOU ARE 7 UNITS FROM MUGWUMP 3 
+YOU ARE 7.2 UNITS FROM MUGWUMP 4 
+
+
+TURN NO. 8 -- WHAT IS YOUR GUESS? 8,8
+YOU ARE 3.1 UNITS FROM MUGWUMP 1 
+YOU ARE 5 UNITS FROM MUGWUMP 2 
+YOU ARE 8 UNITS FROM MUGWUMP 3 
+YOU ARE 8.5 UNITS FROM MUGWUMP 4 
+
+
+TURN NO. 9 -- WHAT IS YOUR GUESS? 9,9
+YOU ARE 4 UNITS FROM MUGWUMP 1 
+YOU ARE 6 UNITS FROM MUGWUMP 2 
+YOU ARE 9.2 UNITS FROM MUGWUMP 3 
+YOU ARE 9.8 UNITS FROM MUGWUMP 4 
+
+
+TURN NO. 10 -- WHAT IS YOUR GUESS? 10,10
+YOU ARE 5 UNITS FROM MUGWUMP 1 
+YOU ARE 7 UNITS FROM MUGWUMP 2 
+YOU ARE 10.4 UNITS FROM MUGWUMP 3 
+YOU ARE 11.1 UNITS FROM MUGWUMP 4 
+
+SORRY, THAT'S 10 TRIES.  HERE IS WHERE THEY'RE HIDING:
+MUGWUMP 1 IS AT ( 9 , 5 )
+MUGWUMP 2 IS AT ( 3 , 9 )
+MUGWUMP 3 IS AT ( 7 , 0 )
+MUGWUMP 4 IS AT ( 5 , 0 )
+
+THAT WAS FUN! LET'S PLAY AGAIN.......
+FOUR MORE MUGWUMPS ARE NOW IN HIDING.
+
+
+TURN NO. 1 -- WHAT IS YOUR GUESS? 
+Error on line 300: No more input

data/test/integration/tests/basic_computer_games/name.bas

@@ -0,0 +1,25 @@
+1 PRINT TAB(34);"NAME"
+2 PRINT TAB(15);"CREATIVE COMPUTING  MORRISTOWN, NEW JERSEY"
+3 PRINT: PRINT: PRINT
+5 DIM B$(40)
+10 PRINT "HELLO.": PRINT "MY NAME IS CREATIVE COMPUTER."
+20 PRINT "WHAT'S YOUR NAME (FIRST AND LAST";: INPUT A$: L=LEN(A$)
+30 PRINT: PRINT "THANK YOU, ";
+40 FOR I=1 TO L: B$(I)=MID$(A$,I,1): NEXT I
+50 FOR I=L TO 1 STEP -1: PRINT B$(I);: NEXT I
+60 PRINT ".": PRINT "OOPS!  I GUESS I GOT IT BACKWARDS.  A SMART"
+70 PRINT "COMPUTER LIKE ME SHOULDN'T MAKE A MISTAKE LIKE THAT!": PRINT
+80 PRINT "BUT I JUST NOTICED YOUR LETTERS ARE OUT OF ORDER."
+90 PRINT "LET'S PUT THEM IN ORDER LIKE THIS: ";
+100 FOR J=2 TO L: I=J-1: T$=B$(J)
+110 IF T$>B$(I) THEN 130
+120 B$(I+1)=B$(I): I=I-1: IF I>0 THEN 110
+130 B$(I+1)=T$: NEXT J
+140 FOR I=1 TO L: PRINT B$(I);: NEXT I: PRINT: PRINT
+150 PRINT "DON'T YOU LIKE THAT BETTER";: INPUT D$
+160 IF D$="YES" THEN 180
+170 PRINT: PRINT "I'M SORRY YOU DON'T LIKE IT THAT WAY.": GOTO 200
+180 PRINT: PRINT "I KNEW YOU'D AGREE!!"
+200 PRINT: PRINT "I REALLY ENJOYED MEETING YOU ";A$;"."
+210 PRINT "HAVE A NICE DAY!"
+999 END

data/test/integration/tests/basic_computer_games/name.input

@@ -0,0 +1,2 @@
+FRED FLINSTONE
+YES