basic101 0.1.0

data/test/integration/tests/basic_computer_games/kinema.output

@@ -0,0 +1,64 @@
+                                 KINEMA
+               CREATIVE COMPUTING  MORRISTOWN, NEW JERSEY
+
+
+
+
+
+A BALL IS THROWN UPWARDS AT 24 METERS PER SECOND.
+
+HOW HIGH WILL IT GO (IN METERS)? 28
+CLOSE ENOUGH.
+CORRECT ANSWER IS  28.8 
+
+HOW LONG UNTIL IT RETURNS (IN SECONDS)? 5
+CLOSE ENOUGH.
+CORRECT ANSWER IS  4.8 
+
+WHAT WILL ITS VELOCITY BE AFTER 4.4 SECONDS? -20
+CLOSE ENOUGH.
+CORRECT ANSWER IS -20 
+
+
+ 3 RIGHT OUT OF 3.  NOT BAD.
+
+
+A BALL IS THROWN UPWARDS AT 26 METERS PER SECOND.
+
+HOW HIGH WILL IT GO (IN METERS)? 30
+CLOSE ENOUGH.
+CORRECT ANSWER IS  33.8 
+
+HOW LONG UNTIL IT RETURNS (IN SECONDS)? 5.5
+CLOSE ENOUGH.
+CORRECT ANSWER IS  5.2 
+
+WHAT WILL ITS VELOCITY BE AFTER 3.8 SECONDS? -20
+NOT EVEN CLOSE....
+CORRECT ANSWER IS -12 
+
+
+ 2 RIGHT OUT OF 3.  NOT BAD.
+
+
+A BALL IS THROWN UPWARDS AT 19 METERS PER SECOND.
+
+HOW HIGH WILL IT GO (IN METERS)? 1
+NOT EVEN CLOSE....
+CORRECT ANSWER IS  18.05 
+
+HOW LONG UNTIL IT RETURNS (IN SECONDS)? 1
+NOT EVEN CLOSE....
+CORRECT ANSWER IS  3.8 
+
+WHAT WILL ITS VELOCITY BE AFTER 3.4 SECONDS? 1
+NOT EVEN CLOSE....
+CORRECT ANSWER IS -15 
+
+
+ 0 RIGHT OUT OF 3.
+
+A BALL IS THROWN UPWARDS AT 20 METERS PER SECOND.
+
+HOW HIGH WILL IT GO (IN METERS)? 
+Error on line 500: No more input

data/test/integration/tests/basic_computer_games/king.bas

@@ -0,0 +1,268 @@
+1 PRINT TAB(34);"KING"
+2 PRINT TAB(15);"CREATIVE COMPUTING  MORRISTOWN, NEW JERSEY"
+3 PRINT:PRINT:PRINT
+4 PRINT "DO YOU WANT INSTRUCTIONS";
+5 INPUT Z$
+6 N5=8
+10 IF LEFT$(Z$,1)="N" THEN 47
+11 IF Z$="AGAIN" THEN 1960
+12 PRINT:PRINT:PRINT
+20 PRINT "CONGRATULATIONS! YOU'VE JUST BEEN ELECTED PREMIER OF SETATS"
+22 PRINT "DETINU, A SMALL COMMUNIST ISLAND 30 BY 70 MILES LONG. YOUR"
+24 PRINT "JOB IS TO DECIDE UPON THE CONTRY'S BUDGET AND DISTRIBUTE"
+26 PRINT "MONEY TO YOUR COUNTRYMEN FROM THE COMMUNAL TREASURY."
+28 PRINT "THE MONEY SYSTEM IS RALLODS, AND EACH PERSON NEEDS 100"
+30 PRINT "RALLODS PER YEAR TO SURVIVE. YOUR COUNTRY'S INCOME COMES"
+32 PRINT "FROM FARM PRODUCE AND TOURISTS VISITING YOUR MAGNIFICENT"
+34 PRINT "FORESTS, HUNTING, FISHING, ETC. HALF YOUR LAND IS FARM LAND"
+36 PRINT "WHICH ALSO HAS AN EXCELLENT MINERAL CONTENT AND MAY BE SOLD"
+38 PRINT "TO FOREIGN INDUSTRY (STRIP MINING) WHO IMPORT AND SUPPORT"
+40 PRINT "THEIR OWN WORKERS. CROPS COST BETWEEN 10 AND 15 RALLODS PER"
+42 PRINT "SQUARE MILE TO PLANT."
+44 PRINT "YOUR GOAL IS TO COMPLETE YOUR";N5;"YEAR TERM OF OFFICE."
+46 PRINT "GOOD LUCK!"
+47 PRINT
+50 A=INT(60000+(1000*RND(1))-(1000*RND(1)))
+55 B=INT(500+(10*RND(1))-(10*RND(1)))
+65 D=2000
+100 W=INT(10*RND(1)+95)
+102 PRINT
+105 PRINT "YOU NOW HAVE ";A;" RALLODS IN THE TREASURY."
+110 PRINT INT(B);:PRINT "COUNTRYMEN, ";
+115 V9=INT(((RND(1)/2)*10+10))
+120 IF C=0 THEN 140
+130 PRINT INT(C);"FOREIGN WORKERS, ";
+140 PRINT "AND";INT(D);"SQ. MILES OF LAND."
+150 PRINT "THIS YEAR INDUSTRY WILL BUY LAND FOR";W;
+152 PRINT "RALLODS PER SQUARE MILE."
+155 PRINT "LAND CURRENTLY COSTS";V9;"RALLODS PER SQUARE MILE TO PLANT."
+162 PRINT
+200 PRINT "HOW MANY SQUARE MILES DO YOU WISH TO SELL TO INDUSTRY";
+210 INPUT H
+215 IF H<0 THEN 200
+220 IF H<=D-1000 THEN 300
+230 PRINT "***  THINK AGAIN. YOU ONLY HAVE";D-1000;"SQUARE MILES OF FARM LAND."
+240 IF X<>0 THEN 200
+250 PRINT:PRINT "(FOREIGN INDUSTRY WILL ONLY BUY FARM LAND BECAUSE"
+260 PRINT "FOREST LAND IS UNECONOMICAL TO STRIP MINE DUE TO TREES,"
+270 PRINT "THICKER TOP SOIL, ETC.)"
+280 X=1
+299 GOTO 200
+300 D=INT(D-H)
+310 A=INT(A+(H*W))
+320 PRINT "HOW MANY RALLODS WILL YOU DISTRIBUTE AMONG YOUR COUNTRYMEN";
+340 INPUT I
+342 IF I<0 THEN 320
+350 IF I<A THEN 400
+360 IF I=A THEN 380
+370 PRINT "   THINK AGAIN. YOU'VE ONLY";A;" RALLODS IN THE TREASURY"
+375 GOTO 320
+380 J=0
+390 K=0
+395 A=0
+399 GOTO 1000
+400 A=INT(A-I)
+410 PRINT "HOW MANY SQUARE MILES DO YOU WISH TO PLANT";
+420 INPUT J
+421 IF J<0 THEN 410
+422 IF J<=B*2 THEN 426
+423 PRINT "   SORRY, BUT EACH COUNTRYMAN CAN ONLY PLANT 2 SQ. MILES."
+424 GOTO 410
+426 IF J<=D-1000 THEN 430
+427 PRINT "   SORRY, BUT YOU'VE ONLY";D-1000;"SQ. MILES OF FARM LAND."
+428 GOTO 410
+430 U1=INT(J*V9)
+435 IF U1<A THEN 500
+440 IF U1=A THEN 490
+450 PRINT "   THINK AGAIN. YOU'VE ONLY";A;" RALLODS LEFT IN THE TREASURY."
+460 GOTO 410
+490 K=0
+495 A=0
+499 GOTO 1000
+500 A=A-U1
+510 PRINT "HOW MANY RALLODS DO YOU WISH TO SPEND ON POLLUTION CONTROL";
+520 INPUT K
+522 IF K<0 THEN 510
+530 IF K<=A THEN 1000
+540 PRINT "   THINK AGAIN. YOU ONLY HAVE ";A;" RALLODS REMAINING."
+550 GOTO 510
+600 IF H<>0 THEN 1002
+602 IF I<>0 THEN 1002
+604 IF J<>0 THEN 1002
+606 IF K<>0 THEN 1002
+609 PRINT
+612 PRINT "GOODBYE."
+614 PRINT "(IF YOU WISH TO CONTINUE THIS GAME AT A LATER DATE, ANSWER"
+616 PRINT "'AGAIN' WHEN ASKED IF YOU WANT INSTRUCTIONS AT THE START"
+617 PRINT "OF THE GAME)."
+618 STOP
+1000 GOTO 600
+1002 PRINT
+1003 PRINT
+1010 A=INT(A-K)
+1020 A4=A
+1100 IF INT(I/100-B)>=0 THEN 1120
+1105 IF I/100<50 THEN 1700
+1110 PRINT INT(B-(I/100));"COUNTRYMEN DIED OF STARVATION"
+1120 F1=INT(RND(1)*(2000-D))
+1122 IF K<25 THEN 1130
+1125 F1=INT(F1/(K/25))
+1130 IF F1<=0 THEN 1150
+1140 PRINT F1;"COUNTRYMEN DIED OF CARBON-MONOXIDE AND DUST INHALATION"
+1150 IF INT((I/100)-B)<0 THEN 1170
+1160 IF F1>0 THEN 1180
+1165 GOTO 1200
+1170 PRINT "   YOU WERE FORCED TO SPEND";INT((F1+(B-(I/100)))*9);
+1172 PRINT "RALLODS ON FUNERAL EXPENSES"
+1174 B5=INT(F1+(B-(I/100)))
+1175 A=INT(A-((F1+(B-(I/100)))*9))
+1176 GOTO 1185
+1180 PRINT "   YOU WERE FORCED TO SPEND ";INT(F1*9);"RALLODS ON ";
+1181 PRINT "FUNERAL EXPENSES."
+1182 B5=F1
+1183 A=INT(A-(F1*9))
+1185 IF A>=0 THEN 1194
+1187 PRINT "   INSUFFICIENT RESERVES TO COVER COST - LAND WAS SOLD"
+1189 D=INT(D+(A/W))
+1190 A=0
+1194 B=INT(B-B5)
+1200 IF H=0 THEN 1250
+1220 C1=INT(H+(RND(1)*10)-(RND(1)*20))
+1224 IF C>0 THEN 1230
+1226 C1=C1+20
+1230 PRINT C1;"WORKERS CAME TO THE COUNTRY AND";
+1250 P1=INT(((I/100-B)/10)+(K/25)-((2000-D)/50)-(F1/2))
+1255 PRINT ABS(P1);"COUNTRYMEN ";
+1260 IF P1<0 THEN 1275
+1265 PRINT "CAME TO";
+1270 GOTO 1280
+1275 PRINT "LEFT";
+1280 PRINT " THE ISLAND."
+1290 B=INT(B+P1)
+1292 C=INT(C+C1)
+1305 U2=INT(((2000-D)*((RND(1)+1.5)/2)))
+1310 IF C=0 THEN 1324
+1320 PRINT "OF ";INT(J);"SQ. MILES PLANTED,";
+1324 IF J>U2 THEN 1330
+1326 U2=J
+1330 PRINT " YOU HARVESTED ";INT(J-U2);"SQ. MILES OF CROPS."
+1340 IF U2=0 THEN 1370
+1344 IF T1>=2 THEN 1370
+1350 PRINT "   (DUE TO ";
+1355 IF T1=0 THEN 1365
+1360 PRINT "INCREASED ";
+1365 PRINT "AIR AND WATER POLLUTION FROM FOREIGN INDUSTRY.)"
+1370 Q=INT((J-U2)*(W/2))
+1380 PRINT "MAKING";INT(Q);"RALLODS."
+1390 A=INT(A+Q)
+1400 V1=INT(((B-P1)*22)+(RND(1)*500))
+1405 V2=INT((2000-D)*15)
+1410 PRINT " YOU MADE";ABS(INT(V1-V2));"RALLODS FROM TOURIST TRADE."
+1420 IF V2=0 THEN 1450
+1425 IF V1-V2>=V3 THEN 1450
+1430 PRINT "   DECREASE BECAUSE ";
+1435 G1=10*RND(1)
+1440 IF G1<=2 THEN 1460
+1442 IF G1<=4 THEN 1465
+1444 IF G1<=6 THEN 1470
+1446 IF G1<=8 THEN 1475
+1448 IF G1<=10 THEN 1480
+1450 V3=INT(A+V3)
+1451 A=INT(A+V3)
+1452 GOTO 1500
+1460 PRINT "FISH POPULATION HAS DWINDLED DUE TO WATER POLLUTION."
+1462 GOTO 1450
+1465 PRINT "AIR POLLUTION IS KILLING GAME BIRD POPULATION."
+1467 GOTO 1450
+1470 PRINT "MINERAL BATHS ARE BEING RUINED BY WATER POLLUTION."
+1472 GOTO 1450
+1475 PRINT "UNPLEASANT SMOG IS DISCOURAGING SUN BATHERS."
+1477 GOTO 1450
+1480 PRINT "HOTELS ARE LOOKING SHABBY DUE TO SMOG GRIT."
+1482 GOTO 1450
+1500 IF B5>200 THEN 1600
+1505 IF B<343 THEN 1700
+1510 IF (A4/100)>5 THEN 1800
+1515 IF C>B THEN 1550
+1520 IF N5-1=X5 THEN 1900
+1545 GOTO 2000
+1550 PRINT
+1552 PRINT
+1560 PRINT "THE NUMBER OF FOREIGN WORKERS HAS EXCEEDED THE NUMBER"
+1562 PRINT "OF COUNTRYMEN. AS A MINORITY, THEY HAVE REVOLTED AND"
+1564 PRINT "TAKEN OVER THE COUNTRY."
+1570 IF RND(1)<=.5 THEN 1580
+1574 PRINT "YOU HAVE BEEN THROWN OUT OF OFFICE AND ARE NOW"
+1576 PRINT "RESIDING IN PRISON."
+1578 GOTO 1590
+1580 PRINT "YOU HAVE BEEN ASSASSINATED."
+1590 PRINT
+1592 PRINT
+1596 STOP
+1600 PRINT
+1602 PRINT
+1610 PRINT B5;"COUNTRYMEN DIED IN ONE YEAR!!!!!"
+1615 PRINT "DUE TO THIS EXTREME MISMANAGEMENT, YOU HAVE NOT ONLY"
+1620 PRINT "BEEN IMPEACHED AND THROWN OUT OF OFFICE, BUT YOU"
+1622 M6=INT(RND(1)*10)
+1625 IF M6<=3 THEN 1670
+1630 IF M6<=6 THEN 1680
+1635 IF M6<=10 THEN 1690
+1670 PRINT "ALSO HAD YOUR LEFT EYE GOUGED OUT!"
+1672 GOTO 1590
+1680 PRINT "HAVE ALSO GAINED A VERY BAD REPUTATION."
+1682 GOTO 1590
+1690 PRINT "HAVE ALSO BEEN DECLARED NATIONAL FINK."
+1692 GOTO 1590
+1700 PRINT
+1702 PRINT
+1710 PRINT "OVER ONE THIRD OF THE POPULTATION HAS DIED SINCE YOU"
+1715 PRINT "WERE ELECTED TO OFFICE. THE PEOPLE (REMAINING)"
+1720 PRINT "HATE YOUR GUTS."
+1730 GOTO 1570
+1800 IF B5-F1<2 THEN 1515
+1807 PRINT
+1815 PRINT "MONEY WAS LEFT OVER IN THE TREASURY WHICH YOU DID"
+1820 PRINT "NOT SPEND. AS A RESULT, SOME OF YOUR COUNTRYMEN DIED"
+1825 PRINT "OF STARVATION. THE PUBLIC IS ENRAGED AND YOU HAVE"
+1830 PRINT "BEEN FORCED TO EITHER RESIGN OR COMMIT SUICIDE."
+1835 PRINT "THE CHOICE IS YOURS."
+1840 PRINT "IF YOU CHOOSE THE LATTER, PLEASE TURN OFF YOUR COMPUTER"
+1845 PRINT "BEFORE PROCEEDING."
+1850 GOTO 1590
+1900 PRINT
+1902 PRINT
+1920 PRINT "CONGRATULATIONS!!!!!!!!!!!!!!!!!!"
+1925 PRINT "YOU HAVE SUCCESFULLY COMPLETED YOUR";N5;"YEAR TERM"
+1930 PRINT "OF OFFICE. YOU WERE, OF COURSE, EXTREMELY LUCKY, BUT"
+1935 PRINT "NEVERTHELESS, IT'S QUITE AN ACHIEVEMENT. GOODBYE AND GOOD"
+1940 PRINT "LUCK - YOU'LL PROBABLY NEED IT IF YOU'RE THE TYPE THAT"
+1945 PRINT "PLAYS THIS GAME."
+1950 GOTO 1590
+1960 PRINT "HOW MANY YEARS HAD YOU BEEN IN OFFICE WHEN INTERRUPTED";
+1961 INPUT X5
+1962 IF X5<0 THEN 1590
+1963 IF X5<8 THEN 1969
+1965 PRINT "   COME ON, YOUR TERM IN OFFICE IS ONLY";N5;"YEARS."
+1967 GOTO 1960
+1969 PRINT "HOW MUCH DID YOU HAVE IN THE TREASURY";
+1970 INPUT A
+1971 IF A<0 THEN 1590
+1975 PRINT "HOW MANY COUNTRYMEN";    
+1976 INPUT B
+1977 IF B<0 THEN 1590
+1980 PRINT "HOW MANY WORKERS";
+1981 INPUT C
+1982 IF C<0 THEN 1590
+1990 PRINT "HOW MANY SQUARE MILES OF LAND";
+1991 INPUT D
+1992 IF D<0 THEN 1590
+1993 IF D>2000 THEN 1996
+1994 IF D>1000 THEN 100
+1996 PRINT "   COME ON, YOU STARTED WITH 1000 SQ. MILES OF FARM LAND"
+1997 PRINT "   AND 10,000 SQ. MILES OF FOREST LAND."
+1998 GOTO 1990
+2000 X5=X5+1
+2020 B5=0
+2040 GOTO 100
+2046 END

data/test/integration/tests/basic_computer_games/king.input

@@ -0,0 +1,7 @@
+YES
+100
+10000
+20000
+1000
+900
+1000

data/test/integration/tests/basic_computer_games/king.output

@@ -0,0 +1,57 @@
+                                  KING
+               CREATIVE COMPUTING  MORRISTOWN, NEW JERSEY
+
+
+
+DO YOU WANT INSTRUCTIONS? YES
+
+
+
+CONGRATULATIONS! YOU'VE JUST BEEN ELECTED PREMIER OF SETATS
+DETINU, A SMALL COMMUNIST ISLAND 30 BY 70 MILES LONG. YOUR
+JOB IS TO DECIDE UPON THE CONTRY'S BUDGET AND DISTRIBUTE
+MONEY TO YOUR COUNTRYMEN FROM THE COMMUNAL TREASURY.
+THE MONEY SYSTEM IS RALLODS, AND EACH PERSON NEEDS 100
+RALLODS PER YEAR TO SURVIVE. YOUR COUNTRY'S INCOME COMES
+FROM FARM PRODUCE AND TOURISTS VISITING YOUR MAGNIFICENT
+FORESTS, HUNTING, FISHING, ETC. HALF YOUR LAND IS FARM LAND
+WHICH ALSO HAS AN EXCELLENT MINERAL CONTENT AND MAY BE SOLD
+TO FOREIGN INDUSTRY (STRIP MINING) WHO IMPORT AND SUPPORT
+THEIR OWN WORKERS. CROPS COST BETWEEN 10 AND 15 RALLODS PER
+SQUARE MILE TO PLANT.
+YOUR GOAL IS TO COMPLETE YOUR 8 YEAR TERM OF OFFICE.
+GOOD LUCK!
+
+
+YOU NOW HAVE  59833  RALLODS IN THE TREASURY.
+ 500 COUNTRYMEN, AND 2000 SQ. MILES OF LAND.
+THIS YEAR INDUSTRY WILL BUY LAND FOR 99 RALLODS PER SQUARE MILE.
+LAND CURRENTLY COSTS 13 RALLODS PER SQUARE MILE TO PLANT.
+
+HOW MANY SQUARE MILES DO YOU WISH TO SELL TO INDUSTRY? 100
+HOW MANY RALLODS WILL YOU DISTRIBUTE AMONG YOUR COUNTRYMEN? 10000
+HOW MANY SQUARE MILES DO YOU WISH TO PLANT? 20000
+   SORRY, BUT EACH COUNTRYMAN CAN ONLY PLANT 2 SQ. MILES.
+HOW MANY SQUARE MILES DO YOU WISH TO PLANT? 1000
+   SORRY, BUT YOU'VE ONLY 900 SQ. MILES OF FARM LAND.
+HOW MANY SQUARE MILES DO YOU WISH TO PLANT? 900
+HOW MANY RALLODS DO YOU WISH TO SPEND ON POLLUTION CONTROL? 1000
+
+
+ 400 COUNTRYMEN DIED OF STARVATION
+ 1 COUNTRYMEN DIED OF CARBON-MONOXIDE AND DUST INHALATION
+   YOU WERE FORCED TO SPEND 3609 RALLODS ON FUNERAL EXPENSES
+ 109 WORKERS CAME TO THE COUNTRY AND 37 COUNTRYMEN CAME TO THE ISLAND.
+OF  900 SQ. MILES PLANTED, YOU HARVESTED  806 SQ. MILES OF CROPS.
+   (DUE TO AIR AND WATER POLLUTION FROM FOREIGN INDUSTRY.)
+MAKING 39897 RALLODS.
+ YOU MADE 1073 RALLODS FROM TOURIST TRADE.
+
+
+ 401 COUNTRYMEN DIED IN ONE YEAR!!!!!
+DUE TO THIS EXTREME MISMANAGEMENT, YOU HAVE NOT ONLY
+BEEN IMPEACHED AND THROWN OUT OF OFFICE, BUT YOU
+HAVE ALSO GAINED A VERY BAD REPUTATION.
+
+
+Break in line 1596

data/test/integration/tests/basic_computer_games/lem.bas

@@ -0,0 +1,246 @@
+2 PRINT TAB(34);"LEM"
+4 PRINT TAB(15);"CREATIVE COMPUTING  MORRISTOWN, NEW JERSEY"
+7 REM ROCKT2 IS AN INTERACTIVE GAME THAT SIMULATES A LUNAR
+8 REM LANDING IS SIMILAR TO THAT OF THE APOLLO PROGRAM.
+9 REM THERE IS ABSOLUTELY NO CHANCE INVOLVED
+10 Z$="GO"
+15 B1=1
+20 M=17.95
+25 F1=5.25
+30 N=7.5
+35 R0=926
+40 V0=1.29
+45 T=0
+50 H0=60
+55 R=R0+H0
+60 A=-3.425
+65 R1=0
+70 A1=8.84361E-04
+75 R3=0
+80 A3=0
+85 M1=7.45
+90 M0=M1
+95 B=750
+100 T1=0
+105 F=0
+110 P=0
+115 N=1
+120 M2=0
+125 S=0
+130 C=0
+135 IF Z$="YES" THEN 1150
+140 PRINT
+145 PRINT "LUNAR LANDING SIMULATION"
+150 PRINT
+155 PRINT "HAVE YOU FLOWN AN APOLLO/LEM MISSION BEFORE";
+160 PRINT " (YES OR NO)";
+165 INPUT Q$
+170 IF Q$="YES" THEN 190
+175 IF Q$="NO" THEN 205
+180 PRINT "JUST ANSWER THE QUESTION, PLEASE, ";
+185 GOTO 160
+190 PRINT
+195 PRINT "INPUT MEASUREMENT OPTION NUMBER";
+200 GOTO 225
+205 PRINT
+210 PRINT "WHICH SYSTEM OF MEASUREMENT DO YOU PREFER?"
+215 PRINT " 1=METRIC     0=ENGLISH"
+220 PRINT "ENTER THE APPROPRIATE NUMBER";
+225 INPUT K
+230 PRINT
+235 IF K=0 THEN 280
+240 IF K=1 THEN 250
+245 GOTO 220
+250 Z=1852.8
+255 M$="METERS"
+260 G3=3.6
+265 N$=" KILOMETERS"
+270 G5=1000
+275 GOTO 305
+280 Z=6080
+285 M$="FEET"
+290 G3=.592
+295 N$="N.MILES"
+300 G5=Z
+305 IF B1=3 THEN 670
+310 IF Q$="YES" THEN 485
+315 PRINT
+320 PRINT "  YOU ARE ON A LUNAR LANDING MISSION.  AS THE PILOT OF"
+325 PRINT "THE LUNAR EXCURSION MODULE, YOU WILL BE EXPECTED TO"
+330 PRINT "GIVE CERTAIN COMMANDS TO THE MODULE NAVIGATION SYSTEM."
+335 PRINT "THE ON-BOARD COMPUTER WILL GIVE A RUNNING ACCOUNT"
+340 PRINT "OF INFORMATION NEEDED TO NAVIGATE THE SHIP."
+345 PRINT
+350 PRINT
+355 PRINT "THE ATTITUDE ANGLE CALLED FOR IS DESCRIBED AS FOLLOWS."
+360 PRINT "+ OR -180 DEGREES IS DIRECTLY AWAY FROM THE MOON"
+365 PRINT "-90 DEGREES IS ON A TANGENT IN THE DIRECTION OF ORBIT"
+370 PRINT "+90 DEGREES IS ON A TANGENT FROM THE DIRECTION OF ORBIT"
+375 PRINT "0 (ZERO) DEGREES IS DIRECTLY TOWARD THE MOON"
+380 PRINT
+385 PRINT TAB(30);"-180|+180"
+390 PRINT TAB(34);"^"
+395 PRINT TAB(27);"-90 < -+- > +90"
+400 PRINT TAB(34);"!"
+405 PRINT TAB(34);"0"
+410 PRINT TAB(21);"<<<< DIRECTION OF ORBIT <<<<"
+415 PRINT
+420 PRINT TAB(20);"------ SURFACE OF MOON ------"
+425 PRINT
+430 PRINT
+435 PRINT "ALL ANGLES BETWEEN -180 AND +180 DEGREES ARE ACCEPTED."
+440 PRINT
+445 PRINT "1 FUEL UNIT = 1 SEC. AT MAX THRUST"
+450 PRINT "ANY DISCREPANCIES ARE ACCOUNTED FOR IN THE USE OF FUEL"
+455 PRINT "FOR AN ATTITUDE CHANGE."
+460 PRINT "AVAILABLE ENGINE POWER: 0 (ZERO) AND ANY VALUE BETWEEN"
+465 PRINT "10 AND 100 PERCENT."
+470 PRINT
+475 PRINT"NEGATIVE THRUST OR TIME IS PROHIBITED."
+480 PRINT
+485 PRINT
+490 PRINT "INPUT: TIME INTERVAL IN SECONDS ------ (T)"
+495 PRINT "       PERCENTAGE OF THRUST ---------- (P)"
+500 PRINT "       ATTITUDE ANGLE IN DEGREES ----- (A)"
+505 PRINT
+510 IF Q$="YES" THEN 535
+515 PRINT "FOR EXAMPLE:"
+520 PRINT "T,P,A? 10,65,-60"
+525 PRINT "TO ABORT THE MISSION AT ANY TIME, ENTER 0,0,0"
+530 PRINT
+535 PRINT "OUTPUT: TOTAL TIME IN ELAPSED SECONDS"
+540 PRINT "        HEIGHT IN ";M$
+545 PRINT "        DISTANCE FROM LANDING SITE IN ";M$
+550 PRINT "        VERTICAL VELOCITY IN ";M$;"/SECOND"
+555 PRINT "        HORIZONTAL VELOCITY IN ";M$;"/SECOND"
+560 PRINT "        FUEL UNITS REMAINING"
+565 PRINT
+570 GOTO 670
+575 PRINT
+580 PRINT "T,P,A";
+585 INPUT T1,F,P
+590 F=F/100
+595 IF T1<0 THEN 905
+600 IF T1=0 THEN 1090
+605 IF ABS(F-.05)>1 THEN 945
+610 IF ABS(F-.05)<.05 THEN 945
+615 IF ABS(P)>180 THEN 925
+620 N=20
+625 IF T1<400 THEN 635
+630 N=T1/20
+635 T1=T1/N
+640 P=P*3.14159/180
+645 S=SIN(P)
+650 C=COS(P)
+655 M2=M0*T1*F/B
+660 R3=-.5*R0*((V0/R)^2)+R*A1*A1
+665 A3=-2*R1*A1/R
+670 FOR I=1 TO N
+675 IF M1=0 THEN 715
+680 M1=M1-M2
+685 IF M1>0 THEN 725
+690 F=F*(1+M1/M2)
+695 M2=M1+M2
+700 PRINT "YOU ARE OUT OF FUEL."
+705 M1=0
+710 GOTO 725
+715 F=0
+720 M2=0
+725 M=M-.5*M2
+730 R4=R3
+735 R3=-.5*R0*((V0/R)^2)+R*A1*A1
+740 R2=(3*R3-R4)/2+.00526*F1*F*C/M
+745 A4=A3
+750 A3=-2*R1*A1/R
+755 A2=(3*A3-A4)/2+.0056*F1*F*S/(M*R)
+760 X=R1*T1+.5*R2*T1*T1
+765 R=R+X
+770 H0=H0+X
+775 R1=R1+R2*T1
+780 A=A+A1*T1+.5*A2*T1*T1
+785 A1=A1+A2*T1
+790 M=M-.5*M2
+795 T=T+T1
+800 IF H0<3.287828E-04 THEN 810
+805 NEXT I
+810 H=H0*Z
+815 H1=R1*Z
+820 D=R0*A*Z
+825 D1=R*A1*Z
+830 T2=M1*B/M0
+835 PRINT " ";T;TAB(10);H;TAB(23);D;
+840 PRINT TAB(37);H1;TAB(49);D1;TAB(60);T2
+845 IF H0<3.287828E-04 THEN 880
+850 IF R0*A>164.474 THEN 1050
+855 IF M1>0 THEN 580
+860 T1=20
+865 F=0
+870 P=0
+875 GOTO 620
+880 IF R1<-8.21957E-04 THEN 1020
+885 IF ABS(R*A1)>4.93174E-04 THEN 1020
+890 IF H0<-3.287828E-04 THEN 1020
+895 IF ABS(D)>10*Z THEN 1065
+900 GOTO 995
+905 PRINT
+910 PRINT "THIS SPACECRAFT IS NOT ABLE TO VIOLATE THE SPACE-";
+915 PRINT "TIME CONTINUUM."
+920 GOTO 575
+925 PRINT
+930 PRINT "IF YOU WANT TO SPIN AROUND, GO OUTSIDE THE MODULE"
+935 PRINT "FOR AN E.V.A."
+940 GOTO 575
+945 PRINT
+950 PRINT "IMPOSSIBLE THRUST VALUE ";
+955 IF F<0 THEN 985
+960 IF F-.05<.05 THEN 975
+965 PRINT "TOO LARGE"
+970 GOTO 575
+975 PRINT "TOO SMALL"
+980 GOTO 575
+985 PRINT "NEGATIVE"
+990 GOTO 575
+995 PRINT
+1000 PRINT "TRANQUILITY BASE HERE -- THE EAGLE HAS LANDED."
+1005 PRINT "CONGRATULATIONS -- THERE WAS NO SPACECRAFT DAMAGE."
+1010 PRINT "YOU MAY NOW PROCEED WITH SURFACE EXPLORATION."
+1015 GOTO 1100
+1020 PRINT
+1025 PRINT "CRASH !!!!!!!!!!!!!!!!"
+1030 PRINT "YOUR IMPACT CREATED A CRATER";ABS(H);M$;" DEEP."
+1035 X1=SQR(D1*D1+H1*H1)*G3
+1040 PRINT "AT CONTACT YOU WERE TRAVELING";X1;N$;"/HR"
+1045 GOTO 1100
+1050 PRINT
+1055 PRINT "YOU HAVE BEEN LOST IN SPACE WITH NO HOPE OF RECOVERY."
+1060 GOTO 1100
+1065 PRINT "YOU ARE DOWN SAFELY - "
+1075 PRINT
+1080 PRINT "BUT MISSED THE LANDING SITE BY";ABS(D/G5);N$;"."
+1085 GOTO 1100
+1090 PRINT
+1095 PRINT "MISSION ABENDED"
+1100 PRINT 
+1105 PRINT "DO YOU WANT TO TRY IT AGAIN (YES/NO)?"
+1110 INPUT Z$
+1115 IF Z$="YES" THEN 20
+1120 IF Z$="NO" THEN 1130
+1125 GOTO 1105
+1130 PRINT
+1135 PRINT "TOO BAD, THE SPACE PROGRAM HATES TO LOSE EXPERIENCED"
+1140 PRINT "ASTRONAUTS."
+1145 STOP
+1150 PRINT
+1155 PRINT "OK, DO YOU WANT THE COMPLETE INSTRUCTIONS OR THE INPUT -"
+1160 PRINT "OUTPUT STATEMENTS?"
+1165 PRINT "1=COMPLETE INSTRUCTIONS"
+1170 PRINT "2=INPUT-OUTPUT STATEMENTS"
+1175 PRINT "3=NEITHER"
+1180 INPUT B1
+1185 Q$="NO"
+1190 IF B1=1 THEN 205
+1195 Q$="YES"
+1200 IF B1=2 THEN 190
+1205 IF B1=3 THEN 190
+1210 GOTO 1165
+1215 END

data/test/integration/tests/basic_computer_games/lem.input

@@ -0,0 +1,4 @@
+NO
+0
+10,65,-60
+20,50,0