basic101 0.1.0

data/test/integration/tests/basic_computer_games/name.output

@@ -0,0 +1,22 @@
+                                  NAME
+               CREATIVE COMPUTING  MORRISTOWN, NEW JERSEY
+
+
+
+HELLO.
+MY NAME IS CREATIVE COMPUTER.
+WHAT'S YOUR NAME (FIRST AND LAST? FRED FLINSTONE
+
+THANK YOU, ENOTSNILF DERF.
+OOPS!  I GUESS I GOT IT BACKWARDS.  A SMART
+COMPUTER LIKE ME SHOULDN'T MAKE A MISTAKE LIKE THAT!
+
+BUT I JUST NOTICED YOUR LETTERS ARE OUT OF ORDER.
+LET'S PUT THEM IN ORDER LIKE THIS:  DEEFFILNNORST
+
+DON'T YOU LIKE THAT BETTER? YES
+
+I KNEW YOU'D AGREE!!
+
+I REALLY ENJOYED MEETING YOU FRED FLINSTONE.
+HAVE A NICE DAY!

data/test/integration/tests/basic_computer_games/nicoma.bas

@@ -0,0 +1,34 @@
+2 PRINT TAB(33);"NICOMA"
+4 PRINT TAB(15);"CREATIVE COMPUTING  MORRISTOWN, NEW JERSEY"
+6 PRINT: PRINT: PRINT
+10 PRINT "BOOMERANG PUZZLE FROM ARITHMETICA OF NICOMACHUS -- A.D. 90!"
+20 PRINT
+30 PRINT "PLEASE THINK OF A NUMBER BETWEEN 1 AND 100."
+40 PRINT "YOUR NUMBER DIVIDED BY 3 HAS A REMAINDER OF";
+45 INPUT A
+50 PRINT "YOUR NUMBER DIVIDED BY 5 HAS A REMAINDER OF";
+55 INPUT B
+60 PRINT "YOUR NUMBER DIVIDED BY 7 HAS A REMAINDER OF";
+65 INPUT C
+70 PRINT
+80 PRINT "LET ME THINK A MOMENT..."
+85 PRINT
+90 FOR I=1 TO 1500: NEXT I
+100 D=70*A+21*B+15*C
+110 IF D<=105 THEN 140
+120 D=D-105
+130 GOTO 110
+140 PRINT "YOUR NUMBER WAS";D;", RIGHT";
+160 INPUT A$
+165 PRINT
+170 IF A$="YES" THEN 220
+180 IF A$="NO" THEN 240
+190 PRINT "EH?  I DON'T UNDERSTAND '";A$;"'  TRY 'YES' OR 'NO'."
+200 GOTO 160
+220 PRINT "HOW ABOUT THAT!!"
+230 GOTO 250
+240 PRINT "I FEEL YOUR ARITHMETIC IS IN ERROR."
+250 PRINT
+260 PRINT "LET'S TRY ANOTHER."
+270 GOTO 20
+999 END

data/test/integration/tests/basic_computer_games/nicoma.input

@@ -0,0 +1,8 @@
+2
+0
+1
+YES
+1
+1
+1
+NO

data/test/integration/tests/basic_computer_games/nicoma.output

@@ -0,0 +1,36 @@
+                                 NICOMA
+               CREATIVE COMPUTING  MORRISTOWN, NEW JERSEY
+
+
+
+BOOMERANG PUZZLE FROM ARITHMETICA OF NICOMACHUS -- A.D. 90!
+
+PLEASE THINK OF A NUMBER BETWEEN 1 AND 100.
+YOUR NUMBER DIVIDED BY 3 HAS A REMAINDER OF? 2
+YOUR NUMBER DIVIDED BY 5 HAS A REMAINDER OF? 0
+YOUR NUMBER DIVIDED BY 7 HAS A REMAINDER OF? 1
+
+LET ME THINK A MOMENT...
+
+YOUR NUMBER WAS 50 , RIGHT? YES
+
+HOW ABOUT THAT!!
+
+LET'S TRY ANOTHER.
+
+PLEASE THINK OF A NUMBER BETWEEN 1 AND 100.
+YOUR NUMBER DIVIDED BY 3 HAS A REMAINDER OF? 1
+YOUR NUMBER DIVIDED BY 5 HAS A REMAINDER OF? 1
+YOUR NUMBER DIVIDED BY 7 HAS A REMAINDER OF? 1
+
+LET ME THINK A MOMENT...
+
+YOUR NUMBER WAS 1 , RIGHT? NO
+
+I FEEL YOUR ARITHMETIC IS IN ERROR.
+
+LET'S TRY ANOTHER.
+
+PLEASE THINK OF A NUMBER BETWEEN 1 AND 100.
+YOUR NUMBER DIVIDED BY 3 HAS A REMAINDER OF? 
+Error on line 45: No more input

data/test/integration/tests/basic_computer_games/nim.bas

@@ -0,0 +1,156 @@
+100 PRINT TAB(33);"NIM"
+110 PRINT TAB(15);"CREATIVE COMPUTING  MORRISTOWN, NEW JERSEY"
+120 PRINT:PRINT:PRINT
+210 DIM A(100),B(100,10),D(2)
+220 PRINT "THIS IS THE GAME OF NIM."
+230 PRINT "DO YOU WANT INSTRUCTIONS";
+240 INPUT Z$
+250 IF Z$="NO" THEN 440
+260 IF Z$="no" THEN 440
+270 IF Z$="YES" THEN 310
+280 IF Z$="yes" THEN 310
+290 PRINT "PLEASE ANSWER YES OR NO"
+300 GOTO 240
+310 PRINT "THE GAME IS PLAYED WITH A NUMBER OF PILES OF OBJECTS."
+320 PRINT "ANY NUMBER OF OBJECTS ARE REMOVED FROM ONE PILE BY YOU AND"
+330 PRINT "THE MACHINE ALTERNATELY.  ON YOUR TURN, YOU MAY TAKE"
+340 PRINT "ALL THE OBJECTS THAT REMAIN IN ANY PILE, BUT YOU MUST"
+350 PRINT "TAKE AT LEAST ONE OBJECT, AND YOU MAY TAKE OBJECTS FROM"
+360 PRINT "ONLY ONE PILE ON A SINGLE TURN.  YOU MUST SPECIFY WHETHER"
+370 PRINT "WINNING IS DEFINED AS TAKING OR NOT TAKING THE LAST OBJECT,"
+380 PRINT "THE NUMBER OF PILES IN THE GAME, AND HOW MANY OBJECTS ARE"
+390 PRINT "ORIGINALLY IN EACH PILE.  EACH PILE MAY CONTAIN A"
+400 PRINT "DIFFERENT NUMBER OF OBJECTS."
+410 PRINT "THE MACHINE WILL SHOW ITS MOVE BY LISTING EACH PILE AND THE"
+420 PRINT "NUMBER OF OBJECTS REMAINING IN THE PILES AFTER  EACH OF ITS"
+430 PRINT "MOVES."
+440 PRINT
+450 PRINT "ENTER WIN OPTION - 1 TO TAKE LAST, 2 TO AVOID LAST";
+460 INPUT W
+470 IF W=1 THEN 490
+480 IF W<>2 THEN 450
+490 PRINT "ENTER NUMBER OF PILES";
+500 INPUT N
+510 IF N>100 THEN 490
+520 IF N<1 THEN 490
+530 IF N<>INT(N) THEN 490
+540 PRINT "ENTER PILE SIZES"
+550 FOR I=1 TO N
+560 PRINT I;
+570 INPUT A(I)
+580 IF A(I)>2000 THEN 560
+590 IF A(I)<1 THEN 560
+600 IF A(I)<>INT(A(I)) THEN 560
+610 NEXT I
+620 PRINT "DO YOU WANT TO MOVE FIRST";
+630 INPUT Q9$
+640 IF Q9$="YES" THEN 1450
+650 IF Q9$="yes" THEN 1450
+660 IF Q9$="NO" THEN 700
+670 IF Q9$="no" THEN 700
+680 PRINT "PLEASE ANSWER YES OR NO."
+690 GOTO 630
+700 IF W=1 THEN 940
+710 LET C=0
+720 FOR I=1 TO N
+730 IF A(I)=0 THEN 770
+740 LET C=C+1
+750 IF C=3 THEN 840
+760 LET D(C)=I
+770 NEXT I
+780 IF C=2 THEN 920
+790 IF A(D(1))>1 THEN 820
+800 PRINT "MACHINE LOSES"
+810 GOTO 1640
+820 PRINT "MACHINE WINS"
+830 GOTO 1640
+840 LET C=0
+850 FOR I=1 TO N
+860 IF A(I)>1 THEN 940
+870 IF A(I)=0 THEN 890
+880 LET C=C+1
+890 NEXT I
+900 IF C/2<>INT(C/2) THEN 800
+910 GOTO 940
+920 IF A(D(1))=1 THEN 820
+930 IF A(D(2))=1 THEN 820
+940 FOR I=1 TO N
+950 LET E=A(I)
+960 FOR J=0 TO 10
+970 LET F=E/2
+980 LET B(I,J)=2*(F-INT(F))
+990 LET E=INT(F)
+1000 NEXT J
+1010 NEXT I
+1020 FOR J=10 TO 0 STEP -1
+1030 LET C=0
+1040 LET H=0
+1050 FOR I=1 TO N
+1060 IF B(I,J)=0 THEN 1110
+1070 LET C=C+1
+1080 IF A(I)<=H THEN 1110
+1090 LET H=A(I)
+1100 LET G=I
+1110 NEXT I
+1120 IF C/2<>INT(C/2) THEN 1190
+1130 NEXT J
+1140 LET E=INT(N*RND(1)+1)
+1150 IF A(E)=0 THEN 1140
+1160 LET F=INT(A(E)*RND(1)+1)
+1170 LET A(E)=A(E)-F
+1180 GOTO 1380
+1190 LET A(G)=0
+1200 FOR J=0 TO 10
+1210 LET B(G,J)=0
+1220 LET C=0
+1230 FOR I=1 TO N
+1240 IF B(I,J)=0 THEN 1260
+1250 LET C=C+1
+1260 NEXT I
+1270 LET A(G)=A(G)+2*(C/2-INT(C/2))*2^J
+1280 NEXT J
+1290 IF W=1 THEN 1380
+1300 LET C=0
+1310 FOR I=1 TO N
+1320 IF A(I)>1 THEN 1380
+1330 IF A(I)=0 THEN 1350
+1340 LET C=C+1
+1350 NEXT I
+1360 IF C/2<>INT(C/2) THEN 1380
+1370 LET A(G)=1-A(G)
+1380 PRINT "PILE  SIZE"
+1390 FOR I=1 TO N
+1400 PRINT I;A(I)
+1410 NEXT I
+1420 IF W=2 THEN 1450
+1430 GOSUB 1570
+1440 IF Z=1 THEN 820
+1450 PRINT "YOUR MOVE - PILE, NUMBER TO BE REMOVED";
+1460 INPUT X,Y
+1470 IF X>N THEN 1450
+1480 IF X<1 THEN 1450
+1490 IF X<>INT(X) THEN 1450
+1500 IF Y>A(X) THEN 1450
+1510 IF Y<1 THEN 1450
+1520 IF Y<>INT(Y) THEN 1450
+1530 LET A(X)=A(X)-Y
+1540 GOSUB 1570
+1550 IF Z=1 THEN 800
+1560 GOTO 700
+1570 LET Z=0
+1580 FOR I=1 TO N
+1590 IF A(I)=0 THEN 1610
+1600 RETURN
+1610 NEXT I
+1620 LET Z=1
+1630 RETURN
+1640 PRINT "do you want to play another game";
+1650 INPUT Q9$
+1660 IF Q9$="YES" GOTO 1720
+1670 IF Q9$="yes" GOTO 1720
+1680 IF Q9$="NO" GOTO 1730
+1690 IF Q9$="no" GOTO 1730
+1700 PRINT "PLEASE.  YES OR NO."
+1710 GOTO 1650 
+1720 GOTO 440
+1730 END

data/test/integration/tests/basic_computer_games/nim.input

@@ -0,0 +1,8 @@
+YES
+2
+2
+10
+6
+YES
+1,10
+NO

data/test/integration/tests/basic_computer_games/nim.output

@@ -0,0 +1,30 @@
+                                 NIM
+               CREATIVE COMPUTING  MORRISTOWN, NEW JERSEY
+
+
+
+THIS IS THE GAME OF NIM.
+DO YOU WANT INSTRUCTIONS? YES
+THE GAME IS PLAYED WITH A NUMBER OF PILES OF OBJECTS.
+ANY NUMBER OF OBJECTS ARE REMOVED FROM ONE PILE BY YOU AND
+THE MACHINE ALTERNATELY.  ON YOUR TURN, YOU MAY TAKE
+ALL THE OBJECTS THAT REMAIN IN ANY PILE, BUT YOU MUST
+TAKE AT LEAST ONE OBJECT, AND YOU MAY TAKE OBJECTS FROM
+ONLY ONE PILE ON A SINGLE TURN.  YOU MUST SPECIFY WHETHER
+WINNING IS DEFINED AS TAKING OR NOT TAKING THE LAST OBJECT,
+THE NUMBER OF PILES IN THE GAME, AND HOW MANY OBJECTS ARE
+ORIGINALLY IN EACH PILE.  EACH PILE MAY CONTAIN A
+DIFFERENT NUMBER OF OBJECTS.
+THE MACHINE WILL SHOW ITS MOVE BY LISTING EACH PILE AND THE
+NUMBER OF OBJECTS REMAINING IN THE PILES AFTER  EACH OF ITS
+MOVES.
+
+ENTER WIN OPTION - 1 TO TAKE LAST, 2 TO AVOID LAST? 2
+ENTER NUMBER OF PILES? 2
+ENTER PILE SIZES
+ 1 ? 10
+ 2 ? 6
+DO YOU WANT TO MOVE FIRST? YES
+YOUR MOVE - PILE, NUMBER TO BE REMOVED? 1,10
+MACHINE WINS
+do you want to play another game? NO

data/test/integration/tests/basic_computer_games/number.bas

@@ -0,0 +1,37 @@
+1 PRINT TAB(33);"NUMBER"
+2 PRINT TAB(15);"CREATIVE COMPUTING  MORRISTOWN, NEW JERSEY"
+3 PRINT:PRINT:PRINT
+4 PRINT "YOU HAVE 100 POINTS.  BY GUESSING NUMBERS FROM 1 TO 5, YOU"
+5 PRINT "CAN GAIN OR LOSE POINTS DEPENDING UPON HOW CLOSE YOU GET TO"
+6 PRINT "A RANDOM NUMBER SELECTED BY THE COMPUTER.": PRINT
+7 PRINT "YOU OCCASIONALLY WILL GET A JACKPOT WHICH WILL DOUBLE(!)"
+8 PRINT "YOUR POINT COUNT.  YOU WIN WHEN YOU GET 500 POINTS."
+9 PRINT: P=100
+10 DEF FNR(X)=INT(5*RND(1)+1)
+12 INPUT "GUESS A NUMBER FROM 1 TO 5";G
+15 R=FNR(1)
+16 S=FNR(1)
+17 T=FNR(1)
+18 U=FNR(1)
+19 V=FNR(1)
+20 IF G=R THEN 30
+21 IF G=S THEN 40
+22 IF G=T THEN 50
+23 IF G=U THEN 60
+24 IF G=V THEN 70
+25 IF G>5 THEN 12
+30 P=P-5
+35 GOTO 80
+40 P=P+5
+45 GOTO 80
+50 P=P+P
+53 PRINT "YOU HIT THE JACKPOT!!!"
+55 GOTO 80
+60 P=P+1
+65 GOTO 80
+70 P=P-(P*.5)
+80 IF P>500 THEN 90
+82 PRINT "YOU HAVE";P;"POINTS.":PRINT
+85 GOTO 12
+90 PRINT "!!!!YOU WIN!!!! WITH ";P;"POINTS."
+99 END

data/test/integration/tests/basic_computer_games/number.input

@@ -0,0 +1,19 @@
+3
+2
+1
+4
+5
+3
+3
+3
+3
+3
+3
+3
+3
+3
+3
+3
+3
+2
+1

data/test/integration/tests/basic_computer_games/number.output

@@ -0,0 +1,73 @@
+                                 NUMBER
+               CREATIVE COMPUTING  MORRISTOWN, NEW JERSEY
+
+
+
+YOU HAVE 100 POINTS.  BY GUESSING NUMBERS FROM 1 TO 5, YOU
+CAN GAIN OR LOSE POINTS DEPENDING UPON HOW CLOSE YOU GET TO
+A RANDOM NUMBER SELECTED BY THE COMPUTER.
+
+YOU OCCASIONALLY WILL GET A JACKPOT WHICH WILL DOUBLE(!)
+YOUR POINT COUNT.  YOU WIN WHEN YOU GET 500 POINTS.
+
+GUESS A NUMBER FROM 1 TO 5? 3
+YOU HAVE 95 POINTS.
+
+GUESS A NUMBER FROM 1 TO 5? 2
+YOU HAVE 47.5 POINTS.
+
+GUESS A NUMBER FROM 1 TO 5? 1
+YOU HAVE 23.75 POINTS.
+
+GUESS A NUMBER FROM 1 TO 5? 4
+YOU HAVE 24.75 POINTS.
+
+GUESS A NUMBER FROM 1 TO 5? 5
+YOU HAVE 19.75 POINTS.
+
+GUESS A NUMBER FROM 1 TO 5? 3
+YOU HAVE 20.75 POINTS.
+
+GUESS A NUMBER FROM 1 TO 5? 3
+YOU HIT THE JACKPOT!!!
+YOU HAVE 41.5 POINTS.
+
+GUESS A NUMBER FROM 1 TO 5? 3
+YOU HAVE 36.5 POINTS.
+
+GUESS A NUMBER FROM 1 TO 5? 3
+YOU HAVE 41.5 POINTS.
+
+GUESS A NUMBER FROM 1 TO 5? 3
+YOU HAVE 36.5 POINTS.
+
+GUESS A NUMBER FROM 1 TO 5? 3
+YOU HAVE 31.5 POINTS.
+
+GUESS A NUMBER FROM 1 TO 5? 3
+YOU HAVE 32.5 POINTS.
+
+GUESS A NUMBER FROM 1 TO 5? 3
+YOU HAVE 27.5 POINTS.
+
+GUESS A NUMBER FROM 1 TO 5? 3
+YOU HAVE 22.5 POINTS.
+
+GUESS A NUMBER FROM 1 TO 5? 3
+YOU HAVE 27.5 POINTS.
+
+GUESS A NUMBER FROM 1 TO 5? 3
+YOU HAVE 22.5 POINTS.
+
+GUESS A NUMBER FROM 1 TO 5? 3
+YOU HAVE 27.5 POINTS.
+
+GUESS A NUMBER FROM 1 TO 5? 2
+YOU HAVE 22.5 POINTS.
+
+GUESS A NUMBER FROM 1 TO 5? 1
+YOU HIT THE JACKPOT!!!
+YOU HAVE 45 POINTS.
+
+GUESS A NUMBER FROM 1 TO 5? 
+Error on line 12: No more input

data/test/integration/tests/basic_computer_games/onecheck.bas

@@ -0,0 +1,86 @@
+2 PRINT TAB(30);"ONE CHECK"
+4 PRINT TAB(15);"CREATIVE COMPUTING  MORRISTOWN, NEW JERSEY"
+6 PRINT: PRINT: PRINT
+8 DIM A(64)
+10 PRINT "SOLITAIRE CHECKER PUZZLE BY DAVID AHL"
+15 PRINT
+20 PRINT "48 CHECKERS ARE PLACED ON THE 2 OUTSIDE SPACES OF A"
+25 PRINT "STANDARD 64-SQUARE CHECKERBOARD.  THE OBJECT IS TO"
+30 PRINT "REMOVE AS MANY CHECKERS AS POSSIBLE BY DIAGONAL JUMPS"
+35 PRINT "(AS IN STANDARD CHECKERS).  USE THE NUMBERED BOARD TO"
+40 PRINT "INDICATE THE SQUARE YOU WISH TO JUMP FROM AND TO.  ON"
+45 PRINT "THE BOARD PRINTED OUT ON EACH TURN '1' INDICATES A"
+50 PRINT "CHECKER AND '0' AN EMPTY SQUARE.  WHEN YOU HAVE NO"
+55 PRINT "POSSIBLE JUMPS REMAINING, INPUT A '0' IN RESPONSE TO"
+60 PRINT "QUESTION 'JUMP FROM ?'"
+62 PRINT
+63 PRINT "HERE IS THE NUMERICAL BOARD:"
+66 PRINT
+70 FOR J=1 TO 57 STEP 8
+74 PRINT J;TAB(4);J+1;TAB(8);J+2;TAB(12);J+3;TAB(16);J+4;TAB(20);J+5;
+75 PRINT TAB(24);J+6;TAB(28);J+7
+76 NEXT J
+77 PRINT
+78 PRINT "AND HERE IS THE OPENING POSITION OF THE CHECKERS."
+79 PRINT
+80 FOR J=1 TO 64
+82 A(J)=1
+84 NEXT J
+86 FOR J=19 TO 43 STEP 8
+88 FOR I=J TO J+3
+90 A(I)=0
+92 NEXT I
+94 NEXT J
+96 M=0
+98 GOTO 340
+100 INPUT "JUMP FROM";F
+105 IF F=0 THEN 500
+110 INPUT "TO";T
+112 PRINT
+118 REM *** CHECK LEGALITY OF MOVE
+120 F1=INT((F-1)/8)
+130 F2=F-8*F1
+140 T1=INT((T-1)/8)
+150 T2=T-8*T1
+160 IF F1>7 THEN 230
+170 IF T1>7 THEN 230
+180 IF F2>8 THEN 230
+190 IF T2>8 THEN 230
+200 IF ABS(F1-T1)<>2 THEN 230
+210 IF ABS(F2-T2)<>2 THEN 230
+212 IF A((T+F)/2)=0 THEN 230
+215 IF A(F)=0 THEN 230
+220 IF A(T)=1 THEN 230
+225 GOTO 250
+230 PRINT "ILLEGAL MOVE.  TRY AGAIN..."
+240 GOTO 100
+245 REM *** UPDATE BOARD
+250 A(T)=1
+260 A(F)=0
+270 A((T+F)/2)=0
+290 M=M+1
+310 REM *** PRINT BOARD
+340 FOR J=1 TO 57 STEP 8
+350 FOR I=J TO J+7
+360 PRINT A(I);
+370 NEXT I
+380 PRINT
+390 NEXT J
+400 PRINT
+410 GOTO 100
+490 REM *** END GAME SUMMARY
+500 S=0
+510 FOR I=1 TO 64
+520 S=S+A(I)
+530 NEXT I
+540 PRINT:PRINT "YOU MADE";M;"JUMPS AND HAD";S;"PIECES"
+550 PRINT "REMAINING ON THE BOARD."
+560 PRINT
+562 INPUT "TRY AGAIN";A$
+570 IF A$="YES" THEN 70
+575 IF A$="NO" THEN 600
+580 PRINT "PLEASE ANSWER 'YES' OR 'NO'."
+590 GOTO 562
+600 PRINT
+610 PRINT "O.K.  HOPE YOU HAD FUN!!"
+999 END

data/test/integration/tests/basic_computer_games/onecheck.input

@@ -0,0 +1,6 @@
+1
+19
+2
+20
+57
+43

data/test/integration/tests/basic_computer_games/onecheck.output

@@ -0,0 +1,77 @@
+                              ONE CHECK
+               CREATIVE COMPUTING  MORRISTOWN, NEW JERSEY
+
+
+
+SOLITAIRE CHECKER PUZZLE BY DAVID AHL
+
+48 CHECKERS ARE PLACED ON THE 2 OUTSIDE SPACES OF A
+STANDARD 64-SQUARE CHECKERBOARD.  THE OBJECT IS TO
+REMOVE AS MANY CHECKERS AS POSSIBLE BY DIAGONAL JUMPS
+(AS IN STANDARD CHECKERS).  USE THE NUMBERED BOARD TO
+INDICATE THE SQUARE YOU WISH TO JUMP FROM AND TO.  ON
+THE BOARD PRINTED OUT ON EACH TURN '1' INDICATES A
+CHECKER AND '0' AN EMPTY SQUARE.  WHEN YOU HAVE NO
+POSSIBLE JUMPS REMAINING, INPUT A '0' IN RESPONSE TO
+QUESTION 'JUMP FROM ?'
+
+HERE IS THE NUMERICAL BOARD:
+
+ 1   2   3   4   5   6   7   8 
+ 9   10  11  12  13  14  15  16 
+ 17  18  19  20  21  22  23  24 
+ 25  26  27  28  29  30  31  32 
+ 33  34  35  36  37  38  39  40 
+ 41  42  43  44  45  46  47  48 
+ 49  50  51  52  53  54  55  56 
+ 57  58  59  60  61  62  63  64 
+
+AND HERE IS THE OPENING POSITION OF THE CHECKERS.
+
+ 1  1  1  1  1  1  1  1 
+ 1  1  1  1  1  1  1  1 
+ 1  1  0  0  0  0  1  1 
+ 1  1  0  0  0  0  1  1 
+ 1  1  0  0  0  0  1  1 
+ 1  1  0  0  0  0  1  1 
+ 1  1  1  1  1  1  1  1 
+ 1  1  1  1  1  1  1  1 
+
+JUMP FROM? 1
+TO? 19
+
+ 0  1  1  1  1  1  1  1 
+ 1  0  1  1  1  1  1  1 
+ 1  1  1  0  0  0  1  1 
+ 1  1  0  0  0  0  1  1 
+ 1  1  0  0  0  0  1  1 
+ 1  1  0  0  0  0  1  1 
+ 1  1  1  1  1  1  1  1 
+ 1  1  1  1  1  1  1  1 
+
+JUMP FROM? 2
+TO? 20
+
+ 0  0  1  1  1  1  1  1 
+ 1  0  0  1  1  1  1  1 
+ 1  1  1  1  0  0  1  1 
+ 1  1  0  0  0  0  1  1 
+ 1  1  0  0  0  0  1  1 
+ 1  1  0  0  0  0  1  1 
+ 1  1  1  1  1  1  1  1 
+ 1  1  1  1  1  1  1  1 
+
+JUMP FROM? 57
+TO? 43
+
+ 0  0  1  1  1  1  1  1 
+ 1  0  0  1  1  1  1  1 
+ 1  1  1  1  0  0  1  1 
+ 1  1  0  0  0  0  1  1 
+ 1  1  0  0  0  0  1  1 
+ 1  1  1  0  0  0  1  1 
+ 1  0  1  1  1  1  1  1 
+ 0  1  1  1  1  1  1  1 
+
+JUMP FROM? 
+Error on line 100: No more input

data/test/integration/tests/basic_computer_games/orbit.bas

@@ -0,0 +1,96 @@
+2 PRINT TAB(33);"ORBIT"
+4 PRINT TAB(15);"CREATIVE COMPUTING  MORRISTOWN, NEW JERSEY"
+6 PRINT:PRINT:PRINT
+10 PRINT "SOMEWHERE ABOVE YOUR PLANET IS A ROMULAN SHIP."
+15 PRINT
+20 PRINT "THE SHIP IS IN A CONSTANT POLAR ORBIT.  ITS"
+25 PRINT "DISTANCE FROM THE CENTER OF YOUR PLANET IS FROM"
+30 PRINT "10,000 TO 30,000 MILES AND AT ITS PRESENT VELOCITY CAN"
+31 PRINT "CIRCLE YOUR PLANET ONCE EVERY 12 TO 36 HOURS."
+35 PRINT
+40 PRINT "UNFORTUNATELY, THEY ARE USING A CLOAKING DEVICE SO"
+45 PRINT "YOU ARE UNABLE TO SEE THEM, BUT WITH A SPECIAL"
+50 PRINT "INSTRUMENT YOU CAN TELL HOW NEAR THEIR SHIP YOUR"
+55 PRINT "PHOTON BOMB EXPLODED.  YOU HAVE SEVEN HOURS UNTIL THEY"
+60 PRINT "HAVE BUILT UP SUFFICIENT POWER IN ORDER TO ESCAPE"
+65 PRINT "YOUR PLANET'S GRAVITY."
+70 PRINT
+75 PRINT "YOUR PLANET HAS ENOUGH POWER TO FIRE ONE BOMB AN HOUR."
+80 PRINT
+85 PRINT "AT THE BEGINNING OF EACH HOUR YOU WILL BE ASKED TO GIVE AN"
+90 PRINT "ANGLE (BETWEEN 0 AND 360) AND A DISTANCE IN UNITS OF"
+95 PRINT "100 MILES (BETWEEN 100 AND 300), AFTER WHICH YOUR BOMB'S"
+100 PRINT "DISTANCE FROM THE ENEMY SHIP WILL BE GIVEN."
+105 PRINT
+110 PRINT "AN EXPLOSION WITHIN 5,000 MILES OF THE ROMULAN SHIP"
+111 PRINT "WILL DESTROY IT."
+114 PRINT
+115 PRINT "BELOW IS A DIAGRAM TO HELP YOU VISUALIZE YOUR PLIGHT."
+116 PRINT
+117 PRINT
+168 PRINT "                          90"
+170 PRINT "                    0000000000000"
+171 PRINT "                 0000000000000000000"
+172 PRINT "               000000           000000"
+173 PRINT "             00000                 00000"
+174 PRINT "            00000    XXXXXXXXXXX    00000"
+175 PRINT "           00000    XXXXXXXXXXXXX    00000"
+176 PRINT "          0000     XXXXXXXXXXXXXXX     0000"
+177 PRINT "         0000     XXXXXXXXXXXXXXXXX     0000"
+178 PRINT "        0000     XXXXXXXXXXXXXXXXXXX     0000"
+179 PRINT "180<== 00000     XXXXXXXXXXXXXXXXXXX     00000 ==>0"
+180 PRINT "        0000     XXXXXXXXXXXXXXXXXXX     0000"
+181 PRINT "         0000     XXXXXXXXXXXXXXXXX     0000"
+182 PRINT "          0000     XXXXXXXXXXXXXXX     0000"
+183 PRINT "           00000    XXXXXXXXXXXXX    00000"
+184 PRINT "            00000    XXXXXXXXXXX    00000"
+185 PRINT "             00000                 00000"
+186 PRINT "               000000           000000"
+187 PRINT "                 0000000000000000000"
+188 PRINT "                    0000000000000"
+190 PRINT "                         270"
+192 PRINT
+195 PRINT "X - YOUR PLANET"
+196 PRINT "O - THE ORBIT OF THE ROMULAN SHIP"
+197 PRINT
+198 PRINT "ON THE ABOVE DIAGRAM, THE ROMULAN SHIP IS CIRCLING"
+199 PRINT "COUNTERCLOCKWISE AROUND YOUR PLANET.  DON'T FORGET THAT"
+200 PRINT "WITHOUT SUFFICIENT POWER THE ROMULAN SHIP'S ALTITUDE"
+210 PRINT "AND ORBITAL RATE WILL REMAIN CONSTANT."
+220 PRINT 
+230 PRINT "GOOD LUCK.  THE FEDERATION IS COUNTING ON YOU."
+270 A=INT(360*RND(1))
+280 D=INT(200*RND(1)+200)
+290 R=INT(20*RND(1)+10)
+300 H=0
+310 IF H=7 THEN 490
+320 H=H+1
+325 PRINT
+326 PRINT
+330 PRINT "THIS IS HOUR";H;", AT WHAT ANGLE DO YOU WISH TO SEND"
+335 PRINT "YOUR PHOTON BOMB";
+340 INPUT A1
+350 PRINT "HOW FAR OUT DO YOU WISH TO DETONATE IT";
+360 INPUT D1
+365 PRINT
+366 PRINT
+370 A=A+R
+380 IF A<360 THEN 400
+390 A=A-360
+400 T=ABS(A-A1)
+410 IF T<180 THEN 430
+420 T=360-T
+430 C=SQR(D*D+D1*D1-2*D*D1*COS(T*3.14159/180))
+440 PRINT "YOUR PHOTON BOMB EXPLODED";C;"*10^2 MILES FROM THE"
+445 PRINT "ROMULAN SHIP."
+450 IF C<=50 THEN 470
+460 GOTO 310
+470 PRINT "YOU HAVE SUCCESFULLY COMPLETED YOUR MISSION."
+480 GOTO 500
+490 PRINT "YOU HAVE ALLOWED THE ROMULANS TO ESCAPE."
+500 PRINT "ANOTHER ROMULAN SHIP HAS GONE INTO ORBIT."
+510 PRINT "DO YOU WISH TO TRY TO DESTROY IT";
+520 INPUT C$
+530 IF C$="YES" THEN 270
+540 PRINT "GOOD BYE."
+999 END