basic101 0.1.0

data/test/integration/tests/basic_computer_games/digits.bas

@@ -0,0 +1,78 @@
+10 PRINT TAB(33);"DIGITS"
+20 PRINT TAB(15);"CREATIVE COMPUTING  MORRISTOWN, NEW JERSEY"
+30 PRINT:PRINT:PRINT
+210 PRINT "THIS IS A GAME OF GUESSING."
+220 PRINT "FOR INSTRUCTIONS, TYPE '1', ELSE TYPE '0'";
+230 INPUT E
+240 IF E=0 THEN 360
+250 PRINT
+260 PRINT "PLEASE TAKE A PIECE OF PAPER AND WRITE DOWN"
+270 PRINT "THE DIGITS '0', '1', OR '2' THIRTY TIMES AT RANDOM."
+280 PRINT "ARRANGE THEM IN THREE LINES OF TEN DIGITS EACH."
+290 PRINT "I WILL ASK FOR THEN TEN AT A TIME."
+300 PRINT "I WILL ALWAYS GUESS THEM FIRST AND THEN LOOK AT YOUR"
+310 PRINT "NEXT NUMBER TO SEE IF I WAS RIGHT. BY PURE LUCK,"
+320 PRINT "I OUGHT TO BE RIGHT TEN TIMES. BUT I HOPE TO DO BETTER"
+330 PRINT "THAN THAT *****"
+340 PRINT:PRINT
+360 READ A,B,C
+370 DATA 0,1,3
+380 DIM M(26,2),K(2,2),L(8,2)
+400 FOR I=0 TO 26: FOR J=0 TO 2: M(I,J)=1: NEXT J: NEXT I
+410 FOR I=0 TO 2: FOR J=0 TO 2: K(I,J)=9: NEXT J: NEXT I
+420 FOR I=0 TO 8: FOR J=0 TO 2: L(I,J)=3: NEXT J: NEXT I
+450 L(0,0)=2: L(4,1)=2: L(8,2)=2
+480 Z=26: Z1=8: Z2=2
+510 X=0
+520 FOR T=1 TO 3
+530 PRINT
+540 PRINT "TEN NUMBERS, PLEASE";
+550 INPUT N(1),N(2),N(3),N(4),N(5),N(6),N(7),N(8),N(9),N(10)
+560 FOR I=1 TO 10
+570 W=N(I)-1
+580 IF W=SGN(W) THEN 620
+590 PRINT "ONLY USE THE DIGITS '0', '1', OR '2'."
+600 PRINT "LET'S TRY AGAIN.":GOTO 530
+620 NEXT I
+630 PRINT: PRINT "MY GUESS","YOUR NO.","RESULT","NO. RIGHT":PRINT
+660 FOR U=1 TO 10
+670 N=N(U): S=0
+690 FOR J=0 TO 2
+700 S1=A*K(Z2,J)+B*L(Z1,J)+C*M(Z,J)
+710 IF S>S1 THEN 760
+720 IF S<S1 THEN 740
+730 IF RND(1)<.5 THEN 760
+740 S=S1: G=J
+760 NEXT J
+770 PRINT "  ";G,"   ";N(U),
+780 IF G=N(U) THEN 810
+790 PRINT " WRONG",X
+800 GOTO 880
+810 X=X+1
+820 PRINT " RIGHT",X
+830 M(Z,N)=M(Z,N)+1
+840 L(Z1,N)=L(Z1,N)+1
+850 K(Z2,N)=K(Z2,N)+1
+860 Z=Z-INT(Z/9)*9
+870 Z=3*Z+N(U)
+880 Z1=Z-INT(Z/9)*9
+890 Z2=N(U)
+900 NEXT U
+910 NEXT T
+920 PRINT
+930 IF X>10 THEN 980
+940 IF X<10 THEN 1010
+950 PRINT "I GUESSED EXACTLY 1/3 OF YOUR NUMBERS."
+960 PRINT "IT'S A TIE GAME."
+970 GOTO 1030
+980 PRINT "I GUESSED MORE THAN 1/3 OF YOUR NUMBERS."
+990 PRINT "I WIN.": FOR Q=1 TO 10: PRINT CHR$(7);: NEXT Q
+1000 GOTO 1030
+1010 PRINT "I GUESSED LESS THAN 1/3 OF YOUR NUMBERS."
+1020 PRINT "YOU BEAT ME.  CONGRATULATIONS *****"
+1030 PRINT
+1040 PRINT "DO YOU WANT TO TRY AGAIN (1 FOR YES, 0 FOR NO)";
+1060 INPUT X
+1070 IF X=1 THEN 400
+1080 PRINT:PRINT "THANKS FOR THE GAME."
+1090 END

data/test/integration/tests/basic_computer_games/digits.input

@@ -0,0 +1,5 @@
+1
+0,1,1,2,1,0,2,1,2,0
+1,0,2,0,2,0,1,0,2,0
+2,2,2,1,1,1,0,1,1,2
+0

data/test/integration/tests/basic_computer_games/digits.output

@@ -0,0 +1,70 @@
+                                 DIGITS
+               CREATIVE COMPUTING  MORRISTOWN, NEW JERSEY
+
+
+
+THIS IS A GAME OF GUESSING.
+FOR INSTRUCTIONS, TYPE '1', ELSE TYPE '0'? 1
+
+PLEASE TAKE A PIECE OF PAPER AND WRITE DOWN
+THE DIGITS '0', '1', OR '2' THIRTY TIMES AT RANDOM.
+ARRANGE THEM IN THREE LINES OF TEN DIGITS EACH.
+I WILL ASK FOR THEN TEN AT A TIME.
+I WILL ALWAYS GUESS THEM FIRST AND THEN LOOK AT YOUR
+NEXT NUMBER TO SEE IF I WAS RIGHT. BY PURE LUCK,
+I OUGHT TO BE RIGHT TEN TIMES. BUT I HOPE TO DO BETTER
+THAN THAT *****
+
+
+
+TEN NUMBERS, PLEASE? 0,1,1,2,1,0,2,1,2,0
+
+MY GUESS      YOUR NO.      RESULT        NO. RIGHT
+
+   1              0          WRONG         0 
+   1              1          RIGHT         1 
+   2              1          WRONG         1 
+   2              2          RIGHT         2 
+   2              1          WRONG         2 
+   1              0          WRONG         2 
+   2              2          RIGHT         3 
+   1              1          RIGHT         4 
+   2              2          RIGHT         5 
+   2              0          WRONG         5 
+
+TEN NUMBERS, PLEASE? 1,0,2,0,2,0,1,0,2,0
+
+MY GUESS      YOUR NO.      RESULT        NO. RIGHT
+
+   2              1          WRONG         5 
+   2              0          WRONG         5 
+   2              2          RIGHT         6 
+   1              0          WRONG         6 
+   1              2          WRONG         6 
+   1              0          WRONG         6 
+   1              1          RIGHT         7 
+   2              0          WRONG         7 
+   2              2          RIGHT         8 
+   2              0          WRONG         8 
+
+TEN NUMBERS, PLEASE? 2,2,2,1,1,1,0,1,1,2
+
+MY GUESS      YOUR NO.      RESULT        NO. RIGHT
+
+   2              2          RIGHT         9 
+   1              2          WRONG         9 
+   1              2          WRONG         9 
+   1              1          RIGHT         10 
+   2              1          WRONG         10 
+   2              1          WRONG         10 
+   2              0          WRONG         10 
+   2              1          WRONG         10 
+   2              1          WRONG         10 
+   2              2          RIGHT         11 
+
+I GUESSED MORE THAN 1/3 OF YOUR NUMBERS.
+I WIN.
+
+DO YOU WANT TO TRY AGAIN (1 FOR YES, 0 FOR NO)? 0
+
+THANKS FOR THE GAME.

data/test/integration/tests/basic_computer_games/evenwin1.bas

@@ -0,0 +1,128 @@
+1 PRINT TAB(31);"EVEN WINS"
+2 PRINT TAB(15);"CREATIVE COMPUTING  MORRISTOWN, NEW JERSEY"
+3 PRINT:PRINT
+4 Y1=0
+10 M1=0
+20 DIM M(20),Y(20)
+30 PRINT "     THIS IS A TWO PERSON GAME CALLED 'EVEN WINS.'"
+40 PRINT "TO PLAY THE GAME, THE PLAYERS NEED 27 MARBLES OR"
+50 PRINT "OTHER OBJECTS ON A TABLE."
+60 PRINT
+70 PRINT 
+80 PRINT "     THE 2 PLAYERS ALTERNATE TURNS, WITH EACH PLAYER"
+90 PRINT "REMOVING FROM 1 TO 4 MARBLES ON EACH MOVE.  THE GAME"
+100 PRINT "ENDS WHEN THERE ARE NO MARBLES LEFT, AND THE WINNER"
+110 PRINT "IS THE ONE WITH AN EVEN NUMBER OF MARBLES."
+120 PRINT
+130 PRINT
+140 PRINT "     THE ONLY RULES ARE THAT (1) YOU MUST ALTERNATE TURNS,"
+150 PRINT "(2) YOU MUST TAKE BETWEEN 1 AND 4 MARBLES EACH TURN,"
+160 PRINT "AND (3) YOU CANNOT SKIP A TURN."
+170 PRINT
+180 PRINT
+190 PRINT
+200 PRINT "     TYPE A '1' IF YOU WANT TO GO FIRST, AND TYPE"
+210 PRINT "A '0' IF YOU WANT ME TO GO FIRST."
+220 INPUT C
+225 PRINT
+230 IF C=0 THEN 250
+240 GOTO 1060
+250 T=27
+260 M=2
+270 PRINT:PRINT "TOTAL=";T:PRINT
+280 M1=M1+M
+290 T=T-M
+300 PRINT "I PICK UP";M;"MARBLES."
+310 IF T=0 THEN 880
+320 PRINT:PRINT "TOTAL=";T
+330 PRINT
+340 PRINT "     AND WHAT IS YOUR NEXT MOVE, MY TOTAL IS";M1
+350 INPUT Y
+360 PRINT
+370 IF Y<1 THEN 1160
+380 IF Y>4 THEN 1160
+390 IF Y<=T THEN 430
+400 PRINT "     YOU HAVE TRIED TO TAKE MORE MARBLES THAN THERE ARE"
+410 PRINT "LEFT.  TRY AGAIN."
+420 GOTO 350
+430 Y1=Y1+Y
+440 T=T-Y
+450 IF T=0 THEN 880
+460 PRINT "TOTAL=";T
+470 PRINT
+480 PRINT "YOUR TOTAL IS";Y1
+490 IF T<.5 THEN 880
+500 R=T-6*INT(T/6)
+510 IF INT(Y1/2)=Y1/2 THEN 700
+520 IF T<4.2 THEN 580
+530 IF R>3.4 THEN 620
+540 M=R+1
+550 M1=M1+M
+560 T=T-M
+570 GOTO 300
+580 M=T
+590 T=T-M
+600 GOTO 830
+610 REM     250 IS WHERE I WIN.
+620 IF R<4.7 THEN 660
+630 IF R>3.5 THEN 660
+640 M=1
+650 GOTO 670
+660 M=4
+670 T=T-M
+680 M1=M1+M
+690 GOTO 300
+700 REM     I AM READY TO ENCODE THE STRAT FOR WHEN OPP TOT IS EVEN
+710 IF R<1.5 THEN 1020
+720 IF R>5.3 THEN 1020
+730 M=R-1
+740 M1=M1+M
+750 T=T-M
+760 IF T<.2 THEN 790
+770 REM     IS # ZERO HERE
+780 GOTO 300
+790 REM     IS = ZERO HERE
+800 PRINT "I PICK UP";M;"MARBLES."
+810 PRINT
+820 GOTO 880
+830 REM    THIS IS WHERE I WIN
+840 PRINT "I PICK UP";M;"MARBLES."
+850 PRINT
+860 PRINT "TOTAL = 0"
+870 M1=M1+M
+880 PRINT "THAT IS ALL OF THE MARBLES."
+890 PRINT
+900 PRINT " MY TOTAL IS";M1;", YOUR TOTAL IS";Y1
+910 PRINT
+920 IF INT(M1/2)=M1/2 THEN 950
+930 PRINT "     YOU WON.  DO YOU WANT TO PLAY"
+940 GOTO 960
+950 PRINT "     I WON.  DO YOU WANT TO PLAY"
+960 PRINT "AGAIN?  TYPE 1 FOR YES AND 0 FOR NO."
+970 INPUT A1
+980 IF A1=0 THEN 1030
+990 M1=0
+1000 Y1=0
+1010 GOTO 200
+1020 GOTO 640
+1030 PRINT
+1040 PRINT "OK.  SEE YOU LATER."
+1050 GOTO 1230
+1060 T=27
+1070 PRINT
+1080 PRINT
+1090 PRINT
+1100 PRINT "TOTAL=";T
+1110 PRINT
+1120 PRINT
+1130 PRINT "WHAT IS YOUR FIRST MOVE";
+1140 INPUT Y
+1150 GOTO 360
+1160 PRINT
+1170 PRINT "THE NUMBER OF MARBLES YOU TAKE MUST BE A POSITIVE"
+1180 PRINT "INTEGER BETWEEN 1 AND 4."
+1190 PRINT
+1200 PRINT "     WHAT IS YOUR NEXT MOVE?"
+1210 PRINT
+1220 GOTO 350
+1230 END

data/test/integration/tests/basic_computer_games/evenwin1.input

@@ -0,0 +1,13 @@
+1
+3
+3
+1
+1
+2
+4
+4
+3
+2
+1
+NO
+0

data/test/integration/tests/basic_computer_games/evenwin1.output

@@ -0,0 +1,116 @@
+                               EVEN WINS
+               CREATIVE COMPUTING  MORRISTOWN, NEW JERSEY
+
+
+     THIS IS A TWO PERSON GAME CALLED 'EVEN WINS.'
+TO PLAY THE GAME, THE PLAYERS NEED 27 MARBLES OR
+OTHER OBJECTS ON A TABLE.
+
+
+     THE 2 PLAYERS ALTERNATE TURNS, WITH EACH PLAYER
+REMOVING FROM 1 TO 4 MARBLES ON EACH MOVE.  THE GAME
+ENDS WHEN THERE ARE NO MARBLES LEFT, AND THE WINNER
+IS THE ONE WITH AN EVEN NUMBER OF MARBLES.
+
+
+     THE ONLY RULES ARE THAT (1) YOU MUST ALTERNATE TURNS,
+(2) YOU MUST TAKE BETWEEN 1 AND 4 MARBLES EACH TURN,
+AND (3) YOU CANNOT SKIP A TURN.
+
+
+
+     TYPE A '1' IF YOU WANT TO GO FIRST, AND TYPE
+A '0' IF YOU WANT ME TO GO FIRST.
+? 1
+
+
+
+
+TOTAL= 27 
+
+
+WHAT IS YOUR FIRST MOVE? 3
+
+TOTAL= 24 
+
+YOUR TOTAL IS 3 
+I PICK UP 1 MARBLES.
+
+TOTAL= 23 
+
+     AND WHAT IS YOUR NEXT MOVE, MY TOTAL IS 1 
+? 3
+
+TOTAL= 20 
+
+YOUR TOTAL IS 6 
+I PICK UP 1 MARBLES.
+
+TOTAL= 19 
+
+     AND WHAT IS YOUR NEXT MOVE, MY TOTAL IS 2 
+? 1
+
+TOTAL= 18 
+
+YOUR TOTAL IS 7 
+I PICK UP 1 MARBLES.
+
+TOTAL= 17 
+
+     AND WHAT IS YOUR NEXT MOVE, MY TOTAL IS 3 
+? 1
+
+TOTAL= 16 
+
+YOUR TOTAL IS 8 
+I PICK UP 3 MARBLES.
+
+TOTAL= 13 
+
+     AND WHAT IS YOUR NEXT MOVE, MY TOTAL IS 6 
+? 2
+
+TOTAL= 11 
+
+YOUR TOTAL IS 10 
+I PICK UP 4 MARBLES.
+
+TOTAL= 7 
+
+     AND WHAT IS YOUR NEXT MOVE, MY TOTAL IS 10 
+? 4
+
+TOTAL= 3 
+
+YOUR TOTAL IS 14 
+I PICK UP 2 MARBLES.
+
+TOTAL= 1 
+
+     AND WHAT IS YOUR NEXT MOVE, MY TOTAL IS 12 
+? 4
+
+     YOU HAVE TRIED TO TAKE MORE MARBLES THAN THERE ARE
+LEFT.  TRY AGAIN.
+? 3
+
+     YOU HAVE TRIED TO TAKE MORE MARBLES THAN THERE ARE
+LEFT.  TRY AGAIN.
+? 2
+
+     YOU HAVE TRIED TO TAKE MORE MARBLES THAN THERE ARE
+LEFT.  TRY AGAIN.
+? 1
+
+THAT IS ALL OF THE MARBLES.
+
+ MY TOTAL IS 12 , YOUR TOTAL IS 15 
+
+     I WON.  DO YOU WANT TO PLAY
+AGAIN?  TYPE 1 FOR YES AND 0 FOR NO.
+? NO
+Not numeric: "NO", try again
+? 0
+
+OK.  SEE YOU LATER.

data/test/integration/tests/basic_computer_games/evenwin2.bas

@@ -0,0 +1,70 @@
+1 PRINT TAB(28);"GAME OF EVEN WINS"
+2 PRINT TAB(15);"CREATIVE COMPUTING  MORRISTOWN, NEW JERSEY"
+3 PRINT:PRINT
+4 INPUT "DO YOU WANT INSTRUCTIONS (YES OR NO)";A$:PRINT
+5 IF A$="NO" THEN 20
+6 PRINT "THE GAME IS PLAYED AS FOLLOWS:":PRINT
+7 PRINT "AT THE BEGINNING OF THE GAME, A RANDOM NUMBER OF CHIPS ARE"
+8 PRINT "PLACED ON THE BOARD.  THE NUMBER OF CHIPS ALWAYS STARTS"
+9 PRINT "AS AN ODD NUMBER.  ON EACH TURN, A PLAYER MUST TAKE ONE,"
+10 PRINT "TWO, THREE, OR FOUR CHIPS.  THE WINNER IS THE PLAYER WHO"
+11 PRINT "FINISHES WITH A TOTAL NUMBER OF CHIPS THAT IS EVEN."
+12 PRINT "THE COMPUTER STARTS OUT KNOWING ONLY THE RULES OF THE"
+13 PRINT "GAME.  IT GRADUALLY LEARNS TO PLAY WELL.  IT SHOULD BE"
+14 PRINT "DIFFICULT TO BEAT THE COMPUTER AFTER TWENTY GAMES IN A ROW."
+15 PRINT "TRY IT!!!!": PRINT
+16 PRINT "TO QUIT AT ANY TIME, TYPE A '0' AS YOUR MOVE.": PRINT
+20 DIM R(1,5)
+25 L=0: B=0
+30 FOR I=0 TO 5
+40 R(1,I)=4
+50 R(0,I)=4
+60 NEXT I
+70 A=0: B=0
+90 P=INT((13*RND(1)+9)/2)*2+1
+100 IF P=1 THEN 530
+110 PRINT "THERE ARE";P;"CHIPS ON THE BOARD."
+120 E1=E
+130 L1=L
+140 E=(A/2-INT(A/2))*2
+150 L=INT((P/6-INT(P/6))*6+.5)
+160 IF R(E,L)>=P THEN 320
+170 M=R(E,L)
+180 IF M<=0 THEN 370
+190 P=P-M
+200 IF M=1 THEN 510
+210 PRINT "COMPUTER TAKES";M;"CHIPS LEAVING";P;"... YOUR MOVE";
+220 B=B+M
+230 INPUT M
+240 M=INT(M)
+250 IF M<1 THEN 450
+260 IF M>4 THEN 460
+270 IF M>P THEN 460
+280 IF M=P THEN 360
+290 P=P-M
+300 A=A+M
+310 GOTO 100
+320 IF P=1 THEN 550
+330 PRINT "COMPUTER TAKES";P;"CHIPS."
+340 R(E,L)=P
+350 B=B+P
+360 IF B/2=INT(B/2) THEN 420
+370 PRINT "GAME OVER ... YOU WIN!!!": PRINT
+390 IF R(E,L)=1 THEN 480
+400 R(E,L)=R(E,L)-1
+410 GOTO 70
+420 PRINT "GAME OVER ... I WIN!!!": PRINT
+430 GOTO 70
+450 IF M=0 THEN 570
+460 PRINT M;"IS AN ILLEGAL MOVE ... YOUR MOVE";
+470 GOTO 230
+480 IF R(E1,L1)=1 THEN 70
+490 R(E1,L1)=R(E1,L1)-1
+500 GOTO 70
+510 PRINT "COMPUTER TAKES 1 CHIP LEAVING";P;"... YOUR MOVE";
+520 GOTO 220
+530 PRINT "THERE IS 1 CHIP ON THE BOARD."
+540 GOTO 120
+550 PRINT "COMPUTER TAKES 1 CHIP."
+560 GOTO 340
+570 END

data/test/integration/tests/basic_computer_games/evenwin2.input

@@ -0,0 +1,14 @@
+YES
+4
+4
+4
+4
+4
+3
+2
+4
+4
+4
+4
+1
+0

data/test/integration/tests/basic_computer_games/evenwin2.output

@@ -0,0 +1,56 @@
+                            GAME OF EVEN WINS
+               CREATIVE COMPUTING  MORRISTOWN, NEW JERSEY
+
+
+DO YOU WANT INSTRUCTIONS (YES OR NO)? YES
+
+THE GAME IS PLAYED AS FOLLOWS:
+
+AT THE BEGINNING OF THE GAME, A RANDOM NUMBER OF CHIPS ARE
+PLACED ON THE BOARD.  THE NUMBER OF CHIPS ALWAYS STARTS
+AS AN ODD NUMBER.  ON EACH TURN, A PLAYER MUST TAKE ONE,
+TWO, THREE, OR FOUR CHIPS.  THE WINNER IS THE PLAYER WHO
+FINISHES WITH A TOTAL NUMBER OF CHIPS THAT IS EVEN.
+THE COMPUTER STARTS OUT KNOWING ONLY THE RULES OF THE
+GAME.  IT GRADUALLY LEARNS TO PLAY WELL.  IT SHOULD BE
+DIFFICULT TO BEAT THE COMPUTER AFTER TWENTY GAMES IN A ROW.
+TRY IT!!!!
+
+TO QUIT AT ANY TIME, TYPE A '0' AS YOUR MOVE.
+
+THERE ARE 17 CHIPS ON THE BOARD.
+COMPUTER TAKES 4 CHIPS LEAVING 13 ... YOUR MOVE? 4
+THERE ARE 9 CHIPS ON THE BOARD.
+COMPUTER TAKES 4 CHIPS LEAVING 5 ... YOUR MOVE? 4
+THERE IS 1 CHIP ON THE BOARD.
+COMPUTER TAKES 1 CHIP.
+GAME OVER ... YOU WIN!!!
+
+THERE ARE 19 CHIPS ON THE BOARD.
+COMPUTER TAKES 1 CHIP LEAVING 18 ... YOUR MOVE? 4
+THERE ARE 14 CHIPS ON THE BOARD.
+COMPUTER TAKES 4 CHIPS LEAVING 10 ... YOUR MOVE? 4
+THERE ARE 6 CHIPS ON THE BOARD.
+COMPUTER TAKES 4 CHIPS LEAVING 2 ... YOUR MOVE? 4
+ 4 IS AN ILLEGAL MOVE ... YOUR MOVE? 3
+ 3 IS AN ILLEGAL MOVE ... YOUR MOVE? 2
+GAME OVER ... YOU WIN!!!
+
+THERE ARE 17 CHIPS ON THE BOARD.
+COMPUTER TAKES 4 CHIPS LEAVING 13 ... YOUR MOVE? 4
+THERE ARE 9 CHIPS ON THE BOARD.
+COMPUTER TAKES 3 CHIPS LEAVING 6 ... YOUR MOVE? 4
+THERE ARE 2 CHIPS ON THE BOARD.
+COMPUTER TAKES 2 CHIPS.
+GAME OVER ... YOU WIN!!!
+
+THERE ARE 17 CHIPS ON THE BOARD.
+COMPUTER TAKES 4 CHIPS LEAVING 13 ... YOUR MOVE? 4
+THERE ARE 9 CHIPS ON THE BOARD.
+COMPUTER TAKES 3 CHIPS LEAVING 6 ... YOUR MOVE? 4
+THERE ARE 2 CHIPS ON THE BOARD.
+COMPUTER TAKES 1 CHIP LEAVING 1 ... YOUR MOVE? 1
+GAME OVER ... I WIN!!!
+
+THERE ARE 15 CHIPS ON THE BOARD.
+COMPUTER TAKES 3 CHIPS LEAVING 12 ... YOUR MOVE? 0

data/test/integration/tests/basic_computer_games/flipflop.bas

@@ -0,0 +1,79 @@
+2 PRINT TAB(32);"FLIPFLOP"
+4 PRINT TAB(15);"CREATIVE COMPUTING  MORRISTOWN, NEW JERSEY"
+6 PRINT
+10 REM *** CREATED BY MICHAEL CASS
+15 DIM A$(20)
+20 PRINT "THE OBJECT OF THIS PUZZLE IS TO CHANGE THIS:"
+30 PRINT
+40 PRINT "X X X X X X X X X X"
+50 PRINT
+60 PRINT "TO THIS:"
+70 PRINT
+80 PRINT "O O O O O O O O O O"
+90 PRINT
+100 PRINT "BY TYPING THE NUMBER CORRESPONDING TO THE POSITION OF THE"
+110 PRINT "LETTER ON SOME NUMBERS, ONE POSITION WILL CHANGE, ON"
+120 PRINT "OTHERS, TWO WILL CHANGE.  TO RESET LINE TO ALL X'S, TYPE 0"
+130 PRINT "(ZERO) AND TO START OVER IN THE MIDDLE OF A GAME, TYPE "
+140 PRINT "11 (ELEVEN)."
+170 PRINT
+180 REM
+190 Q=RND(1)
+200 PRINT "HERE IS THE STARTING LINE OF X'S."
+210 PRINT
+220 C=0
+230 PRINT "1 2 3 4 5 6 7 8 9 10"
+240 PRINT "X X X X X X X X X X"
+250 PRINT
+260 REM
+270 FOR X=1 TO 10
+280 A$(X)="X"
+290 NEXT X
+300 GOTO 320
+310 PRINT "ILLEGAL ENTRY--TRY AGAIN."
+320 PRINT "INPUT THE NUMBER";
+330 INPUT N
+340 IF N<>INT(N) THEN 310
+350 IF N=11 THEN 180
+360 IF N>11 THEN 310
+370 IF N=0 THEN 230
+380 IF M=N THEN 510
+390 M=N
+400 IF A$(N)="O" THEN 480
+410 A$(N)="O"
+420 R=TAN(Q+N/Q-N)-SIN(Q/N)+336*SIN(8*N)
+430 N=R-INT(R)
+440 N=INT(10*N)
+450 IF A$(N)="O" THEN 480
+460 A$(N)="O"
+470 GOTO 610
+480 A$(N)="X"
+490 IF M=N THEN 420
+500 GOTO 610
+510 IF A$(N)="O" THEN 590
+520 A$(N)="O"
+530 R=.592*(1/TAN(Q/N+Q))/SIN(N*2+Q)-COS(N)
+540 N=R-INT(R)
+550 N=INT(10*N)
+560 IF A$(N)="O" THEN 590
+570 A$(N)="O"
+580 GOTO 610
+590 A$(N)="X"
+600 IF M=N THEN 530
+610 PRINT "1 2 3 4 5 6 7 8 9 10"
+620 FOR Z=1 TO 10: PRINT A$(Z);" ";: NEXT Z
+630 C=C+1
+640 PRINT
+650 FOR Z=1 TO 10
+660 IF A$(Z)<>"O" THEN 320
+670 NEXT Z
+680 IF C>12 THEN 710
+690 PRINT "VERY GOOD.  YOU GUESSED IT IN ONLY";C;"GUESSES."
+700 GOTO 720
+710 PRINT "TRY HARDER NEXT TIME.  IT TOOK YOU";C;"GUESSES."
+720 PRINT "DO YOU WANT TO TRY ANOTHER PUZZLE";
+730 INPUT X$
+740 IF LEFT$(X$,1)="N" THEN 780
+760 PRINT
+770 GOTO 180
+780 END

data/test/integration/tests/basic_computer_games/flipflop.input

@@ -0,0 +1,8 @@
+1
+2
+3
+6
+9
+10
+2
+NO

data/test/integration/tests/basic_computer_games/flipflop.output

@@ -0,0 +1,45 @@
+                                FLIPFLOP
+               CREATIVE COMPUTING  MORRISTOWN, NEW JERSEY
+
+THE OBJECT OF THIS PUZZLE IS TO CHANGE THIS:
+
+X X X X X X X X X X
+
+TO THIS:
+
+O O O O O O O O O O
+
+BY TYPING THE NUMBER CORRESPONDING TO THE POSITION OF THE
+LETTER ON SOME NUMBERS, ONE POSITION WILL CHANGE, ON
+OTHERS, TWO WILL CHANGE.  TO RESET LINE TO ALL X'S, TYPE 0
+(ZERO) AND TO START OVER IN THE MIDDLE OF A GAME, TYPE 
+11 (ELEVEN).
+
+HERE IS THE STARTING LINE OF X'S.
+
+1 2 3 4 5 6 7 8 9 10
+X X X X X X X X X X
+
+INPUT THE NUMBER? 1
+1 2 3 4 5 6 7 8 9 10
+O X X X X X X O X X 
+INPUT THE NUMBER? 2
+1 2 3 4 5 6 7 8 9 10
+O O X X O X X O X X 
+INPUT THE NUMBER? 3
+1 2 3 4 5 6 7 8 9 10
+O O O O O X X O X X 
+INPUT THE NUMBER? 6
+1 2 3 4 5 6 7 8 9 10
+O O O O O O O O X X 
+INPUT THE NUMBER? 9
+1 2 3 4 5 6 7 8 9 10
+O O O O X O O O O X 
+INPUT THE NUMBER? 10
+1 2 3 4 5 6 7 8 9 10
+O X O O X O O O O O 
+INPUT THE NUMBER? 2
+1 2 3 4 5 6 7 8 9 10
+O O O O O O O O O O 
+VERY GOOD.  YOU GUESSED IT IN ONLY 7 GUESSES.
+DO YOU WANT TO TRY ANOTHER PUZZLE? NO