basic101 0.1.0

data/test/integration/tests/basic_computer_games/gunner.bas

@@ -0,0 +1,52 @@
+10 PRINT TAB(30);"GUNNER"
+20 PRINT TAB(15);"CREATIVE COMPUTING  MORRISTOWN, NEW JERSEY"
+30 PRINT:PRINT:PRINT
+130 PRINT "YOU ARE THE OFFICER-IN-CHARGE, GIVING ORDERS TO A GUN"
+140 PRINT "CREW, TELLING THEM THE DEGREES OF ELEVATION YOU ESTIMATE"
+150 PRINT "WILL PLACE A PROJECTILE ON TARGET.  A HIT WITHIN 100 YARDS"
+160 PRINT "OF THE TARGET WILL DESTROY IT." : PRINT
+170 R=INT(40000*RND(1)+20000)
+180 PRINT "MAXIMUM RANGE OF YOUR GUN IS";R;" YARDS."
+185 Z=0
+190 PRINT
+195 S1=0
+200 T=INT(R*(.1+.8*RND(1)))
+210 S=0
+220 GOTO 370
+230 PRINT "MINIMUM ELEVATION IS ONE DEGREE."
+240 GOTO 390
+250 PRINT "MAXIMUM ELEVATION IS 89 DEGREES."
+260 GOTO 390
+270 PRINT "OVER TARGET BY ";ABS(E);"YARDS."
+280 GOTO 390
+290 PRINT "SHORT OF TARGET BY "ABS(E);"YARDS."
+300 GOTO 390
+320 PRINT "*** TARGET DESTROYED ***  ";S;"ROUNDS OF AMMUNITION EXPENDED."
+325 S1=S1+S
+330 IF Z=4 THEN 490
+340 Z=Z+1
+345 PRINT
+350 PRINT "THE FORWARD OBSERVER HAS SIGHTED MORE ENEMY ACTIVITY..."
+360 GOTO 200
+370 PRINT "DISTANCE TO THE TARGET IS "T;" YARDS."
+380 PRINT
+390 PRINT
+400 INPUT "ELEVATION";B
+420 IF B>89 THEN 250
+430 IF B<1 THEN 230
+440 S=S+1
+442 IF S<6 THEN 450
+444 PRINT:PRINT "BOOM !!!!   YOU HAVE JUST BEEN DESTROYED ";
+446 PRINT "BY THE ENEMY." : PRINT : PRINT : PRINT : GOTO 495
+450 B2=2*B/57.3 : I=R*SIN(B2) : X=T-I : E=INT(X)
+460 IF ABS(E)<100 THEN 320
+470 IF E>100 THEN 290
+480 GOTO 270
+490 PRINT : PRINT : PRINT "TOTAL ROUNDS EXPENDED WERE:";S1
+492 IF S1>18 THEN 495
+493 PRINT "NICE SHOOTING !!" : GOTO 500
+495 PRINT "BETTER GO BACK TO FORT SILL FOR REFRESHER TRAINING!"
+500 PRINT : INPUT "TRY AGAIN (Y OR N)";Z$
+510 IF Z$="Y" THEN 170
+520 PRINT:PRINT "OK.  RETURN TO BASE CAMP."
+999 END

data/test/integration/tests/basic_computer_games/gunner.input

@@ -0,0 +1,18 @@
+45
+40
+30
+25
+20
+21
+Y
+45
+20
+10
+17
+15
+16
+Y
+30
+20
+17
+19

data/test/integration/tests/basic_computer_games/gunner.output

@@ -0,0 +1,91 @@
+                              GUNNER
+               CREATIVE COMPUTING  MORRISTOWN, NEW JERSEY
+
+
+
+YOU ARE THE OFFICER-IN-CHARGE, GIVING ORDERS TO A GUN
+CREW, TELLING THEM THE DEGREES OF ELEVATION YOU ESTIMATE
+WILL PLACE A PROJECTILE ON TARGET.  A HIT WITHIN 100 YARDS
+OF THE TARGET WILL DESTROY IT.
+
+MAXIMUM RANGE OF YOUR GUN IS 41952  YARDS.
+
+DISTANCE TO THE TARGET IS  28198  YARDS.
+
+
+ELEVATION? 45
+OVER TARGET BY  13754 YARDS.
+
+ELEVATION? 40
+OVER TARGET BY  13116 YARDS.
+
+ELEVATION? 30
+OVER TARGET BY  8132 YARDS.
+
+ELEVATION? 25
+OVER TARGET BY  3938 YARDS.
+
+ELEVATION? 20
+SHORT OF TARGET BY  1233 YARDS.
+
+ELEVATION? 21
+
+BOOM !!!!   YOU HAVE JUST BEEN DESTROYED BY THE ENEMY.
+
+
+
+BETTER GO BACK TO FORT SILL FOR REFRESHER TRAINING!
+
+TRY AGAIN (Y OR N)? Y
+MAXIMUM RANGE OF YOUR GUN IS 44110  YARDS.
+
+DISTANCE TO THE TARGET IS  23638  YARDS.
+
+
+ELEVATION? 45
+OVER TARGET BY  20472 YARDS.
+
+ELEVATION? 20
+OVER TARGET BY  4714 YARDS.
+
+ELEVATION? 10
+SHORT OF TARGET BY  8552 YARDS.
+
+ELEVATION? 17
+OVER TARGET BY  1027 YARDS.
+
+ELEVATION? 15
+SHORT OF TARGET BY  1584 YARDS.
+
+ELEVATION? 16
+
+BOOM !!!!   YOU HAVE JUST BEEN DESTROYED BY THE ENEMY.
+
+
+
+BETTER GO BACK TO FORT SILL FOR REFRESHER TRAINING!
+
+TRY AGAIN (Y OR N)? Y
+MAXIMUM RANGE OF YOUR GUN IS 36946  YARDS.
+
+DISTANCE TO THE TARGET IS  22785  YARDS.
+
+
+ELEVATION? 30
+OVER TARGET BY  9210 YARDS.
+
+ELEVATION? 20
+OVER TARGET BY  962 YARDS.
+
+ELEVATION? 17
+SHORT OF TARGET BY  2126 YARDS.
+
+ELEVATION? 19
+*** TARGET DESTROYED ***   4 ROUNDS OF AMMUNITION EXPENDED.
+
+THE FORWARD OBSERVER HAS SIGHTED MORE ENEMY ACTIVITY...
+DISTANCE TO THE TARGET IS  16628  YARDS.
+
+
+ELEVATION? 
+Error on line 400: No more input

data/test/integration/tests/basic_computer_games/hamurabi.bas

@@ -0,0 +1,119 @@
+10 PRINT TAB(32);"HAMURABI"
+20 PRINT TAB(15);"CREATIVE COMPUTING  MORRISTOWN, NEW JERSEY"
+30 PRINT:PRINT:PRINT
+80 PRINT "TRY YOUR HAND AT GOVERNING ANCIENT SUMERIA"
+90 PRINT "FOR A TEN-YEAR TERM OF OFFICE.":PRINT
+95 D1=0: P1=0
+100 Z=0: P=95:S=2800: H=3000: E=H-S
+110 Y=3: A=H/Y: I=5: Q=1
+210 D=0
+215 PRINT:PRINT:PRINT "HAMURABI:  I BEG TO REPORT TO YOU,": Z=Z+1
+217 PRINT "IN YEAR";Z;",";D;"PEOPLE STARVED,";I;"CAME TO THE CITY,"
+218 P=P+I
+227 IF Q>0 THEN 230
+228 P=INT(P/2)
+229 PRINT "A HORRIBLE PLAGUE STRUCK!  HALF THE PEOPLE DIED."
+230 PRINT "POPULATION IS NOW";P
+232 PRINT "THE CITY NOW OWNS ";A;"ACRES."
+235 PRINT "YOU HARVESTED";Y;"BUSHELS PER ACRE."
+250 PRINT "THE RATS ATE";E;"BUSHELS."
+260 PRINT "YOU NOW HAVE ";S;"BUSHELS IN STORE.": PRINT
+270 IF Z=11 THEN 860
+310 C=INT(10*RND(1)): Y=C+17
+312 PRINT "LAND IS TRADING AT";Y;"BUSHELS PER ACRE."
+320 PRINT "HOW MANY ACRES DO YOU WISH TO BUY";
+321 INPUT Q: IF Q<0 THEN 850
+322 IF Y*Q<=S THEN 330
+323 GOSUB 710
+324 GOTO 320
+330 IF Q=0 THEN 340
+331 A=A+Q: S=S-Y*Q: C=0
+334 GOTO 400
+340 PRINT "HOW MANY ACRES DO YOU WISH TO SELL";
+341 INPUT Q: IF Q<0 THEN 850
+342 IF Q<A THEN 350
+343 GOSUB 720
+344 GOTO 340
+350 A=A-Q: S=S+Y*Q: C=0
+400 PRINT
+410 PRINT "HOW MANY BUSHELS DO YOU WISH TO FEED YOUR PEOPLE";
+411 INPUT Q
+412 IF Q<0 THEN 850
+418 REM *** TRYING TO USE MORE GRAIN THAN IS IN SILOS?
+420 IF Q<=S THEN 430
+421 GOSUB 710
+422 GOTO 410
+430 S=S-Q: C=1: PRINT
+440 PRINT "HOW MANY ACRES DO YOU WISH TO PLANT WITH SEED";
+441 INPUT D: IF D=0 THEN 511
+442 IF D<0 THEN 850
+444 REM *** TRYING TO PLANT MORE ACRES THAN YOU OWN?
+445 IF D<=A THEN 450
+446 GOSUB 720
+447 GOTO 440
+449 REM *** ENOUGH GRAIN FOR SEED?
+450 IF INT(D/2)<=S THEN 455
+452 GOSUB 710
+453 GOTO 440
+454 REM *** ENOUGH PEOPLE TO TEND THE CROPS?
+455 IF D<10*P THEN 510
+460 PRINT "BUT YOU HAVE ONLY";P;"PEOPLE TO TEND THE FIELDS!  NOW THEN,"
+470 GOTO 440
+510 S=S-INT(D/2)
+511 GOSUB 800
+512 REM *** A BOUNTIFUL HARVEST!
+515 Y=C: H=D*Y: E=0
+521 GOSUB 800
+522 IF INT(C/2)<>C/2 THEN 530
+523 REM *** RATS ARE RUNNING WILD!!
+525 E=INT(S/C)
+530 S=S-E+H
+531 GOSUB 800
+532 REM *** LET'S HAVE SOME BABIES
+533 I=INT(C*(20*A+S)/P/100+1)
+539 REM *** HOW MANY PEOPLE HAD FULL TUMMIES?
+540 C=INT(Q/20)
+541 REM *** HORROS, A 15% CHANCE OF PLAGUE
+542 Q=INT(10*(2*RND(1)-.3))
+550 IF P<C THEN 210
+551 REM *** STARVE ENOUGH FOR IMPEACHMENT?
+552 D=P-C: IF D>.45*P THEN 560
+553 P1=((Z-1)*P1+D*100/P)/Z
+555 P=C: D1=D1+D: GOTO 215
+560 PRINT: PRINT "YOU STARVED";D;"PEOPLE IN ONE YEAR!!!"
+565 PRINT "DUE TO THIS EXTREME MISMANAGEMENT YOU HAVE NOT ONLY"
+566 PRINT "BEEN IMPEACHED AND THROWN OUT OF OFFICE BUT YOU HAVE"
+567 PRINT "ALSO BEEN DECLARED NATIONAL FINK!!!!": GOTO 990
+710 PRINT "HAMURABI:  THINK AGAIN.  YOU HAVE ONLY"
+711 PRINT S;"BUSHELS OF GRAIN.  NOW THEN,"
+712 RETURN
+720 PRINT "HAMURABI:  THINK AGAIN.  YOU OWN ONLY";A;"ACRES.  NOW THEN,"
+730 RETURN
+800 C=INT(RND(1)*5)+1
+801 RETURN
+850 PRINT: PRINT "HAMURABI:  I CANNOT DO WHAT YOU WISH."
+855 PRINT "GET YOURSELF ANOTHER STEWARD!!!!!"
+857 GOTO 990
+860 PRINT "IN YOUR 10-YEAR TERM OF OFFICE,";P1;"PERCENT OF THE"
+862 PRINT "POPULATION STARVED PER YEAR ON THE AVERAGE, I.E. A TOTAL OF"
+865 PRINT D1;"PEOPLE DIED!!": L=A/P
+870 PRINT "YOU STARTED WITH 10 ACRES PER PERSON AND ENDED WITH"
+875 PRINT L;"ACRES PER PERSON.": PRINT
+880 IF P1>33 THEN 565
+885 IF L<7 THEN 565
+890 IF P1>10 THEN 940
+892 IF L<9 THEN 940
+895 IF P1>3 THEN 960
+896 IF L<10 THEN 960
+900 PRINT "A FANTASTIC PERFORMANCE!!!  CHARLEMANGE, DISRAELI, AND"
+905 PRINT "JEFFERSON COMBINED COULD NOT HAVE DONE BETTER!":GOTO 990
+940 PRINT "YOUR HEAVY-HANDED PERFORMANCE SMACKS OF NERO AND IVAN IV."
+945 PRINT "THE PEOPLE (REMIANING) FIND YOU AN UNPLEASANT RULER, AND,"
+950 PRINT "FRANKLY, HATE YOUR GUTS!!":GOTO 990
+960 PRINT "YOUR PERFORMANCE COULD HAVE BEEN SOMEWHAT BETTER, BUT"
+965 PRINT "REALLY WASN'T TOO BAD AT ALL. ";INT(P*.8*RND(1));"PEOPLE"
+970 PRINT "WOULD DEARLY LIKE TO SEE YOU ASSASSINATED BUT WE ALL HAVE OUR"
+975 PRINT "TRIVIAL PROBLEMS."
+990 PRINT: FOR N=1 TO 10: PRINT CHR$(7);: NEXT N
+995 PRINT "SO LONG FOR NOW.": PRINT
+999 END

data/test/integration/tests/basic_computer_games/hamurabi.input

@@ -0,0 +1,7 @@
+20
+2000
+500
+20
+1900
+600
+600

data/test/integration/tests/basic_computer_games/hamurabi.output

@@ -0,0 +1,51 @@
+                                HAMURABI
+               CREATIVE COMPUTING  MORRISTOWN, NEW JERSEY
+
+
+
+TRY YOUR HAND AT GOVERNING ANCIENT SUMERIA
+FOR A TEN-YEAR TERM OF OFFICE.
+
+
+
+HAMURABI:  I BEG TO REPORT TO YOU,
+IN YEAR 1 , 0 PEOPLE STARVED, 5 CAME TO THE CITY,
+POPULATION IS NOW 100 
+THE CITY NOW OWNS  1000 ACRES.
+YOU HARVESTED 3 BUSHELS PER ACRE.
+THE RATS ATE 200 BUSHELS.
+YOU NOW HAVE  2800 BUSHELS IN STORE.
+
+LAND IS TRADING AT 22 BUSHELS PER ACRE.
+HOW MANY ACRES DO YOU WISH TO BUY? 20
+
+HOW MANY BUSHELS DO YOU WISH TO FEED YOUR PEOPLE? 2000
+
+HOW MANY ACRES DO YOU WISH TO PLANT WITH SEED? 500
+
+
+HAMURABI:  I BEG TO REPORT TO YOU,
+IN YEAR 2 , 0 PEOPLE STARVED, 7 CAME TO THE CITY,
+POPULATION IS NOW 107 
+THE CITY NOW OWNS  1020 ACRES.
+YOU HARVESTED 4 BUSHELS PER ACRE.
+THE RATS ATE 27 BUSHELS.
+YOU NOW HAVE  2083 BUSHELS IN STORE.
+
+LAND IS TRADING AT 23 BUSHELS PER ACRE.
+HOW MANY ACRES DO YOU WISH TO BUY? 20
+
+HOW MANY BUSHELS DO YOU WISH TO FEED YOUR PEOPLE? 1900
+HAMURABI:  THINK AGAIN.  YOU HAVE ONLY
+ 1623 BUSHELS OF GRAIN.  NOW THEN,
+HOW MANY BUSHELS DO YOU WISH TO FEED YOUR PEOPLE? 600
+
+HOW MANY ACRES DO YOU WISH TO PLANT WITH SEED? 600
+
+YOU STARVED 77 PEOPLE IN ONE YEAR!!!
+DUE TO THIS EXTREME MISMANAGEMENT YOU HAVE NOT ONLY
+BEEN IMPEACHED AND THROWN OUT OF OFFICE BUT YOU HAVE
+ALSO BEEN DECLARED NATIONAL FINK!!!!
+
+SO LONG FOR NOW.
+

data/test/integration/tests/basic_computer_games/hangman.bas

@@ -0,0 +1,81 @@
+10 PRINT TAB(32);"HANGMAN"
+20 PRINT TAB(15);"CREATIVE COMPUTING  MORRISTOWN, NEW JERSEY"
+25 PRINT:PRINT:PRINT
+30 DIM P$(12,12),L$(20),D$(20),N$(26),U(50)
+40 C=1: N=50
+50 FOR I=1 TO 20: D$(I)="-": NEXT I: M=0
+60 FOR I=1 TO 26: N$(I)="": NEXT I
+70 FOR I=1 TO 12: FOR J=1 TO 12: P$(I,J)=" ": NEXT J: NEXT I
+80 FOR I=1 TO 12: P$(I,1)="X": NEXT I
+90 FOR I=1 TO 7: P$(1,I)="X": NEXT: P$(2,7)="X"
+95 IF C<N THEN 100
+97 PRINT "YOU DID ALL THE WORDS!!": STOP
+100 Q=INT(N*RND(1))+1
+110 IF U(Q)=1 THEN 100
+115 U(Q)=1: C=C+1: RESTORE: T1=0
+150 FOR I=1 TO Q: READ A$: NEXT I
+160 L=LEN(A$): FOR I=1 TO LEN(A$): L$(I)=MID$(A$,I,1): NEXT I
+170 PRINT "HERE ARE THE LETTERS YOU USED:"
+180 FOR I=1 TO 26: PRINT N$(I);: IF N$(I+1)="" THEN 200
+190 PRINT ",";: NEXT I
+200 PRINT: PRINT: FOR I=1 TO L: PRINT D$(I);: NEXT I: PRINT: PRINT
+210 INPUT "WHAT IS YOUR GUESS";G$: R=0
+220 FOR I=1 TO 26: IF N$(I)="" THEN 250
+230 IF G$=N$(I) THEN PRINT "YOU GUESSED THAT LETTER BEFORE!": GOTO 170
+240 NEXT I: PRINT "PROGRAM ERROR.  RUN AGAIN.": STOP
+250 N$(I)=G$: T1=T1+1
+260 FOR I=1 TO L: IF L$(I)=G$ THEN 280
+270 NEXT I: IF R=0 THEN 290
+275 GOTO 300
+280 D$(I)=G$: R=R+1: GOTO 270
+290 M=M+1: GOTO 400
+300 FOR I=1 TO L: IF D$(I)="-" THEN 320
+310 NEXT I: GOTO 390
+320 PRINT: FOR I=1 TO L: PRINT D$(I);: NEXT I: PRINT: PRINT
+330 INPUT "WHAT IS YOUR GUESS FOR THE WORD";B$
+340 IF A$=B$ THEN 360
+350 PRINT "WRONG.  TRY ANOTHER LETTER.": PRINT: GOTO 170
+360 PRINT "RIGHT!!  IT TOOK YOU";T1;"GUESSES!"
+370 INPUT "WANT ANOTHER WORD";W$: IF W$="YES" THEN 50
+380 PRINT: PRINT "IT'S BEEN FUN!  BYE FOR NOW.": GOTO 999
+390 PRINT "YOU FOUND THE WORD!": GOTO 370
+400 PRINT: PRINT: PRINT"SORRY, THAT LETTER ISN'T IN THE WORD."
+410 ON M GOTO 415,420,425,430,435,440,445,450,455,460
+415 PRINT "FIRST, WE DRAW A HEAD": GOTO 470
+420 PRINT "NOW WE DRAW A BODY.": GOTO 470
+425 PRINT "NEXT WE DRAW AN ARM.": GOTO 470
+430 PRINT "THIS TIME IT'S THE OTHER ARM.": GOTO 470
+435 PRINT "NOW, LET'S DRAW THE RIGHT LEG.": GOTO 470
+440 PRINT "THIS TIME WE DRAW THE LEFT LEG.": GOTO 470
+445 PRINT "NOW WE PUT UP A HAND.": GOTO 470
+450 PRINT "NEXT THE OTHER HAND.": GOTO 470
+455 PRINT "NOW WE DRAW ONE FOOT": GOTO 470
+460 PRINT "HERE'S THE OTHER FOOT -- YOU'RE HUNG!!"
+470 ON M GOTO 480,490,500,510,520,530,540,550,560,570
+480 P$(3,6)="-": P$(3,7)="-": P$(3,8)="-": P$(4,5)="(": P$(4,6)="."
+481 P$(4,8)=".":P$(4,9)=")":P$(5,6)="-":P$(5,7)="-":P$(5,8)="-":GOTO 580
+490 FOR I=6 TO 9: P$(I,7)="X": NEXT I: GOTO 580
+500 FOR I=4 TO 7: P$(I,I-1)="\": NEXT I: GOTO 580
+510 P$(4,11)="/": P$(5,10)="/": P$(6,9)="/": P$(7,8)="/": GOTO 580
+520 P$(10,6)="/": P$(11,5)="/": GOTO 580
+530 P$(10,8)="\": P$(11,9)="\": GOTO 580
+540 P$(3,11)="\": GOTO 580
+550 P$(3,3)="/": GOTO 580
+560 P$(12,10)="\": P$(12,11)="-": GOTO 580
+570 P$(12,3)="-": P$(12,4)="/"
+580 FOR I=1 TO 12: FOR J=1 TO 12: PRINT P$(I,J);: NEXT J
+590 PRINT: NEXT I: PRINT: PRINT: IF M<>10 THEN 170
+600 PRINT "SORRY, YOU LOSE.  THE WORD WAS ";A$
+610 PRINT "YOU MISSED THAT ONE.  DO YOU ";: GOTO 370
+620 INPUT "TYPE YES OR NO";Y$: IF LEFT$(Y$,1)="Y" THEN 50
+700 DATA "GUM","SIN","FOR","CRY","LUG","BYE","FLY"
+710 DATA "UGLY","EACH","FROM","WORK","TALK","WITH","SELF"
+720 DATA "PIZZA","THING","FEIGN","FIEND","ELBOW","FAULT","DIRTY"
+730 DATA "BUDGET","SPIRIT","QUAINT","MAIDEN","ESCORT","PICKAX"
+740 DATA "EXAMPLE","TENSION","QUININE","KIDNEY","REPLICA","SLEEPER"
+750 DATA "TRIANGLE","KANGAROO","MAHOGANY","SERGEANT","SEQUENCE"
+760 DATA "MOUSTACHE","DANGEROUS","SCIENTIST","DIFFERENT","QUIESCENT"
+770 DATA "MAGISTRATE","ERRONEOUSLY","LOUDSPEAKER","PHYTOTOXIC"
+780 DATA "MATRIMONIAL","PARASYMPATHOMIMETIC","THIGMOTROPISM"
+990 PRINT "BYE NOW"
+999 END

data/test/integration/tests/basic_computer_games/hangman.input

@@ -0,0 +1,69 @@
+E
+T
+A
+N
+R
+S
+H
+M
+O
+X
+B
+P
+L
+L
+YES
+E
+T
+A
+O
+N
+G
+S
+R
+K
+B
+L
+M
+H
+I
+O
+Y
+J
+G
+MAHOGANY
+YES
+T
+A
+E
+O
+I
+S
+H
+N
+R
+D
+B
+G
+X
+Y
+K
+K
+YES
+A
+B
+C
+D
+E
+F
+G
+H
+I
+J
+K
+L
+M
+N
+O
+P
+NO