tree-sitter-wasm 1.0.0

package/out/vim/injections.scm

@@ -0,0 +1,44 @@
+(lua_statement
+  (script
+    (body) @injection.content
+    (#set! injection.language "lua")))
+
+(lua_statement
+  (chunk) @injection.content
+  (#set! injection.language "lua"))
+
+(ruby_statement
+  (script
+    (body) @injection.content
+    (#set! injection.language "ruby")))
+
+(ruby_statement
+  (chunk) @injection.content
+  (#set! injection.language "ruby"))
+
+(python_statement
+  (script
+    (body) @injection.content
+    (#set! injection.language "python")))
+
+(python_statement
+  (chunk) @injection.content
+  (#set! injection.language "python"))
+
+; If we support perl at some point...
+; (perl_statement (script (body) @perl))
+; (perl_statement (chunk) @perl)
+(autocmd_statement
+  (pattern) @injection.content
+  (#set! injection.language "regex"))
+
+((set_item
+  option: (option_name) @_option
+  value: (set_value) @injection.content)
+  (#any-of? @_option
+    "includeexpr" "inex" "printexpr" "pexpr" "formatexpr" "fex" "indentexpr" "inde" "foldtext" "fdt"
+    "foldexpr" "fde" "diffexpr" "dex" "patchexpr" "pex" "charconvert" "ccv")
+  (#set! injection.language "vim"))
+
+((comment) @injection.content
+  (#set! injection.language "comment"))

package/out/vim/locals.scm

@@ -0,0 +1,19 @@
+[
+  (script_file)
+  (function_definition)
+] @local.scope
+
+(function_declaration
+  name: (identifier) @local.definition.function)
+
+(function_declaration
+  parameters: (parameters
+    (identifier) @local.definition.parameter))
+
+(let_statement
+  [
+    (scoped_identifier)
+    (identifier)
+  ] @local.definition.var)
+
+(identifier) @local.reference

package/out/vimdoc/highlights.scm

@@ -0,0 +1,74 @@
+(h1
+  (delimiter) @markup.heading.1
+  (heading) @markup.heading.1)
+
+(h2
+  (delimiter) @markup.heading.2
+  (heading) @markup.heading.2)
+
+(h3
+  (heading) @markup.heading.3)
+
+(column_heading
+  (heading) @markup.heading.4)
+
+(column_heading
+  (delimiter) @markup.heading.4
+  (#set! conceal ""))
+
+(tag
+  "*" @label
+  (#set! conceal ""))
+
+(tag
+  text: (_) @label)
+
+(taglink
+  "|" @markup.link
+  (#set! conceal ""))
+
+(taglink
+  text: (_) @markup.link)
+
+(optionlink
+  text: (_) @markup.link)
+
+(codespan
+  "`" @markup.raw
+  (#set! conceal ""))
+
+(codespan
+  text: (_) @markup.raw)
+
+((codeblock) @markup.raw.block
+  (#set! priority 90))
+
+(codeblock
+  ">" @markup.raw
+  (#set! conceal ""))
+
+(codeblock
+  (language) @label
+  (#set! conceal ""))
+
+(block
+  "<" @markup.raw
+  (#set! conceal ""))
+
+(argument) @variable.parameter
+
+(keycode) @string.special
+
+((url) @string.special.url
+  (#set! @string.special.url url @string.special.url))
+
+(modeline) @keyword.directive
+
+((note) @comment.note
+  (#any-of? @comment.note "Note:" "NOTE:" "Notes:"))
+
+((note) @comment.warning
+  (#any-of? @comment.warning "Warning:" "WARNING:"))
+
+((note) @comment.error
+  (#any-of? @comment.error "Deprecated:" "DEPRECATED:"))

package/out/vimdoc/injections.scm

@@ -0,0 +1,4 @@
+((codeblock
+  (language) @injection.language
+  (code) @injection.content)
+  (#set! injection.include-children))

package/out/vue/folds.scm

@@ -0,0 +1,6 @@
+[
+  (element)
+  (template_element)
+  (script_element)
+  (style_element)
+] @fold

package/out/vue/highlights.scm

@@ -0,0 +1,54 @@
+; inherits: html_tags
+
+[
+  "["
+  "]"
+] @punctuation.bracket
+
+[
+  ":"
+  "."
+] @character.special
+
+[
+  (interpolation)
+  "@"
+] @punctuation.special
+
+(interpolation
+  (raw_text) @none)
+
+(dynamic_directive_inner_value) @variable
+
+(directive_name) @tag.attribute
+
+; Accessing a component object's field
+(":"
+  .
+  (directive_value) @variable.member)
+
+("."
+  .
+  (directive_value) @property)
+
+; @click is like onclick for HTML
+("@"
+  .
+  (directive_value) @function.method)
+
+; Used in v-slot, declaring position the element should be put in
+("#"
+  .
+  (directive_value) @variable)
+
+(directive_attribute
+  (quoted_attribute_value) @punctuation.special)
+
+(directive_attribute
+  (quoted_attribute_value
+    (attribute_value) @none))
+
+(directive_modifier) @function.method
+
+((template_element) @_template
+  (#set! @_template bo.commentstring "<!-- %s -->"))

package/out/vue/indents.scm

@@ -0,0 +1,7 @@
+; inherits: html_tags
+
+(template_element) @indent.begin
+
+(template_element
+  (end_tag
+    ">" @indent.end) @indent.branch)

package/out/vue/injections.scm

@@ -0,0 +1,78 @@
+; inherits: html_tags
+
+; <script lang="css">
+((style_element
+  (start_tag
+    (attribute
+      (attribute_name) @_lang
+      (quoted_attribute_value
+        (attribute_value) @injection.language)))
+  (raw_text) @injection.content)
+  (#eq? @_lang "lang")
+  (#any-of? @injection.language "css" "scss"))
+
+; TODO: When nvim-treesitter has postcss and less parsers, use @injection.language and @injection.content instead
+; <script lang="scss">
+(style_element
+  (start_tag
+    (attribute
+      (attribute_name) @_lang
+      (quoted_attribute_value
+        (attribute_value) @_scss)))
+  (raw_text) @injection.content
+  (#eq? @_lang "lang")
+  (#any-of? @_scss "less" "postcss" "sass")
+  (#set! injection.language "scss"))
+
+; <script lang="js">
+((script_element
+  (start_tag
+    (attribute
+      (attribute_name) @_lang
+      (quoted_attribute_value
+        (attribute_value) @_js)))
+  (raw_text) @injection.content)
+  (#eq? @_lang "lang")
+  (#eq? @_js "js")
+  (#set! injection.language "javascript"))
+
+; <script lang="ts">
+((script_element
+  (start_tag
+    (attribute
+      (attribute_name) @_lang
+      (quoted_attribute_value
+        (attribute_value) @_ts)))
+  (raw_text) @injection.content)
+  (#eq? @_lang "lang")
+  (#eq? @_ts "ts")
+  (#set! injection.language "typescript"))
+
+; <script lang="tsx">
+; <script lang="jsx">
+(script_element
+  (start_tag
+    (attribute
+      (attribute_name) @_attr
+      (quoted_attribute_value
+        (attribute_value) @injection.language)))
+  (#eq? @_attr "lang")
+  (#any-of? @injection.language "tsx" "jsx")
+  (raw_text) @injection.content)
+
+((interpolation
+  (raw_text) @injection.content)
+  (#set! injection.language "typescript"))
+
+(directive_attribute
+  (quoted_attribute_value
+    (attribute_value) @injection.content
+    (#set! injection.language "typescript")))
+
+(template_element
+  (start_tag
+    (attribute
+      (quoted_attribute_value
+        (attribute_value) @injection.language)))
+  (text) @injection.content
+  (#eq? @injection.language "pug"))

package/out/xml/folds.scm

@@ -0,0 +1,5 @@
+[
+  (element)
+  (doctypedecl)
+  (Comment)
+] @fold

package/out/xml/highlights.scm

@@ -0,0 +1,198 @@
+; XML declaration
+(XMLDecl
+  "xml" @keyword.directive)
+
+(XMLDecl
+  [
+    "version"
+    "encoding"
+    "standalone"
+  ] @tag.attribute)
+
+(XMLDecl
+  (EncName) @string.special)
+
+(XMLDecl
+  (VersionNum) @number)
+
+(XMLDecl
+  [
+    "yes"
+    "no"
+  ] @boolean)
+
+; Processing instructions
+(PI) @keyword.directive
+
+; Element declaration
+(elementdecl
+  "ELEMENT" @keyword.directive.define
+  (Name) @tag)
+
+(contentspec
+  (_
+    (Name) @tag.attribute))
+
+"#PCDATA" @type.builtin
+
+[
+  "EMPTY"
+  "ANY"
+] @keyword.modifier
+
+[
+  "*"
+  "?"
+  "+"
+] @character.special
+
+; Entity declaration
+(GEDecl
+  "ENTITY" @keyword.directive.define
+  (Name) @constant)
+
+(GEDecl
+  (EntityValue) @string)
+
+(NDataDecl
+  "NDATA" @keyword
+  (Name) @label)
+
+; Parsed entity declaration
+(PEDecl
+  "ENTITY" @keyword.directive.define
+  "%" @operator
+  (Name) @function.macro)
+
+(PEDecl
+  (EntityValue) @string)
+
+; Notation declaration
+(NotationDecl
+  "NOTATION" @keyword.directive
+  (Name) @label)
+
+; Attlist declaration
+(AttlistDecl
+  "ATTLIST" @keyword.directive.define
+  (Name) @tag)
+
+(AttDef
+  (Name) @tag.attribute)
+
+(AttDef
+  (Enumeration
+    (Nmtoken) @string))
+
+[
+  (StringType)
+  (TokenizedType)
+] @type.builtin
+
+(NotationType
+  "NOTATION" @type.builtin)
+
+[
+  "#REQUIRED"
+  "#IMPLIED"
+  "#FIXED"
+] @attribute
+
+; Entities
+(EntityRef) @constant
+
+((EntityRef) @constant.builtin
+  (#any-of? @constant.builtin "&" "<" ">" """ "'"))
+
+(CharRef) @character
+
+(PEReference) @function.macro
+
+; External references
+[
+  "PUBLIC"
+  "SYSTEM"
+] @keyword
+
+(PubidLiteral) @string.special
+
+(SystemLiteral
+  (URI) @string.special.url)
+
+; Processing instructions
+(XmlModelPI
+  "xml-model" @keyword.directive)
+
+(StyleSheetPI
+  "xml-stylesheet" @keyword.directive)
+
+(PseudoAtt
+  (Name) @tag.attribute)
+
+(PseudoAtt
+  (PseudoAttValue) @string)
+
+; Doctype declaration
+(doctypedecl
+  "DOCTYPE" @keyword.directive.define)
+
+(doctypedecl
+  (Name) @type.definition)
+
+; Tags
+(STag
+  (Name) @tag)
+
+(ETag
+  (Name) @tag)
+
+(EmptyElemTag
+  (Name) @tag)
+
+; Attributes
+(Attribute
+  (Name) @tag.attribute)
+
+(Attribute
+  (AttValue) @string)
+
+; Delimiters & punctuation
+[
+  "<?"
+  "?>"
+  "<"
+  ">"
+  "</"
+  "/>"
+  "<!"
+  "]]>"
+] @tag.delimiter
+
+[
+  "("
+  ")"
+  "["
+  "]"
+] @punctuation.bracket
+
+[
+  "\""
+  "'"
+] @punctuation.delimiter
+
+[
+  ","
+  "|"
+  "="
+] @operator
+
+; Text
+(CharData) @none @spell
+
+(CDSect
+  (CDStart) @module
+  (CData) @markup.raw
+  "]]>" @module)
+
+; Misc
+(Comment) @comment @spell

package/out/xml/indents.scm

@@ -0,0 +1,16 @@
+(element) @indent.begin
+
+[
+  (Attribute)
+  (AttlistDecl)
+  (contentspec)
+] @indent.align
+
+(ETag) @indent.branch
+
+(doctypedecl) @indent.ignore
+
+[
+  (Comment)
+  (ERROR)
+] @indent.auto

package/out/xml/injections.scm

@@ -0,0 +1,32 @@
+((Comment) @injection.content
+  (#set! injection.language "comment"))
+
+; SVG style
+((element
+  (STag
+    (Name) @_name)
+  (content) @injection.content)
+  (#eq? @_name "style")
+  (#set! injection.combined)
+  (#set! injection.include-children)
+  (#set! injection.language "css"))
+
+; SVG script
+((element
+  (STag
+    (Name) @_name)
+  (content) @injection.content)
+  (#eq? @_name "script")
+  (#set! injection.combined)
+  (#set! injection.include-children)
+  (#set! injection.language "javascript"))
+
+; phpMyAdmin dump
+((element
+  (STag
+    (Name) @_name)
+  (content) @injection.content)
+  (#eq? @_name "pma:table")
+  (#set! injection.combined)
+  (#set! injection.include-children)
+  (#set! injection.language "sql"))

package/out/xml/locals.scm

@@ -0,0 +1,35 @@
+; tags
+(elementdecl
+  (Name) @local.definition.type)
+
+(elementdecl
+  (contentspec
+    (children
+      (Name) @local.reference)))
+
+(AttlistDecl
+  .
+  (Name) @local.reference)
+
+(STag
+  (Name) @local.reference)
+
+(ETag
+  (Name) @local.reference)
+
+(EmptyElemTag
+  (Name) @local.reference)
+
+; attributes
+(AttDef
+  (Name) @local.definition.field)
+
+(Attribute
+  (Name) @local.reference)
+
+; entities
+(GEDecl
+  (Name) @local.definition.macro)
+
+(EntityRef
+  (Name) @local.reference)

package/out/yaml/folds.scm

@@ -0,0 +1,4 @@
+[
+  (block_mapping_pair)
+  (block_sequence_item)
+] @fold

package/out/yaml/highlights.scm

@@ -0,0 +1,79 @@
+(boolean_scalar) @boolean
+
+(null_scalar) @constant.builtin
+
+[
+  (double_quote_scalar)
+  (single_quote_scalar)
+  (block_scalar)
+  (string_scalar)
+] @string
+
+[
+  (integer_scalar)
+  (float_scalar)
+] @number
+
+(comment) @comment
+
+[
+  (anchor_name)
+  (alias_name)
+] @label
+
+(tag) @type
+
+[
+  (yaml_directive)
+  (tag_directive)
+  (reserved_directive)
+] @attribute
+
+(block_mapping_pair
+  key: (flow_node
+    [
+      (double_quote_scalar)
+      (single_quote_scalar)
+    ] @property))
+
+(block_mapping_pair
+  key: (flow_node
+    (plain_scalar
+      (string_scalar) @property)))
+
+(flow_mapping
+  (_
+    key: (flow_node
+      [
+        (double_quote_scalar)
+        (single_quote_scalar)
+      ] @property)))
+
+(flow_mapping
+  (_
+    key: (flow_node
+      (plain_scalar
+        (string_scalar) @property))))
+
+[
+  ","
+  "-"
+  ":"
+  ">"
+  "?"
+  "|"
+] @punctuation.delimiter
+
+[
+  "["
+  "]"
+  "{"
+  "}"
+] @punctuation.bracket
+
+[
+  "*"
+  "&"
+  "---"
+  "..."
+] @punctuation.special

package/out/yaml/indents.scm

@@ -0,0 +1,7 @@
+[
+  (block_mapping_pair
+    value: (block_node))
+  (block_sequence_item)
+] @indent.begin
+
+(ERROR) @indent.auto