tree-sitter-wasm 1.0.0

package/out/nix/indents.scm

@@ -0,0 +1,75 @@
+[
+  (list_expression)
+  (indented_string_expression)
+  (let_expression)
+  (if_expression)
+  (binding)
+  (parenthesized_expression)
+] @indent.begin
+
+((attrset_expression) @indent.begin
+  (#not-has-parent? @indent.begin if_expression))
+
+((rec_attrset_expression) @indent.begin
+  (#not-has-parent? @indent.begin if_expression))
+
+((binding
+  "=" @indent.begin)
+  (#set! indent.immediate 1))
+
+(binding
+  ";" @indent.end)
+
+(parenthesized_expression
+  ")" @indent.branch @indent.end)
+
+(attrset_expression
+  "}" @indent.branch @indent.end)
+
+(rec_attrset_expression
+  "}" @indent.branch @indent.end)
+
+(list_expression
+  "]" @indent.branch @indent.dedent)
+
+(indented_string_expression
+  "''" @indent.branch @indent.end .)
+
+[
+  "else"
+  "in"
+] @indent.branch
+
+(let_expression
+  body: (_) @indent.end @indent.dedent)
+
+(string_fragment) @indent.ignore @indent.auto
+
+(if_expression
+  condition: (_) @indent.auto)
+
+alternative: (if_expression) @indent.dedent
+
+(interpolation) @indent.begin @indent.dedent
+
+(interpolation
+  "}" @indent.end @indent.branch)
+
+(ERROR
+  "then" @indent.begin)
+
+(ERROR
+  "then"
+  .
+  (formals) @indent.begin)
+
+(ERROR
+  "then"
+  .
+  (formals
+    "}" @indent.branch @indent.end))
+
+(ERROR
+  "let") @indent.begin
+
+(comment) @indent.ignore

package/out/nix/injections.scm

@@ -0,0 +1,39 @@
+; mark arbitary languages with a comment
+((((comment) @injection.language) .
+  (indented_string_expression (string_fragment) @injection.content))
+  (#set! injection.combined))
+
+((binding
+   attrpath: (attrpath (identifier) @_path)
+   expression: (indented_string_expression
+     (string_fragment) @injection.content))
+ (#match? @_path "(^\\w*Phase|(pre|post)\\w*|(.*\\.)?\\w*([sS]cript|[hH]ook)|(.*\\.)?startup)$")
+ (#set! injection.language "bash")
+ (#set! injection.combined))
+
+((apply_expression
+   function: (apply_expression function: (_) @_func)
+   argument: (indented_string_expression (string_fragment) @injection.content))
+ (#match? @_func "(^|\\.)writeShellScript(Bin)?$")
+ (#set! injection.language "bash")
+ (#set! injection.combined))
+
+(apply_expression
+  (apply_expression
+    function: (apply_expression
+      function: ((_) @_func)))
+    argument: (indented_string_expression (string_fragment) @injection.content)
+  (#match? @_func "(^|\\.)runCommand(((No)?(CC))?(Local)?)?$")
+  (#set! injection.language "bash")
+  (#set! injection.combined))
+
+(apply_expression
+  function: ((_) @_func)
+  argument: (_ (_)* (_ (_)* (binding
+    attrpath: (attrpath (identifier) @_path)
+     expression: (indented_string_expression
+       (string_fragment) @injection.content))))
+  (#match? @_func "(^|\\.)writeShellApplication$")
+  (#match? @_path "^text$")
+  (#set! injection.language "bash")
+  (#set! injection.combined))

package/out/nix/locals.scm

@@ -0,0 +1,33 @@
+;; when using @local.reference, tree-sitter seems to 
+;; apply the scope from the identifier it has looked up,
+;; which makes sense for most languages.
+;; however, we want to highlight things as function based on their call-site,
+;; not their definition; therefore using TS's support for tracking locals
+;; impedes our ability to get the highlighting we want.
+;;
+;; also, TS doesn't seem to support scoping as implemented in languages
+;; with lazy let bindings, which results in syntax highlighting/goto-reference
+;; results that depend on the order of definitions, which is counter to the
+;; semantics of Nix.
+;;
+;; so for now we'll opt for not having any locals queries.
+;;
+;; see: https://github.com/tree-sitter/tree-sitter/issues/918
+
+;(function_expression
+;  universal: (identifier)? @local.definition
+;  formals: (formals (formal name: (identifier) @local.definition)*)
+;  universal: (identifier)? @local.definition
+;  ) @local.scope
+;
+;(rec_attrset_expression
+;  bind: (binding
+;    attrpath: (attrpath . (attr_identifier) @local.definition)) 
+;) @local.scope
+;
+;(let_expression
+;  bind: (binding
+;    attrpath: (attrpath . (attr_identifier) @local.definition)) 
+;) @local.scope
+;
+;(identifier) @local.reference 

package/out/nix/tags.scm

@@ -0,0 +1,16 @@
+;; https://tree-sitter.github.io/tree-sitter/4-code-navigation.html
+
+;;Function definitions
+(binding
+  attrpath: (attrpath attr: (identifier)) @name
+  expression: (function_expression) @definition.function)
+;;Function/method calls
+(apply_expression function: (apply_expression function: (variable_expression name: (identifier) @name)) @reference.call)
+
+;; TODO: (if even applicable?)
+;;Interface definitions       @definition.interface
+;;Interface implementation    @reference.implementation
+;;Class definitions           @definition.class
+;;Class reference             @reference.class
+;;Method definitions          @definition.method
+;;Module definitions          @definition.module

package/out/objc/folds.scm

@@ -0,0 +1,20 @@
+; inherits: c
+
+[
+  (class_declaration)
+  (class_interface)
+  (class_implementation)
+  (protocol_declaration)
+  (property_declaration)
+  (method_declaration)
+  (struct_declaration)
+  (struct_declarator)
+  (try_statement)
+  (catch_clause)
+  (finally_clause)
+  (throw_statement)
+  (block_literal)
+  (ms_asm_block)
+  (dictionary_literal)
+  (array_literal)
+] @fold

package/out/objc/highlights.scm

@@ -0,0 +1,216 @@
+; inherits: c
+
+; Preprocs
+
+(preproc_undef
+  name: (_) @constant) @preproc
+
+; Includes
+
+(module_import "@import" @include path: (identifier) @namespace)
+
+((preproc_include
+  _ @include path: (_))
+  (#any-of? @include "#include" "#import"))
+
+; Type Qualifiers
+
+[
+  "@optional"
+  "@required"
+  "__covariant"
+  "__contravariant"
+  (visibility_specification)
+] @type.qualifier
+
+; Storageclasses
+
+[
+  "@autoreleasepool"
+  "@synthesize"
+  "@dynamic"
+  "volatile"
+  (protocol_qualifier)
+] @storageclass
+
+; Keywords
+
+[
+  "@protocol"
+  "@interface"
+  "@implementation"
+  "@compatibility_alias"
+  "@property"
+  "@selector"
+  "@defs"
+  "availability"
+  "@end"
+] @keyword
+
+(class_declaration "@" @keyword "class" @keyword) ; I hate Obj-C for allowing "@ class" :)
+
+(method_definition ["+" "-"] @keyword.function)
+(method_declaration ["+" "-"] @keyword.function)
+
+[
+  "__typeof__"
+  "__typeof"
+  "typeof"
+  "in"
+] @keyword.operator
+
+[
+  "@synchronized"
+  "oneway"
+] @keyword.coroutine
+
+; Exceptions
+
+[
+  "@try"
+  "__try"
+  "@catch"
+  "__catch"
+  "@finally"
+  "__finally"
+  "@throw"
+] @exception
+
+; Variables
+
+((identifier) @variable.builtin
+  (#any-of? @variable.builtin "self" "super"))
+
+; Functions & Methods
+
+[
+  "objc_bridge_related"
+  "@available"
+  "__builtin_available"
+  "va_arg"
+  "asm"
+] @function.builtin
+
+(method_definition (identifier) @method)
+
+(method_declaration (identifier) @method)
+
+(method_identifier (identifier)? @method ":" @method (identifier)? @method)
+
+(message_expression method: (identifier) @method.call)
+
+; Constructors
+
+((message_expression method: (identifier) @constructor)
+  (#eq? @constructor "init"))
+
+; Attributes
+
+(availability_attribute_specifier 
+  [
+    "CF_FORMAT_FUNCTION" "NS_AVAILABLE" "__IOS_AVAILABLE" "NS_AVAILABLE_IOS"
+    "API_AVAILABLE" "API_UNAVAILABLE" "API_DEPRECATED" "NS_ENUM_AVAILABLE_IOS"
+    "NS_DEPRECATED_IOS" "NS_ENUM_DEPRECATED_IOS" "NS_FORMAT_FUNCTION" "DEPRECATED_MSG_ATTRIBUTE"
+    "__deprecated_msg" "__deprecated_enum_msg" "NS_SWIFT_NAME" "NS_SWIFT_UNAVAILABLE"
+    "NS_EXTENSION_UNAVAILABLE_IOS" "NS_CLASS_AVAILABLE_IOS" "NS_CLASS_DEPRECATED_IOS" "__OSX_AVAILABLE_STARTING"
+    "NS_ROOT_CLASS" "NS_UNAVAILABLE" "NS_REQUIRES_NIL_TERMINATION" "CF_RETURNS_RETAINED"
+    "CF_RETURNS_NOT_RETAINED" "DEPRECATED_ATTRIBUTE" "UI_APPEARANCE_SELECTOR" "UNAVAILABLE_ATTRIBUTE"
+  ]) @attribute
+
+; Macros
+
+(type_qualifier
+  [
+    "_Complex"
+    "_Nonnull"
+    "_Nullable"
+    "_Nullable_result"
+    "_Null_unspecified"
+    "__autoreleasing"
+    "__block"
+    "__bridge"
+    "__bridge_retained"
+    "__bridge_transfer"
+    "__complex"
+    "__kindof"
+    "__nonnull"
+    "__nullable"
+    "__ptrauth_objc_class_ro"
+    "__ptrauth_objc_isa_pointer"
+    "__ptrauth_objc_super_pointer"
+    "__strong"
+    "__thread"
+    "__unsafe_unretained"
+    "__unused"
+    "__weak"
+  ]) @function.macro.builtin
+
+[ "__real" "__imag" ] @function.macro.builtin
+
+((call_expression function: (identifier) @function.macro)
+  (#eq? @function.macro "testassert"))
+
+; Types
+
+(class_declaration (identifier) @type)
+
+(class_interface "@interface" . (identifier) @type superclass: _? @type category: _? @namespace)
+
+(class_implementation "@implementation" . (identifier) @type superclass: _? @type category: _? @namespace)
+
+(protocol_forward_declaration (identifier) @type) ; @interface :(
+
+(protocol_reference_list (identifier) @type) ; ^
+
+[
+  "BOOL"
+  "IMP"
+  "SEL"
+  "Class"
+  "id"
+] @type.builtin
+
+; Constants
+
+(property_attribute (identifier) @constant "="?)
+
+[ "__asm" "__asm__" ] @constant.macro
+
+; Properties
+
+(property_implementation "@synthesize" (identifier) @property)
+
+((identifier) @property
+  (#has-ancestor? @property struct_declaration))
+
+; Parameters
+
+(method_parameter ":" @method (identifier) @parameter)
+
+(method_parameter declarator: (identifier) @parameter)
+
+(parameter_declaration 
+  declarator: (function_declarator 
+                declarator: (parenthesized_declarator 
+                              (block_pointer_declarator 
+                                declarator: (identifier) @parameter))))
+
+"..." @parameter.builtin
+
+; Operators
+
+[
+  "^"
+] @operator
+
+; Literals
+
+(platform) @string.special
+
+(version_number) @text.uri @number
+
+; Punctuation
+
+"@" @punctuation.special
+
+[ "<" ">" ] @punctuation.bracket

package/out/objc/indents.scm

@@ -0,0 +1 @@
+; inherits: c

package/out/objc/injections.scm

@@ -0,0 +1,10 @@
+; inherits: c
+
+; TODO(amaanq): uncomment/add when I add asm support
+; (ms_asm_block "{" _ @asm "}")
+;
+; ((asm_specifier (string_literal) @asm)
+;   (#offset! @asm 0 1 0 -1))
+;
+; ((asm_statement (string_literal) @asm)
+;   (#offset! @asm 0 1 0 -1))

package/out/objc/locals.scm

@@ -0,0 +1 @@
+; inherits: c

package/out/ocaml/folds.scm

@@ -0,0 +1,30 @@
+[
+  (let_binding)
+  (external)
+  (type_binding)
+  (exception_definition)
+  (module_binding)
+  (module_type_definition)
+  (open_module)
+  (include_module)
+  (include_module_type)
+  (class_binding)
+  (class_type_binding)
+  (value_specification)
+  (inheritance_specification)
+  (instance_variable_specification)
+  (method_specification)
+  (inheritance_definition)
+  (instance_variable_definition)
+  (method_definition)
+  (class_initializer)
+  (match_case)
+  (attribute)
+  (item_attribute)
+  (floating_attribute)
+  (extension)
+  (item_extension)
+  (quoted_extension)
+  (quoted_item_extension)
+  (comment)
+] @fold

package/out/ocaml/highlights.scm

@@ -0,0 +1,148 @@
+; Punctuation
+;------------
+
+[
+  "," "." ";" ":" "=" "|" "~" "?" "+" "-" "!" ">" "&"
+  "->" ";;" ":>" "+=" ":=" ".."
+] @punctuation.delimiter
+
+["(" ")" "[" "]" "{" "}" "[|" "|]" "[<" "[>"] @punctuation.bracket
+
+(object_type ["<" ">"] @punctuation.bracket)
+
+"%" @punctuation.special
+
+(attribute ["[@" "]"] @punctuation.special)
+(item_attribute ["[@@" "]"] @punctuation.special)
+(floating_attribute ["[@@@" "]"] @punctuation.special)
+(extension ["[%" "]"] @punctuation.special)
+(item_extension ["[%%" "]"] @punctuation.special)
+(quoted_extension ["{%" "}"] @punctuation.special)
+(quoted_item_extension ["{%%" "}"] @punctuation.special)
+
+; Keywords
+;---------
+
+[
+  "and" "as" "assert" "begin" "class" "constraint" "do" "done" "downto" "effect"
+  "else" "end" "exception" "external" "for" "fun" "function" "functor" "if" "in"
+  "include" "inherit" "initializer" "lazy" "let" "match" "method" "module"
+  "mutable" "new" "nonrec" "object" "of" "open" "private" "rec" "sig" "struct"
+  "then" "to" "try" "type" "val" "virtual" "when" "while" "with"
+] @keyword
+
+; Operators
+;----------
+
+[
+  (prefix_operator)
+  (sign_operator)
+  (pow_operator)
+  (mult_operator)
+  (add_operator)
+  (concat_operator)
+  (rel_operator)
+  (and_operator)
+  (or_operator)
+  (assign_operator)
+  (hash_operator)
+  (indexing_operator)
+  (let_operator)
+  (let_and_operator)
+  (match_operator)
+] @operator
+
+(match_expression (match_operator) @keyword)
+
+(value_definition [(let_operator) (let_and_operator)] @keyword)
+
+["*" "#" "::" "<-"] @operator
+
+; Constants
+;----------
+
+(boolean) @constant
+
+[(number) (signed_number)] @number
+
+[(string) (character)] @string
+
+(quoted_string "{" @string "}" @string) @string
+
+(escape_sequence) @escape
+
+(conversion_specification) @string.special
+
+; Variables
+;----------
+
+[(value_name) (type_variable)] @variable
+
+(value_pattern) @variable.parameter
+
+; Properties
+;-----------
+
+[(label_name) (field_name) (instance_variable_name)] @property
+
+; Functions
+;----------
+
+(let_binding
+  pattern: (value_name) @function
+  (parameter))
+
+(let_binding
+  pattern: (value_name) @function
+  body: [(fun_expression) (function_expression)])
+
+(value_specification (value_name) @function)
+
+(external (value_name) @function)
+
+(method_name) @function.method
+
+(application_expression
+  function: (value_path (value_name) @function))
+
+(infix_expression
+  left: (value_path (value_name) @function)
+  operator: (concat_operator) @operator
+  (#eq? @operator "@@"))
+
+(infix_expression
+  operator: (rel_operator) @operator
+  right: (value_path (value_name) @function)
+  (#eq? @operator "|>"))
+
+(
+  (value_name) @function.builtin
+  (#match? @function.builtin "^(raise(_notrace)?|failwith|invalid_arg)$")
+)
+
+; Types
+;------
+
+[(class_name) (class_type_name) (type_constructor)] @type
+
+(
+  (type_constructor) @type.builtin
+  (#match? @type.builtin "^(int|char|bytes|string|float|bool|unit|exn|array|list|option|int32|int64|nativeint|format6|lazy_t)$")
+)
+
+[(constructor_name) (tag)] @constructor
+
+; Modules
+;--------
+
+[(module_name) (module_type_name)] @module
+
+; Attributes
+;-----------
+
+(attribute_id) @tag
+
+; Comments
+;---------
+
+[(comment) (line_number_directive) (directive) (shebang)] @comment

package/out/ocaml/indents.scm

@@ -0,0 +1,77 @@
+; format-ignore
+[ 
+  (let_binding)                 ; let = ...
+  (type_binding)
+
+  (external)
+  (record_declaration)          ; { foo: bar ... }
+  (structure)                   ; struct ... end
+  (signature)                   ; sig ... end
+  (value_specification)         ; val x: bar
+
+  (do_clause)                   ; do ... done
+  (match_case)
+
+  (field_expression)
+  (application_expression)
+  (parenthesized_expression)    ; ( ... )
+  (record_expression)           ; { foo = bar ... }
+  (list_expression)             ; [...;...]
+  (try_expression)              ; try ... with
+] @indent.begin
+
+; handle if-else if-else case
+(if_expression
+  condition: (_) @indent.begin)
+
+(then_clause) @indent.begin
+
+((else_clause
+  (_) @_not_if) @indent.begin
+  (#not-kind-eq? @_not_if "if_expression"))
+
+((parameter) @indent.begin
+  (#set! indent.start_at_same_line))
+
+(_
+  (ERROR) @indent.begin
+  (#set! indent.start_at_same_line))
+
+(ERROR
+  "|" @indent.begin
+  (#set! indent.start_at_same_line))
+
+(try_expression
+  "with" @indent.branch
+  [
+    (match_case) @indent.dedent
+    (match_case
+      [
+        (parenthesized_expression)
+        (list_expression)
+      ] @indent.dedent)
+  ])
+
+"}" @indent.branch @indent.end
+
+(list_expression
+  "]" @indent.branch)
+
+(parenthesized_expression
+  ")" @indent.branch)
+
+";;" @indent.end
+
+(do_clause
+  "done" @indent.end @indent.branch)
+
+(structure
+  "end" @indent.end @indent.branch)
+
+(signature
+  "end" @indent.end @indent.branch)
+
+[
+  (string)
+  (comment)
+] @indent.auto

package/out/ocaml/injections.scm

@@ -0,0 +1,2 @@
+((comment) @injection.content
+  (#set! injection.language "comment"))