tree-sitter-wasm 1.0.0

package/out/desktop/highlights.scm

@@ -0,0 +1,91 @@
+(comment) @comment @spell
+
+(group_name) @markup.heading
+
+(entry
+  key: (identifier) @property)
+
+[
+  (language)
+  (country)
+  (encoding)
+  (modifier)
+] @string.special
+
+(string) @string
+
+(escape_sequence) @string.escape
+
+(field_code) @character.special
+
+[
+  (true)
+  (false)
+] @boolean
+
+"=" @operator
+
+[
+  ";"
+  "_"
+  "."
+  "@"
+] @punctuation.delimiter
+
+[
+  "["
+  "]"
+] @punctuation.bracket
+
+; Especial entries
+((entry
+  key: (identifier) @_key
+  value: (string) @type)
+  (#eq? @_key "Type")
+  (#any-of? @type "Application" "Link" "Directory"))
+
+((entry
+  key: (identifier) @_key
+  value: (string) @number)
+  (#eq? @_key "Version"))
+
+((entry
+  key: (identifier) @_key
+  value: (string) @string.special.path)
+  (#any-of? @_key "TryExec" "Path"))
+
+((entry
+  key: (identifier) @_key
+  value: (string) @string.special.url)
+  (#eq? @_key "URL"))
+
+; https://specifications.freedesktop.org/menu-spec/latest/category-registry.html
+((entry
+  key: (identifier) @_key
+  value: (list
+    (string) @constant.builtin))
+  (#eq? @_key "Categories")
+  (#any-of? @constant.builtin
+    ; Main categories
+    "AudioVideo" "Audio" "Video" "Development" "Education" "Game" "Graphics" "Network" "Office"
+    "Science" "Settings" "System" "Utility"
+    ; Additional Categories
+    "Building" "Debugger" "IDE" "GUIDesigner" "Profiling" "RevisionControl" "Translation" "Calendar"
+    "ContactManagement" "Database" "Dictionary" "Chart" "Email" "Finance" "FlowChart" "PDA"
+    "ProjectManagement" "Presentation" "Spreadsheet" "WordProcessor" "2DGraphics" "VectorGraphics"
+    "RasterGraphics" "3DGraphics" "Scanning" "OCR" "Photography" "Publishing" "Viewer" "TextTools"
+    "DesktopSettings" "HardwareSettings" "Printing" "PackageManager" "Dialup" "InstantMessaging"
+    "Chat" "IRCClient" "Feed" "FileTransfer" "HamRadio" "News" "P2P" "RemoteAccess" "Telephony"
+    "TelephonyTools" "VideoConference" "WebBrowser" "WebDevelopment" "Midi" "Mixer" "Sequencer"
+    "Tuner" "TV" "AudioVideoEditing" "Player" "Recorder" "DiscBurning" "ActionGame" "AdventureGame"
+    "ArcadeGame" "BoardGame" "BlocksGame" "CardGame" "KidsGame" "LogicGame" "RolePlaying" "Shooter"
+    "Simulation" "SportsGame" "StrategyGame" "Art" "Construction" "Music" "Languages"
+    "ArtificialIntelligence" "Astronomy" "Biology" "Chemistry" "ComputerScience" "DataVisualization"
+    "Economy" "Electricity" "Geography" "Geology" "Geoscience" "History" "Humanities"
+    "ImageProcessing" "Literature" "Maps" "Math" "NumericalAnalysis" "MedicalSoftware" "Physics"
+    "Robotics" "Spirituality" "Sports" "ParallelComputing" "Amusement" "Archiving" "Compression"
+    "Electronics" "Emulator" "Engineering" "FileTools" "FileManager" "TerminalEmulator" "Filesystem"
+    "Monitor" "Security" "Accessibility" "Calculator" "Clock" "TextEditor" "Documentation" "Adult"
+    "Core" "KDE" "COSMIC" "GNOME" "XFCE" "DDE" "GTK" "Qt" "Motif" "Java" "ConsoleOnly"
+    ; Reserved
+    "Screensaver" "TrayIcon" "Applet" "Shell"))

package/out/desktop/injections.scm

@@ -0,0 +1,8 @@
+((comment) @injection.content
+  (#set! injection.language "comment"))
+
+((entry
+  key: (identifier) @_exec
+  value: (string) @injection.content)
+  (#eq? @_exec "Exec")
+  (#set! injection.language "bash"))

package/out/devicetree/folds.scm

@@ -0,0 +1 @@
+(node) @fold

package/out/devicetree/highlights.scm

@@ -0,0 +1,78 @@
+[
+    "/delete-node/"
+    "/delete-property/"
+    "/dts-v1/"
+    "/incbin/"
+    "/include/"
+    "/memreserve/"
+    "/omit-if-no-ref/"
+    "#define"
+    "#undef"
+    "#include"
+    "#if"
+    "#elif"
+    "#else"
+    "#endif"
+    "#ifdef"
+    "#ifndef"
+] @keyword
+
+[
+    "!"
+    "~"
+    "-"
+    "+"
+    "*"
+    "/"
+    "%"
+    "||"
+    "&&"
+    "|"
+    "^"
+    "&"
+    "=="
+    "!="
+    ">"
+    ">="
+    "<="
+    ">"
+    "<<"
+    ">>"
+] @operator
+
+[
+    ","
+    ";"
+] @punctuation.delimiter
+
+[
+    "("
+    ")"
+    "{"
+    "}"
+    "<"
+    ">"
+] @punctuation.bracket
+
+(call_expression
+    function: (identifier) @function)
+
+(node
+    label: (identifier) @label)
+
+(property
+    label: (identifier) @label)
+
+(memory_reservation
+    label: (identifier) @label)
+
+(property
+    name: (identifier) @property)
+
+(identifier) @variable
+
+(unit_address) @tag
+
+(reference) @constant
+
+(comment) @comment

package/out/devicetree/indents.scm

@@ -0,0 +1,12 @@
+[
+  (node)
+  (property)
+  (integer_cells)
+] @indent.begin
+
+[
+  "}"
+  ">"
+] @indent.branch
+
+(comment) @indent.ignore

package/out/devicetree/injections.scm

@@ -0,0 +1,2 @@
+((comment) @injection.content
+  (#set! injection.language "comment"))

package/out/devicetree/locals.scm

@@ -0,0 +1,4 @@
+[
+  (node)
+  (integer_cells)
+] @local.scope

package/out/diff/folds.scm

@@ -0,0 +1,5 @@
+[
+  (block)
+  (hunks)
+  (hunk)
+] @fold

package/out/diff/highlights.scm

@@ -0,0 +1,49 @@
+(comment) @comment @spell
+
+[
+  (addition)
+  (new_file)
+] @diff.plus
+
+[
+  (deletion)
+  (old_file)
+] @diff.minus
+
+(commit) @constant
+
+(location) @attribute
+
+(command
+  "diff" @function
+  (argument) @variable.parameter)
+
+(filename) @string.special.path
+
+(mode) @number
+
+([
+  ".."
+  "+"
+  "++"
+  "+++"
+  "++++"
+  "-"
+  "--"
+  "---"
+  "----"
+] @punctuation.special
+  (#set! priority 95))
+
+[
+  (binary_change)
+  (similarity)
+  (file_change)
+] @label
+
+(index
+  "index" @keyword)
+
+(similarity
+  (score) @number
+  "%" @number)

package/out/diff/injections.scm

@@ -0,0 +1,2 @@
+((comment) @injection.content
+  (#set! injection.language "comment"))

package/out/dockerfile/highlights.scm

@@ -0,0 +1,58 @@
+[
+	"FROM"
+	"AS"
+	"RUN"
+	"CMD"
+	"LABEL"
+	"EXPOSE"
+	"ENV"
+	"ADD"
+	"COPY"
+	"ENTRYPOINT"
+	"VOLUME"
+	"USER"
+	"WORKDIR"
+	"ARG"
+	"ONBUILD"
+	"STOPSIGNAL"
+	"HEALTHCHECK"
+	"SHELL"
+	"MAINTAINER"
+	"CROSS_BUILD"
+	(heredoc_marker)
+	(heredoc_end)
+] @keyword
+
+[
+	":"
+	"@"
+] @operator
+
+(comment) @comment
+
+
+(image_spec
+	(image_tag
+		":" @punctuation.special)
+	(image_digest
+		"@" @punctuation.special))
+
+[
+	(double_quoted_string)
+	(single_quoted_string)
+	(json_string)
+	(heredoc_line)
+] @string
+
+(expansion
+  [
+	"$"
+	"{"
+	"}"
+  ] @punctuation.special
+) @none
+
+((variable) @constant
+ (#match? @constant "^[A-Z][A-Z_0-9]*$"))
+
+

package/out/dockerfile/injections.scm

@@ -0,0 +1,12 @@
+((comment) @injection.content
+  (#set! injection.language "comment"))
+
+((shell_command
+  (shell_fragment) @injection.content)
+  (#set! injection.language "bash")
+  (#set! injection.combined))
+
+((run_instruction
+  (heredoc_block) @injection.content)
+  (#set! injection.language "bash")
+  (#set! injection.include-children))

package/out/dtd/folds.scm

@@ -0,0 +1,4 @@
+[
+  (conditionalSect)
+  (Comment)
+] @fold

package/out/dtd/highlights.scm

@@ -0,0 +1,148 @@
+; Text declaration
+(TextDecl
+  "xml" @keyword.directive)
+
+(TextDecl
+  [
+    "version"
+    "encoding"
+  ] @tag.attribute)
+
+(TextDecl
+  (EncName) @string.special)
+
+(TextDecl
+  (VersionNum) @number)
+
+; Processing instructions
+(PI) @keyword.directive
+
+; Element declaration
+(elementdecl
+  "ELEMENT" @keyword.directive.define
+  (Name) @tag)
+
+(contentspec
+  (_
+    (Name) @tag.attribute))
+
+"#PCDATA" @type.builtin
+
+[
+  "EMPTY"
+  "ANY"
+] @keyword.modifier
+
+[
+  "*"
+  "?"
+  "+"
+] @character.special
+
+; Entity declaration
+(GEDecl
+  "ENTITY" @keyword.directive.define
+  (Name) @constant)
+
+(GEDecl
+  (EntityValue) @string)
+
+(NDataDecl
+  "NDATA" @keyword
+  (Name) @label)
+
+; Parsed entity declaration
+(PEDecl
+  "ENTITY" @keyword.directive.define
+  "%" @operator
+  (Name) @function.macro)
+
+(PEDecl
+  (EntityValue) @string)
+
+; Notation declaration
+(NotationDecl
+  "NOTATION" @keyword.directive
+  (Name) @label)
+
+; Attlist declaration
+(AttlistDecl
+  "ATTLIST" @keyword.directive.define
+  (Name) @tag)
+
+(AttDef
+  (Name) @tag.attribute)
+
+(AttDef
+  (Enumeration
+    (Nmtoken) @string))
+
+[
+  (StringType)
+  (TokenizedType)
+] @type.builtin
+
+(NotationType
+  "NOTATION" @type.builtin)
+
+[
+  "#REQUIRED"
+  "#IMPLIED"
+  "#FIXED"
+] @attribute
+
+; Entities
+(EntityRef) @constant
+
+((EntityRef) @constant.builtin
+  (#any-of? @constant.builtin "&" "<" ">" """ "'"))
+
+(CharRef) @character
+
+(PEReference) @function.macro
+
+; External references
+[
+  "PUBLIC"
+  "SYSTEM"
+] @keyword
+
+(PubidLiteral) @string.special
+
+(SystemLiteral
+  (URI) @string.special.url)
+
+; Delimiters & punctuation
+[
+  "<?"
+  "?>"
+  "<!"
+  ">"
+  "<!["
+  "]]>"
+] @tag.delimiter
+
+[
+  "("
+  ")"
+  "["
+] @punctuation.bracket
+
+[
+  "\""
+  "'"
+] @punctuation.delimiter
+
+[
+  ","
+  "|"
+  "="
+] @operator
+
+; Misc
+[
+  "INCLUDE"
+  "IGNORE"
+] @keyword.import
+
+(Comment) @comment @spell

package/out/dtd/injections.scm

@@ -0,0 +1,2 @@
+((Comment) @injection.content
+  (#set! injection.language "comment"))

package/out/dtd/locals.scm

@@ -0,0 +1,11 @@
+(elementdecl
+  (Name) @local.definition.type)
+
+(elementdecl
+  (contentspec
+    (children
+      (Name) @local.reference)))
+
+(AttlistDecl
+  .
+  (Name) @local.reference)

package/out/editorconfig/folds.scm

@@ -0,0 +1 @@
+(section) @fold

package/out/editorconfig/highlights.scm

@@ -0,0 +1,35 @@
+(comment) @comment @spell
+
+(property) @property
+
+(string) @string
+
+(header
+  (glob) @string.special.path)
+
+(character) @character
+
+(character_escape) @string.escape
+
+(wildcard) @character.special
+
+(integer) @number
+
+[
+  "["
+  "]"
+  "{"
+  "}"
+] @punctuation.bracket
+
+[
+  ","
+  ".."
+  "/"
+  "-"
+] @punctuation.delimiter
+
+[
+  "="
+  "!"
+] @operator

package/out/editorconfig/injections.scm

@@ -0,0 +1,2 @@
+((comment) @injection.content
+  (#set! injection.language "comment"))

package/out/elisp/highlights.scm

@@ -0,0 +1,72 @@
+;; Special forms
+[
+  "and"
+  "catch"
+  "cond"
+  "condition-case"
+  "defconst"
+  "defvar"
+  "function"
+  "if"
+  "interactive"
+  "lambda"
+  "let"
+  "let*"
+  "or"
+  "prog1"
+  "prog2"
+  "progn"
+  "quote"
+  "save-current-buffer"
+  "save-excursion"
+  "save-restriction"
+  "setq"
+  "setq-default"
+  "unwind-protect"
+  "while"
+] @keyword
+
+;; Function definitions
+[
+ "defun"
+ "defsubst"
+ ] @keyword
+(function_definition name: (symbol) @function)
+(function_definition parameters: (list (symbol) @variable.parameter))
+(function_definition docstring: (string) @comment)
+
+;; Highlight macro definitions the same way as function definitions.
+"defmacro" @keyword
+(macro_definition name: (symbol) @function)
+(macro_definition parameters: (list (symbol) @variable.parameter))
+(macro_definition docstring: (string) @comment)
+
+(comment) @comment
+
+(integer) @number
+(float) @number
+(char) @number
+
+(string) @string
+
+[
+  "("
+  ")"
+  "#["
+  "["
+  "]"
+] @punctuation.bracket
+
+[
+  "`"
+  "#'"
+  "'"
+  ","
+  ",@"
+] @operator
+
+;; Highlight nil and t as constants, unlike other symbols
+[
+  "nil"
+  "t"
+] @constant.builtin

package/out/elisp/tags.scm

@@ -0,0 +1,5 @@
+;; defun/defsubst
+(function_definition name: (symbol) @name) @definition.function
+
+;; Treat macros as function definitions for the sake of TAGS.
+(macro_definition name: (symbol) @name) @definition.function

package/out/elixir/folds.scm

@@ -0,0 +1,10 @@
+[
+  (anonymous_function)
+  (stab_clause)
+  (arguments)
+  (block)
+  (do_block)
+  (list)
+  (map)
+  (tuple)
+] @fold