tree-sitter-wasm 1.0.0

package/out/go/injections.scm

@@ -0,0 +1,42 @@
+((comment) @injection.content
+  (#set! injection.language "comment"))
+
+(call_expression
+  (selector_expression) @_function
+  (#any-of? @_function
+    "regexp.Match" "regexp.MatchReader" "regexp.MatchString" "regexp.Compile" "regexp.CompilePOSIX"
+    "regexp.MustCompile" "regexp.MustCompilePOSIX")
+  (argument_list
+    .
+    [
+      (raw_string_literal
+        (raw_string_literal_content) @injection.content)
+      (interpreted_string_literal
+        (interpreted_string_literal_content) @injection.content)
+    ]
+    (#set! injection.language "regex")))
+
+((comment) @injection.content
+  (#match? @injection.content "/\\*!([a-zA-Z]+:)?re2c")
+  (#set! injection.language "re2c"))
+
+((call_expression
+  function: (selector_expression
+    field: (field_identifier) @_method)
+  arguments: (argument_list
+    .
+    (interpreted_string_literal
+      (interpreted_string_literal_content) @injection.content)))
+  (#any-of? @_method "Printf" "Sprintf" "Fatalf" "Scanf" "Errorf" "Skipf" "Logf")
+  (#set! injection.language "printf"))
+
+((call_expression
+  function: (selector_expression
+    field: (field_identifier) @_method)
+  arguments: (argument_list
+    (_)
+    .
+    (interpreted_string_literal
+      (interpreted_string_literal_content) @injection.content)))
+  (#any-of? @_method "Fprintf" "Fscanf" "Appendf" "Sscanf")
+  (#set! injection.language "printf"))

package/out/go/locals.scm

@@ -0,0 +1,88 @@
+((function_declaration
+  name: (identifier) @local.definition.function) ; @function
+  )
+
+((method_declaration
+  name: (field_identifier) @local.definition.method) ; @function.method
+  )
+
+(short_var_declaration
+  left: (expression_list
+    (identifier) @local.definition.var))
+
+(var_spec
+  name: (identifier) @local.definition.var)
+
+(parameter_declaration
+  (identifier) @local.definition.var)
+
+(variadic_parameter_declaration
+  (identifier) @local.definition.var)
+
+(for_statement
+  (range_clause
+    left: (expression_list
+      (identifier) @local.definition.var)))
+
+(const_declaration
+  (const_spec
+    name: (identifier) @local.definition.var))
+
+(type_declaration
+  (type_spec
+    name: (type_identifier) @local.definition.type))
+
+; reference
+(identifier) @local.reference
+
+(type_identifier) @local.reference
+
+(field_identifier) @local.reference
+
+((package_identifier) @local.reference
+  (#set! reference.kind "namespace"))
+
+(package_clause
+  (package_identifier) @local.definition.namespace)
+
+(import_spec_list
+  (import_spec
+    name: (package_identifier) @local.definition.namespace))
+
+; Call references
+((call_expression
+  function: (identifier) @local.reference)
+  (#set! reference.kind "call"))
+
+((call_expression
+  function: (selector_expression
+    field: (field_identifier) @local.reference))
+  (#set! reference.kind "call"))
+
+((call_expression
+  function: (parenthesized_expression
+    (identifier) @local.reference))
+  (#set! reference.kind "call"))
+
+((call_expression
+  function: (parenthesized_expression
+    (selector_expression
+      field: (field_identifier) @local.reference)))
+  (#set! reference.kind "call"))
+
+; Scopes
+(func_literal) @local.scope
+
+(source_file) @local.scope
+
+(function_declaration) @local.scope
+
+(if_statement) @local.scope
+
+(block) @local.scope
+
+(expression_switch_statement) @local.scope
+
+(for_statement) @local.scope
+
+(method_declaration) @local.scope

package/out/go/tags.scm

@@ -0,0 +1,42 @@
+(
+  (comment)* @doc
+  .
+  (function_declaration
+    name: (identifier) @name) @definition.function
+  (#strip! @doc "^//\\s*")
+  (#set-adjacent! @doc @definition.function)
+)
+
+(
+  (comment)* @doc
+  .
+  (method_declaration
+    name: (field_identifier) @name) @definition.method
+  (#strip! @doc "^//\\s*")
+  (#set-adjacent! @doc @definition.method)
+)
+
+(call_expression
+  function: [
+    (identifier) @name
+    (parenthesized_expression (identifier) @name)
+    (selector_expression field: (field_identifier) @name)
+    (parenthesized_expression (selector_expression field: (field_identifier) @name))
+  ]) @reference.call
+
+(type_spec
+  name: (type_identifier) @name) @definition.type
+
+(type_identifier) @name @reference.type
+
+(package_clause "package" (package_identifier) @name)
+
+(type_declaration (type_spec name: (type_identifier) @name type: (interface_type)))
+
+(type_declaration (type_spec name: (type_identifier) @name type: (struct_type)))
+
+(import_declaration (import_spec) @name)
+
+(var_declaration (var_spec name: (identifier) @name))
+
+(const_declaration (const_spec name: (identifier) @name))

package/out/godot_resource/folds.scm

@@ -0,0 +1 @@
+(section) @fold

package/out/godot_resource/highlights.scm

@@ -0,0 +1,49 @@
+(identifier) @variable
+
+(section
+  (identifier) @tag)
+
+(section
+  [
+    "["
+    "]"
+  ] @tag.delimiter)
+
+(attribute
+  (identifier) @tag.attribute)
+
+(property
+  (path) @property)
+
+(constructor
+  (identifier) @constructor)
+
+(string) @string
+
+(integer) @number
+
+(float) @number.float
+
+[
+  (true)
+  (false)
+] @boolean
+
+(null) @constant.builtin
+
+(array
+  [
+    "["
+    "]"
+  ] @punctuation.bracket)
+
+[
+  "("
+  ")"
+  "{"
+  "}"
+] @punctuation.bracket
+
+"=" @operator
+
+(comment) @comment @spell

package/out/godot_resource/injections.scm

@@ -0,0 +1,2 @@
+((comment) @injection.content
+  (#set! injection.language "comment"))

package/out/godot_resource/locals.scm

@@ -0,0 +1 @@
+(section) @local.scope

package/out/graphql/highlights.scm

@@ -0,0 +1,163 @@
+; Types
+;------
+(scalar_type_definition
+  (name) @type)
+
+(object_type_definition
+  (name) @type)
+
+(interface_type_definition
+  (name) @type)
+
+(union_type_definition
+  (name) @type)
+
+(enum_type_definition
+  (name) @type)
+
+(input_object_type_definition
+  (name) @type)
+
+(scalar_type_extension
+  (name) @type)
+
+(object_type_extension
+  (name) @type)
+
+(interface_type_extension
+  (name) @type)
+
+(union_type_extension
+  (name) @type)
+
+(enum_type_extension
+  (name) @type)
+
+(input_object_type_extension
+  (name) @type)
+
+(named_type
+  (name) @type)
+
+; Directives
+;-----------
+(directive_definition
+  "@" @attribute
+  (name) @attribute)
+
+(directive) @attribute
+
+; Properties
+;-----------
+(field
+  (name) @property)
+
+(field
+  (alias
+    (name) @property))
+
+(field_definition
+  (name) @property)
+
+(object_value
+  (object_field
+    (name) @property))
+
+(enum_value
+  (name) @property)
+
+; Variable Definitions and Arguments
+;-----------------------------------
+(operation_definition
+  (name) @variable)
+
+(fragment_name
+  (name) @variable)
+
+(input_fields_definition
+  (input_value_definition
+    (name) @variable.parameter))
+
+(argument
+  (name) @variable.parameter)
+
+(arguments_definition
+  (input_value_definition
+    (name) @variable.parameter))
+
+(variable_definition
+  (variable) @variable.parameter)
+
+(argument
+  (value
+    (variable) @variable))
+
+; Constants
+;----------
+(string_value) @string
+
+(int_value) @number
+
+(float_value) @number.float
+
+(boolean_value) @boolean
+
+; Literals
+;---------
+(description
+  (string_value) @string.documentation @spell)
+
+(comment) @comment @spell
+
+(directive_location
+  (executable_directive_location) @type.builtin)
+
+(directive_location
+  (type_system_directive_location) @type.builtin)
+
+; Keywords
+;----------
+[
+  "query"
+  "mutation"
+  "subscription"
+  "fragment"
+  "scalar"
+  "input"
+  "extend"
+  "directive"
+  "schema"
+  "on"
+  "repeatable"
+  "implements"
+] @keyword
+
+[
+  "enum"
+  "union"
+  "type"
+  "interface"
+] @keyword.type
+
+; Punctuation
+;------------
+[
+  "("
+  ")"
+  "["
+  "]"
+  "{"
+  "}"
+] @punctuation.bracket
+
+"=" @operator
+
+"|" @punctuation.delimiter
+
+"&" @punctuation.delimiter
+
+":" @punctuation.delimiter
+
+"..." @punctuation.special
+
+"!" @punctuation.special

package/out/graphql/indents.scm

@@ -0,0 +1,11 @@
+[
+  (definition)
+  (selection)
+] @indent.begin
+
+[
+  "{"
+  "}"
+] @indent.branch
+
+"}" @indent.end

package/out/graphql/injections.scm

@@ -0,0 +1,2 @@
+((comment) @injection.content
+  (#set! injection.language "comment"))

package/out/groovy/folds.scm

@@ -0,0 +1,6 @@
+[
+  (argument_list)
+  (closure)
+  (list)
+  (map)
+] @fold

package/out/groovy/highlights.scm

@@ -0,0 +1,148 @@
+[
+  "!in"
+  "!instanceof"
+  "as"
+  "assert"
+  "case"
+  "catch"
+  "class"
+  "def"
+  "default"
+  "else"
+  "extends"
+  "finally"
+  "for"
+  "if"
+  "import"
+  "in"
+  "instanceof"
+  "package"
+  "pipeline"
+  "return"
+  "switch"
+  "try"
+  "while"
+  (break)
+  (continue)
+] @keyword
+
+[
+  "true"
+  "false"
+] @boolean
+
+(null) @constant
+"this" @variable.builtin
+
+[ 
+  "int"
+  "char"
+  "short"
+  "long"
+  "boolean"
+  "float"
+  "double"
+  "void"
+] @type.builtin
+
+[ 
+  "final"
+  "private"
+  "protected"
+  "public"
+  "static"
+  "synchronized"
+] @type.qualifier
+
+(comment) @comment
+(shebang) @comment
+
+(string) @string
+(string (escape_sequence) @operator)
+(string (interpolation ([ "$" ]) @operator))
+
+("(") @punctuation.bracket
+(")") @punctuation.bracket
+("[") @punctuation.bracket
+("]") @punctuation.bracket
+("{") @punctuation.bracket
+("}") @punctuation.bracket
+(":") @punctuation.delimiter
+(",") @punctuation.delimiter
+(".") @punctuation.delimiter
+
+(number_literal) @number
+(identifier) @variable
+((identifier) @variable.parameter
+  (#is? @variable.parameter "local.parameter"))
+
+((identifier) @constant
+  (#match? @constant "^[A-Z][A-Z_]+"))
+
+[ 
+  "%" "*" "/" "+" "-" "<<" ">>" ">>>" ".." "..<" "<..<" "<.." "<"
+  "<=" ">" ">=" "==" "!=" "<=>" "===" "!==" "=~" "==~" "&" "^" "|"
+  "&&" "||" "?:" "+" "*" ".&" ".@" "?." "*." "*" "*:" "++" "--" "!"
+] @operator
+
+(string ("/") @string)
+
+(ternary_op ([ "?" ":" ]) @operator)
+
+(map (map_item key: (identifier) @variable.parameter))
+
+(parameter type: (identifier) @type name: (identifier) @variable.parameter)
+(generic_param name: (identifier) @variable.parameter)
+
+(declaration type: (identifier) @type)
+(function_definition type: (identifier) @type)
+(function_declaration type: (identifier) @type)
+(class_definition name: (identifier) @type)
+(class_definition superclass: (identifier) @type)
+(generic_param superclass: (identifier) @type)
+
+(type_with_generics (identifier) @type)
+(type_with_generics (generics (identifier) @type))
+(generics [ "<" ">" ] @punctuation.bracket)
+(generic_parameters [ "<" ">" ] @punctuation.bracket)
+; TODO: Class literals with PascalCase
+
+(declaration ("=") @operator)
+(assignment ("=") @operator)
+
+
+(function_call 
+  function: (identifier) @function)
+(function_call
+  function: (dotted_identifier
+	  (identifier) @function . ))
+(function_call (argument_list
+		 (map_item key: (identifier) @variable.parameter)))
+(juxt_function_call 
+  function: (identifier) @function)
+(juxt_function_call
+  function: (dotted_identifier
+	  (identifier) @function . ))
+(juxt_function_call (argument_list 
+		      (map_item key: (identifier) @variable.parameter)))
+
+(function_definition 
+  function: (identifier) @function)
+(function_declaration 
+  function: (identifier) @function)
+
+(annotation) @function.macro
+(annotation (identifier) @function.macro)
+"@interface" @function.macro
+
+"pipeline" @keyword
+
+(groovy_doc) @comment.documentation
+(groovy_doc 
+  [
+    (groovy_doc_param)
+    (groovy_doc_throws)
+    (groovy_doc_tag)
+  ] @string.special)
+(groovy_doc (groovy_doc_param (identifier) @variable.parameter))
+(groovy_doc (groovy_doc_throws (identifier) @type))

package/out/groovy/indents.scm

@@ -0,0 +1,23 @@
+[
+  (closure)
+  (map)
+  (list)
+  (argument_list)
+  (parameter_list)
+  (for_parameters)
+] @indent.begin
+
+; (function_definition "(" @indent.begin)
+
+(closure "}" @indent.end)
+(argument_list ")" @indent.end)
+(for_parameters ")" @indent.end)
+((for_loop
+  body: (_) @_body) @indent.begin
+  (#not-has-type? @_body closure))
+; TODO: while, try
+
+(list "]" @indent.end)
+(map "]" @indent.end)
+
+[ "}" ")" "]" ] @indent.branch

package/out/groovy/injections.scm

@@ -0,0 +1,5 @@
+((comment) @injection.content
+  (#set! injection.language "comment"))
+
+((groovy_doc) @injection.content
+  (#set! injection.language "comment"))

package/out/groovy/locals.scm

@@ -0,0 +1,6 @@
+[
+  (function_definition)
+] @local.scope
+(parameter name: (identifier) @local.definition.parameter)
+
+(identifier) @local.reference

package/out/haskell/folds.scm

@@ -0,0 +1,6 @@
+[
+  (apply)
+  (do)
+  (function)
+  (import)+
+] @fold