tree-sitter-wasm 1.0.0

package/out/embedded_template/highlights.scm

@@ -0,0 +1,12 @@
+(comment_directive) @comment
+
+[
+  "<%#"
+  "<%"
+  "<%="
+  "<%_"
+  "<%-"
+  "%>"
+  "-%>"
+  "_%>"
+] @keyword

package/out/embedded_template/injections-ejs.scm

@@ -0,0 +1,7 @@
+((content) @injection.content
+ (#set! injection.language "html")
+ (#set! injection.combined))
+
+((code) @injection.content
+ (#set! injection.language "javascript")
+ (#set! injection.combined))

package/out/embedded_template/injections-erb.scm

@@ -0,0 +1,7 @@
+((content) @injection.content
+ (#set! injection.language "html")
+ (#set! injection.combined))
+
+((code) @injection.content
+ (#set! injection.language "ruby")
+ (#set! injection.combined))

package/out/embedded_template/injections-etlua.scm

@@ -0,0 +1,7 @@
+((content) @injection.content
+ (#set! injection.language "html")
+ (#set! injection.combined))
+
+((code) @injection.content
+ (#set! injection.language "lua")
+ (#set! injection.combined))

package/out/embedded_template/injections.scm

@@ -0,0 +1,7 @@
+((content) @injection.content
+  (#set! injection.language "html")
+  (#set! injection.combined))
+
+((code) @injection.content
+  (#set! injection.language "ruby")
+  (#set! injection.combined))

package/out/erlang/folds.scm

@@ -0,0 +1,9 @@
+[
+  (fun_decl)
+  (anonymous_fun)
+  (case_expr)
+  (maybe_expr)
+  (map_expr)
+  (export_attribute)
+  (export_type_attribute)
+] @fold

package/out/erlang/highlights.scm

@@ -0,0 +1,230 @@
+;; Copyright (c) Facebook, Inc. and its affiliates.
+;;
+;; Licensed under the Apache License, Version 2.0 (the "License");
+;; you may not use this file except in compliance with the License.
+;; You may obtain a copy of the License at
+;;
+;;     http://www.apache.org/licenses/LICENSE-2.0
+;;
+;; Unless required by applicable law or agreed to in writing, software
+;; distributed under the License is distributed on an "AS IS" BASIS,
+;; WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+;; See the License for the specific language governing permissions and
+;; limitations under the License.
+;; ---------------------------------------------------------------------
+
+;; Based initially on the contents of https://github.com/WhatsApp/tree-sitter-erlang/issues/2 by @Wilfred
+;; and https://github.com/the-mikedavis/tree-sitter-erlang/blob/main/queries/highlights.scm
+;;
+;; The tests are also based on those in
+;; https://github.com/the-mikedavis/tree-sitter-erlang/tree/main/test/highlight
+;;
+
+;; Last match wins in this file.
+;; As of https://github.com/tree-sitter/tree-sitter/blob/master/CHANGELOG.md#breaking-1
+
+;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
+;; Primitive types
+(string) @string
+(char) @constant
+(integer) @number
+(var) @variable
+(atom) @string.special.symbol
+
+;;; Comments
+((var) @comment.discard
+ (#match? @comment.discard "^_"))
+
+(dotdotdot) @comment.discard
+(comment) @comment
+
+;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
+;; Functions
+(fa fun: (atom) @function)
+(type_name name: (atom) @function)
+(call expr: (atom) @function)
+(function_clause name: (atom) @function)
+(internal_fun fun: (atom) @function)
+
+;; This is a fudge, we should check that the operator is '/'
+;; But our grammar does not (currently) provide it
+(binary_op_expr lhs: (atom) @function rhs: (integer))
+
+;; Others
+(remote_module module: (atom) @module)
+(remote fun: (atom) @function)
+(macro_call_expr name: (var) @constant)
+(macro_call_expr name: (var) @keyword.directive args: (_) )
+(macro_call_expr name: (atom) @keyword.directive)
+(record_field_name name: (atom) @property)
+(record_name name: (atom) @type)
+
+;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
+;; Attributes
+
+;; module attribute
+(module_attribute
+  name: (atom) @module)
+
+;; behaviour
+(behaviour_attribute name: (atom) @module)
+
+;; export
+
+;; Import attribute
+(import_attribute
+    module: (atom) @module)
+
+;; export_type
+
+;; optional_callbacks
+
+;; compile
+(compile_options_attribute
+    options: (tuple
+      expr: (atom)
+      expr: (list
+        exprs: (binary_op_expr
+          lhs: (atom)
+          rhs: (integer)))))
+
+;; file attribute
+
+;; record
+(record_decl name: (atom) @type)
+(record_decl name: (macro_call_expr name: (var) @constant))
+(record_field name: (atom) @property)
+
+;; type alias
+
+;; opaque
+
+;; Spec attribute
+(spec fun: (atom) @function)
+(spec
+  module: (module name: (atom) @module)
+  fun: (atom) @function)
+
+;; callback
+(callback fun: (atom) @function)
+
+;; wild attribute
+(wild_attribute name: (attr_name name: (atom) @keyword))
+
+;; fun decl
+
+;; include/include_lib
+
+;; ifdef/ifndef
+(pp_ifdef name: (_) @keyword.directive)
+(pp_ifndef name: (_) @keyword.directive)
+
+;; define
+(pp_define
+    lhs: (macro_lhs
+      name: (var) @constant))
+(pp_define
+    lhs: (macro_lhs
+      name: (_) @keyword.directive
+      args: (var_args args: (var))))
+
+
+;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
+;; Reserved words
+[ "after"
+  "and"
+  "band"
+  "begin"
+  "behavior"
+  "behaviour"
+  "bnot"
+  "bor"
+  "bsl"
+  "bsr"
+  "bxor"
+  "callback"
+  "case"
+  "catch"
+  "compile"
+  "define"
+  "div"
+  "elif"
+  "else"
+  "end"
+  "endif"
+  "export"
+  "export_type"
+  "file"
+  "fun"
+  "if"
+  "ifdef"
+  "ifndef"
+  "import"
+  "include"
+  "include_lib"
+  "module"
+  "of"
+  "opaque"
+  "optional_callbacks"
+  "or"
+  "receive"
+  "record"
+  "spec"
+  "try"
+  "type"
+  "undef"
+  "unit"
+  "when"
+  "xor"] @keyword
+
+["andalso" "orelse"] @keyword.operator
+
+;; Punctuation
+["," "." ";"] @punctuation.delimiter
+["(" ")" "{" "}" "[" "]" "<<" ">>"] @punctuation.bracket
+
+;; Operators
+["!"
+ "->"
+ "<-"
+ "#"
+ "::"
+ ":>"
+ "|"
+ ":"
+ "="
+ "||"
+
+ "+"
+ "-"
+ "bnot"
+ "not"
+
+ "/"
+ "*"
+ "div"
+ "rem"
+ "band"
+ "and"
+
+ "+"
+ "-"
+ "bor"
+ "bxor"
+ "bsl"
+ "bsr"
+ "or"
+ "xor"
+
+ "++"
+ "--"
+
+ "=="
+ "/="
+ "=<"
+ "<"
+ ">="
+ ">"
+ "=:="
+ "=/="
+ ] @operator

package/out/erlang/injections.scm

@@ -0,0 +1,2 @@
+((comment) @injection.content
+  (#set! injection.language "comment"))

package/out/fish/folds.scm

@@ -0,0 +1,8 @@
+[
+  (function_definition)
+  (if_statement)
+  (switch_statement)
+  (for_statement)
+  (while_statement)
+  (begin_statement)
+] @fold

package/out/fish/highlights.scm

@@ -0,0 +1,61 @@
+[(double_quote_string) (single_quote_string)] @string
+(escape_sequence) @string.escape
+
+(comment) @comment
+
+[(integer) (float)] @number
+
+[
+  "&&"
+  "||"
+  "|"
+  "&|"
+  "2>|"
+  "&"
+  ".."
+  (direction)
+  (stream_redirect)
+] @operator
+
+; match operators of test command
+(command
+  name: (word) @function (#match? @function "^test$")
+  argument: (word) @operator (#match? @operator "^(!?=|-[a-zA-Z]+)$"))
+
+; match operators of [ command
+(command
+  name: (word) @punctuation.bracket (#match? @punctuation.bracket "^\\[$")
+  argument: (word) @operator (#match? @operator "^(!?=|-[a-zA-Z]+)$"))
+
+(variable_expansion) @constant
+
+(command_substitution "$" @punctuation.special)
+(command_substitution ["(" ")"] @punctuation.bracket)
+(list_element_access  ["[" "]"] @punctuation.bracket)
+(brace_expansion      ["{" "}"] @punctuation.bracket)
+(begin_statement      ["{" "}"] @punctuation.bracket)
+
+"," @punctuation.delimiter
+
+(function_definition name: [(word) (concatenation)] @function)
+(command name: (word) @function)
+
+[
+ "switch"
+ "case"
+ "in"
+ "begin"
+ "function"
+ "if"
+ "else"
+ "end"
+ "while"
+ "for"
+ "not"
+ "!"
+ "and"
+ "or"
+ "return"
+ (break)
+ (continue)
+] @keyword

package/out/fish/indents.scm

@@ -0,0 +1,18 @@
+[
+  (function_definition)
+  (while_statement)
+  (for_statement)
+  (if_statement)
+  (begin_statement)
+  (switch_statement)
+] @indent.begin
+
+[
+  "else" ; else and else if must both start the line with "else", so tag the string directly
+  "case"
+  "end"
+] @indent.branch
+
+"end" @indent.end
+
+(comment) @indent.ignore

package/out/fish/injections.scm

@@ -0,0 +1,2 @@
+((comment) @injection.content
+  (#set! injection.language "comment"))

package/out/fish/locals.scm

@@ -0,0 +1,19 @@
+; Scopes
+[
+  (command)
+  (function_definition)
+  (if_statement)
+  (for_statement)
+  (begin_statement)
+  (while_statement)
+  (switch_statement)
+] @local.scope
+
+; Definitions
+(function_definition
+  name: (word) @local.definition.function)
+
+; References
+(variable_name) @local.reference
+
+(word) @local.reference

package/out/gdscript/folds.scm

@@ -0,0 +1,26 @@
+[
+  ; Body fold will "join" the next adjacent fold into a SUPER fold.
+  ; This is an issue with the grammar.
+  ; (body)
+  (if_statement)
+  (elif_clause)
+  (else_clause)
+  (for_statement)
+  (while_statement)
+  (class_definition)
+  (enum_definition)
+  (match_statement)
+  (pattern_section)
+  (function_definition)
+  (lambda)
+  (constructor_definition)
+] @fold
+
+; It's nice to be able to fold the if/elif/else clauses and the entire
+; if_statement.
+(if_statement
+  (body) @fold)
+
+; Fold strings that are probably doc strings.
+(expression_statement
+  (string) @fold)