tree-sitter-wasm 1.0.0

package/out/ocaml_type/locals.scm

@@ -0,0 +1,24 @@
+; Scopes
+;-------
+
+[
+  (let_binding)
+  (class_binding)
+  (class_function)
+  (method_definition)
+  (fun_expression)
+  (object_expression)
+  (for_expression)
+  (match_case)
+  (attribute_payload)
+] @local.scope
+
+; Definitions
+;------------
+
+(value_pattern) @local.definition
+
+; References
+;-----------
+
+(value_path . (value_name) @local.reference)

package/out/ocaml_type/tags.scm

@@ -0,0 +1,170 @@
+; Modules
+;--------
+
+(
+  (comment)? @doc .
+  (module_definition
+    (module_binding (module_name) @name) @definition.module
+  )
+  (#strip! @doc "^\\(\\*+\\s*|\\s*\\*+\\)$")
+)
+
+(module_path (module_name) @name) @reference.module
+(extended_module_path (module_name) @name) @reference.module
+
+(
+  (comment)? @doc .
+  (module_type_definition (module_type_name) @name) @definition.interface
+  (#strip! @doc "^\\(\\*+\\s*|\\s*\\*+\\)$")
+)
+
+(module_type_path (module_type_name) @name) @reference.implementation
+
+
+; Classes
+;--------
+
+(
+  (comment)? @doc .
+  [
+    (class_definition
+      (class_binding (class_name) @name) @definition.class
+    )
+    (class_type_definition
+      (class_type_binding (class_type_name) @name) @definition.class
+    )
+  ]
+  (#strip! @doc "^\\(\\*+\\s*|\\s*\\*+\\)$")
+)
+
+[
+  (class_path (class_name) @name)
+  (class_type_path (class_type_name) @name)
+] @reference.class
+
+(
+  (comment)? @doc .
+  (method_definition (method_name) @name) @definition.method
+  (#strip! @doc "^\\(\\*+\\s*|\\s*\\*+\\)$")
+)
+
+(method_invocation (method_name) @name) @reference.call
+
+
+; Types
+;------
+
+(
+  (comment)? @doc .
+  (type_definition
+    (type_binding
+      name: [
+        (type_constructor) @name
+        (type_constructor_path (type_constructor) @name)
+      ]
+    ) @definition.type
+  )
+  (#strip! @doc "^\\(\\*+\\s*|\\s*\\*+\\)$")
+)
+
+(type_constructor_path (type_constructor) @name) @reference.type
+
+[
+  (constructor_declaration (constructor_name) @name)
+  (tag_specification (tag) @name)
+] @definition.enum_variant
+
+[
+  (constructor_path (constructor_name) @name)
+  (tag) @name
+] @reference.enum_variant
+
+(field_declaration (field_name) @name) @definition.field
+
+(field_path (field_name) @name) @reference.field
+
+
+; Functions
+;----------
+
+(
+  (comment)? @doc .
+  (value_definition
+    [
+      (let_binding pattern: (value_name) @name (parameter))
+      (let_binding
+        pattern: (value_name) @name
+        body: [(fun_expression) (function_expression)]
+      )
+    ] @definition.function
+  )
+  (#strip! @doc "^\\(\\*+\\s*|\\s*\\*+\\)$")
+)
+
+(
+  (comment)? @doc .
+  (external (value_name) @name) @definition.function
+  (#strip! @doc "^\\(\\*+\\s*|\\s*\\*+\\)$")
+)
+
+(application_expression
+  function: (value_path (value_name) @name)
+) @reference.call
+
+(infix_expression
+  left: (value_path (value_name) @name)
+  operator: (concat_operator) @reference.call
+  (#eq? @reference.call "@@")
+)
+
+(infix_expression
+  operator: (rel_operator) @reference.call
+  right: (value_path (value_name) @name)
+  (#eq? @reference.call "|>")
+)
+
+
+; Operators
+;----------
+
+(
+  (comment)? @doc .
+  (value_definition
+    [
+      (let_binding pattern: (parenthesized_operator (_) @name) (parameter))
+      (let_binding
+        pattern: (parenthesized_operator (_) @name)
+        body: [(fun_expression) (function_expression)]
+      )
+    ] @definition.operator
+  )
+  (#strip! @doc "^\\(\\*+\\s*|\\s*\\*+\\)$")
+)
+
+(application_expression
+  function: (value_path (parenthesized_operator (_) @name))
+) @reference.call
+
+(infix_expression
+  left: (value_path (parenthesized_operator (_) @name))
+  operator: (concat_operator) @reference.call
+  (#eq? @reference.call "@@")
+)
+
+(infix_expression
+  operator: (rel_operator) @reference.call
+  right: (value_path (parenthesized_operator (_) @name))
+  (#eq? @reference.call "|>")
+)
+
+(prefix_expression operator: (prefix_operator) @name) @reference.call
+
+(hash_expression operator: (hash_operator) @name) @reference.call
+
+(infix_expression operator: (_) @name) @reference.call
+
+(indexing_operator_path (indexing_operator) @name) @reference.call
+
+(value_definition [(let_operator) (let_and_operator)] @name) @reference.call
+
+(match_expression (match_operator) @name) @reference.call

package/out/perl/folds.scm

@@ -0,0 +1,27 @@
+(comment)+ @fold
+(pod) @fold
+(heredoc_content) @fold
+
+; fold the block-typed package statements only
+(package_statement (block)) @fold
+(class_statement (block)) @fold
+
+[(subroutine_declaration_statement)
+ (method_declaration_statement)
+ (conditional_statement)
+ (loop_statement)
+ (for_statement)
+ (cstyle_for_statement)
+ (block_statement)
+ (defer_statement)
+ (phaser_statement)] @fold
+
+(try_statement (block) @fold)
+
+(eval_expression (block) @fold)
+
+(anonymous_subroutine_expression) @fold
+
+; perhaps folks want to fold these too?
+[(anonymous_array_expression)
+ (anonymous_hash_expression)] @fold

package/out/perl/highlights.scm

@@ -0,0 +1,162 @@
+((source_file . (comment) @preproc)
+  (#lua-match? @preproc "^#!/"))
+
+[ "use" "no" "require" ] @include
+
+[ "if" "elsif" "unless" "else" ] @conditional
+
+(conditional_expression [ "?" ":" ] @conditional.ternary)
+
+[ "while" "until" "for" "foreach" ] @repeat
+("continue" @repeat (block))
+
+[ "try" "catch" "finally" ] @exception
+
+"return" @keyword.return
+
+[ "sub" "method" "async" "extended" ] @keyword.function
+
+[ "map" "grep" "sort" ] @function.builtin
+
+[ "package" "class" "role" ] @include
+
+[
+  "defer"
+  "do" "eval"
+  "my" "our" "local" "dynamically" "state" "field"
+  "last" "next" "redo" "goto"
+  "undef" "await"
+] @keyword
+
+(yadayada) @exception
+
+(phaser_statement phase: _ @keyword.phaser)
+(class_phaser_statement phase: _ @keyword.phaser)
+
+
+
+(_ operator: _ @operator)
+"\\" @operator
+
+[
+  "or" "xor" "and"
+  "eq" "ne" "cmp" "lt" "le" "ge" "gt"
+  "isa"
+] @keyword.operator
+
+(eof_marker) @preproc
+(data_section) @comment
+
+(pod) @text
+
+[
+  (number)
+  (version)
+] @number
+
+[
+  (string_literal)
+  (interpolated_string_literal)
+  (quoted_word_list)
+  (command_string)
+  (heredoc_content)
+  (replacement)
+  (transliteration_content)
+] @string
+
+[
+  (heredoc_token)
+  (command_heredoc_token)
+  (heredoc_end)
+] @label
+
+[(escape_sequence) (escaped_delimiter)] @string.escape
+
+(_ modifiers: _ @character.special)
+[
+ (quoted_regexp)
+ (match_regexp)
+ (regexp_content)
+] @string.regex
+
+(autoquoted_bareword) @string.special
+
+(use_statement (package) @type)
+(package_statement (package) @type)
+(class_statement (package) @type)
+(require_expression (bareword) @type)
+
+(subroutine_declaration_statement name: (bareword) @function)
+(method_declaration_statement name: (bareword) @method)
+(attribute_name) @attribute
+(attribute_value) @string
+
+(label) @label
+
+(statement_label label: _ @label)
+
+(relational_expression operator: "isa" right: (bareword) @type)
+
+(function) @function
+
+(function_call_expression (function) @function.call)
+(method_call_expression (method) @method.call)
+(method_call_expression invocant: (bareword) @type)
+
+(func0op_call_expression function: _ @function.builtin)
+(func1op_call_expression function: _ @function.builtin)
+
+([(function)(expression_statement (bareword))] @function.builtin
+ (#match? @function.builtin
+   "^(accept|atan2|bind|binmode|bless|crypt|chmod|chown|connect|die|dbmopen|exec|fcntl|flock|getpriority|getprotobynumber|gethostbyaddr|getnetbyaddr|getservbyname|getservbyport|getsockopt|glob|index|ioctl|join|kill|link|listen|mkdir|msgctl|msgget|msgrcv|msgsend|opendir|print|printf|push|pack|pipe|return|rename|rindex|read|recv|reverse|say|select|seek|semctl|semget|semop|send|setpgrp|setpriority|seekdir|setsockopt|shmctl|shmread|shmwrite|shutdown|socket|socketpair|split|sprintf|splice|substr|system|symlink|syscall|sysopen|sysseek|sysread|syswrite|tie|truncate|unlink|unpack|utime|unshift|vec|warn|waitpid|formline|open|sort)$"
+))
+
+(ERROR) @error
+
+(
+  [(varname) (filehandle)] @variable.builtin
+  (#match? @variable.builtin "^((ENV|ARGV|INC|ARGVOUT|SIG|STDIN|STDOUT|STDERR)|[_ab]|\\W|\\d+|\\^.*)$")
+)
+
+[(array) (arraylen)] @variable.array
+(glob) @variable.builtin
+(scalar) @variable.scalar
+(hash) @variable.hash
+(amper_deref_expression [ "&" "*" ] @function.call)
+
+(glob_deref_expression "*" @variable.builtin)
+(glob_slot_expression "*" @variable.builtin)
+(scalar_deref_expression [ "$" "*"] @variable.scalar)
+
+; gotta be SUPER GENERIC so we can hit up string interp
+(_
+  [
+   array: (_) @variable.array
+   hash: (_) @variable.hash
+  ])
+(array_deref_expression [ "@" "*"] @variable.array)
+(arraylen_deref_expression [ "$#" "*"] @variable.array)
+(hash_deref_expression [ "%" "*"] @variable.hash)
+(array_element_expression array:(_) @variable.array)
+(slice_expression array:(_) @variable.array)
+
+
+
+(comment) @comment
+
+([ "=>" "," ";" "->" ] @punctuation.delimiter)
+
+(
+  [ "[" "]" "{" "}" "(" ")" ] @punctuation.bracket
+)
+
+(_
+  "{" @punctuation.special
+  (varname)
+  "}" @punctuation.special)
+
+(varname
+  (block
+    "{" @punctuation.special
+    "}" @punctuation.special))
+

package/out/perl/injections.scm

@@ -0,0 +1,14 @@
+; an injections.scm file for nvim-treesitter
+((comment) @injection.content
+ (#set! injection.language "comment"))
+ 
+((pod) @injection.content
+ (#set! injection.language "pod"))
+
+((substitution_regexp
+  (replacement) @injection.content
+  (substitution_regexp_modifiers) @_modifiers)
+    ; match if there's a single `e` in the modifiers list
+  (#match? @_modifiers "e")
+  (#not-match? @_modifiers "e.*e")
+  (#set! injection.language "perl"))

package/out/perl/matchup.scm

@@ -0,0 +1,30 @@
+(conditional_statement
+    ["if" "unless"] @open.if
+    "elsif"? @mid.if.1
+    "else"? @mid.if.2
+    (block "}" @close.if) .
+) @scope.if
+
+(_
+  ["for" "foreach" "while" "unless"] @open.loop
+  (block "}" @close.loop) .
+  ) @scope.loop
+(loopex_expression) @mid.loop.1
+
+(_
+    "sub" @open.fun
+    (block "}" @close.fun) .
+) @scope.fun
+(return_expression "return" @mid.fun.1)
+
+[
+  (_ "'" @open.quotelike (string_content) "'" @close.quotelike)
+  (quoted_regexp "'" @open.quotelike "'" @close.quotelike)
+  (_ "'" @open.quotelike (_) "'"+ @mid.quotelike.1 (replacement) "'" @close.quotelike)
+] @scope.quotelike
+
+(try_statement
+  "try" @open.try
+  "catch"? @mid.try.1
+  "finally"? @close.try
+  ) @scope.try

package/out/php/folds.scm

@@ -0,0 +1 @@
+; inherits: php_only

package/out/php/highlights.scm

@@ -0,0 +1,203 @@
+[
+  (php_tag)
+  (php_end_tag)
+] @tag
+
+; Keywords
+
+[
+  "and"
+  "as"
+  "break"
+  "case"
+  "catch"
+  "class"
+  "clone"
+  "const"
+  "continue"
+  "declare"
+  "default"
+  "do"
+  "echo"
+  "else"
+  "elseif"
+  "enddeclare"
+  "endfor"
+  "endforeach"
+  "endif"
+  "endswitch"
+  "endwhile"
+  "enum"
+  "exit"
+  "extends"
+  "finally"
+  "fn"
+  "for"
+  "foreach"
+  "function"
+  "global"
+  "goto"
+  "if"
+  "implements"
+  "include"
+  "include_once"
+  "instanceof"
+  "insteadof"
+  "interface"
+  "match"
+  "namespace"
+  "new"
+  "or"
+  "print"
+  "require"
+  "require_once"
+  "return"
+  "switch"
+  "throw"
+  "trait"
+  "try"
+  "use"
+  "while"
+  "xor"
+  "yield"
+  "yield from"
+  (abstract_modifier)
+  (final_modifier)
+  (readonly_modifier)
+  (static_modifier)
+  (visibility_modifier)
+] @keyword
+
+(function_static_declaration "static" @keyword)
+
+; Namespace
+
+(namespace_definition
+  name: (namespace_name
+    (name) @module))
+
+(namespace_name
+  (name) @module)
+
+(namespace_use_clause
+  [
+    (name) @type
+    (qualified_name
+      (name) @type)
+    alias: (name) @type
+  ])
+
+(namespace_use_clause
+  type: "function"
+  [
+    (name) @function
+    (qualified_name
+      (name) @function)
+    alias: (name) @function
+  ])
+
+(namespace_use_clause
+  type: "const"
+  [
+    (name) @constant
+    (qualified_name
+      (name) @constant)
+    alias: (name) @constant
+  ])
+
+(relative_name "namespace" @module.builtin)
+
+; Variables
+
+(relative_scope) @variable.builtin
+
+(variable_name) @variable
+
+(method_declaration name: (name) @constructor
+  (#eq? @constructor "__construct"))
+
+(object_creation_expression [
+  (name) @constructor
+  (qualified_name (name) @constructor)
+  (relative_name (name) @constructor)
+])
+
+((name) @constant
+ (#match? @constant "^_?[A-Z][A-Z\\d_]+$"))
+((name) @constant.builtin
+ (#match? @constant.builtin "^__[A-Z][A-Z\d_]+__$"))
+(const_declaration (const_element (name) @constant))
+
+; Types
+
+(primitive_type) @type.builtin
+(cast_type) @type.builtin
+(named_type [
+  (name) @type
+  (qualified_name (name) @type)
+  (relative_name (name) @type)
+]) @type
+(named_type (name) @type.builtin
+  (#any-of? @type.builtin "static" "self"))
+
+(scoped_call_expression
+  scope: [
+    (name) @type
+    (qualified_name (name) @type)
+    (relative_name (name) @type)
+  ])
+
+; Functions
+
+(array_creation_expression "array" @function.builtin)
+(list_literal "list" @function.builtin)
+(exit_statement "exit" @function.builtin "(")
+
+(method_declaration
+  name: (name) @function.method)
+
+(function_call_expression
+  function: [
+    (qualified_name (name))
+    (relative_name (name))
+    (name)
+  ] @function)
+
+(scoped_call_expression
+  name: (name) @function)
+
+(member_call_expression
+  name: (name) @function.method)
+
+(function_definition
+  name: (name) @function)
+
+; Member
+
+(property_element
+  (variable_name) @property)
+
+(member_access_expression
+  name: (variable_name (name)) @property)
+(member_access_expression
+  name: (name) @property)
+
+; Basic tokens
+[
+  (string)
+  (string_content)
+  (encapsed_string)
+  (heredoc)
+  (heredoc_body)
+  (nowdoc_body)
+] @string
+(boolean) @constant.builtin
+(null) @constant.builtin
+(integer) @number
+(float) @number
+(comment) @comment
+
+((name) @variable.builtin
+ (#eq? @variable.builtin "this"))
+
+"$" @operator

package/out/php/indents.scm

@@ -0,0 +1 @@
+; inherits: php_only

package/out/php/injections-text.scm

@@ -0,0 +1,3 @@
+((text) @injection.content
+ (#set! injection.language "html")
+ (#set! injection.combined))

package/out/php/injections.scm

@@ -0,0 +1,10 @@
+((comment) @injection.content
+  (#set! injection.language "phpdoc"))
+
+(heredoc
+  (heredoc_body) @injection.content
+  (heredoc_end) @injection.language)
+
+(nowdoc
+  (nowdoc_body) @injection.content
+  (heredoc_end) @injection.language)

package/out/php/locals.scm

@@ -0,0 +1 @@
+; inherits: php_only

package/out/php/tags.scm

@@ -0,0 +1,40 @@
+(namespace_definition
+  name: (namespace_name) @name) @definition.module
+
+(interface_declaration
+  name: (name) @name) @definition.interface
+
+(trait_declaration
+  name: (name) @name) @definition.interface
+
+(class_declaration
+  name: (name) @name) @definition.class
+
+(class_interface_clause [(name) (qualified_name)] @name) @reference.implementation
+
+(property_declaration
+  (property_element (variable_name (name) @name))) @definition.field
+
+(function_definition
+  name: (name) @name) @definition.function
+
+(method_declaration
+  name: (name) @name) @definition.function
+
+(object_creation_expression
+  [
+    (qualified_name (name) @name)
+    (variable_name (name) @name)
+  ]) @reference.class
+
+(function_call_expression
+  function: [
+    (qualified_name (name) @name)
+    (variable_name (name)) @name
+  ]) @reference.call
+
+(scoped_call_expression
+  name: (name) @name) @reference.call
+
+(member_call_expression
+  name: (name) @name) @reference.call