tree-sitter-wasm 1.0.0

package/out/scala/highlights.scm

@@ -0,0 +1,260 @@
+; CREDITS @stumash (stuart.mashaal@gmail.com)
+
+(field_expression field: (identifier) @property)
+(field_expression value: (identifier) @type
+ (#match? @type "^[A-Z]"))
+
+(type_identifier) @type
+
+(class_definition
+  name: (identifier) @type)
+
+(enum_definition
+  name: (identifier) @type)
+
+(object_definition
+  name: (identifier) @type)
+
+(trait_definition
+  name: (identifier) @type)
+
+(full_enum_case
+  name: (identifier) @type)
+
+(simple_enum_case
+  name: (identifier) @type)
+
+;; variables
+
+(class_parameter
+  name: (identifier) @parameter)
+
+(self_type (identifier) @parameter)
+
+(interpolation (identifier) @none)
+(interpolation (block) @none)
+
+;; types
+
+(type_definition
+  name: (type_identifier) @type.definition)
+
+;; val/var definitions/declarations
+
+(val_definition
+  pattern: (identifier) @variable)
+
+(var_definition
+  pattern: (identifier) @variable)
+
+(val_declaration
+  name: (identifier) @variable)
+
+(var_declaration
+  name: (identifier) @variable)
+
+; imports/exports
+
+(import_declaration
+  path: (identifier) @namespace)
+((stable_identifier (identifier) @namespace))
+
+((import_declaration
+  path: (identifier) @type) (#match? @type "^[A-Z]"))
+((stable_identifier (identifier) @type) (#match? @type "^[A-Z]"))
+
+(export_declaration
+  path: (identifier) @namespace)
+((stable_identifier (identifier) @namespace))
+
+((export_declaration
+  path: (identifier) @type) (#match? @type "^[A-Z]"))
+((stable_identifier (identifier) @type) (#match? @type "^[A-Z]"))
+
+((namespace_selectors (identifier) @type) (#match? @type "^[A-Z]"))
+
+; method invocation
+
+(call_expression
+  function: (identifier) @function.call)
+
+(call_expression
+  function: (operator_identifier) @function.call)
+
+(call_expression
+  function: (field_expression
+    field: (identifier) @method.call))
+
+((call_expression
+   function: (identifier) @constructor)
+ (#match? @constructor "^[A-Z]"))
+
+(generic_function
+  function: (identifier) @function.call)
+
+(interpolated_string_expression
+  interpolator: (identifier) @function.call)
+
+; function definitions
+
+(function_definition
+  name: (identifier) @function)
+
+(parameter
+  name: (identifier) @parameter)
+
+(binding
+  name: (identifier) @parameter)
+
+; method definition
+
+(function_declaration
+      name: (identifier) @method)
+
+(function_definition
+      name: (identifier) @method)
+
+; expressions
+
+(infix_expression operator: (identifier) @operator)
+(infix_expression operator: (operator_identifier) @operator)
+(infix_type operator: (operator_identifier) @operator)
+(infix_type operator: (operator_identifier) @operator)
+
+; literals
+
+(boolean_literal) @boolean
+(integer_literal) @number
+(floating_point_literal) @float
+
+[
+  (string)
+  (character_literal)
+  (interpolated_string_expression)
+] @string
+
+(interpolation "$" @punctuation.special)
+
+;; keywords
+
+(opaque_modifier) @type.qualifier
+(infix_modifier) @keyword
+(transparent_modifier) @type.qualifier
+(open_modifier) @type.qualifier
+
+[
+  "case"
+  "class"
+  "enum"
+  "extends"
+  "derives"
+  "finally"
+;; `forSome` existential types not implemented yet
+;; `macro` not implemented yet
+  "object"
+  "override"
+  "package"
+  "trait"
+  "type"
+  "val"
+  "var"
+  "with"
+  "given"
+  "using"
+  "end"
+  "implicit"
+  "extension"
+  "with"
+] @keyword
+
+[
+  "abstract"
+  "final"
+  "lazy"
+  "sealed"
+  "private"
+  "protected"
+] @type.qualifier
+
+(inline_modifier) @storageclass
+
+(null_literal) @constant.builtin
+
+(wildcard) @parameter
+
+(annotation) @attribute
+
+;; special keywords
+
+"new" @keyword.operator
+
+[
+  "else"
+  "if"
+  "match"
+  "then"
+] @conditional
+
+[
+ "("
+ ")"
+ "["
+ "]"
+ "{"
+ "}"
+]  @punctuation.bracket
+
+[
+ "."
+ ","
+] @punctuation.delimiter
+
+[
+  "do"
+  "for"
+  "while"
+  "yield"
+] @repeat
+
+"def" @keyword.function
+
+[
+ "=>"
+ "<-"
+ "@"
+] @operator
+
+["import" "export"] @include
+
+[
+  "try"
+  "catch"
+  "throw"
+] @exception
+
+"return" @keyword.return
+
+(comment) @spell @comment
+(block_comment) @spell @comment
+
+;; `case` is a conditional keyword in case_block
+
+(case_block
+  (case_clause ("case") @conditional))
+(indented_cases
+  (case_clause ("case") @conditional))
+
+(operator_identifier) @operator
+
+((identifier) @type (#match? @type "^[A-Z]"))
+((identifier) @variable.builtin
+ (#match? @variable.builtin "^this$"))
+
+(
+  (identifier) @function.builtin
+  (#match? @function.builtin "^super$")
+)
+
+;; Scala CLI using directives
+(using_directive_key) @parameter
+(using_directive_value) @string

package/out/scala/indents.scm

@@ -0,0 +1,30 @@
+; These indent queries adhere to nvim-tree-sytter syntax.
+; See `nvim-tree-sitter-indentation-mod` vim help page.
+
+[
+  (template_body)
+  (block)
+  (parameters)
+  (arguments)
+  (match_expression)
+  (splice_expression)
+  (import_declaration)
+  (function_definition)
+  (ERROR ":")
+  (ERROR "=")
+  ("match")
+  (":")
+  ("=")
+] @indent.begin
+
+(arguments ")" @indent.end)
+
+"}" @indent.end
+
+"end" @indent.end
+
+[
+  ")"
+  "]"
+  "}"
+] @indent.branch

package/out/scala/injections.scm

@@ -0,0 +1,5 @@
+((comment) @injection.content
+  (#set! injection.language "comment"))
+
+((block_comment) @injection.content
+  (#set! injection.language "comment"))

package/out/scala/locals.scm

@@ -0,0 +1,30 @@
+(template_body) @local.scope
+(lambda_expression) @local.scope
+
+
+(function_declaration
+      name: (identifier) @local.definition) @local.scope
+
+(function_definition
+      name: (identifier) @local.definition)
+
+(parameter
+  name: (identifier) @local.definition)
+
+(binding
+  name: (identifier) @local.definition)
+
+(val_definition
+  pattern: (identifier) @local.definition)
+
+(var_definition
+  pattern: (identifier) @local.definition)
+
+(val_declaration
+  name: (identifier) @local.definition)
+
+(var_declaration
+  name: (identifier) @local.definition)
+
+(identifier) @local.reference
+

package/out/scala/tags.scm

@@ -0,0 +1,66 @@
+; Definitions
+
+(package_clause
+  name: (package_identifier) @name) @definition.module
+
+(trait_definition
+  name: (identifier) @name) @definition.interface
+
+(enum_definition
+  name: (identifier) @name) @definition.enum
+
+(simple_enum_case
+  name: (identifier) @name) @definition.class
+
+(full_enum_case
+  name: (identifier) @name) @definition.class
+
+(class_definition
+  name: (identifier) @name) @definition.class
+
+(object_definition
+  name: (identifier) @name) @definition.object
+
+(function_definition
+  name: (identifier) @name) @definition.function
+
+(val_definition
+  pattern: (identifier) @name) @definition.variable
+
+(given_definition
+  name: (identifier) @name) @definition.variable
+
+(var_definition
+  pattern: (identifier) @name) @definition.variable
+
+(val_declaration
+  name: (identifier) @name) @definition.variable
+
+(var_declaration
+  name: (identifier) @name) @definition.variable
+
+(type_definition
+  name: (type_identifier) @name) @definition.type
+
+(class_parameter
+  name: (identifier) @name) @definition.property
+
+; References 
+
+(call_expression
+  (identifier) @name) @reference.call
+
+(instance_expression
+  (type_identifier) @name) @reference.interface
+
+(instance_expression
+  (generic_type
+    (type_identifier) @name)) @reference.interface
+
+(extends_clause
+  (type_identifier) @name) @reference.class
+
+(extends_clause
+  (generic_type
+    (type_identifier) @name)) @reference.class
+

package/out/scheme/folds.scm

@@ -0,0 +1,2 @@
+(program
+  (list) @fold)

package/out/scheme/highlights.scm

@@ -0,0 +1,84 @@
+["(" ")" "[" "]" "{" "}"] @punctuation.bracket
+
+(number) @number
+(character) @constant.builtin
+(boolean) @constant.builtin
+(symbol) @variable
+
+(string) @string
+
+(escape_sequence) @escape
+
+(list
+  .
+  (symbol) @function)
+
+(list
+  .
+  "["
+  .
+  (symbol)+ @variable
+  .
+  "]")
+
+((symbol) @operator
+ (#match? @operator "^(\\+|-|\\*|/|=|>|<|>=|<=)$"))
+
+(list
+  .
+  (symbol) @keyword
+  (#match? @keyword
+   "^(define-syntax|let\\*|lambda|λ|case|=>|quote-splicing|unquote-splicing|set!|let|letrec|letrec-syntax|let-values|let\\*-values|do|else|define|cond|syntax-rules|unquote|begin|quote|let-syntax|and|if|quasiquote|letrec|delay|or|when|unless|identifier-syntax|assert|library|export|import|rename|only|except|prefix)$"
+   ))
+
+(list
+  .
+  (symbol) @function.builtin
+  (#match? @function.builtin
+   "^(caar|cadr|call-with-input-file|call-with-output-file|cdar|cddr|list|open-input-file|open-output-file|with-input-from-file|with-output-to-file|\\*|\\+|-|/|<|<=|=|>|>=|abs|acos|angle|append|apply|asin|assoc|assq|assv|atan|boolean\\?|caaaar|caaadr|caaar|caadar|caaddr|caadr|cadaar|cadadr|cadar|caddar|cadddr|caddr|call-with-current-continuation|call-with-values|car|cdaaar|cdaadr|cdaar|cdadar|cdaddr|cdadr|cddaar|cddadr|cddar|cdddar|cddddr|cdddr|cdr|ceiling|char->integer|char-alphabetic\\?|char-ci<=\\?|char-ci<\\?|char-ci=\\?|char-ci>=\\?|char-ci>\\?|char-downcase|char-lower-case\\?|char-numeric\\?|char-ready\\?|char-upcase|char-upper-case\\?|char-whitespace\\?|char<=\\?|char<\\?|char=\\?|char>=\\?|char>\\?|char\\?|close-input-port|close-output-port|complex\\?|cons|cos|current-error-port|current-input-port|current-output-port|denominator|display|dynamic-wind|eof-object\\?|eq\\?|equal\\?|eqv\\?|eval|even\\?|exact->inexact|exact\\?|exp|expt|floor|flush-output|for-each|force|gcd|imag-part|inexact->exact|inexact\\?|input-port\\?|integer->char|integer\\?|interaction-environment|lcm|length|list->string|list->vector|list-ref|list-tail|list\\?|load|log|magnitude|make-polar|make-rectangular|make-string|make-vector|map|max|member|memq|memv|min|modulo|negative\\?|newline|not|null-environment|null\\?|number->string|number\\?|numerator|odd\\?|output-port\\?|pair\\?|peek-char|positive\\?|procedure\\?|quotient|rational\\?|rationalize|read|read-char|real-part|real\\?|remainder|reverse|round|scheme-report-environment|set-car!|set-cdr!|sin|sqrt|string|string->list|string->number|string->symbol|string-append|string-ci<=\\?|string-ci<\\?|string-ci=\\?|string-ci>=\\?|string-ci>\\?|string-copy|string-fill!|string-length|string-ref|string-set!|string<=\\?|string<\\?|string=\\?|string>=\\?|string>\\?|string\\?|substring|symbol->string|symbol\\?|tan|transcript-off|transcript-on|truncate|values|vector|vector->list|vector-fill!|vector-length|vector-ref|vector-set!|vector\\?|write|write-char|zero\\?)$"
+   ))
+
+;; quote ;;
+
+;; hardcoded highlight four levels of nested structure
+
+; 'atom
+(quote
+  _ @constant)
+
+; '()
+(quote
+  (_ _* @constant))
+
+; '(())
+(quote
+  (_ (_ _* @constant)))
+
+; '((()))
+(quote
+  (_ (_ (_ _* @constant))))
+
+;; sexp comment ;;
+
+;; hardcoded highlight four levels of nested structure
+
+; #;atom
+(comment
+  _ @comment)
+
+; #;(list)
+(comment
+  (_ _* @comment))
+
+; #;(list (list))
+(comment
+  (_ (_ _* @comment)))
+
+; #;(list (list (list)))
+(comment
+  (_ (_ (_ _ @comment))))
+
+[(comment)
+ (block_comment)
+ (directive)] @comment
+

package/out/scheme/injections.scm

@@ -0,0 +1,2 @@
+((comment) @injection.content
+  (#set! injection.language "comment"))

package/out/scss/folds.scm

@@ -0,0 +1 @@
+; inherits: css

package/out/scss/highlights.scm

@@ -0,0 +1,69 @@
+[
+  "@at-root"
+  "@debug"
+  "@error"
+  "@extend"
+  "@forward"
+  "@mixin"
+  "@use"
+  "@warn"
+] @keyword
+
+"@function" @keyword.function
+
+"@return" @keyword.return
+
+"@include" @keyword.import
+
+[
+  "@while"
+  "@each"
+  "@for"
+  "from"
+  "through"
+  "in"
+] @keyword.repeat
+
+(js_comment) @comment @spell
+
+(function_name) @function
+
+[
+  ">="
+  "<="
+] @operator
+
+(mixin_statement
+  name: (identifier) @function)
+
+(mixin_statement
+  (parameters
+    (parameter) @variable.parameter))
+
+(function_statement
+  name: (identifier) @function)
+
+(function_statement
+  (parameters
+    (parameter) @variable.parameter))
+
+(plain_value) @string
+
+(keyword_query) @function
+
+(identifier) @variable
+
+(variable) @variable
+
+(argument) @variable.parameter
+
+(arguments
+  (variable) @variable.parameter)
+
+[
+  "["
+  "]"
+] @punctuation.bracket
+
+(include_statement
+  (identifier) @function)

package/out/scss/indents.scm

@@ -0,0 +1,7 @@
+; inherits: css
+
+[
+  (mixin_statement)
+  (while_statement)
+  (each_statement)
+] @indent.begin

package/out/scss/injections.scm

@@ -0,0 +1,2 @@
+((single_line_comment) @injection.content
+  (#set! injection.language "comment"))

package/out/solidity/folds.scm

@@ -0,0 +1,20 @@
+[
+  (error_declaration)
+  (contract_body)
+  (struct_declaration)
+  (enum_declaration)
+  (event_definition)
+  (assembly_statement)
+  (block_statement)
+  (if_statement)
+  (for_statement)
+  (while_statement)
+  (yul_block)
+  (function_body)
+  (call_expression)
+  (inline_array_expression)
+  (tuple_expression)
+  (struct_expression)
+  (comment)
+  (emit_statement)
+] @fold