tree-sitter-wasm 1.0.0

package/out/liquid/highlights.scm

@@ -0,0 +1,119 @@
+([
+  "{{"
+  "}}"
+  "{{-"
+  "-}}"
+  "{%"
+  "%}"
+  "{%-"
+  "-%}"
+  ] @tag.delimiter
+ (#set! priority 101))
+
+
+([
+  "]"
+  "["
+  ")"
+  "("
+  ] @punctuation.bracket
+ (#set! priority 101))
+
+([
+  ","
+  "."
+  ] @punctuation.delimiter
+ (#set! priority 101))
+
+
+([
+  "as"
+  "assign"
+  (break_statement)
+  "by"
+  "capture"
+  "case"
+  (continue_statement)
+  (custom_unpaired_statement)
+  "cycle"
+  "decrement"
+  "doc"
+  "echo"
+  "else"
+  "elsif"
+  "endcapture"
+  "endcase"
+  "enddoc"
+  "endfor"
+  "endform"
+  "endif"
+  "endjavascript"
+  "endpaginate"
+  "endraw"
+  "endschema"
+  "endstyle"
+  "endstylesheet"
+  "endtablerow"
+  "endunless"
+  "for"
+  "form"
+  "if"
+  "include"
+  "include_relative"
+  "increment"
+  "javascript"
+  "layout"
+  "liquid"
+  "paginate"
+  "raw"
+  "render"
+  "schema"
+  "section"
+  "sections"
+  "style"
+  "stylesheet"
+  "tablerow"
+  "unless"
+  "when"
+  "with"
+  ] @keyword
+ (#set! priority 101))
+
+([
+  "and"
+  "contains"
+  "in"
+  "or"
+  ] @keyword.operator
+ (#set! priority 101))
+
+([
+  "|"
+  ":"
+  "="
+  (predicate)
+  ] @operator
+ (#set! priority 101))
+
+((identifier) @variable (#set! priority 101))
+((string) @string (#set! priority 101))
+((boolean) @boolean (#set! priority 101))
+((number) @number (#set! priority 101))
+
+(filter
+  name: (identifier) @function.call (#set! priority 101))
+
+(raw_statement
+  (raw_content) @text.reference (#set! priority 102))
+
+((comment) @comment (#set! priority 102))
+
+((doc) @comment.documentation (#set! priority 102))
+((doc_content) @comment.documentation (#set! priority 102))
+((doc_description_annotation) @keyword (#set! priority 103))
+((doc_example_annotation) @comment.documentation (#set! priority 102))
+((doc_example_content) @none (#set! priority 103))
+((doc_param_name) @variable (#set! priority 103))
+((doc_type) @type (#set! priority 103))
+("@param" @keyword (#set! priority 103))
+("@example" @keyword (#set! priority 103))

package/out/liquid/injections.scm

@@ -0,0 +1,22 @@
+((template_content) @injection.content
+  (#set! injection.language "html")
+  (#set! injection.combined))
+
+((json_content) @injection.content
+  (#set! injection.language "json")
+  (#set! injection.combined))
+
+((style_content) @injection.content
+  (#set! injection.language "css")
+  (#set! injection.combined))
+
+((stylesheet_content) @injection.content
+  (#set! injection.language "css")
+  (#set! injection.combined))
+
+((js_content) @injection.content
+  (#set! injection.language "javascript")
+  (#set! injection.combined))
+
+((front_matter) @injection.content
+  (#set! injection.language "yaml"))

package/out/lua/folds.scm

@@ -0,0 +1,12 @@
+[
+  (do_statement)
+  (while_statement)
+  (repeat_statement)
+  (if_statement)
+  (for_statement)
+  (function_declaration)
+  (function_definition)
+  (parameters)
+  (arguments)
+  (table_constructor)
+] @fold

package/out/lua/highlights.scm

@@ -0,0 +1,201 @@
+; Keywords
+"return" @keyword.return
+
+[
+  "goto"
+  "in"
+  "local"
+] @keyword
+
+(label_statement) @label
+
+(break_statement) @keyword
+
+(do_statement
+  [
+    "do"
+    "end"
+  ] @keyword)
+
+(while_statement
+  [
+    "while"
+    "do"
+    "end"
+  ] @repeat)
+
+(repeat_statement
+  [
+    "repeat"
+    "until"
+  ] @repeat)
+
+(if_statement
+  [
+    "if"
+    "elseif"
+    "else"
+    "then"
+    "end"
+  ] @conditional)
+
+(elseif_statement
+  [
+    "elseif"
+    "then"
+    "end"
+  ] @conditional)
+
+(else_statement
+  [
+    "else"
+    "end"
+  ] @conditional)
+
+(for_statement
+  [
+    "for"
+    "do"
+    "end"
+  ] @repeat)
+
+(function_declaration
+  [
+    "function"
+    "end"
+  ] @keyword.function)
+
+(function_definition
+  [
+    "function"
+    "end"
+  ] @keyword.function)
+
+; Operators
+(binary_expression
+  operator: _ @operator)
+
+(unary_expression
+  operator: _ @operator)
+
+[
+  "and"
+  "not"
+  "or"
+] @keyword.operator
+
+; Punctuations
+[
+  ";"
+  ":"
+  ","
+  "."
+] @punctuation.delimiter
+
+; Brackets
+[
+  "("
+  ")"
+  "["
+  "]"
+  "{"
+  "}"
+] @punctuation.bracket
+
+; Variables
+(identifier) @variable
+
+((identifier) @variable.builtin
+  (#eq? @variable.builtin "self"))
+
+(variable_list
+  (attribute
+    "<" @punctuation.bracket
+    (identifier) @attribute
+    ">" @punctuation.bracket))
+
+; Constants
+((identifier) @constant
+  (#match? @constant "^[A-Z][A-Z_0-9]*$"))
+
+(vararg_expression) @constant
+
+(nil) @constant.builtin
+
+[
+  (false)
+  (true)
+] @boolean
+
+; Tables
+(field
+  name: (identifier) @field)
+
+(dot_index_expression
+  field: (identifier) @field)
+
+(table_constructor
+  [
+    "{"
+    "}"
+  ] @constructor)
+
+; Functions
+(parameters
+  (identifier) @parameter)
+
+(function_declaration
+  name: [
+    (identifier) @function
+    (dot_index_expression
+      field: (identifier) @function)
+  ])
+
+(function_declaration
+  name: (method_index_expression
+    method: (identifier) @method))
+
+(assignment_statement
+  (variable_list
+    .
+    name: [
+      (identifier) @function
+      (dot_index_expression
+        field: (identifier) @function)
+    ])
+  (expression_list
+    .
+    value: (function_definition)))
+
+(table_constructor
+  (field
+    name: (identifier) @function
+    value: (function_definition)))
+
+(function_call
+  name: [
+    (identifier) @function.call
+    (dot_index_expression
+      field: (identifier) @function.call)
+    (method_index_expression
+      method: (identifier) @method.call)
+  ])
+
+(function_call
+  (identifier) @function.builtin
+  (#any-of? @function.builtin
+    ; built-in functions in Lua 5.1
+    "assert" "collectgarbage" "dofile" "error" "getfenv" "getmetatable" "ipairs" "load" "loadfile"
+    "loadstring" "module" "next" "pairs" "pcall" "print" "rawequal" "rawget" "rawset" "require"
+    "select" "setfenv" "setmetatable" "tonumber" "tostring" "type" "unpack" "xpcall"))
+
+; Others
+(comment) @comment
+
+(hash_bang_line) @preproc
+
+(number) @number
+
+(string) @string
+
+(escape_sequence) @string.escape

package/out/lua/indents.scm

@@ -0,0 +1,47 @@
+[
+  (function_definition)
+  (function_declaration)
+  (field)
+  (do_statement)
+  (method_index_expression)
+  (while_statement)
+  (repeat_statement)
+  (if_statement)
+  "then"
+  (for_statement)
+  (return_statement)
+  (table_constructor)
+  (arguments)
+] @indent.begin
+
+[
+  "end"
+  "}"
+  "]]"
+] @indent.end
+
+(")" @indent.end
+  (#not-has-parent? @indent.end parameters))
+
+(return_statement
+  (expression_list
+    (function_call))) @indent.dedent
+
+[
+  "end"
+  "then"
+  "until"
+  "}"
+  ")"
+  "elseif"
+  (elseif_statement)
+  "else"
+  (else_statement)
+] @indent.branch
+
+(comment) @indent.auto
+
+(string) @indent.auto
+
+(ERROR
+  "function") @indent.begin

package/out/lua/injections.scm

@@ -0,0 +1,12 @@
+((function_call
+  name: [
+    (identifier) @_cdef_identifier
+    (_
+      _
+      (identifier) @_cdef_identifier)
+  ]
+  arguments: (arguments
+    (string
+      content: _ @injection.content
+      (#set! injection.language "c"))))
+  (#eq? @_cdef_identifier "cdef"))

package/out/lua/locals.scm

@@ -0,0 +1,32 @@
+; Scopes
+[
+  (chunk)
+  (do_statement)
+  (while_statement)
+  (repeat_statement)
+  (if_statement)
+  (for_statement)
+  (function_declaration)
+  (function_definition)
+] @local.scope
+
+; Definitions
+(assignment_statement
+  (variable_list
+    (identifier) @local.definition))
+
+(function_declaration
+  name: (identifier) @local.definition)
+
+(for_generic_clause
+  (variable_list
+    (identifier) @local.definition))
+
+(for_numeric_clause
+  name: (identifier) @local.definition)
+
+(parameters
+  (identifier) @local.definition)
+
+; References
+(identifier) @local.reference

package/out/lua/tags.scm

@@ -0,0 +1,36 @@
+(function_declaration
+  name: [
+    (identifier) @name
+    (dot_index_expression
+      field: (identifier) @name)
+  ]) @definition.function
+
+(function_declaration
+  name: (method_index_expression
+    method: (identifier) @name)) @definition.method
+
+(assignment_statement
+  (variable_list
+    .
+    name: [
+      (identifier) @name
+      (dot_index_expression
+        field: (identifier) @name)
+    ])
+  (expression_list
+    .
+    value: (function_definition))) @definition.function
+
+(table_constructor
+  (field
+    name: (identifier) @name
+    value: (function_definition))) @definition.function
+
+(function_call
+  name: [
+    (identifier) @name
+    (dot_index_expression
+      field: (identifier) @name)
+    (method_index_expression
+      method: (identifier) @name)
+  ]) @reference.call

package/out/make/folds.scm

@@ -0,0 +1,6 @@
+([
+  (conditional)
+  (rule)
+  (define_directive)
+] @fold
+  (#trim! @fold))

package/out/make/highlights.scm

@@ -0,0 +1,172 @@
+(comment) @comment @spell
+
+(conditional
+  (_
+    [
+      "ifeq"
+      "else"
+      "ifneq"
+      "ifdef"
+      "ifndef"
+    ] @keyword.conditional)
+  "endif" @keyword.conditional)
+
+(rule
+  (targets
+    (word) @function))
+
+(rule
+  (targets) @_target
+  (prerequisites
+    (word) @function
+    (#eq? @_target ".PHONY")))
+
+(rule
+  (targets
+    (word) @function.builtin
+    (#any-of? @function.builtin
+      ".DEFAULT" ".SUFFIXES" ".DELETE_ON_ERROR" ".EXPORT_ALL_VARIABLES" ".IGNORE" ".INTERMEDIATE"
+      ".LOW_RESOLUTION_TIME" ".NOTPARALLEL" ".ONESHELL" ".PHONY" ".POSIX" ".PRECIOUS" ".SECONDARY"
+      ".SECONDEXPANSION" ".SILENT" ".SUFFIXES")))
+
+(rule
+  [
+    "&:"
+    ":"
+    "::"
+    "|"
+  ] @operator)
+
+[
+  "export"
+  "unexport"
+] @keyword.import
+
+(override_directive
+  "override" @keyword)
+
+(include_directive
+  [
+    "include"
+    "-include"
+  ] @keyword.import
+  filenames: (list
+    (word) @string.special.path))
+
+(variable_assignment
+  name: (word) @string.special.symbol
+  [
+    "?="
+    ":="
+    "::="
+    ; ":::="
+    "+="
+    "="
+  ] @operator)
+
+(shell_assignment
+  name: (word) @string.special.symbol
+  "!=" @operator)
+
+(define_directive
+  "define" @keyword
+  name: (word) @string.special.symbol
+  [
+    "="
+    ":="
+    "::="
+    ; ":::="
+    "?="
+    "!="
+  ]? @operator
+  "endef" @keyword)
+
+(variable_assignment
+  (word) @variable.builtin
+  (#any-of? @variable.builtin
+    ".DEFAULT_GOAL" ".EXTRA_PREREQS" ".FEATURES" ".INCLUDE_DIRS" ".RECIPEPREFIX" ".SHELLFLAGS"
+    ".VARIABLES" "MAKEARGS" "MAKEFILE_LIST" "MAKEFLAGS" "MAKE_RESTARTS" "MAKE_TERMERR"
+    "MAKE_TERMOUT" "SHELL"))
+
+; Use string to match bash
+(variable_reference
+  (word) @string) @operator
+
+(shell_function
+  [
+    "$"
+    "("
+    ")"
+  ] @operator
+  "shell" @function.builtin)
+
+(function_call
+  [
+    "$"
+    "("
+    ")"
+  ] @operator)
+
+(substitution_reference
+  [
+    "$"
+    "("
+    ")"
+  ] @operator)
+
+(automatic_variable
+  "$"
+  _ @character.special
+  (#set! priority 105))
+
+(automatic_variable
+  [
+    "$"
+    "("
+    ")"
+  ] @operator
+  (#set! priority 105))
+
+(recipe_line
+  "@" @character.special)
+
+(function_call
+  [
+    "subst"
+    "patsubst"
+    "strip"
+    "findstring"
+    "filter"
+    "filter-out"
+    "sort"
+    "word"
+    "words"
+    "wordlist"
+    "firstword"
+    "lastword"
+    "dir"
+    "notdir"
+    "suffix"
+    "basename"
+    "addsuffix"
+    "addprefix"
+    "join"
+    "wildcard"
+    "realpath"
+    "abspath"
+    "error"
+    "warning"
+    "info"
+    "origin"
+    "flavor"
+    "foreach"
+    "if"
+    "or"
+    "and"
+    "call"
+    "eval"
+    "file"
+    "value"
+  ] @function.builtin)
+
+"\\" @punctuation.special

package/out/make/injections.scm

@@ -0,0 +1,5 @@
+((shell_text) @injection.content
+  (#set! injection.language "bash"))
+
+((shell_command) @injection.content
+  (#set! injection.language "bash"))

package/out/markdown/folds.scm

@@ -0,0 +1,12 @@
+([
+  (fenced_code_block)
+  (indented_code_block)
+  (list_item
+    (list))
+  (section)
+] @fold
+  (#trim! @fold))
+
+(section
+  (list) @fold
+  (#trim! @fold))