tree-sitter-wasm 1.0.0

package/out/terraform/folds.scm

@@ -0,0 +1 @@
+; inherits: hcl

package/out/terraform/highlights.scm

@@ -0,0 +1,41 @@
+; inherits: hcl
+
+; Terraform specific references
+;
+;
+; local/module/data/var/output
+(expression
+  (variable_expr
+    (identifier) @variable.builtin
+    (#any-of? @variable.builtin "data" "var" "local" "module" "output"))
+  (get_attr
+    (identifier) @variable.member))
+
+; path.root/cwd/module
+(expression
+  (variable_expr
+    (identifier) @type.builtin
+    (#eq? @type.builtin "path"))
+  (get_attr
+    (identifier) @variable.builtin
+    (#any-of? @variable.builtin "root" "cwd" "module")))
+
+; terraform.workspace
+(expression
+  (variable_expr
+    (identifier) @type.builtin
+    (#eq? @type.builtin "terraform"))
+  (get_attr
+    (identifier) @variable.builtin
+    (#eq? @variable.builtin "workspace")))
+
+; Terraform specific keywords
+; FIXME: ideally only for identifiers under a `variable` block to minimize false positives
+((identifier) @type.builtin
+  (#any-of? @type.builtin "bool" "string" "number" "object" "tuple" "list" "map" "set" "any"))
+
+(object_elem
+  val: (expression
+    (variable_expr
+      (identifier) @type.builtin
+      (#any-of? @type.builtin "bool" "string" "number" "object" "tuple" "list" "map" "set" "any"))))

package/out/terraform/indents.scm

@@ -0,0 +1 @@
+; inherits: hcl

package/out/terraform/injections.scm

@@ -0,0 +1 @@
+; inherits: hcl

package/out/toml/folds.scm

@@ -0,0 +1,5 @@
+[
+  (table)
+  (array)
+  (table_array_element)
+] @fold

package/out/toml/highlights.scm

@@ -0,0 +1,53 @@
+; Properties
+;-----------
+
+(bare_key) @type
+
+(quoted_key) @string
+
+(pair
+  (bare_key)) @property
+
+(pair
+  (dotted_key
+    (bare_key) @property))
+
+; Literals
+;---------
+
+(boolean) @boolean
+
+(comment) @comment
+
+(string) @string
+
+[
+  (integer)
+  (float)
+] @number
+
+[
+  (offset_date_time)
+  (local_date_time)
+  (local_date)
+  (local_time)
+] @string.special
+
+; Punctuation
+;------------
+
+[
+  "."
+  ","
+] @punctuation.delimiter
+
+"=" @operator
+
+[
+  "["
+  "]"
+  "[["
+  "]]"
+  "{"
+  "}"
+] @punctuation.bracket

package/out/toml/indents.scm

@@ -0,0 +1,11 @@
+[
+  (array)
+  (inline_table)
+] @indent.begin
+
+[
+  "["
+  "]"
+  "{"
+  "}"
+] @indent.branch

package/out/toml/injections.scm

@@ -0,0 +1,2 @@
+((comment) @injection.content
+  (#set! injection.language "comment"))

package/out/toml/locals.scm

@@ -0,0 +1,4 @@
+[
+  (table)
+  (table_array_element)
+] @local.scope

package/out/tsv/highlights.scm

@@ -0,0 +1,4 @@
+(text) @string
+(number) @number
+(float) @float
+(boolean) @boolean

package/out/tsx/folds.scm

@@ -0,0 +1 @@
+; inherits: typescript,jsx

package/out/tsx/highlights.scm

@@ -0,0 +1,35 @@
+; Types
+
+(type_identifier) @type
+(predefined_type) @type.builtin
+
+((identifier) @type
+ (#match? @type "^[A-Z]"))
+
+(type_arguments
+  "<" @punctuation.bracket
+  ">" @punctuation.bracket)
+
+; Variables
+
+(required_parameter (identifier) @variable.parameter)
+(optional_parameter (identifier) @variable.parameter)
+
+; Keywords
+
+[ "abstract"
+  "declare"
+  "enum"
+  "export"
+  "implements"
+  "interface"
+  "keyof"
+  "namespace"
+  "private"
+  "protected"
+  "public"
+  "type"
+  "readonly"
+  "override"
+  "satisfies"
+] @keyword

package/out/tsx/indents.scm

@@ -0,0 +1 @@
+; inherits: typescript,jsx

package/out/tsx/injections.scm

@@ -0,0 +1 @@
+; inherits: typescript,jsx

package/out/tsx/locals.scm

@@ -0,0 +1,2 @@
+(required_parameter (identifier) @local.definition)
+(optional_parameter (identifier) @local.definition)

package/out/tsx/tags.scm

@@ -0,0 +1,23 @@
+(function_signature
+  name: (identifier) @name) @definition.function
+
+(method_signature
+  name: (property_identifier) @name) @definition.method
+
+(abstract_method_signature
+  name: (property_identifier) @name) @definition.method
+
+(abstract_class_declaration
+  name: (type_identifier) @name) @definition.class
+
+(module
+  name: (identifier) @name) @definition.module
+
+(interface_declaration
+  name: (type_identifier) @name) @definition.interface
+
+(type_annotation
+  (type_identifier) @name) @reference.type
+
+(new_expression
+  constructor: (identifier) @name) @reference.class

package/out/typescript/folds.scm

@@ -0,0 +1,8 @@
+; inherits: ecma
+
+[
+  (interface_declaration)
+  (internal_module)
+  (type_alias_declaration)
+  (enum_declaration)
+] @fold

package/out/typescript/highlights.scm

@@ -0,0 +1,35 @@
+; Types
+
+(type_identifier) @type
+(predefined_type) @type.builtin
+
+((identifier) @type
+ (#match? @type "^[A-Z]"))
+
+(type_arguments
+  "<" @punctuation.bracket
+  ">" @punctuation.bracket)
+
+; Variables
+
+(required_parameter (identifier) @variable.parameter)
+(optional_parameter (identifier) @variable.parameter)
+
+; Keywords
+
+[ "abstract"
+  "declare"
+  "enum"
+  "export"
+  "implements"
+  "interface"
+  "keyof"
+  "namespace"
+  "private"
+  "protected"
+  "public"
+  "type"
+  "readonly"
+  "override"
+  "satisfies"
+] @keyword

package/out/typescript/indents.scm

@@ -0,0 +1,7 @@
+; inherits: ecma
+
+[
+  (enum_declaration)
+  (interface_declaration)
+  (object_type)
+] @indent.begin

package/out/typescript/injections.scm

@@ -0,0 +1,28 @@
+; inherits: ecma
+
+; styled.div<{}>`<css>`
+(call_expression
+  function: (non_null_expression
+    (instantiation_expression
+      (member_expression
+        object: (identifier) @_name
+        (#eq? @_name "styled")
+        property: (property_identifier))
+      type_arguments: (type_arguments)))
+  arguments: ((template_string) @injection.content
+    (#offset! @injection.content 0 1 0 -1)
+    (#set! injection.include-children)
+    (#set! injection.language "styled")))
+
+; styled.div<T>`<css>`
+(binary_expression
+  left: (binary_expression
+    left: (member_expression
+      object: (identifier) @_name
+      (#eq? @_name "styled")
+      property: (property_identifier))
+    right: (identifier))
+  right: (template_string) @injection.content
+  (#offset! @injection.content 0 1 0 -1)
+  (#set! injection.include-children)
+  (#set! injection.language "styled"))

package/out/typescript/locals.scm

@@ -0,0 +1,2 @@
+(required_parameter (identifier) @local.definition)
+(optional_parameter (identifier) @local.definition)

package/out/typescript/tags.scm

@@ -0,0 +1,23 @@
+(function_signature
+  name: (identifier) @name) @definition.function
+
+(method_signature
+  name: (property_identifier) @name) @definition.method
+
+(abstract_method_signature
+  name: (property_identifier) @name) @definition.method
+
+(abstract_class_declaration
+  name: (type_identifier) @name) @definition.class
+
+(module
+  name: (identifier) @name) @definition.module
+
+(interface_declaration
+  name: (type_identifier) @name) @definition.interface
+
+(type_annotation
+  (type_identifier) @name) @reference.type
+
+(new_expression
+  constructor: (identifier) @name) @reference.class

package/out/vim/folds.scm

@@ -0,0 +1,4 @@
+[
+  (if_statement)
+  (function_definition)
+] @fold

package/out/vim/highlights.scm

@@ -0,0 +1,362 @@
+(identifier) @variable
+
+((identifier) @constant
+  (#lua-match? @constant "^[A-Z][A-Z_0-9]*$"))
+
+; Keywords
+[
+  "if"
+  "else"
+  "elseif"
+  "endif"
+] @keyword.conditional
+
+[
+  "try"
+  "catch"
+  "finally"
+  "endtry"
+  "throw"
+] @keyword.exception
+
+[
+  "for"
+  "endfor"
+  "in"
+  "while"
+  "endwhile"
+  "break"
+  "continue"
+] @keyword.repeat
+
+[
+  "function"
+  "endfunction"
+] @keyword.function
+
+; Function related
+(function_declaration
+  name: (_) @function)
+
+(call_expression
+  function: (identifier) @function.call)
+
+(call_expression
+  function: (scoped_identifier
+    (identifier) @function.call))
+
+(parameters
+  (identifier) @variable.parameter)
+
+(default_parameter
+  (identifier) @variable.parameter)
+
+[
+  (bang)
+  (spread)
+] @punctuation.special
+
+[
+  (no_option)
+  (inv_option)
+  (default_option)
+  (option_name)
+] @variable.builtin
+
+[
+  (scope)
+  "a:"
+  "$"
+] @module
+
+; Commands and user defined commands
+[
+  "let"
+  "unlet"
+  "const"
+  "call"
+  "execute"
+  "normal"
+  "set"
+  "setfiletype"
+  "setlocal"
+  "silent"
+  "echo"
+  "echon"
+  "echohl"
+  "echomsg"
+  "echoerr"
+  "autocmd"
+  "augroup"
+  "return"
+  "syntax"
+  "filetype"
+  "source"
+  "lua"
+  "ruby"
+  "perl"
+  "python"
+  "highlight"
+  "command"
+  "delcommand"
+  "comclear"
+  "colorscheme"
+  "scriptencoding"
+  "startinsert"
+  "stopinsert"
+  "global"
+  "runtime"
+  "wincmd"
+  "cnext"
+  "cprevious"
+  "cNext"
+  "tab"
+  "vertical"
+  "leftabove"
+  "aboveleft"
+  "rightbelow"
+  "belowright"
+  "topleft"
+  "botright"
+  (unknown_command_name)
+  "edit"
+  "enew"
+  "find"
+  "ex"
+  "visual"
+  "view"
+  "eval"
+  "sign"
+  "abort"
+  "substitute"
+] @keyword
+
+(map_statement
+  cmd: _ @keyword)
+
+(keycode) @character.special
+
+(command_name) @function.macro
+
+; Filetype command
+(filetype_statement
+  [
+    "detect"
+    "plugin"
+    "indent"
+    "on"
+    "off"
+  ] @keyword)
+
+; Syntax command
+(syntax_statement
+  (keyword) @string)
+
+(syntax_statement
+  [
+    "enable"
+    "on"
+    "off"
+    "reset"
+    "case"
+    "spell"
+    "foldlevel"
+    "iskeyword"
+    "keyword"
+    "match"
+    "cluster"
+    "region"
+    "clear"
+    "include"
+  ] @keyword)
+
+(syntax_argument
+  name: _ @keyword)
+
+[
+  "<buffer>"
+  "<nowait>"
+  "<silent>"
+  "<script>"
+  "<expr>"
+  "<unique>"
+] @constant.builtin
+
+(augroup_name) @module
+
+(au_event) @constant
+
+(normal_statement
+  (commands) @constant)
+
+; Highlight command
+(hl_attribute
+  key: _ @property
+  val: _ @constant)
+
+(hl_group) @type
+
+(highlight_statement
+  [
+    "default"
+    "link"
+    "clear"
+  ] @keyword)
+
+; Command command
+(command) @string
+
+(command_attribute
+  name: _ @property
+  val: (behavior
+    name: _ @constant
+    val: (identifier)? @function)?)
+
+; Edit command
+(plus_plus_opt
+  val: _? @constant) @property
+
+(plus_cmd
+  "+" @property) @property
+
+; Runtime command
+(runtime_statement
+  (where) @keyword.operator)
+
+; Colorscheme command
+(colorscheme_statement
+  (name) @string)
+
+; Scriptencoding command
+(scriptencoding_statement
+  (encoding) @string.special)
+
+; Literals
+(string_literal) @string
+
+(integer_literal) @number
+
+(float_literal) @number.float
+
+(comment) @comment @spell
+
+(line_continuation_comment) @comment @spell
+
+(pattern) @string.special
+
+(pattern_multi) @string.regexp
+
+(filename) @string.special.path
+
+(heredoc
+  (body) @string)
+
+(heredoc
+  (parameter) @keyword)
+
+(script
+  (parameter) @keyword)
+
+[
+  (marker_definition)
+  (endmarker)
+] @label
+
+(literal_dictionary
+  (literal_key) @property)
+
+((scoped_identifier
+  (scope) @_scope
+  .
+  (identifier) @boolean)
+  (#eq? @_scope "v:")
+  (#any-of? @boolean "true" "false"))
+
+; Operators
+[
+  "||"
+  "&&"
+  "&"
+  "+"
+  "-"
+  "*"
+  "/"
+  "%"
+  ".."
+  "=="
+  "!="
+  ">"
+  ">="
+  "<"
+  "<="
+  "=~"
+  "!~"
+  "="
+  "^="
+  "+="
+  "-="
+  "*="
+  "/="
+  "%="
+  ".="
+  "..="
+  "<<"
+  "=<<"
+  "->"
+  (match_case)
+] @operator
+
+[
+  "is"
+  "isnot"
+] @keyword.operator
+
+; Some characters have different meanings based on the context
+(unary_operation
+  "!" @operator)
+
+(binary_operation
+  "." @operator)
+
+(lua_statement
+  "=" @keyword)
+
+; Punctuation
+[
+  "("
+  ")"
+  "{"
+  "}"
+  "["
+  "]"
+  "#{"
+] @punctuation.bracket
+
+(field_expression
+  "." @punctuation.delimiter)
+
+[
+  ","
+  ":"
+] @punctuation.delimiter
+
+(ternary_expression
+  [
+    "?"
+    ":"
+  ] @keyword.conditional.ternary)
+
+; Options
+((set_value) @number
+  (#lua-match? @number "^[%d]+(%.[%d]+)?$"))
+
+(inv_option
+  "!" @operator)
+
+(set_item
+  "?" @operator)
+
+((set_item
+  option: (option_name) @_option
+  value: (set_value) @function)
+  (#any-of? @_option "tagfunc" "tfu" "completefunc" "cfu" "omnifunc" "ofu" "operatorfunc" "opfunc"))