tree-sitter-wasm 1.0.0

package/out/php_only/folds.scm

@@ -0,0 +1,19 @@
+[
+  (if_statement)
+  (switch_statement)
+  (while_statement)
+  (do_statement)
+  (for_statement)
+  (foreach_statement)
+  (try_statement)
+  (function_definition)
+  (class_declaration)
+  (interface_declaration)
+  (trait_declaration)
+  (enum_declaration)
+  (function_static_declaration)
+  (method_declaration)
+  (namespace_use_declaration)+
+  (array_creation_expression)
+  (match_expression)
+] @fold

package/out/php_only/highlights.scm

@@ -0,0 +1,203 @@
+[
+  (php_tag)
+  (php_end_tag)
+] @tag
+
+; Keywords
+
+[
+  "and"
+  "as"
+  "break"
+  "case"
+  "catch"
+  "class"
+  "clone"
+  "const"
+  "continue"
+  "declare"
+  "default"
+  "do"
+  "echo"
+  "else"
+  "elseif"
+  "enddeclare"
+  "endfor"
+  "endforeach"
+  "endif"
+  "endswitch"
+  "endwhile"
+  "enum"
+  "exit"
+  "extends"
+  "finally"
+  "fn"
+  "for"
+  "foreach"
+  "function"
+  "global"
+  "goto"
+  "if"
+  "implements"
+  "include"
+  "include_once"
+  "instanceof"
+  "insteadof"
+  "interface"
+  "match"
+  "namespace"
+  "new"
+  "or"
+  "print"
+  "require"
+  "require_once"
+  "return"
+  "switch"
+  "throw"
+  "trait"
+  "try"
+  "use"
+  "while"
+  "xor"
+  "yield"
+  "yield from"
+  (abstract_modifier)
+  (final_modifier)
+  (readonly_modifier)
+  (static_modifier)
+  (visibility_modifier)
+] @keyword
+
+(function_static_declaration "static" @keyword)
+
+; Namespace
+
+(namespace_definition
+  name: (namespace_name
+    (name) @module))
+
+(namespace_name
+  (name) @module)
+
+(namespace_use_clause
+  [
+    (name) @type
+    (qualified_name
+      (name) @type)
+    alias: (name) @type
+  ])
+
+(namespace_use_clause
+  type: "function"
+  [
+    (name) @function
+    (qualified_name
+      (name) @function)
+    alias: (name) @function
+  ])
+
+(namespace_use_clause
+  type: "const"
+  [
+    (name) @constant
+    (qualified_name
+      (name) @constant)
+    alias: (name) @constant
+  ])
+
+(relative_name "namespace" @module.builtin)
+
+; Variables
+
+(relative_scope) @variable.builtin
+
+(variable_name) @variable
+
+(method_declaration name: (name) @constructor
+  (#eq? @constructor "__construct"))
+
+(object_creation_expression [
+  (name) @constructor
+  (qualified_name (name) @constructor)
+  (relative_name (name) @constructor)
+])
+
+((name) @constant
+ (#match? @constant "^_?[A-Z][A-Z\\d_]+$"))
+((name) @constant.builtin
+ (#match? @constant.builtin "^__[A-Z][A-Z\d_]+__$"))
+(const_declaration (const_element (name) @constant))
+
+; Types
+
+(primitive_type) @type.builtin
+(cast_type) @type.builtin
+(named_type [
+  (name) @type
+  (qualified_name (name) @type)
+  (relative_name (name) @type)
+]) @type
+(named_type (name) @type.builtin
+  (#any-of? @type.builtin "static" "self"))
+
+(scoped_call_expression
+  scope: [
+    (name) @type
+    (qualified_name (name) @type)
+    (relative_name (name) @type)
+  ])
+
+; Functions
+
+(array_creation_expression "array" @function.builtin)
+(list_literal "list" @function.builtin)
+(exit_statement "exit" @function.builtin "(")
+
+(method_declaration
+  name: (name) @function.method)
+
+(function_call_expression
+  function: [
+    (qualified_name (name))
+    (relative_name (name))
+    (name)
+  ] @function)
+
+(scoped_call_expression
+  name: (name) @function)
+
+(member_call_expression
+  name: (name) @function.method)
+
+(function_definition
+  name: (name) @function)
+
+; Member
+
+(property_element
+  (variable_name) @property)
+
+(member_access_expression
+  name: (variable_name (name)) @property)
+(member_access_expression
+  name: (name) @property)
+
+; Basic tokens
+[
+  (string)
+  (string_content)
+  (encapsed_string)
+  (heredoc)
+  (heredoc_body)
+  (nowdoc_body)
+] @string
+(boolean) @constant.builtin
+(null) @constant.builtin
+(integer) @number
+(float) @number
+(comment) @comment
+
+((name) @variable.builtin
+ (#eq? @variable.builtin "this"))
+
+"$" @operator

package/out/php_only/indents.scm

@@ -0,0 +1,68 @@
+[
+  (array_creation_expression)
+  (parenthesized_expression)
+  (compound_statement)
+  (declaration_list)
+  (member_call_expression)
+  (binary_expression)
+  (return_statement)
+  (arguments)
+  (formal_parameters)
+  (enum_declaration_list)
+  (switch_block)
+  (match_block)
+  (case_statement)
+  (default_statement)
+  (property_hook_list)
+] @indent.begin
+
+(return_statement
+  [
+    (object_creation_expression)
+    (anonymous_function)
+    (arrow_function)
+    (match_expression)
+  ]) @indent.dedent
+
+[
+  ")"
+  "}"
+  "]"
+] @indent.branch
+
+(comment) @indent.auto
+
+(arguments
+  ")" @indent.end)
+
+(formal_parameters
+  ")" @indent.end)
+
+(compound_statement
+  "}" @indent.end)
+
+(declaration_list
+  "}" @indent.end)
+
+(enum_declaration_list
+  "}" @indent.end)
+
+(return_statement
+  ";" @indent.end)
+
+(property_hook_list
+  "}" @indent.end)
+
+(ERROR
+  "(" @indent.align
+  .
+  (_)
+  (#set! indent.open_delimiter "(")
+  (#set! indent.close_delimiter ")"))
+
+(ERROR
+  "[" @indent.align
+  .
+  (_)
+  (#set! indent.open_delimiter "[")
+  (#set! indent.close_delimiter "]"))

package/out/php_only/injections-text.scm

@@ -0,0 +1,3 @@
+((text) @injection.content
+ (#set! injection.language "html")
+ (#set! injection.combined))

package/out/php_only/injections.scm

@@ -0,0 +1,10 @@
+((comment) @injection.content
+  (#set! injection.language "phpdoc"))
+
+(heredoc
+  (heredoc_body) @injection.content
+  (heredoc_end) @injection.language)
+
+(nowdoc
+  (nowdoc_body) @injection.content
+  (heredoc_end) @injection.language)

package/out/php_only/locals.scm

@@ -0,0 +1,84 @@
+; Scopes
+;-------
+((class_declaration
+  name: (name) @local.definition.type) @local.scope
+  (#set! definition.type.scope "parent"))
+
+((method_declaration
+  name: (name) @local.definition.method) @local.scope
+  (#set! definition.method.scope "parent"))
+
+((function_definition
+  name: (name) @local.definition.function) @local.scope
+  (#set! definition.function.scope "parent"))
+
+(anonymous_function
+  (anonymous_function_use_clause
+    (variable_name
+      (name) @local.definition.var))) @local.scope
+
+; Definitions
+;------------
+(simple_parameter
+  (variable_name
+    (name) @local.definition.var))
+
+(foreach_statement
+  (pair
+    (variable_name
+      (name) @local.definition.var)))
+
+(foreach_statement
+  (variable_name
+    (name) @local.reference
+    (#set! reference.kind "var"))
+  (variable_name
+    (name) @local.definition.var))
+
+(property_declaration
+  (property_element
+    (variable_name
+      (name) @local.definition.field)))
+
+(namespace_use_clause
+  (qualified_name
+    (name) @local.definition.type))
+
+; References
+;------------
+(named_type
+  (name) @local.reference
+  (#set! reference.kind "type"))
+
+(named_type
+  (qualified_name) @local.reference
+  (#set! reference.kind "type"))
+
+(variable_name
+  (name) @local.reference
+  (#set! reference.kind "var"))
+
+(member_access_expression
+  name: (name) @local.reference
+  (#set! reference.kind "field"))
+
+(member_call_expression
+  name: (name) @local.reference
+  (#set! reference.kind "method"))
+
+(function_call_expression
+  function: (qualified_name
+    (name) @local.reference
+    (#set! reference.kind "function")))
+
+(object_creation_expression
+  (qualified_name
+    (name) @local.reference
+    (#set! reference.kind "type")))
+
+(scoped_call_expression
+  scope: (qualified_name
+    (name) @local.reference
+    (#set! reference.kind "type"))
+  name: (name) @local.reference
+  (#set! reference.kind "method"))

package/out/php_only/tags.scm

@@ -0,0 +1,40 @@
+(namespace_definition
+  name: (namespace_name) @name) @definition.module
+
+(interface_declaration
+  name: (name) @name) @definition.interface
+
+(trait_declaration
+  name: (name) @name) @definition.interface
+
+(class_declaration
+  name: (name) @name) @definition.class
+
+(class_interface_clause [(name) (qualified_name)] @name) @reference.implementation
+
+(property_declaration
+  (property_element (variable_name (name) @name))) @definition.field
+
+(function_definition
+  name: (name) @name) @definition.function
+
+(method_declaration
+  name: (name) @name) @definition.function
+
+(object_creation_expression
+  [
+    (qualified_name (name) @name)
+    (variable_name (name) @name)
+  ]) @reference.class
+
+(function_call_expression
+  function: [
+    (qualified_name (name) @name)
+    (variable_name (name)) @name
+  ]) @reference.call
+
+(scoped_call_expression
+  name: (name) @name) @reference.call
+
+(member_call_expression
+  name: (name) @name) @reference.call

package/out/powershell/folds.scm

@@ -0,0 +1,13 @@
+[
+  (expandable_here_string_literal)
+  (verbatim_here_string_characters)
+  (function_statement)
+  (param_block)
+  (script_block_expression)
+  (statement_block)
+  (switch_body)
+  (array_expression)
+  (hash_literal_expression)
+  (class_statement)
+  (class_method_definition)
+] @fold

package/out/powershell/highlights.scm

@@ -0,0 +1,128 @@
+"param" @keyword
+"dynamicparam" @keyword
+"begin" @keyword
+"process" @keyword
+"end" @keyword
+"if" @keyword
+"elseif" @keyword
+"else" @keyword
+"switch" @keyword
+"foreach" @keyword
+"for" @keyword
+"while" @keyword
+"do" @keyword
+"until" @keyword
+"function" @keyword
+"filter" @keyword
+"workflow" @keyword
+"break" @keyword
+"continue" @keyword
+"throw" @keyword
+"return" @keyword
+"exit" @keyword
+"trap" @keyword
+"try" @keyword
+"catch" @keyword
+"finally" @keyword
+"data" @keyword
+"inlinescript" @keyword
+"parallel" @keyword
+"sequence" @keyword
+
+"-as" @operator
+"-ccontains" @operator
+"-ceq" @operator
+"-cge" @operator
+"-cgt" @operator
+"-cle" @operator
+"-clike" @operator
+"-clt" @operator
+"-cmatch" @operator
+"-cne" @operator
+"-cnotcontains" @operator
+"-cnotlike" @operator
+"-cnotmatch" @operator
+"-contains" @operator
+"-creplace" @operator
+"-csplit" @operator
+"-eq" @operator
+"-ge" @operator
+"-gt" @operator
+"-icontains" @operator
+"-ieq" @operator
+"-ige" @operator
+"-igt" @operator
+"-ile" @operator
+"-ilike" @operator
+"-ilt" @operator
+"-imatch" @operator
+"-in" @operator
+"-ine" @operator
+"-inotcontains" @operator
+"-inotlike" @operator
+"-inotmatch" @operator
+"-ireplace" @operator
+"-is" @operator
+"-isnot" @operator
+"-isplit" @operator
+"-join" @operator
+"-le" @operator
+"-like" @operator
+"-lt" @operator
+"-match" @operator
+"-ne" @operator
+"-notcontains" @operator
+"-notin" @operator
+"-notlike" @operator
+"-notmatch" @operator
+"-replace" @operator
+"-shl" @operator
+"-shr" @operator
+"-split" @operator
+"-and" @operator
+"-or" @operator
+"-xor" @operator
+"-band" @operator
+"-bor" @operator
+"-bxor" @operator
+"+" @operator
+"-" @operator
+"/" @operator
+"\\" @operator
+"%" @operator
+"*" @operator
+".." @operator
+"-not" @operator
+
+
+";" @delimiter
+
+(string_literal) @string
+
+(integer_literal) @number
+(real_literal) @number
+
+(command
+  command_name: (command_name) @function)
+
+(function_statement
+  (function_name) @function)
+
+(invokation_expression
+  (member_name) @function)
+
+(member_access
+  (member_name) @property)
+
+(command_invokation_operator) @operator
+
+(type_spec) @type
+
+(variable) @variable
+
+(comment) @comment
+
+(array_expression) @array
+
+(assignment_expression
+  value: (pipeline) @assignvalue)

package/out/powershell/indents.scm

@@ -0,0 +1,41 @@
+(function_statement
+  "}" @indent.branch) @indent.begin
+
+(param_block
+  [
+    "param"
+    "("
+    ")"
+  ] @indent.branch) @indent.begin
+
+(script_block_expression
+  "}" @indent.branch) @indent.begin
+
+(statement_block
+  "}" @indent.branch) @indent.begin
+
+(switch_body
+  "}" @indent.branch) @indent.begin
+
+(array_expression
+  ")" @indent.branch) @indent.begin
+
+(hash_literal_expression
+  "}" @indent.branch) @indent.begin
+
+(class_statement
+  "}" @indent.branch) @indent.begin
+
+(class_method_definition
+  "}" @indent.branch) @indent.begin
+
+[
+  "}"
+  ")"
+] @indent.end
+
+[
+  (comment)
+  (string_literal)
+  (ERROR)
+] @indent.auto

package/out/powershell/injections.scm

@@ -0,0 +1,27 @@
+; comments and block-comments
+((comment) @injection.content
+  (#set! injection.language "comment"))
+
+; dynamic invocation like & "$env:ChocolateyInstall\bin\choco.exe"
+(command
+  (command_invokation_operator) @_operator
+  (command_name_expr
+    (string_literal) @injection.content)
+  (#eq? @_operator "&")
+  (#set! injection.language "powershell")
+  (#offset! @injection.content 0 1 0 -1)
+  (#set! injection.include-children))
+
+; switch -regex
+(switch_statement
+  (switch_parameters
+    (switch_parameter) @_parameter)
+  (switch_body
+    (switch_clauses
+      (switch_clause
+        (switch_clause_condition
+          (string_literal) @injection.content))))
+  (#eq? @_parameter "-regex")
+  (#set! injection.language "regex")
+  (#offset! @injection.content 0 1 0 -1)
+  (#set! injection.include-children))