passagemath-gap-pkg-semigroups 10.6.30__cp311-cp311-macosx_13_0_arm64.whl

gap/pkg/semigroups/m4/ax_check_hpcombi.m4

@@ -0,0 +1,121 @@
+dnl handle HPCombi checks
+
+AC_DEFUN([CHECK_INTRINSIC],
+    [AC_MSG_CHECKING([for $1])
+    saved_CXXFLAGS="$CXXFLAGS"
+    CXXFLAGS="-mavx -flax-vector-conversions"
+    AC_LINK_IFELSE(
+      [AC_LANG_PROGRAM(
+        [[#include <x86intrin.h>]],
+        [$1[($2)];
+        ]
+        )],
+      [],
+      [enable_hpcombi=no]
+      )
+    AC_MSG_RESULT([$enable_hpcombi])
+    CXXFLAGS="$saved_CXXFLAGS"
+    ])
+
+AC_DEFUN([AX_CHECK_HPCOMBI], [
+  m4_define([ax_hpcombi_cxxflags_variable],[HPCOMBI_CXXFLAGS])
+  AC_ARG_ENABLE([hpcombi],
+      [AS_HELP_STRING([--enable-hpcombi], [enable HPCombi])],
+      [],
+      [enable_hpcombi=yes]
+      )
+  AC_MSG_CHECKING([whether to enable HPCombi])
+  AC_MSG_RESULT([$enable_hpcombi])
+
+  AS_IF([test "x$enable_hpcombi" = xyes],
+        [AS_IF([test -f $srcdir/libsemigroups/extern/HPCombi/VERSION],
+                       [],
+                       [AC_MSG_WARN([HPCombi is not available])
+                       [enable_hpcombi=no]])])
+
+  AS_IF([test "x$enable_hpcombi" = xyes],
+        [AC_MSG_CHECKING([the required version of HPCombi])
+         MIN_HPCOMBI_VERSION="0.0.6"
+         AC_MSG_RESULT([$MIN_HPCOMBI_VERSION])])
+
+  AS_IF([test "x$enable_hpcombi" = xyes],
+        [AC_MSG_CHECKING([the version of HPCombi that's present])
+         FOUND_HPCOMBI="$(cat $srcdir/libsemigroups/extern/HPCombi/VERSION)"
+         AC_MSG_RESULT([$FOUND_HPCOMBI])])
+
+  AS_IF([test "x$enable_hpcombi" = xyes],
+        [AX_COMPARE_VERSION($FOUND_HPCOMBI,
+                            [ge],
+                            $MIN_HPCOMBI_VERSION,
+                            [],
+                            [AC_MSG_WARN([the incorrect version of HPCombi is present, HPCombi is disabled])
+                            enable_hpcombi=no])])
+
+  dnl # Check if the flags required for HPCombi are supported
+  AS_IF([test "x$enable_hpcombi" = xyes],
+        [AX_CHECK_COMPILE_FLAG(-mavx,
+                               AX_APPEND_FLAG(-mavx, [ax_hpcombi_cxxflags_variable]),
+                               [AC_MSG_WARN([flag -mavx not supported, HPCombi is disabled])
+                              enable_hpcombi=no])])
+
+  AS_IF([test "x$enable_hpcombi" = xyes],
+        [AX_CHECK_COMPILE_FLAG(-flax-vector-conversions,
+                               AX_APPEND_FLAG(-flax-vector-conversions, [ax_hpcombi_cxxflags_variable]),
+                               [AC_MSG_WARN([flag -flax-vector-conversions not supported, HPCombi is disabled])
+                               enable_hpcombi=no])])
+
+  dnl # Check if the x86intrin.h header is available
+  AS_IF([test "x$enable_hpcombi" = xyes],
+        [AC_CHECK_HEADERS([x86intrin.h], [], [AC_MSG_WARN([header x86intrin.h is required for HPCombi, HPCombi is disabled])
+                               enable_hpcombi=no])])
+
+  AS_IF([test "x$enable_hpcombi" = xyes],
+        [enable_hpcombi_before_builtin_check=yes])
+
+  AS_IF([test "x$enable_hpcombi" = xyes], [CHECK_INTRINSIC([_mm_blendv_epi8],[__m128i{},__m128i{},__m128i{}])])
+  AS_IF([test "x$enable_hpcombi" = xyes], [CHECK_INTRINSIC([_mm_cmpeq_epi8],[__m128i{},__m128i{}])])
+  AS_IF([test "x$enable_hpcombi" = xyes], [CHECK_INTRINSIC([_mm_cmpestri],[__m128i{},1,__m128i{},1,1])])
+  AS_IF([test "x$enable_hpcombi" = xyes], [CHECK_INTRINSIC([_mm_cmpestrm],[__m128i{},1,__m128i{},1,1])])
+  AS_IF([test "x$enable_hpcombi" = xyes], [CHECK_INTRINSIC([_mm_cmplt_epi8],[__m128i{},__m128i{}])])
+  AS_IF([test "x$enable_hpcombi" = xyes], [CHECK_INTRINSIC([_mm_extract_epi64],[__m128i{},1])])
+  AS_IF([test "x$enable_hpcombi" = xyes], [CHECK_INTRINSIC([_mm_max_epi8],[__m128i{},__m128i{}])])
+  AS_IF([test "x$enable_hpcombi" = xyes], [CHECK_INTRINSIC([_mm_max_epu8],[__m128i{},__m128i{}])])
+  AS_IF([test "x$enable_hpcombi" = xyes], [CHECK_INTRINSIC([_mm_min_epi8],[__m128i{},__m128i{}])])
+  AS_IF([test "x$enable_hpcombi" = xyes], [CHECK_INTRINSIC([_mm_min_epu8],[__m128i{},__m128i{}])])
+  AS_IF([test "x$enable_hpcombi" = xyes], [CHECK_INTRINSIC([_mm_movemask_epi8],[__m128i{}])])
+  AS_IF([test "x$enable_hpcombi" = xyes], [CHECK_INTRINSIC([_mm_popcnt_u32],[{}])])
+  AS_IF([test "x$enable_hpcombi" = xyes], [CHECK_INTRINSIC([_mm_set_epi64x],[1,1])])
+  AS_IF([test "x$enable_hpcombi" = xyes], [CHECK_INTRINSIC([_mm_shuffle_epi8],[__m128i{},__m128i{}])])
+  AS_IF([test "x$enable_hpcombi" = xyes], [CHECK_INTRINSIC([_mm_slli_epi32],[__m128i{},1])])
+
+  AS_IF([test "x$enable_hpcombi_before_builtin_check" = xyes],
+        [AS_IF([test "x$enable_hpcombi" = xno],
+         [AC_MSG_WARN([compiler builtin not supported, HPCombi is disabled])])])
+
+  AS_IF([test "x$enable_hpcombi" = xyes],
+        [AC_DEFINE([HPCOMBI_ENABLED], [1], [define if building with HPCombi])])
+
+  dnl # the following is used in Makefile.am
+  AS_IF([test "x$enable_hpcombi" = xyes],
+        AC_SUBST(LIBSEMIGROUPS_HPCOMBI_ENABLED, yes))
+
+  dnl # check for HPCombi's preprocessor macro
+  AS_IF([test "x$enable_hpcombi" = xyes],
+  [AC_MSG_CHECKING([for HPCOMBI_CONSTEXPR_FUN_ARGS])
+   AC_COMPILE_IFELSE(
+                    [AC_LANG_PROGRAM(
+                        [[using T = int; constexpr int exec(T f()) { return f(); }
+                        constexpr int foo() { return 1; }
+                        static_assert(exec(foo) == 1, "Failed exec");]]
+                      )],
+                     [hpcombi_constexpr_fun_args=yes],
+                     [hpcombi_constexpr_fun_args=no]
+                   )
+   AC_MSG_RESULT([$hpcombi_constexpr_fun_args])])
+
+  AS_IF([test "x$hpcombi_constexpr_fun_args" = xyes],
+        AC_SUBST(HPCOMBI_CONSTEXPR_FUN_ARGS, yes))
+
+  AS_IF([test "x$enable_hpcombi" = xyes],
+        AC_SUBST(ax_hpcombi_cxxflags_variable))
+])

gap/pkg/semigroups/m4/ax_check_libsemigroup.m4

@@ -0,0 +1,68 @@
+dnl handle libsemigroups checks
+dnl
+dnl if --with-external-libsemigroups is supplied,
+dnl use it if it is known to pkg-config and is new enough;
+dnl otherwise use the included version
+dnl
+AC_DEFUN([AX_CHECK_LIBSEMIGROUPS], [
+  AC_ARG_WITH([external-libsemigroups],
+	      [AS_HELP_STRING([--with-external-libsemigroups],[use the external libsemigroups])])
+  REQUI_LIBSEMIGROUPS_VERSION="$(cat .LIBSEMIGROUPS_VERSION)"
+  need_included_libsemigroups=yes
+  if test "$with_external_libsemigroups" = yes;  then
+	m4_ifdef([PKG_CHECK_MODULES], [
+	PKG_CHECK_MODULES([LIBSEMIGROUPS], 
+                          [libsemigroups >= $REQUI_LIBSEMIGROUPS_VERSION],
+			  [need_included_libsemigroups=no],
+			  [need_included_libsemigroups=yes])],
+	[AC_MSG_NOTICE(m4_normalize([
+                        ignoring flag --with-external-libsemigroups, the Semigroups configure file
+                        was created on a system without m4 macros for pkg-config available...]))])
+  fi
+  if test "$need_included_libsemigroups" = yes;  then
+	AC_MSG_NOTICE([using included libsemigroups...])
+  	AS_IF(
+   		[test -f libsemigroups/include/libsemigroups/libsemigroups.hpp],
+   		[],
+   		dnl Temporary workaround for backward compatibility with
+   		dnl libsemigroups pre PR 172: Includes in libsemigroups/
+   		[AS_IF(
+   		   [test -f libsemigroups/include/libsemigroups.hpp],
+                   [],
+                   [AC_MSG_ERROR(m4_normalize([
+                                  libsemigroups is required, clone or download the repo from
+                                  https://github.com/libsemigroups/libsemigroups into this directory]))])])
+
+        dnl Temporary workaround for compatibility with dev version of
+        dnl libsemigroups which doesn't contain .VERSION file by default
+	AS_IF(
+   		[test -f libsemigroups/.VERSION],
+   		[],
+        [AS_IF([test -f libsemigroups/etc/version-number.sh], 
+           [cd libsemigroups && etc/version-number.sh > .TMP_VERSION && mv .TMP_VERSION .VERSION && cd ..],
+           [AC_MSG_ERROR([cannot determine the version of libsemigroups])])])
+    
+	AC_MSG_CHECKING([libsemigroups version])
+	FOUND_LIBSEMIGROUPS_VERSION="$(cat libsemigroups/.VERSION)"
+	AC_MSG_RESULT([$FOUND_LIBSEMIGROUPS_VERSION])
+	AX_COMPARE_VERSION($FOUND_LIBSEMIGROUPS_VERSION,
+                   [ge],
+                   $REQUI_LIBSEMIGROUPS_VERSION,
+                   [],
+                   [AC_MSG_ERROR([libsemigroups version $REQUI_LIBSEMIGROUPS_VERSION or higher is required])]
+                  )
+        AC_SUBST(LIBSEMIGROUPS_CFLAGS, ['-I./bin/include -I./bin/include/libsemigroups'])
+        AC_SUBST(LIBSEMIGROUPS_LIBS, ['-L./bin/lib -lsemigroups'])
+        AC_CONFIG_SUBDIRS([libsemigroups])
+
+    AC_SUBST([LIBSEMIGROUPS_RPATH],['-Wl,-rpath,$(abs_top_builddir)/bin/lib'])
+  else 
+        LIBSEMIGROUPS_VERSION="$(pkg-config --modversion libsemigroups)"
+	AC_MSG_NOTICE([using external libsemigroups $LIBSEMIGROUPS_VERSION])
+        PKG_CHECK_VAR([LIBSEMIGROUPS_RPATH], [libsemigroups], [libdir],
+              [AC_SUBST([LIBSEMIGROUPS_RPATH],[-Wl,-rpath,${LIBSEMIGROUPS_RPATH}])])
+  fi
+
+  AS_IF([test "x$need_included_libsemigroups" = xyes],
+        AC_SUBST(WITH_INCLUDED_LIBSEMIGROUPS, yes))
+])

gap/pkg/semigroups/m4/ax_compare_version.m4

@@ -0,0 +1,177 @@
+# ===========================================================================
+#    https://www.gnu.org/software/autoconf-archive/ax_compare_version.html
+# ===========================================================================
+#
+# SYNOPSIS
+#
+#   AX_COMPARE_VERSION(VERSION_A, OP, VERSION_B, [ACTION-IF-TRUE], [ACTION-IF-FALSE])
+#
+# DESCRIPTION
+#
+#   This macro compares two version strings. Due to the various number of
+#   minor-version numbers that can exist, and the fact that string
+#   comparisons are not compatible with numeric comparisons, this is not
+#   necessarily trivial to do in a autoconf script. This macro makes doing
+#   these comparisons easy.
+#
+#   The six basic comparisons are available, as well as checking equality
+#   limited to a certain number of minor-version levels.
+#
+#   The operator OP determines what type of comparison to do, and can be one
+#   of:
+#
+#    eq  - equal (test A == B)
+#    ne  - not equal (test A != B)
+#    le  - less than or equal (test A <= B)
+#    ge  - greater than or equal (test A >= B)
+#    lt  - less than (test A < B)
+#    gt  - greater than (test A > B)
+#
+#   Additionally, the eq and ne operator can have a number after it to limit
+#   the test to that number of minor versions.
+#
+#    eq0 - equal up to the length of the shorter version
+#    ne0 - not equal up to the length of the shorter version
+#    eqN - equal up to N sub-version levels
+#    neN - not equal up to N sub-version levels
+#
+#   When the condition is true, shell commands ACTION-IF-TRUE are run,
+#   otherwise shell commands ACTION-IF-FALSE are run. The environment
+#   variable 'ax_compare_version' is always set to either 'true' or 'false'
+#   as well.
+#
+#   Examples:
+#
+#     AX_COMPARE_VERSION([3.15.7],[lt],[3.15.8])
+#     AX_COMPARE_VERSION([3.15],[lt],[3.15.8])
+#
+#   would both be true.
+#
+#     AX_COMPARE_VERSION([3.15.7],[eq],[3.15.8])
+#     AX_COMPARE_VERSION([3.15],[gt],[3.15.8])
+#
+#   would both be false.
+#
+#     AX_COMPARE_VERSION([3.15.7],[eq2],[3.15.8])
+#
+#   would be true because it is only comparing two minor versions.
+#
+#     AX_COMPARE_VERSION([3.15.7],[eq0],[3.15])
+#
+#   would be true because it is only comparing the lesser number of minor
+#   versions of the two values.
+#
+#   Note: The characters that separate the version numbers do not matter. An
+#   empty string is the same as version 0. OP is evaluated by autoconf, not
+#   configure, so must be a string, not a variable.
+#
+#   The author would like to acknowledge Guido Draheim whose advice about
+#   the m4_case and m4_ifvaln functions make this macro only include the
+#   portions necessary to perform the specific comparison specified by the
+#   OP argument in the final configure script.
+#
+# LICENSE
+#
+#   Copyright (c) 2008 Tim Toolan <toolan@ele.uri.edu>
+#
+#   Copying and distribution of this file, with or without modification, are
+#   permitted in any medium without royalty provided the copyright notice
+#   and this notice are preserved. This file is offered as-is, without any
+#   warranty.
+
+#serial 13
+
+dnl #########################################################################
+AC_DEFUN([AX_COMPARE_VERSION], [
+  AC_REQUIRE([AC_PROG_AWK])
+
+  # Used to indicate true or false condition
+  ax_compare_version=false
+
+  # Convert the two version strings to be compared into a format that
+  # allows a simple string comparison.  The end result is that a version
+  # string of the form 1.12.5-r617 will be converted to the form
+  # 0001001200050617.  In other words, each number is zero padded to four
+  # digits, and non digits are removed.
+  AS_VAR_PUSHDEF([A],[ax_compare_version_A])
+  A=`echo "$1" | sed -e 's/\([[0-9]]*\)/Z\1Z/g' \
+                     -e 's/Z\([[0-9]]\)Z/Z0\1Z/g' \
+                     -e 's/Z\([[0-9]][[0-9]]\)Z/Z0\1Z/g' \
+                     -e 's/Z\([[0-9]][[0-9]][[0-9]]\)Z/Z0\1Z/g' \
+                     -e 's/[[^0-9]]//g'`
+
+  AS_VAR_PUSHDEF([B],[ax_compare_version_B])
+  B=`echo "$3" | sed -e 's/\([[0-9]]*\)/Z\1Z/g' \
+                     -e 's/Z\([[0-9]]\)Z/Z0\1Z/g' \
+                     -e 's/Z\([[0-9]][[0-9]]\)Z/Z0\1Z/g' \
+                     -e 's/Z\([[0-9]][[0-9]][[0-9]]\)Z/Z0\1Z/g' \
+                     -e 's/[[^0-9]]//g'`
+
+  dnl # In the case of le, ge, lt, and gt, the strings are sorted as necessary
+  dnl # then the first line is used to determine if the condition is true.
+  dnl # The sed right after the echo is to remove any indented white space.
+  m4_case(m4_tolower($2),
+  [lt],[
+    ax_compare_version=`echo "x$A
+x$B" | sed 's/^ *//' | sort -r | sed "s/x${A}/false/;s/x${B}/true/;1q"`
+  ],
+  [gt],[
+    ax_compare_version=`echo "x$A
+x$B" | sed 's/^ *//' | sort | sed "s/x${A}/false/;s/x${B}/true/;1q"`
+  ],
+  [le],[
+    ax_compare_version=`echo "x$A
+x$B" | sed 's/^ *//' | sort | sed "s/x${A}/true/;s/x${B}/false/;1q"`
+  ],
+  [ge],[
+    ax_compare_version=`echo "x$A
+x$B" | sed 's/^ *//' | sort -r | sed "s/x${A}/true/;s/x${B}/false/;1q"`
+  ],[
+    dnl Split the operator from the subversion count if present.
+    m4_bmatch(m4_substr($2,2),
+    [0],[
+      # A count of zero means use the length of the shorter version.
+      # Determine the number of characters in A and B.
+      ax_compare_version_len_A=`echo "$A" | $AWK '{print(length)}'`
+      ax_compare_version_len_B=`echo "$B" | $AWK '{print(length)}'`
+
+      # Set A to no more than B's length and B to no more than A's length.
+      A=`echo "$A" | sed "s/\(.\{$ax_compare_version_len_B\}\).*/\1/"`
+      B=`echo "$B" | sed "s/\(.\{$ax_compare_version_len_A\}\).*/\1/"`
+    ],
+    [[0-9]+],[
+      # A count greater than zero means use only that many subversions
+      A=`echo "$A" | sed "s/\(\([[0-9]]\{4\}\)\{m4_substr($2,2)\}\).*/\1/"`
+      B=`echo "$B" | sed "s/\(\([[0-9]]\{4\}\)\{m4_substr($2,2)\}\).*/\1/"`
+    ],
+    [.+],[
+      AC_WARNING(
+        [invalid OP numeric parameter: $2])
+    ],[])
+
+    # Pad zeros at end of numbers to make same length.
+    ax_compare_version_tmp_A="$A`echo $B | sed 's/./0/g'`"
+    B="$B`echo $A | sed 's/./0/g'`"
+    A="$ax_compare_version_tmp_A"
+
+    # Check for equality or inequality as necessary.
+    m4_case(m4_tolower(m4_substr($2,0,2)),
+    [eq],[
+      test "x$A" = "x$B" && ax_compare_version=true
+    ],
+    [ne],[
+      test "x$A" != "x$B" && ax_compare_version=true
+    ],[
+      AC_WARNING([invalid OP parameter: $2])
+    ])
+  ])
+
+  AS_VAR_POPDEF([A])dnl
+  AS_VAR_POPDEF([B])dnl
+
+  dnl # Execute ACTION-IF-TRUE / ACTION-IF-FALSE.
+  if test "$ax_compare_version" = "true" ; then
+    m4_ifvaln([$4],[$4],[:])dnl
+    m4_ifvaln([$5],[else $5])dnl
+  fi
+]) dnl AX_COMPARE_VERSION