kibi-swipl-linux-x64-gnu 1.0.0

package/lib/swipl/library/ext/RDF/rewrite_term.pl

@@ -0,0 +1,177 @@
+/*  Part of SWI-Prolog
+
+    Author:        Jan Wielemaker
+    E-mail:        J.Wielemaker@vu.nl
+    WWW:           http://www.swi-prolog.org
+    Copyright (c)  2010-2020, University of Amsterdam
+                              CWI, Amsterdam
+    All rights reserved.
+
+    Redistribution and use in source and binary forms, with or without
+    modification, are permitted provided that the following conditions
+    are met:
+
+    1. Redistributions of source code must retain the above copyright
+       notice, this list of conditions and the following disclaimer.
+
+    2. Redistributions in binary form must reproduce the above copyright
+       notice, this list of conditions and the following disclaimer in
+       the documentation and/or other materials provided with the
+       distribution.
+
+    THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
+    "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
+    LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
+    FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
+    COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
+    INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
+    BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
+    LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
+    CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
+    LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
+    ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
+    POSSIBILITY OF SUCH DAMAGE.
+*/
+
+:- module(rewrite_term,
+          [ rewrite_term/2,                  % +Rule, +Input
+            rew_term_expansion/2,
+            rew_goal_expansion/2,
+
+            op(1200, xfx, (::=))
+          ]).
+:- autoload(library(occurs),[sub_term/2]).
+
+:- meta_predicate
+    rewrite_term(1, +).
+
+                 /*******************************
+                 *          COMPILATION         *
+                 *******************************/
+
+rew_term_expansion((Rule ::= RuleBody), (Head :- Body)) :-
+    translate(RuleBody, Term, Body0),
+    simplify(Body0, Body),
+    Rule =.. [Name|List],
+    Head =.. [Name,Term|List].
+
+rew_goal_expansion(rewrite_term(To, From), Goal) :-
+    nonvar(To),
+    To = \Rule,
+    callable(Rule),
+    Rule =.. [Name|List],
+    Goal =.. [Name,From|List].
+
+
+                 /*******************************
+                 *            TOPLEVEL          *
+                 *******************************/
+
+%!  rewrite_term(:To, +From)
+%
+%   Invoke the term-rewriting system
+
+rewrite_term(M:T, From) :-
+    (   var(T)
+    ->  From = T
+    ;   T = \Rule
+    ->  Rule =.. [Name|List],
+        Goal =.. [Name,From|List],
+        M:Goal
+    ;   match(T, M, From)
+    ).
+
+match(Rule, M, From) :-
+    translate(Rule, From, Code),
+    M:Code.
+
+translate(Var, Var, true) :-
+    var(Var),
+    !.
+translate((\Command, !), Var, (Goal, !)) :-
+    !,
+    (   callable(Command),
+        Command =.. [Name|List]
+    ->  Goal =.. [Name,Var|List]
+    ;   Goal = rewrite(\Command, Var)
+    ).
+translate(\Command, Var, Goal) :-
+    !,
+    (   callable(Command),
+        Command =.. [Name|List]
+    ->  Goal =.. [Name,Var|List]
+    ;   Goal = rewrite(\Command, Var)
+    ).
+translate(Atomic, Atomic, true) :-
+    atomic(Atomic),
+    !.
+translate(C, _, Cmd) :-
+    command(C, Cmd),
+    !.
+translate((A, B), T, Code) :-
+    (   command(A, Cmd)
+    ->  !, translate(B, T, C),
+        Code = (Cmd, C)
+    ;   command(B, Cmd)
+    ->  !, translate(A, T, C),
+        Code = (C, Cmd)
+    ).
+translate(Term0, Term, Command) :-
+    functor(Term0, Name, Arity),
+    functor(Term, Name, Arity),
+    translate_args(0, Arity, Term0, Term, Command).
+
+translate_args(N, N, _, _, true) :- !.
+translate_args(I0, Arity, T0, T1, (C0,C)) :-
+    I is I0 + 1,
+    arg(I, T0, A0),
+    arg(I, T1, A1),
+    translate(A0, A1, C0),
+    translate_args(I, Arity, T0, T1, C).
+
+command(0, _) :-                       % catch variables
+    !,
+    fail.
+command({A}, A).
+command(!, !).
+
+                 /*******************************
+                 *            SIMPLIFY          *
+                 *******************************/
+
+%!  simplify(+Raw, -Simplified)
+%
+%   Get rid of redundant `true' goals generated by translate/3.
+
+simplify(V, V) :-
+    var(V),
+    !.
+simplify((A0,B), A) :-
+    B == true,
+    !,
+    simplify(A0, A).
+simplify((A,B0), B) :-
+    A == true,
+    !,
+    simplify(B0, B).
+simplify((A0, B0), C) :-
+    !,
+    simplify(A0, A),
+    simplify(B0, B),
+    (   (   A \== A0
+        ;   B \== B0
+        )
+    ->  simplify((A,B), C)
+    ;   C = (A,B)
+    ).
+simplify(X, X).
+
+                 /*******************************
+                 *             XREF             *
+                 *******************************/
+
+:- multifile
+    prolog:called_by/2.
+
+prolog:called_by(rewrite(Spec, _Term), Called) :-
+    findall(G+1, sub_term(\G, Spec), Called).

package/lib/swipl/library/ext/chr/chr/a_star.pl

@@ -0,0 +1,80 @@
+/*  Part of CHR (Constraint Handling Rules)
+
+    Author:        Tom Schrijvers
+    E-mail:        Tom.Schrijvers@cs.kuleuven.be
+    WWW:           http://www.swi-prolog.org
+    Copyright (c)  2004-2011, K.U. Leuven
+    All rights reserved.
+
+    Redistribution and use in source and binary forms, with or without
+    modification, are permitted provided that the following conditions
+    are met:
+
+    1. Redistributions of source code must retain the above copyright
+       notice, this list of conditions and the following disclaimer.
+
+    2. Redistributions in binary form must reproduce the above copyright
+       notice, this list of conditions and the following disclaimer in
+       the documentation and/or other materials provided with the
+       distribution.
+
+    THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
+    "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
+    LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
+    FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
+    COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
+    INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
+    BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
+    LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
+    CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
+    LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
+    ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
+    POSSIBILITY OF SUCH DAMAGE.
+*/
+
+:- module(a_star,
+	[
+		a_star/4
+	]).
+
+:- use_module(binomialheap).
+
+:- use_module(find).
+
+:- use_module(library(dialect/hprolog)).
+
+a_star(DataIn,FinalData,ExpandData,DataOut) :-
+	a_star_node(DataIn,0,InitialNode),
+	empty_q(NewQueue),
+	insert_q(NewQueue,InitialNode,Queue),
+	a_star_aux(Queue,FinalData,ExpandData,EndNode),
+	a_star_node(DataOut,_,EndNode).
+
+a_star_aux(Queue,FinalData,ExpandData,EndNode) :-
+	delete_min_q(Queue,Queue1,Node),
+	( final_node(FinalData,Node) ->
+		Node = EndNode
+	;
+		expand_node(ExpandData,Node,Nodes),
+		insert_list_q(Nodes,Queue1,NQueue),
+		a_star_aux(NQueue,FinalData,ExpandData,EndNode)
+	).
+
+final_node(D^Call,Node) :-
+	a_star_node(Data,_,Node),
+	term_variables(Call,Vars),
+	chr_delete(Vars,D,DVars),
+	copy_term(D^Call-DVars,Data^NCall-DVars),
+	call(NCall).
+
+expand_node(D^Ds^C^Call,Node,Nodes) :-
+	a_star_node(Data,Score,Node),
+	term_variables(Call,Vars),
+	chr_delete(Vars,D,DVars0),
+	chr_delete(DVars0,Ds,DVars1),
+	chr_delete(DVars1,C,DVars),
+	copy_term(D^Ds^C^Call-DVars,Data^EData^Cost^NCall-DVars),
+	term_variables(Node,NVars,DVars),
+	find_with_var_identity(ENode,NVars,(NCall,EScore is Cost + Score,a_star:a_star_node(EData,EScore,ENode)),Nodes).
+
+a_star_node(Data,Score,Data-Score).

package/lib/swipl/library/ext/chr/chr/binomialheap.pl

@@ -0,0 +1,142 @@
+/*  Part of CHR (Constraint Handling Rules)
+
+    Author:        Tom Schrijvers
+    E-mail:        Tom.Schrijvers@cs.kuleuven.be
+    WWW:           http://www.swi-prolog.org
+    Copyright (c)  2004-2011, K.U. Leuven
+    All rights reserved.
+
+    Redistribution and use in source and binary forms, with or without
+    modification, are permitted provided that the following conditions
+    are met:
+
+    1. Redistributions of source code must retain the above copyright
+       notice, this list of conditions and the following disclaimer.
+
+    2. Redistributions in binary form must reproduce the above copyright
+       notice, this list of conditions and the following disclaimer in
+       the documentation and/or other materials provided with the
+       distribution.
+
+    THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
+    "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
+    LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
+    FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
+    COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
+    INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
+    BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
+    LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
+    CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
+    LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
+    ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
+    POSSIBILITY OF SUCH DAMAGE.
+*/
+
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+% Binomial Heap imlementation based on
+%
+%	Functional Binomial Queues
+%	James F. King
+%	University of Glasgow
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+
+:- module(binomialheap,
+	[
+		empty_q/1,
+		insert_q/3,
+		insert_list_q/3,
+		delete_min_q/3,
+		find_min_q/2
+	]).
+
+:- use_module(library(lists),[reverse/2]).
+
+% data Tree a = Node a [Tree a]
+% type BinQueue a = [Maybe (Tree a)]
+% data Maybe a = Zero | One a
+% type Item = (Entry,Key)
+
+key(_-Key,Key).
+
+empty_q([]).
+
+meld_q(P,Q,R) :-
+	meld_qc(P,Q,zero,R).
+
+meld_qc([],Q,zero,Q) :- !.
+meld_qc([],Q,C,R) :- !,
+	meld_q(Q,[C],R).
+meld_qc(P,[],C,R) :- !,
+	meld_qc([],P,C,R).
+meld_qc([zero|Ps],[zero|Qs],C,R) :- !,
+	R = [C | Rs],
+	meld_q(Ps,Qs,Rs).
+meld_qc([one(node(X,Xs))|Ps],[one(node(Y,Ys))|Qs],C,R) :- !,
+	key(X,KX),
+	key(Y,KY),
+	( KX < KY ->
+		T = node(X,[node(Y,Ys)|Xs])
+	;
+		T = node(Y,[node(X,Xs)|Ys])
+	),
+	R = [C|Rs],
+	meld_qc(Ps,Qs,one(T),Rs).
+meld_qc([P|Ps],[Q|Qs],C,Rs) :-
+	meld_qc([Q|Ps],[C|Qs],P,Rs).
+
+insert_q(Q,I,NQ) :-
+	meld_q([one(node(I,[]))],Q,NQ).
+
+insert_list_q([],Q,Q).
+insert_list_q([I|Is],Q,NQ) :-
+	insert_q(Q,I,Q1),
+	insert_list_q(Is,Q1,NQ).
+
+min_tree([T|Ts],MT) :-
+	min_tree_acc(Ts,T,MT).
+
+min_tree_acc([],MT,MT).
+min_tree_acc([T|Ts],Acc,MT) :-
+	least(T,Acc,NAcc),
+	min_tree_acc(Ts,NAcc,MT).
+
+least(zero,T,T) :- !.
+least(T,zero,T) :- !.
+least(one(node(X,Xs)),one(node(Y,Ys)),T) :-
+	key(X,KX),
+	key(Y,KY),
+	( KX < KY ->
+		T = one(node(X,Xs))
+	;
+		T = one(node(Y,Ys))
+	).
+
+remove_tree([],_,[]).
+remove_tree([T|Ts],I,[NT|NTs]) :-
+	( T == zero ->
+		NT = T
+	;
+		T = one(node(X,_)),
+		( X == I ->
+			NT = zero
+		;
+			NT = T
+		)
+	),
+	remove_tree(Ts,I,NTs).
+
+delete_min_q(Q,NQ,Min) :-
+	min_tree(Q,one(node(Min,Ts))),
+	remove_tree(Q,Min,Q1),
+	reverse(Ts,RTs),
+	make_ones(RTs,Q2),
+	meld_q(Q2,Q1,NQ).
+
+make_ones([],[]).
+make_ones([N|Ns],[one(N)|RQ]) :-
+	make_ones(Ns,RQ).
+
+find_min_q(Q,I) :-
+	min_tree(Q,one(node(I,_))).
+
+