kibi-swipl-linux-x64-gnu 1.0.0

package/lib/swipl/library/dialect/sicstus/lists.pl

@@ -0,0 +1,167 @@
+/*  Part of SWI-Prolog
+
+    Author:        Jan Wielemaker
+    E-mail:        J.Wielemaker@vu.nl
+    WWW:           http://www.swi-prolog.org
+    Copyright (c)  2010-2011, University of Amsterdam
+    All rights reserved.
+
+    Redistribution and use in source and binary forms, with or without
+    modification, are permitted provided that the following conditions
+    are met:
+
+    1. Redistributions of source code must retain the above copyright
+       notice, this list of conditions and the following disclaimer.
+
+    2. Redistributions in binary form must reproduce the above copyright
+       notice, this list of conditions and the following disclaimer in
+       the documentation and/or other materials provided with the
+       distribution.
+
+    THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
+    "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
+    LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
+    FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
+    COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
+    INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
+    BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
+    LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
+    CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
+    LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
+    ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
+    POSSIBILITY OF SUCH DAMAGE.
+*/
+
+:- module(sicstus_lists,
+	  [ substitute/4,		% +Elem, +List, +NewElem, -List
+	    nth/3,			% ?N, ?List, ?Element
+	    nth/4,			% ?N, ?List, ?Element, ?Rest
+	    same_length/3,		% ?List1, ?List2, ?Length
+	    sublist/2,			% ?Sub, +List
+	    suffix/2,			% ?Suffix, ?List
+
+	    % The following predicates are built-in on SWI.
+	    % We re-export them here to avoid warnings
+	    % when SICStus code explicitly imports them from library(lists).
+	    is_list/1,			% +Term
+	    memberchk/2			% +Element, +List
+	  ]).
+:- reexport('../../lists',
+	    [ append/3,
+	      delete/3,
+	      last/2,
+	      max_list/2,
+	      member/2,
+	      min_list/2,
+	      nextto/3,
+	      nth0/3,
+	      nth0/4,
+	      permutation/2,
+	      prefix/2,
+	      reverse/2,
+	      same_length/2,
+	      select/3,
+	      sum_list/2
+	    ]).
+
+:- multifile sicstus:rename_module/2.
+
+sicstus:rename_module(lists, sicstus_lists).
+
+/** <module> SICStus 3-compatible library(lists).
+
+@tbd	This library is incomplete.
+	As of SICStus 3.12.11, the following predicates are missing:
+
+	* no_doubles/1
+	* non_member/2
+	* remove_duplicates/2
+
+@see	https://sicstus.sics.se/sicstus/docs/3.12.11/html/sicstus/Lists.html
+*/
+
+%%	substitute(+OldElem, +List, +NewElem, -NewList) is det.
+%
+%	NewList is List with all values that are identical (==) to OldElem
+%	replaced by NewElem.
+
+substitute(Old, List, New, NewList) :-
+	substitute_(List, Old, New, NewList).
+
+substitute_([], _, _, []).
+substitute_([O|T0], Old, New, [V|T]) :-
+	(   Old == O
+	->  V = New
+	;   V = O
+	),
+	substitute_(T0, Old, New, T).
+
+
+%%	nth(?Index, ?List, ?Element) is nondet.
+%
+%	True if Element is the N-th element  in List. Counting starts at
+%	1.
+%
+%	@deprecated use nth1/3.
+
+nth(Index, List, Element) :-
+	nth1(Index, List, Element).
+
+
+%%	nth(?Index, ?List, ?Element, ?Rest) is nondet.
+%
+%	True if Element is the N-th element in List and Rest is the
+%	remainder (as if by select/3) of List. Counting starts at 1.
+%
+%	@deprecated use nth1/4.
+
+nth(Index, List, Element, Rest) :-
+	nth1(Index, List, Element, Rest).
+
+
+%%	same_length(?List1, ?List2, ?Length) is nondet.
+%
+%	True if List1 and List2 both have length Length.
+
+same_length(List1, List2, Length) :-
+	(   var(List1)
+	->  length(List2, Length),
+	    length(List1, Length)
+	;   length(List1, Length),
+	    length(List2, Length)
+	).
+
+
+%%	sublist(?Sub, +List)
+%
+%	True when all members of Sub  are   members  of List in the same
+%	order.
+%
+%	@compat sicstus.  The order of generating sublists differs.
+%	@compat This predicate is known in many Prolog implementations,
+%		but the semantics differ. E.g. In YAP it is a continuous
+%		sub-list.
+
+sublist(Sub, List) :-
+	sublist_(List, Sub).
+
+sublist_([], []).
+sublist_([H|T], Sub) :-
+	sublist__(T, H, Sub).
+
+sublist__([], H, [H]).
+sublist__([], _, []).
+sublist__([H|T], X, [X|Sub]) :-
+	sublist__(T, H, Sub).
+sublist__([H|T], _, Sub) :-
+	sublist__(T, H, Sub).
+
+
+%%	suffix(?Suffix, ?List) is nondet.
+%
+%	True if Suffix is a suffix of List. Not the same as suffix/2
+%	in SICStus 4 - the arguments are reversed!
+
+suffix(List, List).
+suffix(Suffix, [_|Tail]) :-
+	suffix(Suffix, Tail).

package/lib/swipl/library/dialect/sicstus/ordsets.pl

@@ -0,0 +1,52 @@
+/*  Part of SWI-Prolog
+
+    WWW:           http://www.swi-prolog.org
+    Copyright (c)  2021, SWI-Prolog Solutions b.v.
+    All rights reserved.
+
+    Redistribution and use in source and binary forms, with or without
+    modification, are permitted provided that the following conditions
+    are met:
+
+    1. Redistributions of source code must retain the above copyright
+       notice, this list of conditions and the following disclaimer.
+
+    2. Redistributions in binary form must reproduce the above copyright
+       notice, this list of conditions and the following disclaimer in
+       the documentation and/or other materials provided with the
+       distribution.
+
+    THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
+    "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
+    LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
+    FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
+    COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
+    INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
+    BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
+    LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
+    CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
+    LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
+    ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
+    POSSIBILITY OF SUCH DAMAGE.
+*/
+
+:- module(sicstus_ordsets,
+	  [ ord_member/2		% +Elt, +Set
+	  ]).
+:- reexport('../../ordsets').
+
+:- multifile sicstus:rename_module/2.
+
+sicstus:rename_module(ordsets, sicstus_ordsets).
+
+/** <module> SICStus 3 library(ordsets).
+
+@tbd	This library is incomplete.
+	As of SICStus 3.2.11, the following predicates are missing:
+
+	* ord_setproduct/2
+
+@see	https://sicstus.sics.se/sicstus/docs/3.12.11/html/sicstus/Ordsets.html
+*/
+
+ord_member(Elt, Set) :- ord_memberchk(Elt, Set).

package/lib/swipl/library/dialect/sicstus/sockets.pl

@@ -0,0 +1,174 @@
+/*  Part of SWI-Prolog
+
+    Author:        Jan Wielemaker
+    E-mail:        J.Wielemaker@vu.nl
+    WWW:           http://www.swi-prolog.org
+    Copyright (c)  2010-2012, University of Amsterdam
+                              VU University Amsterdam
+    All rights reserved.
+
+    Redistribution and use in source and binary forms, with or without
+    modification, are permitted provided that the following conditions
+    are met:
+
+    1. Redistributions of source code must retain the above copyright
+       notice, this list of conditions and the following disclaimer.
+
+    2. Redistributions in binary form must reproduce the above copyright
+       notice, this list of conditions and the following disclaimer in
+       the documentation and/or other materials provided with the
+       distribution.
+
+    THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
+    "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
+    LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
+    FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
+    COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
+    INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
+    BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
+    LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
+    CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
+    LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
+    ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
+    POSSIBILITY OF SUCH DAMAGE.
+*/
+
+:- module(sicstus_sockets,
+	  [ socket/2,			% +Domain, -Socket
+	    socket_close/1,		% +Socket
+	    socket_bind/2,		% +Socket, 'AF_INET'(+Host,+Port)
+	    socket_connect/3,		% +Socket, 'AF_INET'(+Host,+Port), -Stream
+	    socket_listen/2,		% +Socket, +Length
+	    socket_accept/2,		% +Socket, -Stream
+	    socket_accept/3,		% +Socket, -Client, -Stream
+	    socket_select/5,		% +TermsSockets, -NewTermsStreams,
+					% +TimeOut, +Streams, -ReadStreams
+	    current_host/1,		% ?HostName
+	    hostname_address/2		% ?HostName, ?HostAddress
+	  ]).
+:- use_module(library(socket)).
+:- use_module(library(error)).
+:- use_module(library(apply)).
+:- use_module(library(pairs)).
+:- use_module(library(lists)).
+
+:- multifile sicstus:rename_module/2.
+
+sicstus:rename_module(sockets, sicstus_sockets).
+
+/** <module> SICStus 3-compatible library(sockets).
+
+@tbd Our implementation does not support AF_UNIX sockets.
+@see https://sicstus.sics.se/sicstus/docs/3.12.11/html/sicstus/Sockets.html
+*/
+
+socket(Domain, Socket) :-
+	must_be(oneof(['AF_INET']), Domain),
+	tcp_socket(Socket).
+
+socket_close(Socket) :-
+	tcp_close_socket(Socket).
+
+socket_bind(Socket, Address) :-
+	(   Address = 'AF_INET'(Host, Port)
+	->  true
+	;   type_error(socket_address, Address)
+	),
+	(   var(Host)
+	->  gethostname(Host)
+	;   true			% Warning?
+	),
+	tcp_bind(Socket, Port).
+
+socket_connect(Socket, Address, StreamPair) :-
+	(   Address = 'AF_INET'(Host, Port)
+	->  true
+	;   type_error(socket_address, Address)
+	),
+	tcp_connect(Socket, Host:Port),
+	tcp_open_socket(Socket, Read, Write),
+	stream_pair(StreamPair, Read, Write).
+
+socket_listen(Socket, Length) :-
+	tcp_listen(Socket, Length).
+
+socket_accept(Socket, Client, StreamPair) :-
+	tcp_accept(Socket, Socket2, Peer),
+	peer_to_client(Peer, Client),
+	tcp_open_socket(Socket2, Read, Write),
+	stream_pair(StreamPair, Read, Write).
+
+socket_accept(Socket, Stream) :-
+	socket_accept(Socket, _Client, Stream).
+
+
+peer_to_client(ip(A,B,C,D), Client) :-
+	Parts = [A,B,C,D],
+	ground(Parts), !,
+	atomic_list_concat(Parts, '.', Client).
+peer_to_client(ip(A,B,C,D), Client) :-
+	atomic_list_concat(Parts, '.', Client),
+	maplist(atom_number, Parts, Numbers),
+	length(Numbers, 4), !,
+	Numbers = [A,B,C,D].
+peer_to_client(_, Client) :-
+	domain_error(ip_address, Client).
+
+
+%%	socket_select(+TermsSockets, -NewTermsStreams,
+%%		      +TimeOut, +Streams, -ReadStreams) is det.
+%
+%	The  list  of  streams  in  Streams   is  checked  for  readable
+%	characters. A stream can be any   stream  associated with an I/O
+%	descriptor.  The  list  ReadStreams  returns  the  streams  with
+%	readable data. socket_select/5 also waits for connections to the
+%	sockets specified by TermsSockets.  This   argument  should be a
+%	list of Term-Socket pairs, where Term, which can be any term, is
+%	used  as  an  identifier.   NewTermsStreams    is   a   list  of
+%	Term-connection(Client,Stream) pairs, where  Stream   is  a  new
+%	stream open for communicating with a   process connecting to the
+%	socket identified with Term, Client is   the client host address
+%	(see socket_accept/3). If TimeOut is   instantiated  to off, the
+%	predicate waits until something is available.  If TimeOut is S:U
+%	the predicate waits at most S seconds and U microseconds. Both S
+%	and U must be integers >=0. If   there is a timeout, ReadStreams
+%	and NewTermsStreams are [].
+
+socket_select(TermsSockets, NewTermsStreams, SicsTimeOut, Streams, ReadStreams) :-
+	pairs_values(TermsSockets, Sockets),
+	append(Sockets, Streams, AllStream),
+	map_timeout(SicsTimeOut, TimeOut),
+	wait_for_input(AllStream, ReadyStream, TimeOut),
+	process_ready(ReadyStream, TermsSockets, NewTermsStreams, ReadStreams).
+
+map_timeout(off, infinite) :- !.
+map_timeout(S:U, Seconds) :- !,
+	Seconds is S+U/1000000.
+map_timeout(SicsTimeOut, _) :-
+	type_error(sicstus_timeout, SicsTimeOut).
+
+process_ready([], _, [], []).
+process_ready([H|T], TermsSockets, NewTermsStreams, ReadStreams) :-
+	memberchk(Term-H, TermsSockets), !,
+	socket_accept(H, Client, Stream),
+	NewTermsStreams = [Term-connection(Client,Stream)|NewTSTail],
+	process_ready(T, TermsSockets, NewTSTail, ReadStreams).
+process_ready([H|T], TermsSockets, NewTermsStreams, [H|ReadStreams]) :-
+	process_ready(T, TermsSockets, NewTermsStreams, ReadStreams).
+
+
+%%	current_host(-Host) is det.
+%
+%	True when Host is an atom that denotes the name of the host.
+%
+current_host(Host) :-
+	gethostname(Host).
+
+%%	hostname_address(+Host:atom, -Address:atom) is det.
+%
+%	True when Address is the IP address of Host.
+
+hostname_address(Host, Address) :-
+	nonvar(Host), !,
+	tcp_host_to_address(Host, IP),
+	peer_to_client(IP, Address).

package/lib/swipl/library/dialect/sicstus/system.pl

@@ -0,0 +1,262 @@
+/*  Part of SWI-Prolog
+
+    Author:        Jan Wielemaker
+    E-mail:        J.Wielemaker@vu.nl
+    WWW:           http://www.swi-prolog.org
+    Copyright (c)  2010-2016, University of Amsterdam
+    All rights reserved.
+
+    Redistribution and use in source and binary forms, with or without
+    modification, are permitted provided that the following conditions
+    are met:
+
+    1. Redistributions of source code must retain the above copyright
+       notice, this list of conditions and the following disclaimer.
+
+    2. Redistributions in binary form must reproduce the above copyright
+       notice, this list of conditions and the following disclaimer in
+       the documentation and/or other materials provided with the
+       distribution.
+
+    THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
+    "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
+    LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
+    FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
+    COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
+    INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
+    BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
+    LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
+    CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
+    LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
+    ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
+    POSSIBILITY OF SUCH DAMAGE.
+*/
+
+:- module(sicstus_system,
+	  [ environ/2,			% ?Name, ?Value
+
+	    exec/3,			% +Command, -Streams, -PID
+	    wait/2,			% +PID, -Status
+	    pid/1,			% -PID
+
+	    now/1,			% -TimeStamp
+	    datime/1,			% -DaTime
+	    datime/2,			% +TimeStamp, -DaTime
+	    sleep/1,			% +Seconds
+
+	    shell/0,
+	    shell/1,			% +Command
+	    shell/2,			% +Command, -Status
+
+	    system/0,
+	    system/1,			% +Command
+	    system/2,			% +Command, -Status
+
+	    popen/3,			% +Command, +Mode, -Stream
+
+	    host_name/1,		% -HostName
+
+	    working_directory/2,	% -Old, +New
+	    make_directory/1,		% +DirName
+	    file_exists/1,		% +FileName
+	    delete_file/1,		% +FileName
+	    rename_file/2,		% +Old, +New
+	    mktemp/2,			% +Template, -FileName
+	    tmpnam/1			% -FileName
+	  ]).
+:- use_module(library(process)).
+:- use_module(library(socket)).
+:- use_module(library(shell), [shell/0]).
+
+:- multifile sicstus:rename_module/2.
+
+sicstus:rename_module(system, sicstus_system).
+
+/** <module> SICStus 3-compatible library(system).
+
+@tbd	This library is incomplete.
+	As of SICStus 3.12.11, the following predicates are missing:
+
+	* delete_file/2
+	* directory_files/2
+	* file_exists/2
+	* file_property/2
+	* host_id/1
+	* kill/2
+
+@see	https://sicstus.sics.se/sicstus/docs/3.12.11/html/sicstus/System-Utilities.html
+*/
+
+%%	environ(?Name, ?Value) is nondet.
+%
+%	True if Value is an atom associated with the environment variable
+%	or system property Name.
+%
+%	@tbd	Mode -Name is not supported.
+%
+%		Because SWI-Prolog doesn't have an obvious equivalent to
+%		SICStus system properties, this predicate currently
+%		behaves as if no system properties are defined,
+%		i. e. only environment variables are returned.
+%
+%	@compat sicstus
+
+environ(Name, Value) :-
+	getenv(Name, Value).
+
+
+		 /*******************************
+		 *	      PROCESSES		*
+		 *******************************/
+
+%%	exec(+Command, +Streams, -PID)
+%
+%	SICStus 3 compatible implementation of  exec/3   on  top  of the
+%	SICStus 4 compatible process_create/3.
+%
+%	@bug	The SICStus version for Windows seems to hand Command
+%		directly to CreateProcess(). We hand it to
+%
+%		  ==
+%		  %COMSPEC% /s /c "Command"
+%		  ==
+%
+%		In case of conflict, it is adviced to use
+%		process_create/3
+
+exec(Command, Streams, PID) :-
+	Streams = [In, Out, Error],
+	shell(Shell, Command, Argv),
+	process_create(Shell, Argv,
+		       [ stdin(In),
+			 stdout(Out),
+			 stderr(Error),
+			 process(PID)
+		       ]).
+
+shell(Shell, Command, ['/s', '/c', Command]) :-
+	current_prolog_flag(windows, true), !,
+	getenv('COMSPEC', Shell).
+shell('/bin/sh', Command, ['-c', Command]).
+
+%%	wait(+PID, -Status)
+%
+%	Wait for processes created using exec/3.
+%
+%	@see exec/3
+
+wait(PID, Status) :-
+	process_wait(PID, Status).
+
+%%	pid(-PID)
+%
+%	Process ID of the current process.
+%
+%	@compat sicstus.
+
+pid(PID) :-
+	current_prolog_flag(pid, PID).
+
+%%	now(-When) is det.
+%
+%	Unify when with the current time-stamp
+%
+%	@compat sicstus
+
+now(When) :-
+	get_time(Now),
+	When is integer(Now).
+
+%%	datime(+When, -Datime) is det.
+%%	datime(-When, +Datime) is det.
+%
+%	True when Datime is a  datime/6   record  that reflects the time
+%	stamp When.
+%
+%	@compat sicstus
+
+datime(When, datime(Year,Month,Day,Hour,Min,Sec)) :-
+	var(When),
+	!,
+	date_time_stamp(date(Year,Month,Day,Hour,Min,Sec,_,_,_), When).
+datime(When, datime(Year,Month,Day,Hour,Min,Sec)) :-
+	stamp_date_time(When, date(Year,Month,Day,Hour,Min,SecF,_,_,_), local),
+	Sec is integer(SecF).
+
+%%	datime(-Datime) is det.
+%
+%	Unifies Datime with the current  date   and  time  as a datime/6
+%	record  of  the  form  datime(Year,Month,Day,Hour,Min,Sec).  All
+%	fields are integers.
+%
+%	@compat sicstus
+
+datime(datime(Year,Month,Day,Hour,Min,Sec)) :-
+	get_time(Now),
+	stamp_date_time(Now, date(Year,Month,Day,Hour,Min,SecF,_,_,_), local),
+	Sec is integer(SecF).
+
+
+%%	system.
+%%	system(+Command).
+%%	system(+Command, -Status).
+%
+%	Synomyms for shell/0, shell/1 and shell/2.
+%
+%	@compat sicstus.
+
+system :- shell.
+system(Command) :- shell(Command).
+system(Command, Status) :- shell(Command, Status).
+
+%%	popen(+Command, +Mode, ?Stream)
+%
+%	@compat sicstus
+
+popen(Command, Mode, Stream) :-
+	open(pipe(Command), Mode, Stream).
+
+%%	host_name(-HostName)
+%
+%	@compat sicstus
+%	@see gethostname/1
+
+host_name(HostName) :-
+	gethostname(HostName).
+
+
+		 /*******************************
+		 *	 FILE OPERATIONS	*
+		 *******************************/
+
+%%	mktemp(+Template, -File) is det.
+%
+%	Interface to the Unix function.  This emulation uses
+%	tmp_file/2 and ignores Template.
+%
+%	@compat sicstus
+%	@deprecated This interface is a security-risc.  Use
+%	tmp_file_stream/3.
+
+mktemp(_Template, File) :-
+	tmp_file(mkstemp, File).
+
+%%	tmpnam(-FileName)
+%
+%	Interface to tmpnam(). This emulation uses tmp_file/2.
+%
+%	@compat sicstus
+%	@deprecated This interface is a security-risc.  Use
+%	tmp_file_stream/3.
+
+tmpnam(File) :-
+	tmp_file(tmpnam, File).
+
+%%	file_exists(+FileName) is semidet.
+%
+%	True if a file named FileName exists.
+%
+%	@compat sicstus
+
+file_exists(FileName) :-
+	exists_file(FileName).

package/lib/swipl/library/dialect/sicstus/terms.pl

@@ -0,0 +1,57 @@
+/*  Part of SWI-Prolog
+
+    Author:        Jan Wielemaker
+    E-mail:        J.Wielemaker@vu.nl
+    WWW:           http://www.swi-prolog.org
+    Copyright (c)  2012, VU University Amsterdam
+    All rights reserved.
+
+    Redistribution and use in source and binary forms, with or without
+    modification, are permitted provided that the following conditions
+    are met:
+
+    1. Redistributions of source code must retain the above copyright
+       notice, this list of conditions and the following disclaimer.
+
+    2. Redistributions in binary form must reproduce the above copyright
+       notice, this list of conditions and the following disclaimer in
+       the documentation and/or other materials provided with the
+       distribution.
+
+    THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
+    "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
+    LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
+    FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
+    COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
+    INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
+    BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
+    LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
+    CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
+    LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
+    ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
+    POSSIBILITY OF SUCH DAMAGE.
+*/
+
+:- module(sicstus_terms,
+	  [ term_variables_bag/2	% +Term, -List
+	  ]).
+:- reexport('../../terms').
+
+:- multifile sicstus:rename_module/2.
+
+sicstus:rename_module(terms, sicstus_terms).
+
+/** <module> SICStus 3-compatible library(terms).
+
+@see	https://sicstus.sics.se/sicstus/docs/3.12.11/html/sicstus/Term-Utilities.html
+*/
+
+%%	term_variables_bag(+Term, -Variables) is det.
+%
+%	Variables is a list  of  variables   that  appear  in  Term. The
+%	variables are ordered according to depth-first left-right walking
+%	of the term. Variables contains no  duplicates. This is the same
+%	as SWI-Prolog's term_variables/2.
+
+term_variables_bag(Term, Variables) :-
+	term_variables(Term, Variables).