kibi-swipl-linux-x64-gnu 1.0.0

package/lib/swipl/library/dialect/swi/syspred_options.pl

@@ -0,0 +1,250 @@
+/*  Part of SWI-Prolog
+
+    Author:        Jan Wielemaker
+    E-mail:        J.Wielemaker@vu.nl
+    WWW:           http://www.swi-prolog.org
+    Copyright (c)  2011-2025, VU University Amsterdam
+                              CWI, Amsterdam
+                              SWI-Prolog Solutions b.v.
+    All rights reserved.
+
+    Redistribution and use in source and binary forms, with or without
+    modification, are permitted provided that the following conditions
+    are met:
+
+    1. Redistributions of source code must retain the above copyright
+       notice, this list of conditions and the following disclaimer.
+
+    2. Redistributions in binary form must reproduce the above copyright
+       notice, this list of conditions and the following disclaimer in
+       the documentation and/or other materials provided with the
+       distribution.
+
+    THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
+    "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
+    LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
+    FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
+    COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
+    INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
+    BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
+    LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
+    CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
+    LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
+    ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
+    POSSIBILITY OF SUCH DAMAGE.
+*/
+
+:- module(prolog_system_predicate_options, []).
+
+/** <module> Provide declarations for options to built-in predicates
+*/
+
+:- predicate_options(system:open/4, 4,
+		     [ type(oneof([text,binary])),
+		       alias(atom),
+		       encoding(encoding),
+                       newline(oneof([dos,posix,detect])),
+		       bom(boolean),
+		       create(list(atom)),
+		       eof_action(oneof([eof_code,error,reset])),
+		       buffer(oneof([full,line,false])),
+		       close_on_abort(boolean),
+		       close_on_exec(boolean),
+		       lock(oneof([none,read,shared,write,exclusive])),
+                       reposition(boolean),
+		       wait(boolean),
+		       locale(any)		% no type-check yet
+		     ]).
+:- predicate_options(system:write_term/3, 3,
+		     [ attributes(oneof([ignore,dots,write,portray])),
+		       backquoted_string(boolean),
+		       blobs(oneof([portray])),
+                       brace_terms(boolean),
+		       character_escapes(boolean),
+                       character_escapes_unicode(boolean),
+		       cycles(boolean),
+		       fullstop(boolean),
+		       nl(boolean),
+                       no_lists(boolean),
+		       ignore_ops(boolean),
+		       portable(boolean),
+		       max_depth(nonneg),
+		       max_text(nonneg),
+                       truncated(-boolean),
+		       module(atom),
+		       numbervars(boolean),
+		       partial(boolean),
+		       portray(boolean),
+		       portray_goal(callable+2), % as in meta_predicate
+		       priority(between(0,1200)),
+                       quote_non_ascii(boolean),
+		       quoted(boolean),
+		       spacing(oneof([standard,next_argument])),
+		       variable_names(list)
+		     ]).
+:- predicate_options(system:write_term/2, 2,
+		     [ pass_to(system:write_term/3, 3)
+		     ]).
+:- predicate_options(system:write_length/3, 3,
+		     [ max_length(nonneg),
+		       pass_to(system:write_term/3, 3)
+		     ]).
+:- predicate_options(system:read_clause/3, 3,
+		     [ syntax_errors(oneof([error,fail,quiet,dec10])),
+		       process_comment(boolean),
+		       term_position(-any),
+		       variable_names(-list),
+		       subterm_positions(-any),
+		       comments(-list)
+		     ]).
+:- predicate_options(system:read_term/3, 3,
+		     [ backquoted_string(boolean),
+		       character_escapes(boolean),
+		       comments(-any),
+		       cycles(boolean),
+		       double_quotes(boolean),
+		       module(atom),
+		       singletons(-list),
+		       syntax_errors(oneof([error,fail,quiet,dec10])),
+		       subterm_positions(-any),
+		       term_position(-any),
+		       variables(-list),
+		       variable_names(-list)
+		     ]).
+:- predicate_options(system:read_term/2, 2,
+		     [ pass_to(system:read_term/3, 3)
+		     ]).
+:- predicate_options(system:numbervars/4, 4,
+		     [ functor_name(atom),
+		       attvar(oneof([skip,bind,error])),
+		       singletons(boolean)
+		     ]).
+:- predicate_options(system:absolute_file_name/3, 3,
+		     [ extensions(list(atom)),
+		       relative_to(atom),
+		       access(oneof([read,write,append,execute,exist,none])),
+		       file_type(oneof([txt,prolog,source,qlf,executable,directory])),
+		       file_errors(oneof([fail,error])),
+		       solutions(oneof([first,all])),
+		       expand(boolean)
+		     ]).
+:- predicate_options(system:load_files/2, 2,
+		     [ autoload(boolean),
+		       derived_from(atom),
+                       dialect(atom),
+		       encoding(encoding),
+		       expand(boolean),
+		       format(oneof([source,qlf])),
+		       if(oneof([true,changed,not_loaded])),
+		       imports(any),
+		       modified(float),
+		       module(atom),
+                       check_script(boolean),
+		       must_be_module(boolean),
+		       qcompile(oneof([never,auto,large,part])),
+                       optimise(boolean),
+		       redefine_module(oneof([false,true,ask])),
+		       reexport(boolean),
+		       sandboxed(boolean),
+		       scope_settings(boolean),
+		       silent(boolean),
+		       stream(any),
+                       '$qlf'(atom)
+		     ]).
+:- predicate_options(system:qcompile/2, 2,
+		     [ pass_to(system:load_files/2, 2)
+		     ]).
+:- predicate_options(system:close/2, 2,
+		     [ force(boolean)
+		     ]).
+:- predicate_options(system:create_prolog_flag/3, 3,
+		     [ access(oneof([read_write,read_only])),
+		       type(( oneof([boolean,atom,integer,float,term])
+                            ; compound(oneof(list(atom)))
+                            )),
+		       keep(boolean),
+                       warn_not_accessed(boolean)
+		     ]).
+:- predicate_options(system:qsave_program/2, 2,
+		     [ local(nonneg),
+		       global(nonneg),
+		       trail(nonneg),
+		       argument(nonneg),
+		       goal(callable),
+		       toplevel(callable),
+		       init_file(atom),
+		       class(oneof([runtime,kernel,development])),
+		       autoload(boolean),
+		       map(atom),
+		       op(oneof([save,standard])),
+		       stand_alone(boolean),
+		       emulator(atom)
+		     ]).
+:- predicate_options(system:thread_create/3, 3,
+		     [ affinity(list(integer)),
+                       alias(atom),
+                       class(atom),
+		       at_exit(callable),
+		       debug(boolean),
+		       inherit_from(any),
+		       detached(boolean),
+                       stack_limit(nonneg),
+		       c_stack(nonneg),
+                       queue_max_size(nonneg)
+		     ]).
+:- predicate_options(system:message_queue_create/2, 2,
+		     [ alias(atom),
+		       max_size(nonneg)
+		     ]).
+:- predicate_options(system:mutex_create/2, 2,
+		     [ alias(atom)
+		     ]).
+:- predicate_options(system:thread_send_message/3, 3,
+		     [ timeout(number),
+		       deadline(number),
+		       signals(any)
+		     ]).
+:- predicate_options(system:thread_get_message/3, 3,
+		     [ timeout(number),
+		       deadline(number),
+		       signals(any)
+		     ]).
+:- predicate_options(system:locale_create/3, 3,
+		     [ alias(atom),
+		       decimal_point(atom),
+		       thousands_sep(atom),
+		       grouping(list(any))
+		     ]).
+:- predicate_options(system:term_string/3, 3,
+		     [ pass_to(system:write_term/3, 3),
+		       pass_to(system:read_term/3, 3)
+		     ]).
+:- predicate_options(system:wildcard_match/3, 3,
+		     [ case_sensitive(boolean)
+		     ]).
+:- predicate_options('$syspreds':(dynamic)/2, 2,
+		     [ incremental(boolean),
+                       abstract(between(0,0)),
+                       volatile(boolean),
+                       discontiguous(boolean),
+                       multifile(boolean),
+                       thread(oneof([local,shared]))
+		     ]).
+:- predicate_options(system:prolog_listen/3, 3,
+                     [ as(oneof([first,last])),
+                       name(atom)
+                     ]).
+:- predicate_options(system:open_shared_object/3, 3,
+                     [ resolve(oneof([lazy,now])),
+                       visibility(oneof([local,global])),
+                       now(bool),
+                       global(bool),
+		       delete(bool),
+		       load(bool),
+		       deepbind(bool)
+                     ]).
+:- predicate_options('$pack':attach_packs/2, 2,
+                     [ duplicate(oneof([warning,keep,replace])),
+                       search(oneof([first,last])),
+                       replace(boolean)
+                     ]).

package/lib/swipl/library/dialect/xsb/README.md

@@ -0,0 +1,20 @@
+# XSB Prolog dialect support
+
+This directory provides the library emulation   for  XSB. It is normally
+activated using the directive below or by loading a file with the ``.P``
+extension.
+
+    :- expects_dialect(xsb).
+
+The library files themselves are either   SWI-Prolog module files or XSB
+module files. They are available through   the XSB directive below after
+the xsb dialect is selected.
+
+    :- import Pred, ... from Library.
+
+## Providing a transparent user experience
+
+The user may include the following   in ``<config>/init.pl`` to activate
+XSB dialect support simply by loading ``.P`` files.
+
+    :- use_module(library(dialect/xsb/source)).

package/lib/swipl/library/dialect/xsb/basics.pl

@@ -0,0 +1,318 @@
+/*  Part of SWI-Prolog
+
+    Author:        David Warren and Jan Wielemaker
+    E-mail:        jan@swi-prolog.org
+    WWW:           https://www.swi-prolog.org
+    Copyright (c)  2019-2024, CWI, Amsterdam
+                              SWI-Prolog Solutions b.v.
+    All rights reserved.
+
+    Redistribution and use in source and binary forms, with or without
+    modification, are permitted provided that the following conditions
+    are met:
+
+    1. Redistributions of source code must retain the above copyright
+       notice, this list of conditions and the following disclaimer.
+
+    2. Redistributions in binary form must reproduce the above copyright
+       notice, this list of conditions and the following disclaimer in
+       the documentation and/or other materials provided with the
+       distribution.
+
+    THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
+    "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
+    LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
+    FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
+    COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
+    INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
+    BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
+    LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
+    CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
+    LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
+    ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
+    POSSIBILITY OF SUCH DAMAGE.
+
+    This module is based on the XSB ``basics.P`` module, licensed under
+    LGPLv2.  The SWI-Prolog port has been re-licensed under BSD-2 with
+    permission from David Warren, Sep 11, 2024.
+*/
+
+:- module(basics,
+	  [ append/3, flatten/2, ith/3,
+            length/2, member/2, memberchk/2, subset/2,
+            reverse/2, select/3,
+
+            for/3,                               % ?I,+B1,+B2)
+            between/3,
+
+            ground/1,
+            copy_term/2,
+            copy_term_nat/2,
+
+            log_ith/3, log_ith_bound/3, log_ith_new/3, log_ith_to_list/2,
+            logk_ith/4,
+
+            comma_memberchk/2, abscomma_memberchk/2, comma_to_list/2,
+            comma_length/2, comma_member/2, comma_append/3
+	  ]).
+:- use_module(library(lists)).
+
+/** <module> XSB basics.P emulation
+
+This module provides the XSB `basics`  module. The implementation either
+simply uses SWI-Prolog built-ins and libraries or is copied from the XSB
+file.
+*/
+
+%!  for(?I,+B1,+B2)
+%
+%   Nondeterministically binds I to all  integer   values  from B1 to B2
+%   inclusive. B1 and B2 must be integers, but either may be larger.
+
+for(I, B1, B2) :-
+    B2 >= B1,
+    !,
+    between(B1, B2, I).
+for(I, B1, B2) :-
+    End is B1 - B2,
+    between(0, End, Diff),
+    I is B1-Diff.
+
+%!  ith(?Index, +List, ?Element)
+
+ith(Index,List,Element) :-
+    nth1(Index, List, Element).
+
+log_ith(K,T,E) :-
+	(integer(K)	% integer
+	 ->	log_ith0(K,T,E,1)
+	 ;	log_ith1(K,T,E,1)
+	).
+
+% K is bound
+log_ith0(K,[L|R],E,N) :-
+	(K < N
+	 ->	bintree0(K,L,E,N)
+	 ;	K1 is K-N,
+		N2 is N+N,
+		log_ith0(K1,R,E,N2)
+	).
+
+% First arg (K) is bound
+bintree0(K,T,E,N) :-
+	(N > 1
+	 ->	T = [L|R],
+		N2 is N // 2,
+		(K < N2
+		 ->	bintree0(K,L,E,N2)
+		 ;	K1 is K - N2,
+			bintree0(K1,R,E,N2)
+		)
+	 ;      K =:= 0,
+		T = E
+	).
+
+
+% K is unbound
+log_ith1(K,[L|_R],E,N) :-
+	bintree1(K,L,E,N).
+log_ith1(K,[_L|R],E,N) :-
+	N1 is N + N,
+	log_ith1(K1,R,E,N1),
+	K is K1 + N.
+
+% First arg (K) is unbound
+bintree1(0,E,E,1).
+bintree1(K,[L|R],E,N) :-
+	N > 1,
+	N2 is N // 2,
+	(bintree1(K,L,E,N2)
+	 ;
+	 bintree1(K1,R,E,N2),
+	 K is K1 + N2
+	).
+
+% log_ith_bound(Index,ListStr,Element) is like log_ith, but only
+% succeeds if the Index_th element of ListStr is nonvariable and equal
+% to Element.  This can be used in both directions, and is most useful
+% with Index unbound, since it will then bind Index and Element for each
+% nonvariable element in ListStr (in time proportional to N*logN, for N
+% the number of nonvariable entries in ListStr.)
+
+log_ith_bound(K,T,E) :-
+	nonvar(T),
+	(integer(K)	% integer
+	 ->	log_ith2(K,T,E,1)
+	 ;	log_ith3(K,T,E,1)
+	).
+
+log_ith2(K,[L|R],E,N) :-
+	(K < N
+	 ->	nonvar(L),bintree2(K,L,E,N)
+	 ;	nonvar(R),
+		K1 is K-N,
+		N2 is N+N,
+		log_ith2(K1,R,E,N2)
+	).
+
+bintree2(0,E,E,1) :- !.
+bintree2(K,[L|R],E,N) :-
+	N > 1,
+	N2 is N // 2,
+	(K < N2
+	 ->	nonvar(L),
+		bintree2(K,L,E,N2)
+	 ;	nonvar(R),
+		K1 is K - N2,
+		bintree2(K1,R,E,N2)
+	).
+
+log_ith3(K,[L|_R],E,N) :-
+	nonvar(L),
+	bintree3(K,L,E,N).
+log_ith3(K,[_L|R],E,N) :-
+	nonvar(R),
+	N1 is N + N,
+	log_ith3(K1,R,E,N1),
+	K is K1 + N.
+
+bintree3(0,E,E,1).
+bintree3(K,[L|R],E,N) :-
+	N > 1,
+	N2 is N // 2,
+	(nonvar(L),
+	 bintree3(K,L,E,N2)
+	 ;
+	 nonvar(R),
+	 bintree3(K1,R,E,N2),
+	 K is K1 + N2
+	).
+
+%% convert a log_ith structure to a list of nonempty elements
+log_ith_to_list(T,L) :- log_ith_to_list(T,0,L,[]).
+
+log_ith_to_list(T,K,L0,L) :-
+	(var(T)
+	 ->	L = L0
+	 ;	T = [F|R],
+		log_ith_to_list_btree(F,K,L0,L1),
+		K1 is K+1,
+		log_ith_to_list(R,K1,L1,L)
+	).
+
+log_ith_to_list_btree(T,K,L0,L) :-
+	(var(T)
+	 ->	L = L0
+	 ; K =:= 0
+	 ->	L0 = [T|L]
+	 ;	T = [TL|TR],
+		K1 is K-1,
+		log_ith_to_list_btree(TL,K1,L0,L1),
+		log_ith_to_list_btree(TR,K1,L1,L)
+	).
+
+/* log_ith_new(I,T,E) adds E to the "end" of the log_list and unifies
+I to its index.  */
+log_ith_new(I,T,E) :-
+	(var(T)
+	 ->	T = [E|_],
+		I = 0
+	 ;	log_ith_new_o(I,T,E,1,1)
+	).
+
+log_ith_new_o(I,[L|R],E,K,NI) :-
+	(var(R),
+	 log_ith_new_d(I,L,E,K,NIA)
+	 ->	I is NI + NIA - 1
+	 ;	NNI is 2*NI,
+		K1 is K+1,
+		log_ith_new_o(I,R,E,K1,NNI)
+	).
+
+log_ith_new_d(I,T,E,K,NIA) :-
+	(K =< 1
+	 ->	var(T),
+		T=E,
+		NIA = 0
+	 ;	K1 is K-1,
+		T = [L|R],
+		(var(R),
+		 log_ith_new_d(I,L,E,K1,NIA)
+		 ->	true
+		 ;	log_ith_new_d(I,R,E,K1,NNIA),
+			NIA is NNIA + 2 ** (K1-1)
+		)
+	).
+
+
+/* logk_ith(+KBase,+Index,?ListStr,?Element) is similar log_ith/3
+except it uses a user specified base of KBase, which must be between 2
+and 255.  log_ith uses binary trees with a list cons at each node;
+logk_ith uses a term of arity KBase at each node.  KBase and Index
+must be bound to integers. */
+% :- mode logk_ith(+,+,?,?).
+logk_ith(K,I,T,E) :-
+	integer(K),
+	integer(I),	% integer
+	logk_ith0(K,I,T,E,K).
+
+% I is bound
+logk_ith0(K,I,[L|R],E,N) :-
+	(I < N
+	 ->	ktree0(K,I,L,E,N)
+	 ;	I1 is I - N,
+		N2 is K*N,
+		logk_ith0(K,I1,R,E,N2)
+	).
+
+% First arg (I) is bound
+ktree0(K,I,T,E,N) :-
+	(var(T)
+	 ->	functor(T,n,K)
+	 ;	true
+	),
+	(N > K
+	 ->	N2 is N // K,
+		N3 is I // N2 + 1,
+		I1 is I rem N2,  %  mod overflows?
+		arg(N3,T,T1),
+		ktree0(K,I1,T1,E,N2)
+	 ;	I1 is I+1,
+		arg(I1,T,E)
+	).
+
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+% Commautils.
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+
+comma_to_list((One,Two),[One|Twol]):- !,
+	comma_to_list(Two,Twol).
+comma_to_list(One,[One]).
+
+% warning: may bind variables.
+comma_member(A,','(A,_)).
+comma_member(A,','(_,R)):-
+	comma_member(A,R).
+comma_member(A,A):- \+ (functor(A,',',2)).
+
+comma_memberchk(A,','(A,_)):- !.
+comma_memberchk(A,','(_,R)):-
+	comma_memberchk(A,R).
+comma_memberchk(A,A):- \+ (functor(A,',',_)).
+
+abscomma_memberchk(A,A1):- A == A1,!.
+abscomma_memberchk(','(A,_),A1):- A == A1,!.
+abscomma_memberchk(','(_,R),A1):-
+	abscomma_memberchk(R,A1).
+
+comma_length(','(_L,R),N1):- !,
+	comma_length(R,N),
+	N1 is N + 1.
+comma_length(true,0):- !.
+comma_length(_,1).
+
+comma_append(','(L,R),Cl,','(L,R1)):- !,
+	comma_append(R,Cl,R1).
+comma_append(true,Cl,Cl):- !.
+comma_append(L,Cl,Out):-
+	(Cl == true -> Out = L ; Out = ','(L,Cl)).

package/lib/swipl/library/dialect/xsb/consult.pl

@@ -0,0 +1,87 @@
+/*  Part of SWI-Prolog
+
+    Author:        Jan Wielemaker
+    E-mail:        J.Wielemaker@vu.nl
+    WWW:           http://www.swi-prolog.org
+    Copyright (c)  2019, VU University Amsterdam
+                         CWI, Amsterdam
+    All rights reserved.
+
+    Redistribution and use in source and binary forms, with or without
+    modification, are permitted provided that the following conditions
+    are met:
+
+    1. Redistributions of source code must retain the above copyright
+       notice, this list of conditions and the following disclaimer.
+
+    2. Redistributions in binary form must reproduce the above copyright
+       notice, this list of conditions and the following disclaimer in
+       the documentation and/or other materials provided with the
+       distribution.
+
+    THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
+    "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
+    LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
+    FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
+    COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
+    INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
+    BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
+    LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
+    CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
+    LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
+    ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
+    POSSIBILITY OF SUCH DAMAGE.
+*/
+
+:- module(consult,
+          [ consult/1,                  % :File
+            ensure_dync_loaded/1,       % +File
+            add_lib_dir/1,              % +Directories
+            add_lib_dir/2               % +Root, +Directories
+          ]).
+:- use_module(library(error)).
+:- use_module(library(filesex)).
+
+:- meta_predicate
+    ensure_dync_loaded(:).
+
+ensure_dync_loaded(File) :-
+    load_files(File, [if(not_loaded), dialect(xsb)]).
+
+%!  add_lib_dir(+Directories) is det.
+%!  add_lib_dir(+Root, +Directories) is det.
+%
+%   Add    members    of    the    comma      list     Directories    to
+%   user:library_directory/1.  If  Root  is  given,    all   members  of
+%   Directories are interpreted relative to Root.
+
+add_lib_dir(Directories) :-
+    add_lib_dir('.', Directories).
+
+add_lib_dir(_, Var) :-
+    var(Var),
+    !,
+    instantiation_error(Var).
+add_lib_dir(Root, (A,B)) :-
+    !,
+    add_lib_dir(Root, A),
+    add_lib_dir(Root, B).
+add_lib_dir(Root, a(Dir)) :-
+    !,
+    add_to_library_directory(Root, Dir, asserta).
+add_lib_dir(Root, Dir) :-
+    add_to_library_directory(Root, Dir, assertz).
+
+add_to_library_directory(Root, Dir, How) :-
+    (   expand_file_name(Dir, [Dir1])
+    ->  true
+    ;   Dir1 = Dir
+    ),
+    relative_file_name(TheDir, Root, Dir1),
+    exists_directory(TheDir),
+    !,
+    (   user:library_directory(TheDir)
+    ->  true
+    ;   call(How, user:library_directory(TheDir))
+    ).
+add_to_library_directory(_, _, _).