kibi-swipl-linux-x64-gnu 1.0.0

package/lib/swipl/library/dialect/sicstus4/lists.pl

@@ -0,0 +1,274 @@
+/*  Part of SWI-Prolog
+
+    WWW:           http://www.swi-prolog.org
+    Copyright (c)  2020-2021, SWI-Prolog Solutions b.v.
+    All rights reserved.
+
+    Redistribution and use in source and binary forms, with or without
+    modification, are permitted provided that the following conditions
+    are met:
+
+    1. Redistributions of source code must retain the above copyright
+       notice, this list of conditions and the following disclaimer.
+
+    2. Redistributions in binary form must reproduce the above copyright
+       notice, this list of conditions and the following disclaimer in
+       the documentation and/or other materials provided with the
+       distribution.
+
+    THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
+    "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
+    LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
+    FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
+    COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
+    INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
+    BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
+    LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
+    CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
+    LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
+    ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
+    POSSIBILITY OF SUCH DAMAGE.
+*/
+
+:- module(sicstus4_lists,
+	  [ keys_and_values/3,		% ?Pairs, ?Keys, ?Values
+	    rev/2,			% +List, ?Reversed
+	    shorter_list/2,		% ?Short, ?Long
+	    append_length/4,		% ?Prefix, ?Suffix, ?List, ?Length
+	    append_length/3,		% ?Suffix, ?List, ?Length
+	    prefix_length/3,		% ?List, ?Prefix, ?Length
+	    proper_prefix_length/3,	% ?List, ?Prefix, ?Length
+	    suffix_length/3,		% ?List, ?Suffix, ?Length
+	    proper_suffix_length/3,	% ?List, ?Suffix, ?Length
+	    sublist/5,			% +Whole, ?Part, ?Before, ?Length, ?After
+	    sublist/4,			% +Whole, ?Part, ?Before, ?Length
+	    sublist/3,			% +Whole, ?Part, ?Before
+	    cons/3,			% ?Head, ?Tail, ?List
+	    last/3,			% ?Fore, ?Last, ?List
+	    head/2,			% ?List, ?Head
+	    tail/2,			% ?List, ?Tail
+	    prefix/2,			% ?List, ?Prefix
+	    proper_prefix/2,		% ?List, ?Prefix
+	    suffix/2,			% ?List, ?Suffix
+	    proper_suffix/2,		% ?List, ?Suffix
+	    subseq/3,			% ?Sequence, ?SubSequence, ?Complement
+	    subseq0/2,			% +Sequence, ?SubSequence
+	    subseq1/2,			% +Sequence, ?SubSequence
+	    scanlist/4,			% :Pred, ?Xs, ?V1, ?V
+	    scanlist/5,			% :Pred, ?Xs, ?Ys, ?V1, ?V
+	    scanlist/6,			% :Pred, ?Xs, ?Ys, ?Zs, ?V1, ?V
+	    
+	    % is_list/1 is built-in on SWI.
+	    % We re-export it here to avoid warnings
+	    % when SICStus code explicitly imports it from library(lists).
+	    is_list/1			% +Term
+	  ]).
+:- reexport('../../lists',
+	    [ select/3,
+	      selectchk/3,
+	      append/2,
+	      delete/3,
+	      last/2,
+	      % SWI lists:list_to_set/2 actually behaves
+	      % like SICStus lists:remove_dups/2
+	      % and not like SICStus sets:list_to_set/2.
+	      list_to_set/2 as remove_dups,
+	      nextto/3,
+	      nth1/3,
+	      nth1/4,
+	      nth0/3,
+	      nth0/4,
+	      permutation/2,
+	      proper_length/2,
+	      reverse/2,
+	      same_length/2,
+	      select/4,
+	      selectchk/4,
+	      sum_list/2 as sumlist,
+	      max_member/2,
+	      min_member/2,
+	      max_member/3,
+	      min_member/3,
+	      clumped/2
+	    ]).
+:- reexport('../../apply',
+	    [ maplist/2,
+	      maplist/3,
+	      maplist/4,
+	      convlist/3,
+	      exclude/3,
+	      include/3,
+	      partition/5
+	    ]).
+:- reexport('../../clp/clpfd', [transpose/2]).
+:- reexport('../sicstus/lists', [same_length/3]).
+:- use_module(library(pairs), [pairs_keys_values/3]).
+
+:- multifile sicstus4:rename_module/2.
+
+sicstus4:rename_module(lists, sicstus4_lists).
+
+/** <module> SICStus 4-compatible library(lists).
+
+@tbd	This library is incomplete.
+	As of SICStus 4.6.0, the following predicates are missing:
+
+	* append/5
+	* correspond/4
+	* delete/4
+	* one_longer/2
+	* perm/2
+	* perm2/4
+	* rotate_list/[2,3]
+	* segment/2
+	* proper_segment/2
+	* cumlist/[4,5,6]
+	* map_product/4
+	* some/[2,3,4]
+	* somechk/[2,3,4]
+	* exclude/[4,5]
+	* include/[4,5]
+	* group/[3,4,5]
+	* ordered/[1,2]
+	* select_min/[3,4]
+	* select_max/[3,4]
+	* increasing_prefix/[3,4]
+	* decreasing_prefix/[3,4]
+	* clumps/2
+	* keyclumps/2
+	* keyclumped/2
+
+@see	https://sicstus.sics.se/sicstus/docs/4.6.0/html/sicstus.html/lib_002dlists.html
+*/
+
+keys_and_values(Pairs, Keys, Values) :-
+	pairs_keys_values(Pairs, Keys, Values).
+
+
+%%	rev(+List, ?Reversed) is semidet.
+%
+%	Same as reverse/2, but List must be a proper list.
+
+rev(List, Reversed) :- rev_(List, [], Reversed).
+rev_([], Reversed, Reversed).
+rev_([Head|Tail], RevTail, Reversed) :-
+	rev_(Tail, [Head|RevTail], Reversed).
+
+
+%%	shorter_list(?Short, ?Long) is nondet.
+%
+%	True if Short is a shorter list than Long. The lists' contents
+%	are insignificant, only the lengths matter. Mode -Short, +Long
+%	can be used to enumerate list skeletons shorter than Long.
+
+shorter_list([], [_|_]).
+shorter_list([_|ShortTail], [_|LongTail]) :-
+	shorter_list(ShortTail, LongTail).
+
+
+% TODO The *_length predicates can probably be implemented more efficiently.
+
+append_length(Prefix, Suffix, List, Length) :-
+	append(Prefix, Suffix, List),
+	length(Prefix, Length).
+
+append_length(Suffix, List, Length) :-
+	append_length(_, Suffix, List, Length).
+
+prefix_length(List, Prefix, Length) :-
+	prefix(List, Prefix),
+	length(Prefix, Length).
+
+proper_prefix_length(List, Prefix, Length) :-
+	proper_prefix(List, Prefix),
+	length(Prefix, Length).
+
+suffix_length(List, Suffix, Length) :-
+	suffix(List, Suffix),
+	length(Suffix, Length).
+
+proper_suffix_length(List, Suffix, Length) :-
+	proper_suffix(List, Suffix),
+	length(Suffix, Length).
+
+
+sublist(Whole, Part, Before, Length, After) :-
+	append(Prefix, Tail, Whole),
+	append(Part, Suffix, Tail),
+	length(Prefix, Before),
+	length(Part, Length),
+	length(Suffix, After).
+
+sublist(Whole, Part, Before, Length) :-
+	sublist(Whole, Part, Before, Length, _).
+
+sublist(Whole, Part, Before) :-
+	sublist(Whole, Part, Before, _, _).
+
+
+cons(Head, Tail, [Head|Tail]).
+last(Fore, Last, List) :- append(Fore, [Last], List).
+head([Head|_], Head).
+tail([_|Tail], Tail).
+
+
+%%	prefix(?List, ?Prefix) is nondet.
+%
+%	True if Prefix is a prefix of List. Not the same as prefix/2
+%	in SICStus 3 or SWI - the arguments are reversed!
+
+prefix(List, Prefix) :-
+	append(Prefix, _, List).
+
+%%	proper_prefix(?List, ?Prefix) is nondet.
+%
+%	True if Prefix is a prefix of List, but is not List itself.
+
+proper_prefix(List, Prefix) :-
+	prefix(List, Prefix),
+	Prefix \== List.
+
+%%	suffix(?List, ?Prefix) is nondet.
+%
+%	True if Suffix is a suffix of List. Not the same as suffix/2
+%	in SICStus 3 - the arguments are reversed!
+
+suffix(List, List).
+suffix([_|Tail], Suffix) :-
+	suffix(Tail, Suffix).
+
+%%	proper_suffix(?List, ?Prefix) is nondet.
+%
+%	True if Suffix is a suffix of List, but is not List itself.
+
+proper_suffix([_|Tail], Suffix) :-
+	suffix(Tail, Suffix).
+
+
+%%	scanlist(:Pred, ?Xs, ?V1, ?V) is nondet.
+%%	scanlist(:Pred, ?Xs, ?Ys, ?V1, ?V) is nondet.
+%%	scanlist(:Pred, ?Xs, ?Ys, ?Zs, ?V1, ?V) is nondet.
+%
+%	Same as foldl/[4,5,6].
+%
+%	@compat SICStus 4
+
+:- meta_predicate scanlist(3, ?, ?, ?).
+scanlist(Pred, Xs, V1, V) :- foldl(Pred, Xs, V1, V).
+:- meta_predicate scanlist(4, ?, ?, ?, ?).
+scanlist(Pred, Xs, Ys, V1, V) :- foldl(Pred, Xs, Ys, V1, V).
+:- meta_predicate scanlist(5, ?, ?, ?, ?, ?).
+scanlist(Pred, Xs, Ys, Zs, V1, V) :- foldl(Pred, Xs, Ys, Zs, V1, V).
+
+
+subseq(Sequence, [], Sequence).
+subseq([Head|Tail], [Head|SubTail], Complement) :-
+	subseq(Tail, SubTail, Complement).
+subseq([Head|Tail], SubSequence, [Head|Complement]) :-
+	subseq(Tail, SubSequence, Complement).
+
+
+subseq0(Sequence, SubSequence) :- subseq(Sequence, SubSequence, _).
+subseq1(Sequence, SubSequence) :-
+	subseq(Sequence, SubSequence, Complement),
+	Complement \== [].

package/lib/swipl/library/dialect/sicstus4/ordsets.pl

@@ -0,0 +1,54 @@
+/*  Part of SWI-Prolog
+
+    WWW:           http://www.swi-prolog.org
+    Copyright (c)  2021, SWI-Prolog Solutions b.v.
+    All rights reserved.
+
+    Redistribution and use in source and binary forms, with or without
+    modification, are permitted provided that the following conditions
+    are met:
+
+    1. Redistributions of source code must retain the above copyright
+       notice, this list of conditions and the following disclaimer.
+
+    2. Redistributions in binary form must reproduce the above copyright
+       notice, this list of conditions and the following disclaimer in
+       the documentation and/or other materials provided with the
+       distribution.
+
+    THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
+    "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
+    LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
+    FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
+    COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
+    INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
+    BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
+    LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
+    CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
+    LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
+    ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
+    POSSIBILITY OF SUCH DAMAGE.
+*/
+
+:- module(sicstus4_ordsets,
+	  [ ord_nonmember/2		% +Item, +Set
+	  ]).
+:- reexport('../sicstus/ordsets').
+
+:- multifile sicstus4:rename_module/2.
+
+sicstus4:rename_module(ordsets, sicstus4_ordsets).
+
+/** <module> SICStus 4 library(ordsets).
+
+@tbd	This library is incomplete.
+	As of SICStus 4.6.0, the following predicates are missing:
+
+	* ord_setproduct/2
+	* ord_disjoint_union/3
+	* ordset_order/3
+
+@see	https://sicstus.sics.se/sicstus/docs/4.6.0/html/sicstus/lib_002dordsets.html
+*/
+
+ord_nonmember(Item, Set) :- \+ ord_memberchk(Item, Set).

package/lib/swipl/library/dialect/sicstus4/samsort.pl

@@ -0,0 +1,86 @@
+/*  Part of SWI-Prolog
+
+    WWW:           http://www.swi-prolog.org
+    Copyright (c)  2021, SWI-Prolog Solutions b.v.
+    All rights reserved.
+
+    Redistribution and use in source and binary forms, with or without
+    modification, are permitted provided that the following conditions
+    are met:
+
+    1. Redistributions of source code must retain the above copyright
+       notice, this list of conditions and the following disclaimer.
+
+    2. Redistributions in binary form must reproduce the above copyright
+       notice, this list of conditions and the following disclaimer in
+       the documentation and/or other materials provided with the
+       distribution.
+
+    THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
+    "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
+    LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
+    FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
+    COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
+    INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
+    BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
+    LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
+    CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
+    LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
+    ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
+    POSSIBILITY OF SUCH DAMAGE.
+*/
+
+:- module(samsort,
+	  [ samsort/2,			% +RawList, -Sorted
+	    samsort/3,			% :Order, +RawList, -SortedList
+	    samkeysort/2		% +RawList, -Sorted
+	  ]).
+:- reexport('../../backcomp', [merge/3]).
+
+/** <module> SICStus 4 library(samsort).
+
+@tbd	This library is incomplete.
+	As of SICStus 4.6.0, the following predicates are missing:
+
+	* merge/4
+	* keymerge/3
+
+@see	https://sicstus.sics.se/sicstus/docs/4.6.0/html/sicstus.html/lib_002dsamsort.html
+*/
+
+%!	samsort(+RawList, -Sorted) is det.
+%
+%	Same as msort/2.
+%
+%	@compat SICStus 4
+
+samsort(RawList, Sorted) :- msort(RawList, Sorted).
+
+:- meta_predicate samsort_3_key(2, -, +, +).
+samsort_3_key(OrderPred, Delta, E1, E2) :-
+	% Intentionally never set Delta = (=),
+	% because predsort removes duplicates
+	% (i. e. if two items compare equal, one is removed),
+	% but SICStus samsort doesn't.
+	call(OrderPred, E1, E2) -> Delta = (<) ; Delta = (>).
+
+%!	samsort(:Order, +RawList, -Sorted) is det.
+%
+%	Similar to predsort/3, but the predicate Order is used to determine the
+%	order of terms. Order is called with two arguments, and if it succeeds,
+%	the first argument will be sorted before the second argument.
+%	Duplicates are not removed.
+%
+%	@compat SICStus 4
+
+:- meta_predicate samsort(2, +, -).
+samsort(Order, RawList, SortedList) :-
+	predsort(samsort_3_key(Order), RawList, SortedList).
+
+%!	samkeysort(+RawList, -Sorted) is det.
+%
+%	Same as keysort/2.
+%
+%	@compat SICStus 4
+
+samkeysort(RawList, Sorted) :- keysort(RawList, Sorted).

package/lib/swipl/library/dialect/sicstus4/sets.pl

@@ -0,0 +1,124 @@
+/*  Part of SWI-Prolog
+
+    WWW:           http://www.swi-prolog.org
+    Copyright (c)  2021, SWI-Prolog Solutions b.v.
+    All rights reserved.
+
+    Redistribution and use in source and binary forms, with or without
+    modification, are permitted provided that the following conditions
+    are met:
+
+    1. Redistributions of source code must retain the above copyright
+       notice, this list of conditions and the following disclaimer.
+
+    2. Redistributions in binary form must reproduce the above copyright
+       notice, this list of conditions and the following disclaimer in
+       the documentation and/or other materials provided with the
+       distribution.
+
+    THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
+    "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
+    LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
+    FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
+    COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
+    INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
+    BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
+    LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
+    CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
+    LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
+    ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
+    POSSIBILITY OF SUCH DAMAGE.
+*/
+
+:- module(sets,
+	  [ add_element/3,		% +Element, +Set1, -Set2
+	    del_element/3,		% +Element, +Set1, -Set2
+	    disjoint/2,			% +Set1, +Set2
+	    intersect/2,		% +Set1, +Set2
+	    set_order/3,		% +Xs, +Ys, -R
+	    seteq/2,			% +Set1, +Set2
+	    list_to_set/2,		% +List, -Set
+	    disjoint_union/3,		% +Set1, +Set2, -Union
+	    union/4			% +Set1, +Set2, -Union, -Difference
+	  ]).
+:- reexport(library(lists),
+	    [ is_set/1,
+	      subset/2,
+	      intersection/3,
+	      subtract/3,
+	      union/3
+	    ]).
+:- use_module(library(lists), [selectchk/3]).
+
+/** <module> SICStus 4 library(sets).
+
+@tbd	This library is incomplete.
+	As of SICStus 4.6.0, the following predicates are missing:
+
+	* pairfrom/4
+	* power_set/2
+	* intersection/2
+	* symdiff/3
+	* setproduct/3
+	* union/2
+
+@see	https://sicstus.sics.se/sicstus/docs/4.6.0/html/sicstus.html/lib_002dsets.html
+*/
+
+add_element(Element, Set1, Set2) :-
+	(   memberchk(Element, Set1)
+	->  Set2 = Set1
+	;   Set2 = [Element|Set1]
+	).
+
+del_element(Element, Set1, Set2) :-
+	(   selectchk(Element, Set1, Set2)
+	->  true
+	;   Set2 = Set1
+	).
+
+disjoint(Set1, Set2) :-
+	intersection(Set1, Set2, []).
+
+intersect(Set1, Set2) :-
+	intersection(Set1, Set2, Intersection),
+	Intersection \= [].
+
+set_order(Xs, Ys, R) :-
+	(   subset(Xs, Ys)
+	->  (   subset(Ys, Xs)
+	    ->  R = (=)
+	    ;   R = (<)
+	    )
+	;   (   subset(Ys, Xs)
+	    ->  R = (>)
+	    ;   fail
+	    )
+	).
+
+seteq(Set1, Set2) :- set_order(Set1, Set2, =).
+
+%%	list_to_set(+List, -Set) is det.
+%
+%	Set is List with all duplicates removed. Duplicates are removed
+%	by unification. This is not the same as SWI-Prolog's
+%	list_to_set/2 in library(lists), which finds duplicates based on
+%	term equality (==).
+%
+%	@compat SICStus 4
+
+list_to_set([], []).
+list_to_set([X|Tail], Set) :-
+	(   memberchk(X, Tail)
+	->  Set = SetTail
+	;   Set = [X|SetTail]
+	),
+	list_to_set(Tail, SetTail).
+
+disjoint_union(Set1, Set2, Union) :-
+	disjoint(Set1, Set2),
+	append(Set1, Set2, Union).
+
+union(Set1, Set2, Union, Difference) :-
+	union(Set1, Set2, Union),
+	subtract(Set1, Set2, Difference).

package/lib/swipl/library/dialect/sicstus4/sockets.pl

@@ -0,0 +1,164 @@
+/*  Part of SWI-Prolog
+
+    WWW:           http://www.swi-prolog.org
+    Copyright (c)  2021, SWI-Prolog Solutions b.v.
+    All rights reserved.
+
+    Redistribution and use in source and binary forms, with or without
+    modification, are permitted provided that the following conditions
+    are met:
+
+    1. Redistributions of source code must retain the above copyright
+       notice, this list of conditions and the following disclaimer.
+
+    2. Redistributions in binary form must reproduce the above copyright
+       notice, this list of conditions and the following disclaimer in
+       the documentation and/or other materials provided with the
+       distribution.
+
+    THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
+    "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
+    LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
+    FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
+    COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
+    INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
+    BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
+    LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
+    CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
+    LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
+    ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
+    POSSIBILITY OF SUCH DAMAGE.
+*/
+
+:- module(sicstus4_sockets,
+	  [ socket_client_open/3,
+	    socket_server_open/2,
+	    socket_server_open/3,
+	    socket_server_accept/4,
+	    socket_server_close/1,
+	    socket_select/7,
+	    current_host/1
+	  ]).
+
+:- reexport('../sicstus/sockets',
+	    [ current_host/1
+	    ]).
+
+:- use_module(library(lists)).
+:- use_module(library(socket), [tcp_connect/3]).
+
+:- multifile sicstus4:rename_module/2.
+
+sicstus4:rename_module(sockets, sicstus4_sockets).
+
+/** <module> SICStus 4-compatible library(sockets).
+
+@tbd	This library is incomplete.
+	Some predicates don't fully support all options available on SICStus.
+	See the documentation for individual predicates for details.
+
+@see	https://sicstus.sics.se/sicstus/docs/4.6.0/html/sicstus.html/lib_002dsockets.html
+*/
+
+sicstus_address_to_swi(Address, Address) :- var(Address), !.
+sicstus_address_to_swi(inet(Nodename, Servname), SwiAddress) :- !,
+	sicstus_address_to_swi(Nodename:Servname, SwiAddress).
+sicstus_address_to_swi('':Servname, Servname) :- !.
+sicstus_address_to_swi(Address, Address).
+
+% The following options are not supported yet:
+% * eof_action(Action)
+% * eol(Eol)
+sicstus_parse_stream_options(Options, [type(Type), encoding(Encoding)]) :-
+	(   selectchk(type(Type), Options, Options1)
+	->  true
+	;   Type = text,
+	    Options1 = Options
+	),
+	(   selectchk(encoding(Encoding), Options1, Options2)
+	->  true
+	;   Encoding = iso_latin_1,
+	    Options2 = Options1
+	),
+	% Check that no unsupported options were passed
+	Options2 == [].
+
+sicstus_apply_stream_options(Stream, ParsedOptions) :-
+	maplist(set_stream(Stream), ParsedOptions).
+
+socket_client_open(Addr, Stream, Options) :-
+	sicstus_address_to_swi(Addr, SwiAddr),
+	sicstus_parse_stream_options(Options, ParsedOptions),
+	tcp_connect(SwiAddr, Stream, []),
+	sicstus_apply_stream_options(Stream, ParsedOptions).
+
+sicstus_address_handle_loopback(Address, false, Address) :- !.
+sicstus_address_handle_loopback(Servname, true, localhost:Servname) :- var(Servname), !.
+sicstus_address_handle_loopback(_Nodename:Servname, true, localhost:Servname) :- !.
+sicstus_address_handle_loopback(Servname, true, localhost:Servname) :- !.
+
+sicstus_server_address_to_swi(Address, Loopback, SwiAddress) :-
+	sicstus_address_to_swi(Address, TempAddress),
+	sicstus_address_handle_loopback(TempAddress, Loopback, SwiAddress).
+
+% The following options are not supported yet:
+% * numeric_nodename(Bool)
+% * numeric_servname(Bool)
+socket_server_open(Addr, ServerSocket) :- socket_server_open(Addr, ServerSocket, []).
+socket_server_open(Addr, ServerSocket, Options) :-
+	(   selectchk(reuseaddr(ReuseAddr), Options, Options1)
+	->  (ReuseAddr == true ; ReuseAddr == false)
+	;   ReuseAddr = false,
+	    Options1 = Options
+	),
+	(   selectchk(loopback(Loopback), Options1, Options2)
+	->  (Loopback == true ; Loopback == false)
+	;   Loopback = false,
+	    Options2 = Options1
+	),
+	sicstus_server_address_to_swi(Addr, Loopback, SwiAddr),
+	% Check that no unsupported options were passed
+	Options2 == [],
+	tcp_socket(SocketId),
+	(   ReuseAddr == true
+	->  tcp_setopt(SocketId, reuseaddr)
+	;   true
+	),
+	tcp_bind(SocketId, SwiAddr),
+	tcp_listen(SocketId, 5),
+	tcp_open_socket(SocketId, ServerSocket).
+
+socket_server_accept(ServerSocket, Client, Stream, StreamOptions) :-
+	sicstus_parse_stream_options(StreamOptions, ParsedStreamOptions),
+	tcp_accept(ServerSocket, ClientSocket, Client),
+	tcp_open_socket(ClientSocket, Stream),
+	sicstus_apply_stream_options(Stream, ParsedStreamOptions).
+
+socket_server_close(ServerSocket) :- close(ServerSocket).
+
+sicstus_timeout_to_swi(off, infinite).
+sicstus_timeout_to_swi(Seconds:Microseconds, N) :-
+	number(Seconds),
+	number(Microseconds),
+	N is Seconds + Microseconds / 1000000,
+	N > 0.
+sicstus_timeout_to_swi(N, N) :-
+	number(N),
+	N > 0.
+
+:- use_module(library(lists), [list_to_set/2, intersection/3]).
+% On SICStus, the input lists can contain not just streams/sockets,
+% but also pairs of the form Identifier-Stream, where Identifier may be
+% an arbitrary term. If a stream from such a pair is ready, the entire
+% pair is returned in the corresponding ready list(s). This allows the
+% calling code to tell apart different ready streams more easily.
+% This emulation currently does *not* support this feature
+% and only accepts and returns bare streams.
+socket_select(ServerSockets, SReady, ReadStreams, RReady, WriteStreams, WReady, Timeout) :-
+	sicstus_timeout_to_swi(Timeout, SwiTimeout),
+	append([ServerSockets, ReadStreams, WriteStreams], AllStreamsDup),
+	list_to_set(AllStreamsDup, AllStreams),
+	wait_for_input(AllStreams, ReadyList, SwiTimeout),
+	intersection(ServerSockets, ReadyList, SReady),
+	intersection(ReadStreams, ReadyList, RReady),
+	intersection(WriteStreams, ReadyList, WReady).