kibi-swipl-linux-x64-gnu 1.0.0

package/lib/swipl/library/ext/http/http/http_server.pl

@@ -0,0 +1,105 @@
+/*  Part of SWI-Prolog
+
+    Author:        Jan Wielemaker
+    E-mail:        J.Wielemaker@vu.nl
+    WWW:           http://www.swi-prolog.org
+    Copyright (c)  2019, VU University Amsterdam
+    All rights reserved.
+
+    Redistribution and use in source and binary forms, with or without
+    modification, are permitted provided that the following conditions
+    are met:
+
+    1. Redistributions of source code must retain the above copyright
+       notice, this list of conditions and the following disclaimer.
+
+    2. Redistributions in binary form must reproduce the above copyright
+       notice, this list of conditions and the following disclaimer in
+       the documentation and/or other materials provided with the
+       distribution.
+
+    THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
+    "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
+    LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
+    FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
+    COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
+    INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
+    BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
+    LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
+    CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
+    LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
+    ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
+    POSSIBILITY OF SUCH DAMAGE.
+*/
+
+:- module(http_server,
+          [ http_server/1,		% +Options
+            % from thread_httpd
+            http_current_server/2,      % ?:Goal, ?Port
+            http_server_property/2,     % ?Port, ?Property
+            http_server/2,              % :Goal, +Options
+            http_workers/2,             % +Port, ?WorkerCount
+            http_add_worker/2,          % +Port, +Options
+            http_current_worker/2,      % ?Port, ?ThreadID
+            http_stop_server/2,         % +Port, +Options
+            http_spawn/2,               % :Goal, +Options
+            % from http_dispatch
+            http_dispatch/1,            % +Request
+            http_handler/3,             % +Path, +Predicate, +Options
+            http_delete_handler/1,      % +Path
+            http_request_expansion/2,   % :Goal, +Rank
+            http_reply_file/3,          % +File, +Options, +Request
+            http_redirect/3,            % +How, +Path, +Request
+            http_404/2,                 % +Options, +Request
+            http_switch_protocol/2,     % :Goal, +Options
+            http_current_handler/2,     % ?Path, ?Pred
+            http_current_handler/3,     % ?Path, ?Pred, -Options
+            http_location_by_id/2,      % +ID, -Location
+            http_link_to_id/3,          % +ID, +Parameters, -HREF
+            http_reload_with_parameters/3, % +Request, +Parameters, -HREF
+            % from http_wrapper
+            http_current_request/1,     % -Request
+            http_peer/2,
+            % from http_parameters
+            http_parameters/2,          % +Request, -Params
+            http_parameters/3,
+            % from html_write
+            reply_html_page/2,          % :Head, :Body
+            html//1,                    % :Content
+                                        % Extension support
+            (html_meta)/1,              % +Spec
+            op(1150, fx, html_meta),
+            % from http_json
+            reply_json_dict/1,          % +JSON
+            reply_json_dict/2,          % +JSON, Options
+            http_read_json_dict/2,      % +Request, -Dict
+            http_read_json_dict/3,      % +Request, -Dict, +Options
+
+            is_json_content_type/1
+          ]).
+:- use_module(library(http/thread_httpd)).
+:- use_module(library(http/http_dispatch)).
+:- use_module(library(http/http_wrapper)).
+:- use_module(library(http/http_parameters)).
+:- use_module(library(http/html_write)).
+:- use_module(library(http/http_json)).
+:- use_module(library(http/http_dyn_workers)).
+
+/** <module> HTTP server library
+
+This  library  combines  the  core  server  functionality  provided  by
+several libraries that are needed by almost any web server.  It exports
+the   commonly   used  predicates   from    library(http/thread_httpd),
+library(http/http_dispatch),                library(http/http_wrapper),
+library(http/http_parameters),                library(http/html_write),
+library(http/http_json),      and       library(http/http_dyn_workers).
+
+*/
+
+%!  http_server(+Options) is det.
+%
+%   Create an HTTP server using   http_dispatch/1 for handling requests.
+%   See http_server/2 and http_dispatch/1 for details.
+
+http_server(Options) :-
+    http_server(http_dispatch, Options).

package/lib/swipl/library/ext/http/http/http_server_files.pl

@@ -0,0 +1,126 @@
+/*  Part of SWI-Prolog
+
+    Author:        Jan Wielemaker
+    E-mail:        J.Wielemaker@vu.nl
+    WWW:           http://www.swi-prolog.org
+    Copyright (c)  2009-2014, VU University, Amsterdam
+    All rights reserved.
+
+    Redistribution and use in source and binary forms, with or without
+    modification, are permitted provided that the following conditions
+    are met:
+
+    1. Redistributions of source code must retain the above copyright
+       notice, this list of conditions and the following disclaimer.
+
+    2. Redistributions in binary form must reproduce the above copyright
+       notice, this list of conditions and the following disclaimer in
+       the documentation and/or other materials provided with the
+       distribution.
+
+    THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
+    "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
+    LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
+    FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
+    COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
+    INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
+    BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
+    LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
+    CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
+    LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
+    ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
+    POSSIBILITY OF SUCH DAMAGE.
+*/
+
+:- module(http_server_files,
+          [ serve_files_in_directory/2  % +Alias, +HTTPRequest
+          ]).
+:- use_module(library(http/http_path)).
+:- use_module(library(http/http_dispatch)).
+
+/** <module> Serve files needed by modules from the server
+
+This module provides an infrastructure   for serving resource-files such
+as icons, JavaScript, CSS files, etc.   The default configuration serves
+the    HTTP    locations    =icons=,     =css=      and     =js=    (see
+http_absolute_location/3)
+
+The location for these services  can  be   changed  by  adding rules for
+http:location/3.  Directories  providing  additional    or   alternative
+resources can be achieved by adding rules for user:file_search_path/2.
+*/
+
+:- multifile
+    http:location/3.                % Alias, Expansion, Options
+:- dynamic
+    http:location/3.                % Alias, Expansion, Options
+
+http:location(icons, root(icons), [ priority(-100) ]).
+http:location(css,   root(css),   [ priority(-100) ]).
+http:location(js,    root(js),    [ priority(-100) ]).
+
+:- multifile
+    user:file_search_path/2.
+:- dynamic
+    user:file_search_path/2.
+
+user:file_search_path(icons, library('http/web/icons')).
+user:file_search_path(css,   library('http/web/css')).
+user:file_search_path(js,    library('http/web/js')).
+
+:- http_handler(icons(.), serve_files_in_directory(icons),
+                [prefix, priority(-100)]).
+:- http_handler(css(.),   serve_files_in_directory(css),
+                [prefix, priority(-100)]).
+:- http_handler(js(.),    serve_files_in_directory(js),
+                [prefix, priority(-100)]).
+
+%!  serve_files_in_directory(+Alias, +Request)
+%
+%   Serve files from the directory  Alias   from  the path-info from
+%   Request.    This    predicate    is     used    together    with
+%   file_search_path/2. Note that multiple  clauses   for  the  same
+%   file_search_path alias can be used to merge files from different
+%   physical locations onto the same HTTP   directory. Note that the
+%   handler must be declared  as  =prefix=.   Below  is  an  example
+%   serving images from  http://<host>/img/...   from  the directory
+%   =http/web/icons=.
+%
+%       ==
+%       http:location(img, root(img), []).
+%       user:file_search_path(icons, library('http/web/icons')).
+%
+%       :- http_handler(img(.), serve_files_in_directory(icons), [prefix]).
+%       ==
+%
+%   This predicate calls http_404/2 if the   physical file cannot be
+%   located. If the requested  path-name   is  unsafe  (i.e., points
+%   outside  the  hierarchy  defines    by   the  file_search_path/2
+%   declaration), this handlers returns a _403 Forbidden_ page.
+%
+%   @see http_reply_file/3
+
+serve_files_in_directory(Alias, Request) :-
+    memberchk(path_info(PathInfo), Request),
+    !,
+    Term =.. [Alias,PathInfo],
+    (   catch(http_safe_file(Term, []),
+              error(permission_error(read, file, _), _),
+              fail)
+    ->  (   absolute_file_name(Term, Path,
+                               [ access(read),
+                                 file_errors(fail)
+                               ])
+        ->  http_reply_file(Path,
+                            [ unsafe(true),
+                              static_gzip(true)
+                            ], Request)
+        ;   http_404([], Request)
+        )
+    ;   memberchk(path(Path), Request),
+        throw(http_reply(forbidden(Path)))
+    ).
+serve_files_in_directory(_Alias, Request) :-
+    memberchk(path(Path), Request),
+    throw(http_reply(forbidden(Path))).
+

package/lib/swipl/library/ext/http/http/http_server_health.pl

@@ -0,0 +1,186 @@
+/*  Part of SWI-Prolog
+
+    Author:        Jan Wielemaker
+    E-mail:        jan@swi-prolog.org
+    WWW:           http://www.swi-prolog.org
+    Copyright (C): 2024 SWI-Prolog Solutions b.v.
+
+    This program is free software; you can redistribute it and/or
+    modify it under the terms of the GNU General Public License
+    as published by the Free Software Foundation; either version 2
+    of the License, or (at your option) any later version.
+
+    This program is distributed in the hope that it will be useful,
+    but WITHOUT ANY WARRANTY; without even the implied warranty of
+    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+    GNU General Public License for more details.
+
+    You should have received a copy of the GNU General Public
+    License along with this library; if not, write to the Free Software
+    Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
+
+    As a special exception, if you link this library with other files,
+    compiled with a Free Software compiler, to produce an executable, this
+    library does not by itself cause the resulting executable to be covered
+    by the GNU General Public License. This exception does not however
+    invalidate any other reasons why the executable file might be covered by
+    the GNU General Public License.
+*/
+
+:- module(http_server_health,
+          [ server_health/1             % +Request
+          ]).
+:- autoload(library(lists), [member/2]).
+:- autoload(library(aggregate), [aggregate_all/3, aggregate_all/4]).
+:- autoload(library(apply), [maplist/3]).
+:- autoload(library(option), [option/2]).
+:- use_module(library(http/http_dispatch), [http_handler/3]).
+:- autoload(library(http/http_json), [reply_json/1]).
+:- autoload(library(http/http_parameters), [http_parameters/2]).
+:- autoload(library(http/thread_httpd), [http_server_property/2, http_workers/2]).
+:- autoload(library(http/http_stream), [cgi_statistics/1]).
+:- use_module(library(http/http_cors), [cors_enable/2, cors_enable/0]).
+
+:- http_handler(root(health), server_health, [id(server_health), priority(-10)]).
+
+/** <module> HTTP Server health statistics
+
+This module defines an HTTP handler for ``/health``. The handler returns
+a JSON document  with  elementary  health   statistics  on  the  running
+instance. The location can be changed  using http_handler/3. Keys may be
+added using additional clauses for health/2 or hidden using hide/1.
+
+This  library  defines  an  HTTP  handler   and  defines  two  multifile
+predicates (health/2 and hide/1) to control the information presented.
+*/
+
+%!  server_health(+Request)
+%
+%   HTTP handler that replies with  the   overall  health of the server.
+%   Returns a JSON object from all solutions of health/2.
+%
+%   Processes an optional parameter `fields` to  specify the fields that
+%   should be returned.  The  fields  content   is  ","  or  white space
+%   delimited.
+
+server_health(Request) :-
+    option(method(options), Request), !,
+    cors_enable(Request,
+                [ methods([get])
+                ]),
+    format('~n').
+server_health(Request) :-
+    http_parameters(Request,
+                    [ fields(FieldSpec, [ optional(true) ])
+                    ]),
+    cors_enable,
+    (   var(FieldSpec)
+    ->  true
+    ;   split_string(FieldSpec, ", \t\r\n", " \t\r\n", Strings),
+        maplist(atom_string, Fields, Strings)
+    ),
+    get_server_health(Health, Fields),
+    reply_json(Health).
+
+get_server_health(Health, Fields) :-
+    var(Fields),
+    !,
+    findall(Key-Value, health(Key, Value), Pairs),
+    dict_pairs(Health, health, Pairs).
+get_server_health(Health, Fields) :-
+    findall(Key-Value, (member(Key,Fields),health(Key, Value)), Pairs),
+    dict_pairs(Health, health, Pairs).
+
+%!  health(-Key, -Value) is nondet.
+%
+%   Multifile extensible. True when  Key/Value  can   be  reported  as a
+%   health statistics. Keys may  be  added   by  adding  clauses to this
+%   multifile predicate. Keys may be   filtered using hide/1. Predefined
+%   Key values are:
+%
+%     - up
+%       Defined to be `true`.
+%     - epoch
+%       Starting time of the server in seconds after Jan 1, 1970 UTC.
+%     - cpu_time
+%       Total process CPU usage in seconds.
+%     - threads
+%       Number of active threads
+%     - workers
+%       Number of HTTP _worker_ threads.
+%     - requests
+%       Number of HTTP requests processed.
+%     - bytes_sent
+%       Number of bytes send in reply to HTTP requests.
+%     - open_files
+%       Number of open file streams.  This includes physical files as
+%       well as sockets (except for Windows).  On Linux we count the
+%       file handles in ``/proc/self/fd``.  Otherwise we use
+%       stream_property/2 with the file_no(Fd) property.
+%     - loadavg
+%       An array holding the load average over the last [1,5,15]
+%       minutes.  This key is only supported on Linux machines.  It
+%       is based on ``/proc/loadavg``
+%     - heap
+%       When compiled with TCMalloc, this provides two properties:
+%       - inuse: Bytes
+%         Total amount of in-use memory in bytes
+%       - size: Bytes
+%         Same as `inuse`, but including the TCMalloc overhead and
+%         (thus) memory that has been freed and is not (yet) reused.
+%
+%   @arg Key is the name of the JSON key.  Must be an atom
+%   @arg Value is the Prolog representation for a JSON (dict) value.
+
+:- multifile health/2.
+
+term_expansion((health(Key,Value) :- Body),
+               (health(Key,Value) :- \+ hide(Key), Body)).
+
+health(up, true) :-
+    true.
+health(epoch, Epoch) :-
+    http_server_property(_, start_time(Epoch)).
+health(cpu_time, Time) :-
+    statistics(process_cputime, Time).
+health(threads, Count) :-
+    statistics(threads, Count).
+health(workers, Count) :-
+    aggregate_all(sum(N), http_workers(_,N), Count).
+health(requests, RequestCount) :-
+    cgi_statistics(requests(RequestCount)).
+health(bytes_sent, BytesSent) :-
+    cgi_statistics(bytes_sent(BytesSent)).
+:- if(exists_directory('/proc/self/fd')).
+health(open_files, Streams) :-
+    directory_files('/proc/self/fd', FDs),
+    length(FDs, Files),
+    Streams is Files - 2.               % Ignore . and ..
+:- else.
+health(open_files, Streams) :-
+    findall(N, stream_property(_, file_no(N)), FDs),
+    sort(FDs, Unique),
+    length(Unique, Streams).
+:- endif.
+health(loadavg, LoadAVG) :-
+    access_file('/proc/loadavg', exist),
+    catch(setup_call_cleanup(
+              open('/proc/loadavg', read, In),
+              read_string(In, _, String),
+              close(In)),
+	      _, fail),
+    split_string(String, " ", " ", [One,Five,Fifteen|_]),
+    maplist(number_string, LoadAVG, [One,Five,Fifteen]).
+:- if(current_predicate(malloc_property/1)).
+health(heap, json{inuse:InUse, size:Size}) :-
+    malloc_property('generic.current_allocated_bytes'(InUse)),
+    malloc_property('generic.heap_size'(Size)).
+:- endif.
+
+%!  hide(?Key) is nondet.
+%
+%   Multifile hook. If true for  a   specific  Key, hide this statistics
+%   from the output. This may be used to hide keys that are considered a
+%   security risk.
+
+:- multifile hide/1.