kibi-swipl-linux-x64-gnu 1.0.0

package/lib/swipl/doc/packages/examples/chr/listdom.chr

@@ -0,0 +1,138 @@
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+%%
+%% Slim Abdennadher, Thom Fruehwirth, LMU, July 1998
+%% Finite (enumeration, list) domain solver over integers
+%%
+%% * ported to hProlog by Tom Schrijvers, K.U.Leuven
+
+% :- module(listdom,[]).
+
+:- use_module( library(chr)).
+
+:- use_module( library(lists)).
+
+
+%% for domain constraints
+:- op( 700,xfx,'::').
+:- op( 600,xfx,'..').
+
+%% for inequality constraints
+:- op( 700,xfx,lt).
+:- op( 700,xfx,le).
+:- op( 700,xfx,ne).
+
+%% for domain constraints
+?- op( 700,xfx,'::').
+?- op( 600,xfx,'..').
+
+%% for inequality constraints
+?- op( 700,xfx,lt).
+?- op( 700,xfx,le).
+?- op( 700,xfx,ne).
+
+:- constraints (::)/2, (le)/2, (lt)/2, (ne)/2, add/3, mult/3.
+%% X::Dom - X must be element of the finite list domain Dom
+
+%% special cases
+X::[] <=> fail.				
+%%X::[Y] <=> X=Y.
+%%X::[A|L] <=> ground(X) | (member(X,[A|L]) -> true).
+
+%% intersection of domains for the same variable
+X::L1, X::L2 <=> is_list(L1), is_list(L2) | 
+intersection(L1,L2,L) , X::L.
+
+X::L, X::Min..Max <=> is_list(L) |  
+remove_lower(Min,L,L1), remove_higher(Max,L1,L2), 
+X::L2.
+
+
+%% interaction with inequalities
+
+X le Y, X::L1,  Y::L2 ==> is_list(L1),is_list(L2),  
+min_list(L1,MinX), min_list(L2,MinY), MinX > MinY | 
+max_list(L2,MaxY), Y::MinX..MaxY.
+X le Y, X::L1,  Y::L2 ==> is_list(L1),is_list(L2),  
+max_list(L1,MaxX), max_list(L2,MaxY), MaxX > MaxY  | 
+min_list(L1,MinX), X::MinX..MaxY.
+
+X lt Y, X::L1,  Y::L2 ==> is_list(L1), is_list(L2), 
+max_list(L1,MaxX), max_list(L2,MaxY), 
+MaxY1 is MaxY - 1, MaxY1 < MaxX |
+min_list(L1,MinX), X::MinX..MaxY1.
+X lt Y, X::L1,  Y::L2 ==> is_list(L1), is_list(L2), 
+min_list(L1,MinX), min_list(L2,MinY),  
+MinX1 is MinX + 1, MinX1 > MinY |
+max_list(L2,MaxY), Y :: MinX1..MaxY.
+
+X ne Y \  Y::D <=> ground(X), is_list(D), member(X,D) | select(X,D,D1), Y::D1.
+Y ne X \  Y::D <=> ground(X), is_list(D), member(X,D) | select(X,D,D1), Y::D1.
+Y::D \ X ne Y <=>  ground(X), is_list(D), \+ member(X,D) | true.
+Y::D \ Y ne X <=>  ground(X), is_list(D), \+ member(X,D) | true.
+
+
+%% interaction with addition
+%% no backpropagation yet!
+
+add(X,Y,Z), X::L1, Y::L2 ==> is_list(L1), is_list(L2) | 
+all_addition(L1,L2,L3), Z::L3.
+
+%% interaction with multiplication
+%% no backpropagation yet!
+
+mult(X,Y,Z), X::L1, Y::L2 ==> is_list(L1), is_list(L2) |
+all_multiplication(L1,L2,L3), Z::L3.
+
+
+%% auxiliary predicates =============================================
+
+remove_lower(_,[],L1):- !, L1=[].
+remove_lower(Min,[X|L],L1):-
+	X@<Min,
+	!,
+	remove_lower(Min,L,L1).
+remove_lower(Min,[X|L],[X|L1]):-
+	remove_lower(Min,L,L1).
+
+remove_higher(_,[],L1):- !, L1=[].
+remove_higher(Max,[X|L],L1):-
+	X@>Max,
+	!,
+	remove_higher(Max,L,L1).
+remove_higher(Max,[X|L],[X|L1]):-
+	remove_higher(Max,L,L1).
+
+intersection([], _, []).
+intersection([Head|L1tail], L2, L3) :-
+	memberchk(Head, L2),
+	!,
+	L3 = [Head|L3tail],
+	intersection(L1tail, L2, L3tail).
+intersection([_|L1tail], L2, L3) :-
+	intersection(L1tail, L2, L3).
+
+all_addition(L1,L2,L3) :- 
+	setof(Z, X^Y^(member(X,L1), member(Y,L2), Z is X + Y), L3).
+
+all_multiplication(L1,L2,L3) :-
+	setof(Z, X^Y^(member(X,L1), member(Y,L2), Z is X * Y), L3).
+
+
+%% EXAMPLE ==========================================================
+
+/*
+?- X::[1,2,3,4,5,6,7], Y::[2,4,6,7,8,0], Y lt X, X::4..9, X ne Y, 
+add(X,Y,Z), mult(X,Y,Z).
+*/
+
+%% end of handler listdom.pl =================================================
+%% ===========================================================================
+  
+
+/*
+
+?- X::[1,2,3,4,5,6,7], Y::[2,4,6,7,8,0], Y lt X, X::4..9, X ne Y,
+   add(X,Y,Z), mult(X,Y,Z).
+
+Bad call to builtin predicate: _9696 =.. ['add/3__0',AttVar4942,AttVar5155,AttVar6836|_9501] in predicate mknewterm / 3
+*/

package/lib/swipl/doc/packages/examples/chr/primes.chr

@@ -0,0 +1,29 @@
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+%%
+%% Sieve of eratosthenes to compute primes
+%% thom fruehwirth 920218-20, 980311
+%% christian holzbaur 980207 for Sicstus CHR
+%%
+%% ported to hProlog by Tom Schrijvers
+%% Updated to current CHR and added how to extract the primes by
+%% Jan Wielemaker.
+
+:- module(primes,
+          [ candidate/1,                % +Max
+            primes/2                    % +Max, -ListOfPrimes
+          ]).
+:- use_module(library(chr)).
+
+:- chr_constraint candidate/1.
+:- chr_constraint prime/1.
+
+candidate(1) <=> true.
+candidate(N) <=> prime(N), N1 is N - 1, candidate(N1).
+
+absorb @ prime(Y) \ prime(X) <=> 0 is X mod Y | true.
+
+primes(Max, Primes) :-
+    findall(P,
+            ( candidate(Max),
+              current_chr_constraint(prime(P))),
+            Primes).

package/lib/swipl/doc/packages/examples/http/README.md

@@ -0,0 +1,98 @@
+# HTTP example files
+
+This is a simple demo of the  HTTP server facilities, providing a simple
+body and the three documented server instantiations.
+
+## The server main programs are:
+
+	$ demo_threads.pl :
+	Run threaded server. Requires SWI-Prolog with thread-support.
+	The server is started at port 3000 using server/0.  server/2
+	allows to specify options. tm/0 provides a graphical display
+	of the runing threads.  See source-file.
+
+## Unix services demo:
+
+	$ demo_daemon.pl :
+	Demo script to run the SWI-Prolog HTTP server as a Unix
+	service.
+
+	$ linux-init-script :
+	/etc/init.d script for Debian and Redhat based Unix systems.
+	Must be configured.
+
+	$ upstart-script.conf :
+	Ubuntu `upstart` script.  Must be configured and placed in
+	`/etc/init`
+
+	$ systemd-script.service :
+	Linux `systemd` script.  The typical installation sequence
+	is:
+
+	    cp systemd-script.service demo.service
+	    <edit>
+	    cp demo.service /etc/systemd/system
+	    systemctl enable demo
+	    systemctl start demo
+	    journalctl -f -u demo
+
+## Session management demo:
+
+	$ calc.pl :
+	Multi-threaded server with session management using the
+	html_write.pl library.  See source for usage.
+
+## File serving demo:
+
+	$ demo_files.pl :
+	Is a multi-threaded server that serves static files and
+	directory indices.
+
+## Client demo
+
+	$ demo_client.pl :
+	Simple multi-threaded client to test the server under
+	different conditions.  Requires SWI-Prolog with thread-support.
+	See source for usage.
+
+## HTTP digest authentication
+
+	$ demo_digest.pl :
+	Simple demo showing HTTP digest authentication at work.
+
+## Login and request rewriting
+
+	$ demo_login.pl :
+	Demonstrated using request rewriting and redefining status
+	pages to provide cookie based login with RBAC authorization.
+
+	$ demo_rest.pl :
+	Demonstrates path wildcarts for common REST api routing.
+
+## Performance testing
+
+A very early start of some  routines   to  validate the server platform.
+Eventually, stress_server.pl will serve different   tests  from multiple
+locations  and  stress_client.pl  will  contain    client  code  to  run
+individual tests as well as doing multi-threaded tests.
+
+	$ stress_server.pl :
+	Server platform.
+
+	$ stress_client.pl :
+	Client.
+
+
+
+
+
+
+
+
+
+
+
+
+
+
+

package/lib/swipl/doc/packages/examples/http/calc.pl

@@ -0,0 +1,92 @@
+/*  $Id$
+
+    Part of SWI-Prolog
+
+    Author:        Jan Wielemaker
+    E-mail:        wielemak@science.uva.nl
+    WWW:           http://www.swi-prolog.org
+    Copyright (C): Public domain
+*/
+
+:- use_module(library('http/thread_httpd')).
+:- use_module(library('http/html_write')).
+:- use_module(library('http/http_session')).
+:- use_module(library('http/http_error')).
+
+/* - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
+This demo shows session state  management   in  a very simple calculator
+package. It also demonstrates the use of  the html_write library. To use
+it, start Prolog, load this file and run
+
+        ?- server.
+
+Now direct your browser to http://localhost:3000/
+- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - */
+
+server :-
+    server(3000, []).
+
+server(Port, Options) :-
+    http_server(reply,
+                [ port(Port),
+                  timeout(20)
+                | Options
+                ]).
+
+reply(Request) :-
+    memberchk(path(Path), Request),
+    reply(Path, Request).
+
+reply(/, _Request) :-
+    http_session_retractall(formula(_)),
+    Formula = 0,
+    http_session_assert(formula(Formula)),
+    page(Formula).
+
+reply('/calc', Request) :-
+    memberchk(search(Search), Request),
+    memberchk(operation=Op, Search),
+    memberchk(value=AtomVal, Search),
+    atom_number(AtomVal, Val),
+    http_session_retract(formula(Formula0)),
+    debug(calc, 'Formula0 = ~w', [Formula0]),
+    Formula =.. [Op, Formula0, Val],
+    http_session_assert(formula(Formula)),
+    page(Formula).
+
+
+page(Formula) :-
+    reply_page('HTTP Session DEMO',
+               [ h2('Simple session demo'),
+                 form([ action('/calc'),
+                        method('GET')
+                      ],
+                      table([align(center), border(1)],
+                            [ tr(td(\formula(Formula))),
+                              tr(td([ \ops,
+                                      input([ name(value) ]),
+                                      input([ type(submit),
+                                              value('Calc!')
+                                            ])
+                                    ]))
+                            ]))
+               ]).
+
+formula(Formula) -->
+    { sformat(S, '~w', [Formula]),
+      Value is Formula
+    },
+    html([ S, ' = ', Value ]).
+
+ops -->
+    html(select(name(operation),
+                [ option([selected], +),
+                  option([], -),
+                  option([], /),
+                  option([], *)
+                ])).
+
+reply_page(Title, Content) :-
+    phrase(page(title(Title), Content), HTML),
+    format('Content-type: text/html~n~n'),
+    print_html(HTML).

package/lib/swipl/doc/packages/examples/http/demo_body.pl

@@ -0,0 +1,232 @@
+/*  Part of SWI-Prolog
+
+    Author:        Jan Wielemaker
+    E-mail:        J.Wielemaker@vu.nl
+    WWW:           http://www.swi-prolog.org
+    Copyright (c)  2002-2025, University of Amsterdam
+                              VU University Amsterdam
+                              SWI-Prolog Solutions b.v.
+    All rights reserved.
+
+    Redistribution and use in source and binary forms, with or without
+    modification, are permitted provided that the following conditions
+    are met:
+
+    1. Redistributions of source code must retain the above copyright
+       notice, this list of conditions and the following disclaimer.
+
+    2. Redistributions in binary form must reproduce the above copyright
+       notice, this list of conditions and the following disclaimer in
+       the documentation and/or other materials provided with the
+       distribution.
+
+    THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
+    "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
+    LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
+    FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
+    COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
+    INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
+    BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
+    LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
+    CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
+    LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
+    ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
+    POSSIBILITY OF SUCH DAMAGE.
+*/
+
+:- module(demo_body,
+          [ reply/1
+          ]).
+:- use_module(library(http/http_client)).
+
+:- discontiguous
+    reply/1.
+
+/** <module> Demo implementation of some HTTP handlers
+
+This module implements some HTTP handlers  using rather low-level simple
+primitives. It illustrates the process that HTTP handlers are similar to
+CGI handlers in the sense that they need  to write a CGI document to the
+`current_output` stream.  For high level primitives:
+
+  - More advanced dispatching of requests over predicates that implement
+    them is provided by http_handler/3 from library(http/http_dispatch).
+  - High level HTML is generated with library(http/html_write).
+
+@see    http://www.swi-prolog.org/howto/http/ provides a much better
+        tutorial introduction to the SWI-Prolog HTTP services.
+*/
+
+
+reply(_) :-
+    flag(request, N, N+1),
+    fail.
+
+%       /
+%
+%       Show available locations
+
+reply(Request) :-
+    memberchk(path('/'), Request),
+    !,
+    format('Content-type: text/html~n~n', []),
+    format('<html>~n', []),
+    format('<h1>Some simple demo queries</h1>', []),
+    format('<ul>~n', []),
+    format('  <li><a href="quit">Say bye bye</a>'),
+    format('  <li><a href="env">Print environment</a>'),
+    format('  <li><a href="upload">Upload some data</a>'),
+    format('  <li><a href="xml">Reply with an XML document</a>'),
+    format('  <li><a href="foreign">Reply Chinese characters</a>'),
+    format('  <li><a href="work">Work hard for a while</a>'),
+    format('  <li><a href="error">Show what happens on an error</a>'),
+    format('  <li><a href="xpce?class=box">Return image (requires xpce)</a>'),
+    format('  <li><a href="otherwise">Otherwise, print request</a>'),
+    format('</ul>~n', []),
+    format('</html>~n', []).
+
+%       /quit
+%
+%       Explicitely close the connection
+
+reply(Request) :-
+    member(path('/quit'), Request),
+    !,
+    format('Connection: close~n', []),
+    format('Content-type: text/html~n~n', []),
+    format('Bye Bye~n').
+
+%       /env
+%
+%       Reply with the output of printenv (Unix systems only).
+
+reply(Request) :-
+    member(path('/env'), Request),
+    !,
+    expand_file_name(~, Home),
+    format('Content-type: text/html~n~n', []),
+    format('<html>~n', []),
+    flag(request, RN, RN),
+    format('Request ~d~n', [RN]),
+    format('<pre>~n', []),
+    format('HOME = ~w~n~n', [Home]),
+    open(pipe(printenv), read, Fd),
+    copy_stream_data(Fd, current_output),
+    close(Fd),
+    format('</pre>~n', []),
+    format('</html>~n', []).
+
+%       /upload
+%       /upload_reply
+%
+%       Provide a form for uploading a file, and deal with the resulting
+%       upload.  Contributed by Nicos Angelopoulos.
+
+reply(Request) :-
+    member(path('/upload'), Request),
+    !,
+    format('Content-type: text/html~n~n', []),
+    format('<html>~n', []),
+    format('<form action="/upload_reply" enctype="multipart/form-data" method="post">~n', []),
+    format('<input type="file" name="datafile">'),
+    format('<input type="submit" name="sent">'),
+    format('</body>~n', []),
+    format('</html>~n', []).
+
+reply(Request) :-
+    member(path('/upload_reply'), Request),
+    !,
+    format('Content-type: text/html~n~n', []),
+    format('<html>~n', []),
+    format('<pre>~n', []),
+    write( req(Request) ), nl,
+    http_read_data(Request, Data, []),
+    write( data(Data) ), nl,
+    format('</pre>'),
+    format('</body>~n', []),
+    format('</html>~n', []).
+
+%       /xml
+%
+%       Return a simple formatted XML message.
+
+reply(Request) :-
+    member(path('/xml'), Request),
+    !,
+    format('Content-type: text/xml~n~n', []),
+    format('\c
+<message>
+  <head>
+  <from>Jan Wielemaker</from>
+  <to>Prolog users</to>
+  <subject>The SWI-Prolog web-server</subject>
+  </head>
+  <body>
+<p>
+This is the first demo of the web-server serving an XML message
+</p>
+  </body>
+</message>
+', []).
+
+%       /foreign
+%
+%       Test emitting text using UTF-8 encoding
+
+reply(Request) :-
+    member(path('/foreign'), Request),
+    !,
+    format('Content-type: text/html~n~n', []),
+    format('\c
+<html>
+<head><title>Foreign characters</title></head>
+<body>
+<p>Chinese for book is \u5b66\u4e60
+</body>
+</html>
+').
+
+
+%       /work
+%
+%       Do a lot of work and then say 'ok'. Can be used to test
+%       concurrent access using the multi-threaded server.
+
+reply(Request) :-
+    member(path('/work'), Request),
+    format(user_error, 'Starting work ...', []),
+    forall(between(1, 10000000, _), atom_codes(_, "hello")),
+    format(user_error, 'done!~n', []),
+    format('Content-type: text/plain~n~n', []),
+    format('ok~n').
+
+%       /error
+%
+%       Produce an error.  Load http_error to see the effect.
+
+reply(Request) :-
+    member(path('/error'), Request),
+    A is 1/0,
+    format('Content-type: text/plain~n~n', []),
+    format('A = ~w~n', [A]).
+
+%       ... Otherwise
+%
+%       Print the request itself.
+
+reply(Request) :-
+    format('Content-type: text/html~n~n', []),
+    format('<html>~n', []),
+    format('<table border=1>~n'),
+    print_request(Request),
+    format('~n</table>~n'),
+    format('</html>~n', []).
+
+print_request([]).
+print_request([H|T]) :-
+    H =.. [Name, Value],
+    format('<tr><td>~w<td>~w~n', [Name, Value]),
+    print_request(T).
+
+
+