kibi-swipl-linux-x64-gnu 1.0.0

package/lib/swipl/library/ext/clib/streaminfo.pl

@@ -0,0 +1,103 @@
+/*  Part of SWI-Prolog
+
+    Author:        Jan Wielemaker
+    E-mail:        J.Wielemaker@vu.nl
+    WWW:           http://www.swi-prolog.org
+    Copyright (c)  2009-2020, University of Amsterdam
+                              CWI, Amsterdam
+    All rights reserved.
+
+    Redistribution and use in source and binary forms, with or without
+    modification, are permitted provided that the following conditions
+    are met:
+
+    1. Redistributions of source code must retain the above copyright
+       notice, this list of conditions and the following disclaimer.
+
+    2. Redistributions in binary form must reproduce the above copyright
+       notice, this list of conditions and the following disclaimer in
+       the documentation and/or other materials provided with the
+       distribution.
+
+    THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
+    "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
+    LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
+    FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
+    COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
+    INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
+    BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
+    LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
+    CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
+    LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
+    ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
+    POSSIBILITY OF SUCH DAMAGE.
+*/
+
+:- module(stream_info,
+          [ stream_info/1               % +Stream
+          ]).
+:- autoload(library(error),[existence_error/2]).
+:- autoload(library(lists),[member/2]).
+
+:- use_foreign_library(foreign(streaminfo)).
+
+%!  stream_info(+Stream) is det.
+%
+%   Print detailed information about a stream   or  a file-number to
+%   the error output. The  output  of   this  command  is  meant for
+%   experts and requires  knowledge  about   the  implementation  of
+%   streams. It has been  added  to   diagnose  leaking  streams  in
+%   web-servers. For example,  on  linux   systems  we  can  examine
+%   process file-descriptors using
+%
+%   ==
+%   % ls -l /proc/<pid>/fd
+%   ==
+%
+%   If now (say) descriptor 15 is open   where  it should not be, we
+%   can this command to find the associated Prolog streams and print
+%   as mush as possible information about the stream.
+%
+%   ==
+%   ?- stream_info(15).
+%   ==
+%
+%   @param  Stream  A stream-handle, alias name, (integer) system
+%           file handle or `'<stream>(address)'` atom.
+
+stream_info(Stream) :-
+    is_stream(Stream),
+    !,
+    forall(stream_property(Stream, P),
+           print_property(P)),
+    nl,
+    catch('$stream_info'(current_output, Stream), E, true),
+    (   nonvar(E)
+    ->  format('~w:~t~25|~q~n', ['pending exception', E])
+    ;   true
+    ).
+stream_info(FileNo) :-
+    integer(FileNo),
+    !,
+    findall(S, stream_property(S, file_no(FileNo)), Streams),
+    length(Streams, Len),
+    format('File no ~w is connected to ~d streams~n', [FileNo, Len]),
+    forall(member(Stream, Streams),
+           (   format('****************~nStream ~p:~n', [Stream]),
+               stream_info(Stream))).
+stream_info(Atom) :-
+    atom(Atom),
+    (   stream_property(Stream, type(_)),
+        format(atom(Atom), '~p', [Stream])
+    ->  stream_info(Stream)
+    ;   existence_error(stream, Atom)
+    ).
+
+print_property(P) :-
+    P =.. [Name,Value],
+    !,
+    format('~w:~t~25|~q~n', [Name, Value]).
+print_property(input) :- !.
+print_property(output) :- !.
+print_property(P) :-
+    format('~p~n', [P]).

package/lib/swipl/library/ext/clib/streampool.pl

@@ -0,0 +1,136 @@
+/*  Part of SWI-Prolog
+
+    Author:        Jan Wielemaker
+    E-mail:        J.Wielemaker@vu.nl
+    WWW:           http://www.swi-prolog.org
+    Copyright (c)  2002-2018, University of Amsterdam
+                              CWI, Amsterdam
+    All rights reserved.
+
+    Redistribution and use in source and binary forms, with or without
+    modification, are permitted provided that the following conditions
+    are met:
+
+    1. Redistributions of source code must retain the above copyright
+       notice, this list of conditions and the following disclaimer.
+
+    2. Redistributions in binary form must reproduce the above copyright
+       notice, this list of conditions and the following disclaimer in
+       the documentation and/or other materials provided with the
+       distribution.
+
+    THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
+    "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
+    LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
+    FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
+    COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
+    INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
+    BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
+    LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
+    CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
+    LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
+    ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
+    POSSIBILITY OF SUCH DAMAGE.
+*/
+
+:- module(stream_pool,
+          [ add_stream_to_pool/2,       % +Stream, :Goal
+            delete_stream_from_pool/1,  % +Stream
+            close_stream_pool/0,
+            dispatch_stream_pool/1,     % +TimeOut
+            stream_pool_main_loop/0
+          ]).
+:- use_module(library(debug),[debug/3]).
+
+:- meta_predicate
+    add_stream_to_pool(+, 0).
+
+:- volatile
+    pool/2.                         % sockets don't survive a saved-state
+:- dynamic
+    pool/2.                         % Stream, Action
+
+/** <module> Input multiplexing
+
+This libary allows a single thread to  monitor multiple streams and call
+a goal if input is available on a stream.
+
+@bug Note that if the processing   predicate blocks other input channals
+are not processed. This may happen, for example, if a read/2 call blocks
+due to incomplete input.
+*/
+
+%!   add_stream_to_pool(+Stream :Goal)
+%
+%    Call Goal whenever there is input on Stream.
+
+add_stream_to_pool(Stream, Action) :-
+    strip_module(Action, Module, Plain),
+    register_stream(Stream, Module:Plain).
+
+register_stream(Stream, Goal) :-
+    assert(pool(Stream, Goal)).
+
+%!  delete_stream_from_pool(+Stream)
+%
+%   Retract stream from the pool
+
+delete_stream_from_pool(Stream) :-
+    retractall(pool(Stream, _)).
+
+%!  close_stream_pool
+%
+%   Close all streams in the   pool. This causes stream_pool_main_loop/0
+%   to terminate.
+
+close_stream_pool :-
+    forall(retract(pool(Stream, _)),
+           close(Stream, [force(true)])).
+
+%!  dispatch_stream_pool(+TimeOut)
+%
+%   Wait for input on one or more streams   and handle that. Wait for at
+%   most TimeOut seconds (0 means infinite).
+
+dispatch_stream_pool(Timeout) :-
+    findall(S, pool(S, _), Pool),
+    debug(tcp, 'Select ~p ...', [Pool]),
+    catch(wait_for_input(Pool, Ready, Timeout), E, true),
+    debug(tcp, '    --> ~p (E=~p)', [Ready, E]),
+    (   var(E)
+    ->  actions(Ready)
+    ;   E = error(existence_error(stream, Stream), _)
+    ->  delete_stream_from_pool(Stream)
+    ).
+
+actions([]).
+actions([H|T]) :-
+    action(H),
+    actions(T).
+
+action(Stream) :-
+    pool(Stream, Action),
+    (   catch(Action, E, true)
+    ->  (   var(E)
+        ->  true
+        ;   print_message(error, E)
+        )
+    ;   print_message(warning,
+                      goal_failed(Action, stream_pool))
+    ).
+
+%!  stream_pool_main_loop
+%
+%   Keep handling input from the streams in the pool until they have all
+%   died away.
+
+stream_pool_main_loop :-
+    pool(_, _),
+    !,
+    (   current_prolog_flag(windows, true)
+    ->  dispatch_stream_pool(1)     % so we can break out easily
+    ;   dispatch_stream_pool(0)
+    ),
+    stream_pool_main_loop.
+stream_pool_main_loop.
+

package/lib/swipl/library/ext/clib/syslog.pl

@@ -0,0 +1,180 @@
+/*  Part of SWI-Prolog
+
+    Author:        Jan Wielemaker
+    E-mail:        J.Wielemaker@vu.nl
+    WWW:           http://www.swi-prolog.org
+    Copyright (c)  2013-2020, VU University Amsterdam
+                              CWI Amsterdam
+    All rights reserved.
+
+    Redistribution and use in source and binary forms, with or without
+    modification, are permitted provided that the following conditions
+    are met:
+
+    1. Redistributions of source code must retain the above copyright
+       notice, this list of conditions and the following disclaimer.
+
+    2. Redistributions in binary form must reproduce the above copyright
+       notice, this list of conditions and the following disclaimer in
+       the documentation and/or other materials provided with the
+       distribution.
+
+    THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
+    "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
+    LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
+    FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
+    COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
+    INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
+    BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
+    LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
+    CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
+    LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
+    ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
+    POSSIBILITY OF SUCH DAMAGE.
+*/
+
+:- module(syslog,
+          [ openlog/3,                  % +Ident, +Options, +Facility
+            syslog/2,                   % +Priority, +Message
+            syslog/3,                   % +Priority, +Format, +Args
+            closelog/0
+          ]).
+:- autoload(library(lists),[member/2]).
+
+/** <module> Unix syslog interface
+
+This library provides an interface to   the  Unix syslog() facility. The
+interface is an almost direct translation of  the POSIX syslog API, with
+two additions:
+
+  - syslog/3 exploits format/3 to format syslog messages
+  - The library integrates into library(debug) using
+    prolog:debug_print_hook/3, where debug _topics_ are mapped to
+    syslog _priorities_ and remaining debug _topics_ are mapped
+    to the syslog _priority_ =debug=.
+
+Note that this interface  makes  no   attempt  to  abstract over logging
+facilities of operating systems. We expect   that such abstractions will
+be implemented at the Prolog  level   using  multiple  integrations into
+library(debug).
+
+@see    detach_IO/1 to detach normal I/O of the process and remove it
+        from the process group.
+@see    fork/1 to create a daemon process.
+@see    library(uid) to manage user identifiers (e.g., drop root
+        privileges).
+*/
+
+:- use_foreign_library(foreign(syslog)).
+
+:- dynamic syslog/1.
+
+%!  openlog(+Ident:atom, +Options:list(atom), +Facility:atom) is det.
+%
+%   Open system log. This predicate provides a direct interface into
+%   the openlog() library call. If the   library call is successful,
+%   it runs at_halt(closelog) to ensure closing   the  system log on
+%   clean exit.
+%
+%   @param  Ident prepended to every message, and is typically set
+%           to the program name.
+%   @param  Options is a list of options.  Values are corresponding
+%           C options, after removing =LOG_= and translation to
+%           lower case: =cons=, =ndelay=, =nowait=, =odelay=,
+%           =perror=, =pid=.
+%   @param  Facility is one of =auth=, =authpriv=, =cron=, =daemon=,
+%           =ftp=, =kern=, =local0= ... =local7=, =lpr=, =mail=,
+%           =news=, =syslog=, =user= or =uucp=.
+
+openlog(Ident, Options, Facility) :-
+    '$openlog'(Ident, Options, Facility),
+    asserta(syslog(Ident)),
+    at_halt(closelog).
+
+%!  syslog(+Priority, +Message) is det.
+%
+%   Send a message to the system  log. Note that syslog/2 implicitly
+%   opens a connection to the system log   if  such a connection has
+%   not been opened explicitly using openlog/3.
+%
+%   @param  Priority is one of =emerg=, =alert=, =crit=, =err=,
+%           =warning=, =notice=, =info= or =debug=.
+
+%!  syslog(+Priority, +Format, +Args) is det.
+%
+%   Send a formatted message to the system  log if system logging is
+%   opened using openlog/3. This predicate   combined  format/3 with
+%   syslog/2. If there is no open  syslog connection, syslog/3 calls
+%   print_message/2.
+
+syslog(Priority, Format, Args) :-
+    syslog(_),
+    !,
+    format(string(Msg), Format, Args),
+    syslog(Priority, Msg).
+syslog(Priority, Format, Args) :-
+    syslog_priority(Priority, Kind),
+    print_message(Kind, format(Format, Args)).
+
+%!  closelog is det.
+%
+%   Close the system log.
+
+closelog :-
+    retractall(syslog(_)),
+    '$closelog'.
+
+
+                 /*******************************
+                 *     DEBUG INTEGRATION        *
+                 *******************************/
+
+:- multifile
+    prolog:debug_print_hook/3.
+
+%!  prolog:debug_print_hook(+Topic, +Format, +Args) is semidet.
+%
+%   Integration of debug/3 with the syslog   facility.  If syslog is
+%   enabled, debug/3 is re-routed to use   the syslog facilities. If
+%   the _topic_ of the  debug  message   matches  one  of  the sylog
+%   _priority_ values (see syslog/2), the message   is sent with the
+%   corresponding syslog priority. Otherwise  it   it  sent with the
+%   =debug= priority.
+
+prolog:debug_print_hook(Topic, Format, Args) :-
+    syslog(_),
+    debug_priority(Topic, Priority),
+    syslog(Priority, Format, Args).
+
+debug_priority(Topic, Priority) :-
+    (   syslog_priority(Topic, _Kind)
+    ->  Priority = Topic
+    ;   Priority = debug
+    ).
+
+syslog_priority(emerg,   error).
+syslog_priority(alert,   warning).
+syslog_priority(crit,    error).
+syslog_priority(err,     error).
+syslog_priority(warning, warning).
+syslog_priority(notice,  informational).
+syslog_priority(info,    informational).
+syslog_priority(debug,   debug).
+
+
+                 /*******************************
+                 *      MESSAGE INTEGRATION     *
+                 *******************************/
+
+user:message_hook(Term, Kind, _) :-
+    syslog(_),
+    kind_syslog_priority(Kind, Level),
+    message_to_string(Term, Message),
+    atomic_list_concat(Lines, '\n', Message),
+    forall(member(Line, Lines),
+           syslog(Level, Line)),
+    fail.
+
+kind_syslog_priority(error,         err).
+kind_syslog_priority(warning,       warning).
+kind_syslog_priority(informational, info).

package/lib/swipl/library/ext/clib/time.pl

@@ -0,0 +1,194 @@
+/*  Part of SWI-Prolog
+
+    Author:        Jan Wielemaker
+    E-mail:        J.Wielemaker@vu.nl
+    WWW:           http://www.swi-prolog.org
+    Copyright (c)  2002-2023, University of Amsterdam
+                              VU University Amsterdam
+                              CWI, Amsterdam
+                              SWI-Prolog Solutions b.v.
+    All rights reserved.
+
+    Redistribution and use in source and binary forms, with or without
+    modification, are permitted provided that the following conditions
+    are met:
+
+    1. Redistributions of source code must retain the above copyright
+       notice, this list of conditions and the following disclaimer.
+
+    2. Redistributions in binary form must reproduce the above copyright
+       notice, this list of conditions and the following disclaimer in
+       the documentation and/or other materials provided with the
+       distribution.
+
+    THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
+    "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
+    LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
+    FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
+    COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
+    INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
+    BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
+    LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
+    CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
+    LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
+    ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
+    POSSIBILITY OF SUCH DAMAGE.
+*/
+
+:- module(time,
+          [ alarm/3,                    % +Time, :Callable, -Id
+            alarm/4,                    % +Time, :Callable, -Id, +Options
+            alarm_at/3,                 % +Time, :Callable, -Id
+            alarm_at/4,                 % +Time, :Callable, -Id, +Options
+            remove_alarm/1,             % +Id
+            install_alarm/1,            % +Id
+            install_alarm/2,            % +Id, +Time
+            uninstall_alarm/1,          % +Id
+            current_alarm/4,            % ?At, ?:Goal, ?Id, ?Status
+            call_with_time_limit/2,     % +Time, :Callable
+            call_with_time_limit/3      % +Time, :Callable, +Context
+          ]).
+:- autoload(library(lists),[member/2]).
+
+:- set_prolog_flag(generate_debug_info, false).
+
+:- meta_predicate
+    call_with_time_limit(+, 0),
+    call_with_time_limit(+, 0, +),
+    alarm(+, 0, -),
+    alarm(+, 0, -, +),
+    alarm_at(+, 0, -, +),
+    current_alarm(?, :, ?, ?).
+
+:- predicate_options(alarm/4, 4,
+                     [ remove(boolean),
+                       install(boolean)
+                     ]).
+
+
+/** <module> Time and alarm library
+
+The library(time) provides timing and alarm functions. Alarms are
+thread-specific, i.e., creating an alarm causes the alarm goal to be
+called in the thread that created it. The predicate current_alarm/4 only
+reports alarms that are related to the calling thread. If a thread
+terminates, all remaining alarms are silently removed. Most applications
+use call_with_time_limit/2.
+*/
+
+%!  alarm(+Time, :Callable, -Id) is det.
+%!  alarm(+Time, :Callable, -Id, +Options) is det.
+%
+%   Set up an alarm to be  signaled   Time  seconds from now. If the
+%   alarm expires, Callable is called   asynchronously. Callable can
+%   be used to raise  an  exception   using  throw/1  to  abort some
+%   execution.
+%
+%   Options is a list of Name(Value) options.  Currently defined
+%   options are:
+%
+%           * remove(Bool)
+%           If =true= (default =false=), remove the alarm-event (as
+%           remove_alarm/1) after it has been fired.
+%           * install(Bool)
+%           If =false= (default =true=) do not install the alarm.
+%           It must be installed separately using install_alarm/1.
+
+%!  alarm_at(+Time, :Callable, -Id) is det.
+%!  alarm_at(+Time, :Callable, -Id, +Options) is det.
+%
+%   As alarm/3 and alarm/4, but schedule   the  alarm at an absolute
+%   point in time.
+%
+%   @see date_time_stamp/2.
+
+%!  install_alarm(+Id) is det.
+%!  install_alarm(+Id, +RelTime) is det.
+%
+%   Install an alarm allocated using alarm/4 with the install(false)
+%   option or de-activated using  uninstall_alarm/1.   With  a given
+%   RelTime, the alarm  is  scheduled  at   the  RelTime  from  now.
+%   Otherwise it is scheduled on the   same (absolute) time on which
+%   is was created.
+
+%!  uninstall_alarm(+Id) is det.
+%
+%   De-activate an alarm. This does _not_ invalidate Id, but ensures
+%   that the alarm will not fire. The alarm can be rescheduled to
+%   the original time using install_alarm/1 or to a new time using
+%   install_alarm/2.
+
+%!  remove_alarm(+Id) is det.
+%
+%   Remove an alarm.  If it has not yet been fired, it never will.
+
+%!  current_alarm(?Time, :Goal, ?Id, ?Status) is nondet.
+%
+%   Enumerate the alarms in the schedule.  Time is the absolute time
+%   the event is scheduled for (see   also  get_time/1). Goal is the
+%   goal to execute,  Id  is  the   identifier  and  Status  is  the
+%   scheduling status. It takes the value   =done=  if the alarm has
+%   been fired, =next= if the event is   the next to be executed and
+%   =scheduled= otherwise.
+
+:- use_foreign_library(foreign(time)).
+:- public time_debug/1.                 % set debugging
+
+%!  call_with_time_limit(+Time, :Goal) is det.
+%!  call_with_time_limit(+Time, :Goal, +Context) is det.
+%
+%   Call Goal, while watching out for a (wall-time) limit. If this limit
+%   is  exceeded,  the  exception    `time_limit_exceeded`   is  raised.
+%   call_with_time_limit/3 throws time_limit_exceeded(Context).  Goal is
+%   called as in once/1.
+%
+%   @throws `time_limit_exceeded` (call_with_time_limit/2) or
+%   time_limit_exceeded(Context) (call_with_time_limit/3).
+
+call_with_time_limit(Time, Goal) :-
+    call_with_time_limit(Time, Goal, '$no_ctx').
+
+call_with_time_limit(Time, Goal, Ctx) :-
+    Time > 0,
+    !,
+    setup_call_cleanup(alarm(Time, time_limit_exceeded(Time, Ctx),
+                             Id, [install(false)]),
+                       run_alarm_goal(Id, Goal),
+                       remove_alarm_notrace(Id)).
+call_with_time_limit(_Time, _Goal, _Ctx) :-
+    throw(time_limit_exceeded).
+
+run_alarm_goal(AlarmID, Goal) :-
+    install_alarm(AlarmID),
+    Goal,
+    !.
+
+time_limit_exceeded(_Time, Ctx) :-
+    (   Ctx == '$no_ctx'
+    ->  throw(time_limit_exceeded)
+    ;   throw(time_limit_exceeded(Ctx))
+    ).
+
+current_alarm(Time, Goal, Id, Status) :-
+    current_alarms(Time, Goal, Id, Status, List),
+    member(alarm(Time, Goal, Id, Status), List).
+
+                 /*******************************
+                 *        HANDLE MESSAGES       *
+                 *******************************/
+
+:- multifile
+    prolog:message/3.
+
+prolog:message(time_limit_exceeded) -->
+    [ 'Time limit exceeded' ].
+prolog:message(time_limit_exceeded(Context)) -->
+    [ 'Time limit exceeded: ~p'-[Context] ].
+
+                 /*******************************
+                 *             ALARM            *
+                 *******************************/
+
+:- multifile sandbox:safe_meta_predicate/1.
+
+sandbox:safe_meta_predicate(time:call_with_time_limit/2).