kibi-swipl-linux-x64-gnu 1.0.0

package/lib/swipl/library/writef.pl

@@ -0,0 +1,278 @@
+/*  Part of SWI-Prolog
+
+    Author:        Jan Wielemaker
+    E-mail:        J.Wielemaker@vu.nl
+    WWW:           http://www.swi-prolog.org
+    Copyright (c)  2011-2013, University of Amsterdam
+                              VU University Amsterdam
+    All rights reserved.
+
+    Redistribution and use in source and binary forms, with or without
+    modification, are permitted provided that the following conditions
+    are met:
+
+    1. Redistributions of source code must retain the above copyright
+       notice, this list of conditions and the following disclaimer.
+
+    2. Redistributions in binary form must reproduce the above copyright
+       notice, this list of conditions and the following disclaimer in
+       the documentation and/or other materials provided with the
+       distribution.
+
+    THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
+    "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
+    LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
+    FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
+    COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
+    INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
+    BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
+    LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
+    CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
+    LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
+    ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
+    POSSIBILITY OF SUCH DAMAGE.
+*/
+
+:- module(writef,
+          [ writef/1,                   % +Format
+            writef/2,                   % +Format, +Args
+            swritef/2,                  % -String, +Format
+            swritef/3                   % -String, +Format, +Args
+          ]).
+:- set_prolog_flag(generate_debug_info, false).
+
+/** <module> Old-style formatted write
+
+This library provides writef/1 and   friends. These predicates originate
+from Edinburgh C-Prolog and and provided for compatibility purposes. New
+code should use format/1, format/2  and   friends,  which  are currently
+supported by more Prolog implementations.
+
+The   writef-family   of   predicates   conflicts    with   the   modern
+_|character-esacapes|_ flag about  the   interpretation  of \-sequences.
+This can be avoided by
+
+  1. Disable character escapes (not recommended unless one wants to
+  run really outdated code unmodified).
+  2. Double the \ for conflicting interpretations
+  3. Use ISO compliant alternatives for conflicting interpretations
+
+@copyright      Copied from Edinburgh C-Prolog. Original version by Byrd,
+                changed many times since.
+*/
+
+%!  writef(+Format) is det.
+%!  writef(+Format, +Arguments) is det.
+%
+%   Formatted write to the  =current_output=.   Format  is  a format
+%   specifier. Some escape sequences require  arguments that must be
+%   provided in the list Arguments. There   are  two types of escape
+%   sequences: special characters  start  with   =|\|=  and  include
+%   arguments start with =|%|=. The special character sequences are:
+%
+%       | =|\n|= | Output a newline character |
+%       | =|\l|= | Output a line separator (same as =|\n|=) |
+%       | =|\r|= | Output a carriage-return character (ASCII 13) |
+%       | =|\r|= | Output a TAB character (ASCII 9) |
+%       | =|\\|= | Output =|\|= |
+%       | =|\%|= | Output =|%|= |
+%       | =|\nnn|= | Output character <nnn>. <nnn> is a 1-3 decimal number |
+%
+%   Escape sequences to include arguments  from Arguments. Each time
+%   a %-escape sequence is found in   Format  the next argument from
+%   Arguments is formatted according to the specification.
+%
+%       | =|%t|= | print/1 the next item (mnemonic: term) |
+%       | =|%w|= | write/1 the next item |
+%       | =|%q|= | writeq/1 the next item  |
+%       | =|%d|= | display/1 the next item |
+%       | =|%n|= | Put the next item as a character |
+%       | =|%r|= | Write the next item N times where N is the second item (an integer) |
+%       | =|%s|= | Write the next item as a String (so it must be a list of characters) |
+%       | =|%f|= |Perform a ttyflush/0 (no items used) |
+%       | =|%Nc|= | Write the next item Centered in N columns. |
+%       | =|%Nl|= | Write the next item Left justified in N columns. |
+%       | =|%Nr|= | Write the next item Right justified in N columns. |
+%
+%   @deprecated New code should use format/1, format/2, etc.
+
+writef(Format) :-
+    writef(Format, []).
+
+writef([F|String], List) :-
+    '$writefs'([F|String], List),
+    fail.                           % clean up global stack
+writef(String, List) :-
+    string(String),
+    string_codes(String, Fstring),
+    '$writefs'(Fstring, List),
+    fail.                           % clean up global stack
+writef(Format, List) :-
+    atom(Format),
+    name(Format, Fstring),
+    '$writefs'(Fstring, List),
+    fail.                           % clean up global stack
+writef(_, _).
+
+%!  swritef(-String, +Format) is det.
+%!  swritef(-String, +Format, +Arguments) is det.
+%
+%   Use writef/1 or writef/2 and  write   the  result to a _string_.
+%   Note that this is a  string   in  the sense of string_codes/2,
+%   _not_ a list of character(-code)s.
+%
+%   @deprecated.  See format/2,3 and/or with_output_to/2.
+
+swritef(String, Format, Arguments) :-
+    with_output_to(string(String), writef(Format, Arguments)).
+swritef(String, Format) :-
+    with_output_to(string(String), writef(Format)).
+
+                        % Formatted write for a string (i.e. a list of
+                        % character codes).
+
+'$writefs'([], _).
+'$writefs'([0'%, A|Rest], List) :-      %   %<$action'>
+    '$action'(A, List, More),
+    !,
+    '$writefs'(Rest, More).
+'$writefs'([0'%, D|Rest], [Head|Tail]) :-       %   %<columns><just>
+    between(0'0, 0'9, D),
+    '$getpad'(Size, Just, [D|Rest], More),
+    !,
+    '$padout'(Head, Size, Just),
+    '$writefs'(More, Tail).
+'$writefs'([0'\\, C|Rest], List) :-     %   \<special>
+    '$special'(C, Char),
+    !,
+    put(Char),
+    '$writefs'(Rest, List).
+'$writefs'([0'\\|Rest], List) :-        %   \<character code in decimal>
+    '$getcode'(Char, Rest, More),
+    !,
+    put(Char),
+    '$writefs'(More, List).
+'$writefs'([Char|Rest], List) :-        %   <ordinary character>
+    put(Char),
+    '$writefs'(Rest, List).
+
+
+'$action'(0't, [Head|Tail], Tail) :-    %   Term
+    print(Head).
+'$action'(0'd, [Head|Tail], Tail) :-    %   Display
+    write_canonical(Head).
+'$action'(0'w, [Head|Tail], Tail) :-    %   Write
+    write(Head).
+'$action'(0'q, [Head|Tail], Tail) :-    %   Quoted
+    writeq(Head).
+'$action'(0'p,  [Head|Tail], Tail) :-   %   Print
+    print(Head).
+'$action'(0'f, List, List) :-           %   Flush
+    ttyflush.
+'$action'(0'n, [Char|Tail], Tail) :-    %   iNteger (character)
+    put(Char).
+'$action'(0'r, [Thing, Times|Tail], Tail) :-    %   Repeatedly
+    '$writelots'(Times, Thing).
+'$action'(0's, [Head|Tail], Tail) :-    %   String
+    '$padout'(Head).
+
+'$special'(0'n, 10).            /*  n  */
+'$special'(0'l, 10).            /*  l  */
+'$special'(0'r, 10).            /*  r  */
+'$special'(0't,  9).            /*  t  */
+'$special'(0'\\, 0'\\).         /*  \  */
+'$special'(0'%, 0'%).           /*  %  */
+
+'$getcode'(Char, In, Out) :-
+    '$getdigits'(3, Digits, In, Out),
+    Digits = [_|_],
+    name(Char, Digits),
+    Char < 128.
+
+'$getdigits'(Limit, [Digit|Digits], [Digit|Out0], Out) :-
+    Limit > 0,
+    between(0'0, 0'9, Digit),
+    Fewer is Limit - 1,
+    !,
+    '$getdigits'(Fewer, Digits, Out0, Out).
+'$getdigits'(_, [], Out, Out).
+
+'$writelots'(N, T) :-
+    N > 0,
+    !,
+    write(T),
+    M is N - 1,
+    '$writelots'(M, T).
+'$writelots'(_, _).
+
+/*  The new formats are %nC, %nL, and %nR for centered, left, and right
+    justified output of atoms, integers, and strings.  This is meant to
+    simplify the production of tabular output when it is appropriate.
+    At least one space will always precede/follow the item written.
+*/
+
+'$getpad'(Size, Just, In, Out) :-
+    '$getdigits'(3, Digits, In, [Out1|Out]),
+    name(Size, Digits),
+    '$getpad'(Out1, Just).
+
+'$getpad'(0'r, r).              %  right justified
+'$getpad'(0'l, l).              %  left justified
+'$getpad'(0'c, c).              %  centered
+'$getpad'(0'R, r).              %  right justified
+'$getpad'(0'L, l).              %  left justified
+'$getpad'(0'C, c).              %  centered
+
+
+                                %   '$padout'(A, S, J) writes the item A in a
+                                %   field of S or more characters, Justified.
+
+'$padout'(String, Size, Just) :-
+    '$string'(String),
+    !,
+    name(Atom, String),
+    '$padout'(Atom, Size, Just).
+'$padout'(Term, Size, Just) :-
+    format(string(String), '~w', [Term]),
+    atom_length(String, Length),
+    '$padout'(Just, Size, Length, Left, Right),
+    tab(Left),
+    write(String),
+    tab(Right).
+
+'$string'(0) :- !, fail.
+'$string'([]) :- !.
+'$string'([H|T]) :-
+    '$print'(H),
+    !,
+    '$string'(T).
+
+'$print'(10).                   % newline
+'$print'(9).                    % tab
+'$print'(X) :-
+    integer(X),
+    between(32, 0'~, X).
+
+
+                                %   '$padout'(Just, Size, Length, Left, Right)
+                                %   calculates the number of spaces to put
+                                %   on the Left and Right of an item needing
+                                %   Length characters in a field of Size.
+
+'$padout'(l, Size, Length, 0, Right) :-
+    !,
+    Right is max(1, Size-Length).
+'$padout'(r, Size, Length, Left, 0) :-
+    !,
+    Left is max(1, Size-Length).
+'$padout'(c, Size, Length, Left, Right) :-
+    Left is max(1, round((Size - Length)/2)),
+    Right is max(1, Size - Length - Left).
+
+                                %   '$padout'(Str) writes a string.
+
+'$padout'([Head|Tail]) :-
+    !,
+    put(Head),
+    '$padout'(Tail).
+'$padout'([]).

package/lib/swipl/library/www_browser.pl

@@ -0,0 +1,251 @@
+/*  Part of SWI-Prolog
+
+    Author:        Jan Wielemaker
+    E-mail:        J.Wielemaker@vu.nl
+    WWW:           http://www.swi-prolog.org
+    Copyright (c)  2006-2015, University of Amsterdam
+                              VU University Amsterdam
+    All rights reserved.
+
+    Redistribution and use in source and binary forms, with or without
+    modification, are permitted provided that the following conditions
+    are met:
+
+    1. Redistributions of source code must retain the above copyright
+       notice, this list of conditions and the following disclaimer.
+
+    2. Redistributions in binary form must reproduce the above copyright
+       notice, this list of conditions and the following disclaimer in
+       the documentation and/or other materials provided with the
+       distribution.
+
+    THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
+    "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
+    LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
+    FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
+    COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
+    INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
+    BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
+    LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
+    CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
+    LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
+    ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
+    POSSIBILITY OF SUCH DAMAGE.
+*/
+
+:- module(www_browser,
+          [ www_open_url/1,             % +UrlOrSpec
+            expand_url_path/2           % +Spec, -URL
+          ]).
+:- autoload(library(lists),[member/2]).
+
+:- if(exists_source(library(process))).
+:- autoload(library(process), [process_create/3]).
+:- endif.
+
+:- multifile
+    known_browser/2.
+
+/** <module> Open a URL in the users browser
+
+This library deals with the highly platform   specific task of opening a
+web  page.  In  addition,   is   provides    a   mechanism   similar  to
+absolute_file_name/3 that expands compound terms   to concrete URLs. For
+example, the SWI-Prolog home page can be opened using:
+
+  ==
+  ?- www_open_url(swipl(.)).
+  ==
+*/
+
+%!  www_open_url(+Url)
+%
+%   Open URL in running version of the users' browser or start a new
+%   browser.  This predicate tries the following steps:
+%
+%     1. If a prolog flag (see set_prolog_flag/2) =browser= is set
+%     and this is the name of a known executable, use this.  The
+%     flag may be set to `Command-Mode`, where mode is one of `fg`
+%     or `bg`, requesting Command to run in foreground or background
+%     mode.  Default is `bg`.
+%
+%     2. On Windows, use win_shell(open, URL)
+%
+%     3. Find a generic `open' comment.  Candidates are =xdg-open=,
+%     =open= or =|gnome-open|=.
+%
+%     4. If a environment variable =BROWSER= is set
+%     and this is the name of a known executable, use this.
+%
+%     5. Try to find a known browser.
+%
+%     @tbd  Figure out the right tool in step 3 as it is not
+%           uncommon that multiple are installed.
+
+www_open_url(Spec) :-                   % user configured
+    expand_url_path(Spec, URL),
+    open_url(URL).
+
+open_url(URL) :-
+    current_prolog_flag(browser, Browser),
+    expand_browser_flag(Browser, Command, Mode),
+    has_command(Command),
+    !,
+    run_command(Command, [URL], Mode).
+:- if(current_predicate(win_shell/2)).
+open_url(URL) :-                        % Windows shell
+    win_shell(open, URL),
+    !.
+:- endif.
+open_url(URL) :-                        % Unix `open document'
+    open_command(Open),
+    has_command(Open),
+    !,
+    run_command(Open, [URL], fg).
+open_url(URL) :-                        % user configured
+    getenv('BROWSER', Browser),
+    has_command(Browser),
+    !,
+    run_browser(Browser, URL).
+open_url(URL) :-                        % something we know
+    known_browser(Browser, _),
+    has_command(Browser),
+    !,
+    run_browser(Browser, URL).
+
+expand_browser_flag(Command-Mode, Command, Mode) :- !.
+expand_browser_flag(Command, Command, bg) :- atomic(Command).
+
+open_command(open) :-                   % Apples open command
+    current_prolog_flag(apple, true).
+open_command('xdg-open').               % Free desktop
+open_command('gnome-open').             % Gnome (deprecated in favour of xdg-open
+open_command(open).                     % Who knows
+
+%!  run_browser(+Browser, +URL) is det.
+%
+%   Open a page using a browser.
+
+run_browser(Browser, URL) :-
+    run_command(Browser, [URL], bg).
+
+%!  run_command(+Command, +Args, +Background)
+%
+%   Run OS command Command using Args,   silencing  the error output
+%   because many browsers are rather verbose.
+
+:- if(current_predicate(process_create/3)).
+run_command(Command, Args, fg) :-
+    !,
+    process_create(path(Command), Args, [stderr(null)]).
+:- endif.
+:- if(current_prolog_flag(unix, true)).
+run_command(Command, [Arg], fg) :-
+    format(string(Cmd), "\"~w\" \"~w\" &> /dev/null", [Command, Arg]),
+    shell(Cmd).
+run_command(Command, [Arg], bg) :-
+    format(string(Cmd), "\"~w\" \"~w\" &> /dev/null &", [Command, Arg]),
+    shell(Cmd).
+:- else.
+run_command(Command, [Arg], fg) :-
+    format(string(Cmd), "\"~w\" \"~w\"", [Command, Arg]),
+    shell(Cmd).
+run_command(Command, [Arg], bg) :-
+    format(string(Cmd), "\"~w\" \"~w\" &", [Command, Arg]),
+    shell(Cmd).
+:- endif.
+
+%!  known_browser(+FileBaseName, -Compatible)
+%
+%   True if browser FileBaseName has a remote protocol compatible to
+%   Compatible.
+
+known_browser(firefox,   netscape).
+known_browser(mozilla,   netscape).
+known_browser(netscape,  netscape).
+known_browser(konqueror, -).
+known_browser(opera,     -).
+
+
+%!  has_command(+Command)
+%
+%   Succeeds if Command is in  $PATH.   Works  for Unix systems. For
+%   Windows we have to test for executable extensions.
+
+:- dynamic
+    command_cache/2.
+:- volatile
+    command_cache/2.
+
+has_command(Command) :-
+    command_cache(Command, Path),
+    !,
+    Path \== (-).
+has_command(Command) :-
+    (   getenv('PATH', Path),
+        (   current_prolog_flag(windows, true)
+        ->  Sep = (;)
+        ;   Sep = (:)
+        ),
+        atomic_list_concat(Parts, Sep, Path),
+        member(Part, Parts),
+        prolog_to_os_filename(PlPart, Part),
+        atomic_list_concat([PlPart, Command], /, Exe),
+        access_file(Exe, execute)
+    ->  assert(command_cache(Command, Exe))
+    ;   assert(command_cache(Command, -)),
+        fail
+    ).
+
+
+                 /*******************************
+                 *            NET PATHS         *
+                 *******************************/
+
+%!  url_path(+Alias, -Expansion) is nondet.
+%
+%   Define URL path aliases. This multifile  predicate is defined in
+%   module =user=. Expansion is either a URL, or a term Alias(Sub).
+
+:- multifile
+    user:url_path/2.
+
+user:url_path(swipl,          'http://www.swi-prolog.org').
+user:url_path(swipl_book,     'http://books.google.nl/books/about/\c
+                               SWI_Prolog_Reference_Manual_6_2_2.html?\c
+                               id=q6R3Q3B-VC4C&redir_esc=y').
+
+user:url_path(swipl_faq,      swipl('FAQ')).
+user:url_path(swipl_man,      swipl('pldoc/doc_for?object=manual')).
+user:url_path(swipl_mail,     swipl('Mailinglist.html')).
+user:url_path(swipl_download, swipl('Download.html')).
+user:url_path(swipl_pack,     swipl('pack/list')).
+user:url_path(swipl_bugs,     swipl('bug.html')).
+user:url_path(swipl_quick,    swipl('man/quickstart.html')).
+
+%!  expand_url_path(+Spec, -URL)
+%
+%   Expand URL specifications similar   to absolute_file_name/3. The
+%   predicate url_path/2 plays the role of file_search_path/2.
+%
+%   @error  existence_error(url_path, Spec) if the location is not
+%           defined.
+
+expand_url_path(URL, URL) :-
+    atomic(URL),
+    !.                 % Allow atom and string
+expand_url_path(Spec, URL) :-
+    Spec =.. [Path, Local],
+    (   user:url_path(Path, Spec2)
+    ->  expand_url_path(Spec2, URL0),
+        (   Local == '.'
+        ->  URL = URL0
+        ;   sub_atom(Local, 0, _, _, #)
+        ->  atom_concat(URL0, Local, URL)
+        ;   sub_atom(URL0, 0, _, _, /)
+        ->  absolute_file_name(Local, URL, [relative_to(URL0)])
+        ;   atomic_list_concat([URL0, Local], /, URL)
+        )
+    ;   throw(error(existence_error(url_path, Path), expand_url_path/2))
+    ).
+