@tushar-br/editing-pack 1.0.195 → 1.0.196

package/staging_area/Blender/blender.shared/usd/usdMtlx/resources/libraries/pbrlib/genglsl/lib/mx_microfacet_specular.glsl

@@ -1,510 +0,0 @@
-#include "mx_microfacet.glsl"
-
-const int FRESNEL_MODEL_DIELECTRIC = 0;
-const int FRESNEL_MODEL_CONDUCTOR = 1;
-const int FRESNEL_MODEL_SCHLICK = 2;
-
-// Parameters for Fresnel calculations
-struct FresnelData
-{
-    // Fresnel model
-    int model;
-    bool airy;
-
-    // Physical Fresnel
-    vec3 ior;
-    vec3 extinction;
-
-    // Generalized Schlick Fresnel
-    vec3 F0;
-    vec3 F82;
-    vec3 F90;
-    float exponent;
-
-    // Thin film
-    float tf_thickness;
-    float tf_ior;
-
-    // Refraction
-    bool refraction;
-};
-
-// https://media.disneyanimation.com/uploads/production/publication_asset/48/asset/s2012_pbs_disney_brdf_notes_v3.pdf
-// Appendix B.2 Equation 13
-float mx_ggx_NDF(vec3 H, vec2 alpha)
-{
-    vec2 He = H.xy / alpha;
-    float denom = dot(He, He) + mx_square(H.z);
-    return 1.0 / (M_PI * alpha.x * alpha.y * mx_square(denom));
-}
-
-// https://ggx-research.github.io/publication/2023/06/09/publication-ggx.html
-vec3 mx_ggx_importance_sample_VNDF(vec2 Xi, vec3 V, vec2 alpha)
-{
-    // Transform the view direction to the hemisphere configuration.
-    V = normalize(vec3(V.xy * alpha, V.z));
-
-    // Sample a spherical cap in (-V.z, 1].
-    float phi = 2.0 * M_PI * Xi.x;
-    float z = (1.0 - Xi.y) * (1.0 + V.z) - V.z;
-    float sinTheta = sqrt(clamp(1.0 - z * z, 0.0, 1.0));
-    float x = sinTheta * mx_cos(phi);
-    float y = sinTheta * mx_sin(phi);
-    vec3 c = vec3(x, y, z);
-
-    // Compute the microfacet normal.
-    vec3 H = c + V;
-
-    // Transform the microfacet normal back to the ellipsoid configuration.
-    H = normalize(vec3(H.xy * alpha, max(H.z, 0.0)));
-
-    return H;
-}
-
-// https://www.cs.cornell.edu/~srm/publications/EGSR07-btdf.pdf
-// Equation 34
-float mx_ggx_smith_G1(float cosTheta, float alpha)
-{
-    float cosTheta2 = mx_square(cosTheta);
-    float tanTheta2 = (1.0 - cosTheta2) / cosTheta2;
-    return 2.0 / (1.0 + sqrt(1.0 + mx_square(alpha) * tanTheta2));
-}
-
-// Height-correlated Smith masking-shadowing
-// http://jcgt.org/published/0003/02/03/paper.pdf
-// Equations 72 and 99
-float mx_ggx_smith_G2(float NdotL, float NdotV, float alpha)
-{
-    float alpha2 = mx_square(alpha);
-    float lambdaL = sqrt(alpha2 + (1.0 - alpha2) * mx_square(NdotL));
-    float lambdaV = sqrt(alpha2 + (1.0 - alpha2) * mx_square(NdotV));
-    return 2.0 / (lambdaL / NdotL + lambdaV / NdotV);
-}
-
-// Rational quadratic fit to Monte Carlo data for GGX directional albedo.
-vec3 mx_ggx_dir_albedo_analytic(float NdotV, float alpha, vec3 F0, vec3 F90)
-{
-    float x = NdotV;
-    float y = alpha;
-    float x2 = mx_square(x);
-    float y2 = mx_square(y);
-    vec4 r = vec4(0.1003, 0.9345, 1.0, 1.0) +
-             vec4(-0.6303, -2.323, -1.765, 0.2281) * x +
-             vec4(9.748, 2.229, 8.263, 15.94) * y +
-             vec4(-2.038, -3.748, 11.53, -55.83) * x * y +
-             vec4(29.34, 1.424, 28.96, 13.08) * x2 +
-             vec4(-8.245, -0.7684, -7.507, 41.26) * y2 +
-             vec4(-26.44, 1.436, -36.11, 54.9) * x2 * y +
-             vec4(19.99, 0.2913, 15.86, 300.2) * x * y2 +
-             vec4(-5.448, 0.6286, 33.37, -285.1) * x2 * y2;
-    vec2 AB = clamp(r.xy / r.zw, 0.0, 1.0);
-    return F0 * AB.x + F90 * AB.y;
-}
-
-vec3 mx_ggx_dir_albedo_table_lookup(float NdotV, float alpha, vec3 F0, vec3 F90)
-{
-#if DIRECTIONAL_ALBEDO_METHOD == 1
-    if (textureSize($albedoTable, 0).x > 1)
-    {
-        vec2 AB = texture($albedoTable, vec2(NdotV, alpha)).rg;
-        return F0 * AB.x + F90 * AB.y;
-    }
-#endif
-    return vec3(0.0);
-}
-
-// https://cdn2.unrealengine.com/Resources/files/2013SiggraphPresentationsNotes-26915738.pdf
-vec3 mx_ggx_dir_albedo_monte_carlo(float NdotV, float alpha, vec3 F0, vec3 F90)
-{
-    NdotV = clamp(NdotV, M_FLOAT_EPS, 1.0);
-    vec3 V = vec3(sqrt(1.0 - mx_square(NdotV)), 0, NdotV);
-
-    vec2 AB = vec2(0.0);
-    const int SAMPLE_COUNT = 64;
-    for (int i = 0; i < SAMPLE_COUNT; i++)
-    {
-        vec2 Xi = mx_spherical_fibonacci(i, SAMPLE_COUNT);
-
-        // Compute the half vector and incoming light direction.
-        vec3 H = mx_ggx_importance_sample_VNDF(Xi, V, vec2(alpha));
-        vec3 L = -reflect(V, H);
-        
-        // Compute dot products for this sample.
-        float NdotL = clamp(L.z, M_FLOAT_EPS, 1.0);
-        float VdotH = clamp(dot(V, H), M_FLOAT_EPS, 1.0);
-
-        // Compute the Fresnel term.
-        float Fc = mx_fresnel_schlick(VdotH, 0.0, 1.0);
-
-        // Compute the per-sample geometric term.
-        // https://hal.inria.fr/hal-00996995v2/document, Algorithm 2
-        float G2 = mx_ggx_smith_G2(NdotL, NdotV, alpha);
-        
-        // Add the contribution of this sample.
-        AB += vec2(G2 * (1.0 - Fc), G2 * Fc);
-    }
-
-    // Apply the global component of the geometric term and normalize.
-    AB /= mx_ggx_smith_G1(NdotV, alpha) * float(SAMPLE_COUNT);
-
-    // Return the final directional albedo.
-    return F0 * AB.x + F90 * AB.y;
-}
-
-vec3 mx_ggx_dir_albedo(float NdotV, float alpha, vec3 F0, vec3 F90)
-{
-#if DIRECTIONAL_ALBEDO_METHOD == 0
-    return mx_ggx_dir_albedo_analytic(NdotV, alpha, F0, F90);
-#elif DIRECTIONAL_ALBEDO_METHOD == 1
-    return mx_ggx_dir_albedo_table_lookup(NdotV, alpha, F0, F90);
-#else
-    return mx_ggx_dir_albedo_monte_carlo(NdotV, alpha, F0, F90);
-#endif
-}
-
-float mx_ggx_dir_albedo(float NdotV, float alpha, float F0, float F90)
-{
-    return mx_ggx_dir_albedo(NdotV, alpha, vec3(F0), vec3(F90)).x;
-}
-
-// https://blog.selfshadow.com/publications/turquin/ms_comp_final.pdf
-// Equations 14 and 16
-vec3 mx_ggx_energy_compensation(float NdotV, float alpha, vec3 Fss)
-{
-    float Ess = mx_ggx_dir_albedo(NdotV, alpha, 1.0, 1.0);
-    return 1.0 + Fss * (1.0 - Ess) / Ess;
-}
-
-float mx_ggx_energy_compensation(float NdotV, float alpha, float Fss)
-{
-    return mx_ggx_energy_compensation(NdotV, alpha, vec3(Fss)).x;
-}
-
-// Compute the average of an anisotropic alpha pair.
-float mx_average_alpha(vec2 alpha)
-{
-    return sqrt(alpha.x * alpha.y);
-}
-
-// Convert a real-valued index of refraction to normal-incidence reflectivity.
-float mx_ior_to_f0(float ior)
-{
-    return mx_square((ior - 1.0) / (ior + 1.0));
-}
-
-// Convert normal-incidence reflectivity to real-valued index of refraction.
-float mx_f0_to_ior(float F0)
-{
-    float sqrtF0 = sqrt(clamp(F0, 0.01, 0.99));
-    return (1.0 + sqrtF0) / (1.0 - sqrtF0);
-}
-vec3 mx_f0_to_ior(vec3 F0)
-{
-    vec3 sqrtF0 = sqrt(clamp(F0, 0.01, 0.99));
-    return (vec3(1.0) + sqrtF0) / (vec3(1.0) - sqrtF0);
-}
-
-// https://renderwonk.com/publications/wp-generalization-adobe/gen-adobe.pdf
-vec3 mx_fresnel_hoffman_schlick(float cosTheta, FresnelData fd)
-{
-    const float COS_THETA_MAX = 1.0 / 7.0;
-    const float COS_THETA_FACTOR = 1.0 / (COS_THETA_MAX * pow(1.0 - COS_THETA_MAX, 6.0));
-
-    float x = clamp(cosTheta, 0.0, 1.0);
-    vec3 a = mix(fd.F0, fd.F90, pow(1.0 - COS_THETA_MAX, fd.exponent)) * (vec3(1.0) - fd.F82) * COS_THETA_FACTOR;
-    return mix(fd.F0, fd.F90, pow(1.0 - x, fd.exponent)) - a * x * mx_pow6(1.0 - x);
-}
-
-// https://seblagarde.wordpress.com/2013/04/29/memo-on-fresnel-equations/
-float mx_fresnel_dielectric(float cosTheta, float ior)
-{
-    float c = cosTheta;
-    float g2 = ior*ior + c*c - 1.0;
-    if (g2 < 0.0)
-    {
-        // Total internal reflection
-        return 1.0;
-    }
-
-    float g = sqrt(g2);
-    return 0.5 * mx_square((g - c) / (g + c)) *
-                (1.0 + mx_square(((g + c) * c - 1.0) / ((g - c) * c + 1.0)));
-}
-
-// https://seblagarde.wordpress.com/2013/04/29/memo-on-fresnel-equations/
-vec2 mx_fresnel_dielectric_polarized(float cosTheta, float ior)
-{
-    float cosTheta2 = mx_square(clamp(cosTheta, 0.0, 1.0));
-    float sinTheta2 = 1.0 - cosTheta2;
-
-    float t0 = max(ior * ior - sinTheta2, 0.0);
-    float t1 = t0 + cosTheta2;
-    float t2 = 2.0 * sqrt(t0) * cosTheta;
-    float Rs = (t1 - t2) / (t1 + t2);
-
-    float t3 = cosTheta2 * t0 + sinTheta2 * sinTheta2;
-    float t4 = t2 * sinTheta2;
-    float Rp = Rs * (t3 - t4) / (t3 + t4);
-
-    return vec2(Rp, Rs);
-}
-
-// https://seblagarde.wordpress.com/2013/04/29/memo-on-fresnel-equations/
-void mx_fresnel_conductor_polarized(float cosTheta, vec3 n, vec3 k, out vec3 Rp, out vec3 Rs)
-{
-    float cosTheta2 = mx_square(clamp(cosTheta, 0.0, 1.0));
-    float sinTheta2 = 1.0 - cosTheta2;
-    vec3 n2 = n * n;
-    vec3 k2 = k * k;
-
-    vec3 t0 = n2 - k2 - vec3(sinTheta2);
-    vec3 a2plusb2 = sqrt(t0 * t0 + 4.0 * n2 * k2);
-    vec3 t1 = a2plusb2 + vec3(cosTheta2);
-    vec3 a = sqrt(max(0.5 * (a2plusb2 + t0), 0.0));
-    vec3 t2 = 2.0 * a * cosTheta;
-    Rs = (t1 - t2) / (t1 + t2);
-
-    vec3 t3 = cosTheta2 * a2plusb2 + vec3(sinTheta2 * sinTheta2);
-    vec3 t4 = t2 * sinTheta2;
-    Rp = Rs * (t3 - t4) / (t3 + t4);
-}
-
-vec3 mx_fresnel_conductor(float cosTheta, vec3 n, vec3 k)
-{
-    vec3 Rp, Rs;
-    mx_fresnel_conductor_polarized(cosTheta, n, k, Rp, Rs);
-    return 0.5 * (Rp  + Rs);
-}
-
-// https://belcour.github.io/blog/research/publication/2017/05/01/brdf-thin-film.html
-void mx_fresnel_conductor_phase_polarized(float cosTheta, float eta1, vec3 eta2, vec3 kappa2, out vec3 phiP, out vec3 phiS)
-{
-    vec3 k2 = kappa2 / eta2;
-    vec3 sinThetaSqr = vec3(1.0) - cosTheta * cosTheta;
-    vec3 A = eta2*eta2*(vec3(1.0)-k2*k2) - eta1*eta1*sinThetaSqr;
-    vec3 B = sqrt(A*A + mx_square(2.0*eta2*eta2*k2));
-    vec3 U = sqrt((A+B)/2.0);
-    vec3 V = max(vec3(0.0), sqrt((B-A)/2.0));
-
-    phiS = mx_atan(2.0*eta1*V*cosTheta, U*U + V*V - mx_square(eta1*cosTheta));
-    phiP = mx_atan(2.0*eta1*eta2*eta2*cosTheta * (2.0*k2*U - (vec3(1.0)-k2*k2) * V),
-                   mx_square(eta2*eta2*(vec3(1.0)+k2*k2)*cosTheta) - eta1*eta1*(U*U+V*V));
-}
-
-// https://belcour.github.io/blog/research/publication/2017/05/01/brdf-thin-film.html
-vec3 mx_eval_sensitivity(float opd, vec3 shift)
-{
-    // Use Gaussian fits, given by 3 parameters: val, pos and var
-    float phase = 2.0*M_PI * opd;
-    vec3 val = vec3(5.4856e-13, 4.4201e-13, 5.2481e-13);
-    vec3 pos = vec3(1.6810e+06, 1.7953e+06, 2.2084e+06);
-    vec3 var = vec3(4.3278e+09, 9.3046e+09, 6.6121e+09);
-    vec3 xyz = val * sqrt(2.0*M_PI * var) * mx_cos(pos * phase + shift) * exp(- var * phase*phase);
-    xyz.x   += 9.7470e-14 * sqrt(2.0*M_PI * 4.5282e+09) * mx_cos(2.2399e+06 * phase + shift[0]) * exp(- 4.5282e+09 * phase*phase);
-    return xyz / 1.0685e-7;
-}
-
-// A Practical Extension to Microfacet Theory for the Modeling of Varying Iridescence
-// https://belcour.github.io/blog/research/publication/2017/05/01/brdf-thin-film.html
-vec3 mx_fresnel_airy(float cosTheta, FresnelData fd)
-{
-    // XYZ to CIE 1931 RGB color space (using neutral E illuminant)
-    const mat3 XYZ_TO_RGB = mat3(2.3706743, -0.5138850, 0.0052982, -0.9000405, 1.4253036, -0.0146949, -0.4706338, 0.0885814, 1.0093968);
-
-    // Assume vacuum on the outside
-    float eta1 = 1.0;
-    float eta2 = max(fd.tf_ior, eta1);
-    vec3 eta3 = (fd.model == FRESNEL_MODEL_SCHLICK) ? mx_f0_to_ior(fd.F0) : fd.ior;
-    vec3 kappa3 = (fd.model == FRESNEL_MODEL_SCHLICK) ? vec3(0.0) : fd.extinction;
-    float cosThetaT = sqrt(1.0 - (1.0 - mx_square(cosTheta)) * mx_square(eta1 / eta2));
-
-    // First interface
-    vec2 R12 = mx_fresnel_dielectric_polarized(cosTheta, eta2 / eta1);
-    if (cosThetaT <= 0.0)
-    {
-        // Total internal reflection
-        R12 = vec2(1.0);
-    }
-    vec2 T121 = vec2(1.0) - R12;
-
-    // Second interface
-    vec3 R23p, R23s;
-    if (fd.model == FRESNEL_MODEL_SCHLICK)
-    {
-        vec3 f = mx_fresnel_hoffman_schlick(cosThetaT, fd);
-        R23p = 0.5 * f;
-        R23s = 0.5 * f;
-    }
-    else
-    {
-        mx_fresnel_conductor_polarized(cosThetaT, eta3 / eta2, kappa3 / eta2, R23p, R23s);
-    }
-
-    // Phase shift
-    float cosB = mx_cos(mx_atan(eta2 / eta1));
-    vec2 phi21 = vec2(cosTheta < cosB ? 0.0 : M_PI, M_PI);
-    vec3 phi23p, phi23s;
-    if (fd.model == FRESNEL_MODEL_SCHLICK)
-    {
-        phi23p = vec3((eta3[0] < eta2) ? M_PI : 0.0,
-                      (eta3[1] < eta2) ? M_PI : 0.0,
-                      (eta3[2] < eta2) ? M_PI : 0.0);
-        phi23s = phi23p;
-    }
-    else
-    {
-        mx_fresnel_conductor_phase_polarized(cosThetaT, eta2, eta3, kappa3, phi23p, phi23s);
-    }
-    vec3 r123p = max(sqrt(R12.x*R23p), 0.0);
-    vec3 r123s = max(sqrt(R12.y*R23s), 0.0);
-
-    // Iridescence term
-    vec3 I = vec3(0.0);
-    vec3 Cm, Sm;
-
-    // Optical path difference
-    float distMeters = fd.tf_thickness * 1.0e-9;
-    float opd = 2.0 * eta2 * cosThetaT * distMeters;
-
-    // Iridescence term using spectral antialiasing for Parallel polarization
-
-    // Reflectance term for m=0 (DC term amplitude)
-    vec3 Rs = (mx_square(T121.x) * R23p) / (vec3(1.0) - R12.x*R23p);
-    I += R12.x + Rs;
-
-    // Reflectance term for m>0 (pairs of diracs)
-    Cm = Rs - T121.x;
-    for (int m=1; m<=2; m++)
-    {
-        Cm *= r123p;
-        Sm  = 2.0 * mx_eval_sensitivity(float(m) * opd, float(m)*(phi23p+vec3(phi21.x)));
-        I  += Cm*Sm;
-    }
-
-    // Iridescence term using spectral antialiasing for Perpendicular polarization
-
-    // Reflectance term for m=0 (DC term amplitude)
-    vec3 Rp = (mx_square(T121.y) * R23s) / (vec3(1.0) - R12.y*R23s);
-    I += R12.y + Rp;
-
-    // Reflectance term for m>0 (pairs of diracs)
-    Cm = Rp - T121.y;
-    for (int m=1; m<=2; m++)
-    {
-        Cm *= r123s;
-        Sm  = 2.0 * mx_eval_sensitivity(float(m) * opd, float(m)*(phi23s+vec3(phi21.y)));
-        I  += Cm*Sm;
-    }
-
-    // Average parallel and perpendicular polarization
-    I *= 0.5;
-
-    // Convert back to RGB reflectance
-    I = clamp(XYZ_TO_RGB * I, 0.0, 1.0);
-
-    return I;
-}
-
-FresnelData mx_init_fresnel_dielectric(float ior, float tf_thickness, float tf_ior)
-{
-    FresnelData fd;
-    fd.model = FRESNEL_MODEL_DIELECTRIC;
-    fd.airy = tf_thickness > 0.0;
-    fd.ior = vec3(ior);
-    fd.extinction = vec3(0.0);
-    fd.F0 = vec3(0.0);
-    fd.F82 = vec3(0.0);
-    fd.F90 = vec3(0.0);
-    fd.exponent = 0.0;
-    fd.tf_thickness = tf_thickness;
-    fd.tf_ior = tf_ior;
-    fd.refraction = false;
-    return fd;
-}
-
-FresnelData mx_init_fresnel_conductor(vec3 ior, vec3 extinction, float tf_thickness, float tf_ior)
-{
-    FresnelData fd;
-    fd.model = FRESNEL_MODEL_CONDUCTOR;
-    fd.airy = tf_thickness > 0.0;
-    fd.ior = ior;
-    fd.extinction = extinction;
-    fd.F0 = vec3(0.0);
-    fd.F82 = vec3(0.0);
-    fd.F90 = vec3(0.0);
-    fd.exponent = 0.0;
-    fd.tf_thickness = tf_thickness;
-    fd.tf_ior = tf_ior;
-    fd.refraction = false;
-    return fd;
-}
-
-FresnelData mx_init_fresnel_schlick(vec3 F0, vec3 F82, vec3 F90, float exponent, float tf_thickness, float tf_ior)
-{
-    FresnelData fd;
-    fd.model = FRESNEL_MODEL_SCHLICK;
-    fd.airy = tf_thickness > 0.0;
-    fd.ior = vec3(0.0);
-    fd.extinction = vec3(0.0);
-    fd.F0 = F0;
-    fd.F82 = F82;
-    fd.F90 = F90;
-    fd.exponent = exponent;
-    fd.tf_thickness = tf_thickness;
-    fd.tf_ior = tf_ior;
-    fd.refraction = false;
-    return fd;
-}
-
-vec3 mx_compute_fresnel(float cosTheta, FresnelData fd)
-{
-    if (fd.airy)
-    {
-         return mx_fresnel_airy(cosTheta, fd);
-    }
-    else if (fd.model == FRESNEL_MODEL_DIELECTRIC)
-    {
-        return vec3(mx_fresnel_dielectric(cosTheta, fd.ior.x));
-    }
-    else if (fd.model == FRESNEL_MODEL_CONDUCTOR)
-    {
-        return mx_fresnel_conductor(cosTheta, fd.ior, fd.extinction);
-    }
-    else
-    {
-        return mx_fresnel_hoffman_schlick(cosTheta, fd);
-    }
-}
-
-// Compute the refraction of a ray through a solid sphere.
-vec3 mx_refraction_solid_sphere(vec3 R, vec3 N, float ior)
-{
-    R = refract(R, N, 1.0 / ior);
-    vec3 N1 = normalize(R * dot(R, N) - N * 0.5);
-    return refract(R, N1, ior);
-}
-
-vec2 mx_latlong_projection(vec3 dir)
-{
-    float latitude = -mx_asin(dir.y) * M_PI_INV + 0.5;
-    float longitude = mx_atan(dir.x, -dir.z) * M_PI_INV * 0.5 + 0.5;
-    return vec2(longitude, latitude);
-}
-
-vec3 mx_latlong_map_lookup(vec3 dir, mat4 transform, float lod, sampler2D envSampler)
-{
-    vec3 envDir = normalize((transform * vec4(dir,0.0)).xyz);
-    vec2 uv = mx_latlong_projection(envDir);
-    return textureLod(envSampler, uv, lod).rgb;
-}
-
-// Return the mip level with the appropriate coverage for a filtered importance sample.
-// https://developer.nvidia.com/gpugems/GPUGems3/gpugems3_ch20.html
-// Section 20.4 Equation 13
-float mx_latlong_compute_lod(vec3 dir, float pdf, float maxMipLevel, int envSamples)
-{
-    const float MIP_LEVEL_OFFSET = 1.5;
-    float effectiveMaxMipLevel = maxMipLevel - MIP_LEVEL_OFFSET;
-    float distortion = sqrt(1.0 - mx_square(dir.y));
-    return max(effectiveMaxMipLevel - 0.5 * log2(float(envSamples) * pdf * distortion), 0.0);
-}

package/staging_area/Blender/blender.shared/usd/usdMtlx/resources/libraries/pbrlib/genglsl/lib/mx_shadow.glsl

@@ -1,23 +0,0 @@
-// https://developer.nvidia.com/gpugems/gpugems3/part-ii-light-and-shadows/chapter-8-summed-area-variance-shadow-maps
-float mx_variance_shadow_occlusion(vec2 moments, float fragmentDepth)
-{
-    const float MIN_VARIANCE = 0.00001;
-
-    // One-tailed inequality valid if fragmentDepth > moments.x.
-    float p = (fragmentDepth <= moments.x) ? 1.0 : 0.0;
-
-    // Compute variance.
-    float variance = moments.y - mx_square(moments.x);
-    variance = max(variance, MIN_VARIANCE);
-
-    // Compute probabilistic upper bound.
-    float d = fragmentDepth - moments.x;
-    float pMax = variance / (variance + mx_square(d));
-    return max(p, pMax);
-}
-
-vec2 mx_compute_depth_moments()
-{
-    float depth = gl_FragCoord.z;
-    return vec2(depth, mx_square(depth));
-}

package/staging_area/Blender/blender.shared/usd/usdMtlx/resources/libraries/pbrlib/genglsl/lib/mx_transmission_opacity.glsl

@@ -1,6 +0,0 @@
-#include "mx_microfacet_specular.glsl"
-
-vec3 mx_surface_transmission(vec3 N, vec3 V, vec3 X, vec2 alpha, int distribution, FresnelData fd, vec3 tint)
-{
-    return tint;
-}

package/staging_area/Blender/blender.shared/usd/usdMtlx/resources/libraries/pbrlib/genglsl/lib/mx_transmission_refract.glsl

@@ -1,14 +0,0 @@
-#include "mx_microfacet_specular.glsl"
-
-vec3 mx_surface_transmission(vec3 N, vec3 V, vec3 X, vec2 alpha, int distribution, FresnelData fd, vec3 tint)
-{
-    // Approximate the appearance of surface transmission as glossy
-    // environment map refraction, ignoring any scene geometry that might
-    // be visible through the surface.
-    fd.refraction = true;
-    if ($refractionTwoSided)
-    {
-        tint = mx_square(tint);
-    }
-    return mx_environment_radiance(N, V, X, alpha, distribution, fd) * tint;
-}

package/staging_area/Blender/blender.shared/usd/usdMtlx/resources/libraries/pbrlib/genglsl/mx_add_bsdf.glsl

@@ -1,7 +0,0 @@
-#include "lib/mx_closure_type.glsl"
-
-void mx_add_bsdf(ClosureData closureData, BSDF in1, BSDF in2, out BSDF result)
-{
-    result.response = in1.response + in2.response;
-    result.throughput = in1.throughput + in2.throughput;
-}

package/staging_area/Blender/blender.shared/usd/usdMtlx/resources/libraries/pbrlib/genglsl/mx_add_edf.glsl

@@ -1,6 +0,0 @@
-#include "lib/mx_closure_type.glsl"
-
-void mx_add_edf(ClosureData closureData, EDF in1, EDF in2, out EDF result)
-{
-    result = in1 + in2;
-}

package/staging_area/Blender/blender.shared/usd/usdMtlx/resources/libraries/pbrlib/genglsl/mx_anisotropic_vdf.glsl

@@ -1,6 +0,0 @@
-#include "lib/mx_closure_type.glsl"
-
-void mx_anisotropic_vdf(ClosureData closureData, vec3 absorption, vec3 scattering, float anisotropy, inout BSDF bsdf)
-{
-    // TODO: Add some approximation for volumetric light absorption.
-}

package/staging_area/Blender/blender.shared/usd/usdMtlx/resources/libraries/pbrlib/genglsl/mx_artistic_ior.glsl

@@ -1,17 +0,0 @@
-void mx_artistic_ior(vec3 reflectivity, vec3 edge_color, out vec3 ior, out vec3 extinction)
-{
-    // "Artist Friendly Metallic Fresnel", Ole Gulbrandsen, 2014
-    // http://jcgt.org/published/0003/04/03/paper.pdf
-
-    vec3 r = clamp(reflectivity, 0.0, 0.99);
-    vec3 r_sqrt = sqrt(r);
-    vec3 n_min = (1.0 - r) / (1.0 + r);
-    vec3 n_max = (1.0 + r_sqrt) / (1.0 - r_sqrt);
-    ior = mix(n_max, n_min, edge_color);
-
-    vec3 np1 = ior + 1.0;
-    vec3 nm1 = ior - 1.0;
-    vec3 k2 = (np1*np1 * r - nm1*nm1) / (1.0 - r);
-    k2 = max(k2, 0.0);
-    extinction = sqrt(k2);
-}

package/staging_area/Blender/blender.shared/usd/usdMtlx/resources/libraries/pbrlib/genglsl/mx_blackbody.glsl

@@ -1,48 +0,0 @@
-/// XYZ to Rec.709 RGB colorspace conversion
-const mat3 XYZ_to_RGB = mat3( 3.2406, -0.9689, 0.0557,
-                             -1.5372, 1.8758, -0.2040,
-                             -0.4986, 0.0415, 1.0570);
-
-void mx_blackbody(float temperatureKelvin, out vec3 colorValue)
-{
-    float xc, yc;
-    float t, t2, t3, xc2, xc3;
-
-    // if value outside valid range of approximation clamp to accepted temperature range
-    temperatureKelvin = clamp(temperatureKelvin, 1667.0, 25000.0);
-
-    t = 1000.0 / temperatureKelvin;
-    t2 = t * t;
-    t3 = t * t * t;
-
-    // Cubic spline approximation for Kelvin temperature to sRGB conversion
-    // (https://en.wikipedia.org/wiki/Planckian_locus#Approximation)
-    if (temperatureKelvin < 4000.0) {  // 1667K <= temperatureKelvin < 4000K
-      xc = -0.2661239 * t3 - 0.2343580 * t2 + 0.8776956 * t + 0.179910;
-    }
-    else {  // 4000K <= temperatureKelvin <= 25000K
-      xc = -3.0258469 * t3 + 2.1070379 * t2 + 0.2226347 * t + 0.240390;
-    }
-    xc2 = xc * xc;
-    xc3 = xc * xc * xc;
-
-    if (temperatureKelvin < 2222.0) {  // 1667K <= temperatureKelvin < 2222K
-      yc = -1.1063814 * xc3 - 1.34811020 * xc2 + 2.18555832 * xc - 0.20219683;
-    }
-    else if (temperatureKelvin < 4000.0) {  // 2222K <= temperatureKelvin < 4000K
-      yc = -0.9549476 * xc3 - 1.37418593 * xc2 + 2.09137015 * xc - 0.16748867;
-    }
-    else {  // 4000K <= temperatureKelvin <= 25000K
-      yc = 3.0817580 * xc3 - 5.87338670 * xc2 + 3.75112997 * xc - 0.37001483;
-    }
-
-    if (yc <= 0.0) {  // avoid division by zero
-      colorValue = vec3(1.0);
-      return;
-    }
-
-    vec3 XYZ = vec3(xc / yc, 1.0, (1.0 - xc - yc) / yc);
-
-    colorValue = XYZ_to_RGB * XYZ;
-    colorValue = max(colorValue, vec3(0.0));
-}

package/staging_area/Blender/blender.shared/usd/usdMtlx/resources/libraries/pbrlib/genglsl/mx_burley_diffuse_bsdf.glsl

@@ -1,33 +0,0 @@
-#include "lib/mx_closure_type.glsl"
-#include "lib/mx_microfacet_diffuse.glsl"
-
-void mx_burley_diffuse_bsdf(ClosureData closureData, float weight, vec3 color, float roughness, vec3 N, inout BSDF bsdf)
-{
-    bsdf.throughput = vec3(0.0);
-
-    if (weight < M_FLOAT_EPS)
-    {
-        return;
-    }
-
-    vec3 V = closureData.V;
-    vec3 L = closureData.L;
-
-    N = mx_forward_facing_normal(N, V);
-    float NdotV = clamp(dot(N, V), M_FLOAT_EPS, 1.0);
-
-    if (closureData.closureType == CLOSURE_TYPE_REFLECTION)
-    {
-        float NdotL = clamp(dot(N, L), M_FLOAT_EPS, 1.0);
-        float LdotH = clamp(dot(L, normalize(L + V)), M_FLOAT_EPS, 1.0);
-
-        bsdf.response = color * closureData.occlusion * weight * NdotL * M_PI_INV;
-        bsdf.response *= mx_burley_diffuse(NdotV, NdotL, LdotH, roughness);
-    }
-    else if (closureData.closureType == CLOSURE_TYPE_INDIRECT)
-    {
-        vec3 Li = mx_environment_irradiance(N) *
-                  mx_burley_diffuse_dir_albedo(NdotV, roughness);
-        bsdf.response = Li * color * weight;
-    }
-}