@tushar-br/editing-pack 1.0.195 → 1.0.196

package/staging_area/Blender/blender.shared/usd/usdMtlx/resources/libraries/pbrlib/genglsl/lib/mx_environment_fis.glsl

@@ -1,69 +0,0 @@
-#include "mx_microfacet_specular.glsl"
-
-vec3 mx_environment_radiance(vec3 N, vec3 V, vec3 X, vec2 alpha, int distribution, FresnelData fd)
-{
-    // Generate tangent frame.
-    X = normalize(X - dot(X, N) * N);
-    vec3 Y = cross(N, X);
-    mat3 tangentToWorld = mat3(X, Y, N);
-
-    // Transform the view vector to tangent space.
-    V = vec3(dot(V, X), dot(V, Y), dot(V, N));
-
-    // Compute derived properties.
-    float NdotV = clamp(V.z, M_FLOAT_EPS, 1.0);
-    float avgAlpha = mx_average_alpha(alpha);
-    float G1V = mx_ggx_smith_G1(NdotV, avgAlpha);
-    
-    // Integrate outgoing radiance using filtered importance sampling.
-    // http://cgg.mff.cuni.cz/~jaroslav/papers/2008-egsr-fis/2008-egsr-fis-final-embedded.pdf
-    vec3 radiance = vec3(0.0);
-    int envRadianceSamples = $envRadianceSamples;
-    for (int i = 0; i < envRadianceSamples; i++)
-    {
-        vec2 Xi = mx_spherical_fibonacci(i, envRadianceSamples);
-
-        // Compute the half vector and incoming light direction.
-        vec3 H = mx_ggx_importance_sample_VNDF(Xi, V, alpha);
-        vec3 L = fd.refraction ? mx_refraction_solid_sphere(-V, H, fd.ior.x) : -reflect(V, H);
-        
-        // Compute dot products for this sample.
-        float NdotL = clamp(L.z, M_FLOAT_EPS, 1.0);
-        float VdotH = clamp(dot(V, H), M_FLOAT_EPS, 1.0);
-
-        // Sample the environment light from the given direction.
-        vec3 Lw = tangentToWorld * L;
-        float pdf = mx_ggx_NDF(H, alpha) * G1V / (4.0 * NdotV);
-        float lod = mx_latlong_compute_lod(Lw, pdf, float($envRadianceMips - 1), envRadianceSamples);
-        vec3 sampleColor = mx_latlong_map_lookup(Lw, $envMatrix, lod, $envRadiance);
-
-        // Compute the Fresnel term.
-        vec3 F = mx_compute_fresnel(VdotH, fd);
-
-        // Compute the geometric term.
-        float G = mx_ggx_smith_G2(NdotL, NdotV, avgAlpha);
-
-        // Compute the combined FG term, which simplifies to inverted Fresnel for refraction.
-        vec3 FG = fd.refraction ? vec3(1.0) - F : F * G;
-
-        // Add the radiance contribution of this sample.
-        // From https://cdn2.unrealengine.com/Resources/files/2013SiggraphPresentationsNotes-26915738.pdf
-        //   incidentLight = sampleColor * NdotL
-        //   microfacetSpecular = D * F * G / (4 * NdotL * NdotV)
-        //   pdf = D * G1V / (4 * NdotV);
-        //   radiance = incidentLight * microfacetSpecular / pdf
-        radiance += sampleColor * FG;
-    }
-
-    // Apply the global component of the geometric term and normalize.
-    radiance /= G1V * float(envRadianceSamples);
-
-    // Return the final radiance.
-    return radiance * $envLightIntensity;
-}
-
-vec3 mx_environment_irradiance(vec3 N)
-{
-    vec3 Li = mx_latlong_map_lookup(N, $envMatrix, 0.0, $envIrradiance);
-    return Li * $envLightIntensity;
-}

package/staging_area/Blender/blender.shared/usd/usdMtlx/resources/libraries/pbrlib/genglsl/lib/mx_environment_none.glsl

@@ -1,11 +0,0 @@
-#include "mx_microfacet_specular.glsl"
-
-vec3 mx_environment_radiance(vec3 N, vec3 V, vec3 X, vec2 roughness, int distribution, FresnelData fd)
-{
-    return vec3(0.0);
-}
-
-vec3 mx_environment_irradiance(vec3 N)
-{
-    return vec3(0.0);
-}

package/staging_area/Blender/blender.shared/usd/usdMtlx/resources/libraries/pbrlib/genglsl/lib/mx_environment_prefilter.glsl

@@ -1,30 +0,0 @@
-#include "mx_microfacet_specular.glsl"
-
-// Return the mip level associated with the given alpha in a prefiltered environment.
-float mx_latlong_alpha_to_lod(float alpha)
-{
-    float lodBias = (alpha < 0.25) ? sqrt(alpha) : 0.5 * alpha + 0.375;
-    return lodBias * float($envRadianceMips - 1);
-}
-
-vec3 mx_environment_radiance(vec3 N, vec3 V, vec3 X, vec2 alpha, int distribution, FresnelData fd)
-{
-    N = mx_forward_facing_normal(N, V);
-    vec3 L = fd.refraction ? mx_refraction_solid_sphere(-V, N, fd.ior.x) : -reflect(V, N);
-
-    float NdotV = clamp(dot(N, V), M_FLOAT_EPS, 1.0);
-
-    float avgAlpha = mx_average_alpha(alpha);
-    vec3 F = mx_compute_fresnel(NdotV, fd);
-    float G = mx_ggx_smith_G2(NdotV, NdotV, avgAlpha);
-    vec3 FG = fd.refraction ? vec3(1.0) - (F * G) : F * G;
-
-    vec3 Li = mx_latlong_map_lookup(L, $envMatrix, mx_latlong_alpha_to_lod(avgAlpha), $envRadiance);
-    return Li * FG * $envLightIntensity;
-}
-
-vec3 mx_environment_irradiance(vec3 N)
-{
-    vec3 Li = mx_latlong_map_lookup(N, $envMatrix, 0.0, $envIrradiance);
-    return Li * $envLightIntensity;
-}

package/staging_area/Blender/blender.shared/usd/usdMtlx/resources/libraries/pbrlib/genglsl/lib/mx_generate_albedo_table.glsl

@@ -1,10 +0,0 @@
-#include "mx_microfacet_sheen.glsl"
-#include "mx_microfacet_specular.glsl"
-
-vec3 mx_generate_dir_albedo_table()
-{
-    vec2 uv = gl_FragCoord.xy / $albedoTableSize;
-    vec2 ggxDirAlbedo = mx_ggx_dir_albedo(uv.x, uv.y, vec3(1, 0, 0), vec3(0, 1, 0)).xy;
-    float sheenDirAlbedo = mx_imageworks_sheen_dir_albedo(uv.x, uv.y);
-    return vec3(ggxDirAlbedo, sheenDirAlbedo);
-}

package/staging_area/Blender/blender.shared/usd/usdMtlx/resources/libraries/pbrlib/genglsl/lib/mx_generate_prefilter_env.glsl

@@ -1,66 +0,0 @@
-#include "mx_microfacet_specular.glsl"
-
-// Return the alpha associated with the given mip level in a prefiltered environment.
-float mx_latlong_lod_to_alpha(float lod)
-{
-    float lodBias = lod / float($envRadianceMips - 1);
-    return (lodBias < 0.5) ? mx_square(lodBias) : 2.0 * (lodBias - 0.375);
-}
-
-// The inverse of mx_latlong_projection.
-vec3 mx_latlong_map_projection_inverse(vec2 uv)
-{
-    float latitude = (uv.y - 0.5) * M_PI;
-    float longitude = (uv.x - 0.5) * M_PI * 2.0;
-
-    float x = -mx_cos(latitude) * mx_sin(longitude);
-    float y = -mx_sin(latitude);
-    float z = mx_cos(latitude) * mx_cos(longitude);
-
-    return vec3(x, y, z);
-}
-
-vec3 mx_generate_prefilter_env()
-{
-    // The tangent view vector is aligned with the normal.
-    vec3 V = vec3(0.0, 0.0, 1.0);
-    float NdotV = 1.0;
-
-    // Compute derived properties.
-    vec2 uv = gl_FragCoord.xy * pow(2.0, $envPrefilterMip) / vec2(textureSize($envRadiance, 0));
-    vec3 worldN = mx_latlong_map_projection_inverse(uv);
-    mat3 tangentToWorld = mx_orthonormal_basis(worldN);
-    float alpha = mx_latlong_lod_to_alpha(float($envPrefilterMip));
-    float G1V = mx_ggx_smith_G1(NdotV, alpha);
-
-    // Integrate the LD term for the given environment and alpha.
-    vec3 radiance = vec3(0.0, 0.0, 0.0);
-    float weight = 0.0;
-    int envRadianceSamples = 1024;
-    for (int i = 0; i < envRadianceSamples; i++)
-    {
-        vec2 Xi = mx_spherical_fibonacci(i, envRadianceSamples);
-
-        // Compute the half vector and incoming light direction.
-        vec3 H = mx_ggx_importance_sample_VNDF(Xi, V, vec2(alpha));
-        vec3 L = -V + 2.0 * H.z * H;
-
-        // Compute dot products for this sample.
-        float NdotL = clamp(L.z, M_FLOAT_EPS, 1.0);
-
-        // Compute the geometric term.
-        float G = mx_ggx_smith_G2(NdotL, NdotV, alpha);
-
-        // Sample the environment light from the given direction.
-        vec3 Lw = tangentToWorld * L;
-        float pdf = mx_ggx_NDF(H, vec2(alpha)) * G1V / (4.0 * NdotV);
-        float lod = mx_latlong_compute_lod(Lw, pdf, float($envRadianceMips - 1), envRadianceSamples);
-        vec3 sampleColor = mx_latlong_map_lookup(Lw, $envMatrix, lod, $envRadiance);
-
-        // Add the radiance contribution of this sample.
-        radiance += G * sampleColor;
-        weight += G;
-    }
-
-    return radiance / weight;
-}

package/staging_area/Blender/blender.shared/usd/usdMtlx/resources/libraries/pbrlib/genglsl/lib/mx_microfacet.glsl

@@ -1,106 +0,0 @@
-#define M_PI 3.1415926535897932
-#define M_PI_INV (1.0 / M_PI)
-
-float mx_pow5(float x)
-{
-    return mx_square(mx_square(x)) * x;
-}
-
-float mx_pow6(float x)
-{
-    float x2 = mx_square(x);
-    return mx_square(x2) * x2;
-}
-
-// Standard Schlick Fresnel
-float mx_fresnel_schlick(float cosTheta, float F0)
-{
-    float x = clamp(1.0 - cosTheta, 0.0, 1.0);
-    float x5 = mx_pow5(x);
-    return F0 + (1.0 - F0) * x5;
-}
-vec3 mx_fresnel_schlick(float cosTheta, vec3 F0)
-{
-    float x = clamp(1.0 - cosTheta, 0.0, 1.0);
-    float x5 = mx_pow5(x);
-    return F0 + (1.0 - F0) * x5;
-}
-
-// Generalized Schlick Fresnel
-float mx_fresnel_schlick(float cosTheta, float F0, float F90)
-{
-    float x = clamp(1.0 - cosTheta, 0.0, 1.0);
-    float x5 = mx_pow5(x);
-    return mix(F0, F90, x5);
-}
-vec3 mx_fresnel_schlick(float cosTheta, vec3 F0, vec3 F90)
-{
-    float x = clamp(1.0 - cosTheta, 0.0, 1.0);
-    float x5 = mx_pow5(x);
-    return mix(F0, F90, x5);
-}
-
-// Generalized Schlick Fresnel with a variable exponent
-float mx_fresnel_schlick(float cosTheta, float F0, float F90, float exponent)
-{
-    float x = clamp(1.0 - cosTheta, 0.0, 1.0);
-    return mix(F0, F90, pow(x, exponent));
-}
-vec3 mx_fresnel_schlick(float cosTheta, vec3 F0, vec3 F90, float exponent)
-{
-    float x = clamp(1.0 - cosTheta, 0.0, 1.0);
-    return mix(F0, F90, pow(x, exponent));
-}
-
-// Enforce that the given normal is forward-facing from the specified view direction.
-vec3 mx_forward_facing_normal(vec3 N, vec3 V)
-{
-    return (dot(N, V) < 0.0) ? -N : N;
-}
-
-// https://www.graphics.rwth-aachen.de/publication/2/jgt.pdf
-float mx_golden_ratio_sequence(int i)
-{
-    const float GOLDEN_RATIO = 1.6180339887498948;
-    return fract((float(i) + 1.0) * GOLDEN_RATIO);
-}
-
-// https://people.irisa.fr/Ricardo.Marques/articles/2013/SF_CGF.pdf
-vec2 mx_spherical_fibonacci(int i, int numSamples)
-{
-    return vec2((float(i) + 0.5) / float(numSamples), mx_golden_ratio_sequence(i));
-}
-
-// Generate a uniform-weighted sample on the unit hemisphere.
-vec3 mx_uniform_sample_hemisphere(vec2 Xi)
-{
-    float phi = 2.0 * M_PI * Xi.x;
-    float cosTheta = 1.0 - Xi.y;
-    float sinTheta = sqrt(1.0 - mx_square(cosTheta));
-    return vec3(mx_cos(phi) * sinTheta,
-                mx_sin(phi) * sinTheta,
-                cosTheta);
-}
-
-// Generate a cosine-weighted sample on the unit hemisphere.
-vec3 mx_cosine_sample_hemisphere(vec2 Xi)
-{
-    float phi = 2.0 * M_PI * Xi.x;
-    float cosTheta = sqrt(Xi.y);
-    float sinTheta = sqrt(1.0 - Xi.y);
-    return vec3(mx_cos(phi) * sinTheta,
-                mx_sin(phi) * sinTheta,
-                cosTheta);
-}
-
-// Construct an orthonormal basis from a unit vector.
-// https://graphics.pixar.com/library/OrthonormalB/paper.pdf
-mat3 mx_orthonormal_basis(vec3 N)
-{
-    float sign = (N.z < 0.0) ? -1.0 : 1.0;
-    float a = -1.0 / (sign + N.z);
-    float b = N.x * N.y * a;
-    vec3 X = vec3(1.0 + sign * N.x * N.x * a, sign * b, -sign * N.x);
-    vec3 Y = vec3(b, sign + N.y * N.y * a, -N.y);
-    return mat3(X, Y, N);
-}

package/staging_area/Blender/blender.shared/usd/usdMtlx/resources/libraries/pbrlib/genglsl/lib/mx_microfacet_diffuse.glsl

@@ -1,199 +0,0 @@
-#include "mx_microfacet.glsl"
-
-const float FUJII_CONSTANT_1 = 0.5 - 2.0 / (3.0 * M_PI);
-const float FUJII_CONSTANT_2 = 2.0 / 3.0 - 28.0 / (15.0 * M_PI);
-
-// Qualitative Oren-Nayar diffuse with simplified math:
-// https://www1.cs.columbia.edu/CAVE/publications/pdfs/Oren_SIGGRAPH94.pdf
-float mx_oren_nayar_diffuse(float NdotV, float NdotL, float LdotV, float roughness)
-{
-    float s = LdotV - NdotL * NdotV;
-    float stinv = (s > 0.0) ? s / max(NdotL, NdotV) : 0.0;
-
-    float sigma2 = mx_square(roughness);
-    float A = 1.0 - 0.5 * (sigma2 / (sigma2 + 0.33));
-    float B = 0.45 * sigma2 / (sigma2 + 0.09);
-
-    return A + B * stinv;
-}
-
-// Rational quadratic fit to Monte Carlo data for Oren-Nayar directional albedo.
-float mx_oren_nayar_diffuse_dir_albedo_analytic(float NdotV, float roughness)
-{
-    vec2 r = vec2(1.0, 1.0) +
-             vec2(-0.4297, -0.6076) * roughness +
-             vec2(-0.7632, -0.4993) * NdotV * roughness +
-             vec2(1.4385, 2.0315) * mx_square(roughness);
-    return r.x / r.y;
-}
-
-float mx_oren_nayar_diffuse_dir_albedo_table_lookup(float NdotV, float roughness)
-{
-#if DIRECTIONAL_ALBEDO_METHOD == 1
-    if (textureSize($albedoTable, 0).x > 1)
-    {
-        return texture($albedoTable, vec2(NdotV, roughness)).b;
-    }
-#endif
-    return 0.0;
-}
-
-float mx_oren_nayar_diffuse_dir_albedo_monte_carlo(float NdotV, float roughness)
-{
-    NdotV = clamp(NdotV, M_FLOAT_EPS, 1.0);
-    vec3 V = vec3(sqrt(1.0 - mx_square(NdotV)), 0, NdotV);
-
-    float radiance = 0.0;
-    const int SAMPLE_COUNT = 64;
-    for (int i = 0; i < SAMPLE_COUNT; i++)
-    {
-        vec2 Xi = mx_spherical_fibonacci(i, SAMPLE_COUNT);
-
-        // Compute the incoming light direction.
-        vec3 L = mx_uniform_sample_hemisphere(Xi);
-        
-        // Compute dot products for this sample.
-        float NdotL = clamp(L.z, M_FLOAT_EPS, 1.0);
-        float LdotV = clamp(dot(L, V), M_FLOAT_EPS, 1.0);
-
-        // Compute diffuse reflectance.
-        float reflectance = mx_oren_nayar_diffuse(NdotV, NdotL, LdotV, roughness);
-
-        // Add the radiance contribution of this sample.
-        //   uniform_pdf = 1 / (2 * PI)
-        //   radiance = (reflectance * NdotL) / (uniform_pdf * PI);
-        radiance += reflectance * NdotL;
-    }
-
-    // Apply global components and normalize.
-    radiance *= 2.0 / float(SAMPLE_COUNT);
-
-    // Return the final directional albedo.
-    return radiance;
-}
-
-float mx_oren_nayar_diffuse_dir_albedo(float NdotV, float roughness)
-{
-#if DIRECTIONAL_ALBEDO_METHOD == 2
-    float dirAlbedo = mx_oren_nayar_diffuse_dir_albedo_monte_carlo(NdotV, roughness);
-#else
-    float dirAlbedo = mx_oren_nayar_diffuse_dir_albedo_analytic(NdotV, roughness);
-#endif
-    return clamp(dirAlbedo, 0.0, 1.0);
-}
-
-// Improved Oren-Nayar diffuse from Fujii:
-// https://mimosa-pudica.net/improved-oren-nayar.html
-float mx_oren_nayar_fujii_diffuse_dir_albedo(float cosTheta, float roughness)
-{
-    float A = 1.0 / (1.0 + FUJII_CONSTANT_1 * roughness);
-    float B = roughness * A;
-    float Si = sqrt(max(0.0, 1.0 - mx_square(cosTheta)));
-    float G = Si * (mx_acos(clamp(cosTheta, -1.0, 1.0)) - Si * cosTheta) +
-              2.0 * ((Si / cosTheta) * (1.0 - Si * Si * Si) - Si) / 3.0;
-    return A + (B * G * M_PI_INV);
-}
-
-float mx_oren_nayar_fujii_diffuse_avg_albedo(float roughness)
-{
-    float A = 1.0 / (1.0 + FUJII_CONSTANT_1 * roughness);
-    return A * (1.0 + FUJII_CONSTANT_2 * roughness);
-}   
-
-// Energy-compensated Oren-Nayar diffuse from OpenPBR Surface:
-// https://academysoftwarefoundation.github.io/OpenPBR/
-vec3 mx_oren_nayar_compensated_diffuse(float NdotV, float NdotL, float LdotV, float roughness, vec3 color)
-{
-    float s = LdotV - NdotL * NdotV;
-    float stinv = (s > 0.0) ? s / max(NdotL, NdotV) : s;
-
-    // Compute the single-scatter lobe.
-    float A = 1.0 / (1.0 + FUJII_CONSTANT_1 * roughness);
-    vec3 lobeSingleScatter = color * A * (1.0 + roughness * stinv);
-
-    // Compute the multi-scatter lobe.
-    float dirAlbedoV = mx_oren_nayar_fujii_diffuse_dir_albedo(NdotV, roughness);
-    float dirAlbedoL = mx_oren_nayar_fujii_diffuse_dir_albedo(NdotL, roughness);
-    float avgAlbedo = mx_oren_nayar_fujii_diffuse_avg_albedo(roughness);
-    vec3 colorMultiScatter = mx_square(color) * avgAlbedo /
-                             (vec3(1.0) - color * max(0.0, 1.0 - avgAlbedo));
-    vec3 lobeMultiScatter = colorMultiScatter *
-                            max(M_FLOAT_EPS, 1.0 - dirAlbedoV) *
-                            max(M_FLOAT_EPS, 1.0 - dirAlbedoL) /
-                            max(M_FLOAT_EPS, 1.0 - avgAlbedo);
-
-    // Return the sum.
-    return lobeSingleScatter + lobeMultiScatter;
-}
-
-vec3 mx_oren_nayar_compensated_diffuse_dir_albedo(float cosTheta, float roughness, vec3 color)
-{
-    float dirAlbedo = mx_oren_nayar_fujii_diffuse_dir_albedo(cosTheta, roughness);
-    float avgAlbedo = mx_oren_nayar_fujii_diffuse_avg_albedo(roughness);
-    vec3 colorMultiScatter = mx_square(color) * avgAlbedo /
-                             (vec3(1.0) - color * max(0.0, 1.0 - avgAlbedo));
-    return mix(colorMultiScatter, color, dirAlbedo);
-}
-  
-// https://media.disneyanimation.com/uploads/production/publication_asset/48/asset/s2012_pbs_disney_brdf_notes_v3.pdf
-// Section 5.3
-float mx_burley_diffuse(float NdotV, float NdotL, float LdotH, float roughness)
-{
-    float F90 = 0.5 + (2.0 * roughness * mx_square(LdotH));
-    float refL = mx_fresnel_schlick(NdotL, 1.0, F90);
-    float refV = mx_fresnel_schlick(NdotV, 1.0, F90);
-    return refL * refV;
-}
-
-// Compute the directional albedo component of Burley diffuse for the given
-// view angle and roughness.  Curve fit provided by Stephen Hill.
-float mx_burley_diffuse_dir_albedo(float NdotV, float roughness)
-{
-    float x = NdotV;
-    float fit0 = 0.97619 - 0.488095 * mx_pow5(1.0 - x);
-    float fit1 = 1.55754 + (-2.02221 + (2.56283 - 1.06244 * x) * x) * x;
-    return mix(fit0, fit1, roughness);
-}
-
-// Evaluate the Burley diffusion profile for the given distance and diffusion shape.
-// Based on https://graphics.pixar.com/library/ApproxBSSRDF/
-vec3 mx_burley_diffusion_profile(float dist, vec3 shape)
-{
-    vec3 num1 = exp(-shape * dist);
-    vec3 num2 = exp(-shape * dist / 3.0);
-    float denom = max(dist, M_FLOAT_EPS);
-    return (num1 + num2) / denom;
-}
-
-// Integrate the Burley diffusion profile over a sphere of the given radius.
-// Inspired by Eric Penner's presentation in http://advances.realtimerendering.com/s2011/
-vec3 mx_integrate_burley_diffusion(vec3 N, vec3 L, float radius, vec3 mfp)
-{
-    float theta = mx_acos(dot(N, L));
-
-    // Estimate the Burley diffusion shape from mean free path.
-    vec3 shape = vec3(1.0) / max(mfp, 0.1);
-
-    // Integrate the profile over the sphere.
-    vec3 sumD = vec3(0.0);
-    vec3 sumR = vec3(0.0);
-    const int SAMPLE_COUNT = 32;
-    const float SAMPLE_WIDTH = (2.0 * M_PI) / float(SAMPLE_COUNT);
-    for (int i = 0; i < SAMPLE_COUNT; i++)
-    {
-        float x = -M_PI + (float(i) + 0.5) * SAMPLE_WIDTH;
-        float dist = radius * abs(2.0 * mx_sin(x * 0.5));
-        vec3 R = mx_burley_diffusion_profile(dist, shape);
-        sumD += R * max(mx_cos(theta + x), 0.0);
-        sumR += R;
-    }
-
-    return sumD / sumR;
-}
-
-vec3 mx_subsurface_scattering_approx(vec3 N, vec3 L, vec3 P, vec3 albedo, vec3 mfp)
-{
-    float curvature = length(fwidth(N)) / length(fwidth(P));
-    float radius = 1.0 / max(curvature, 0.01);
-    return albedo * mx_integrate_burley_diffusion(N, L, radius, mfp) / vec3(M_PI);
-}

package/staging_area/Blender/blender.shared/usd/usdMtlx/resources/libraries/pbrlib/genglsl/lib/mx_microfacet_sheen.glsl

@@ -1,189 +0,0 @@
-#include "mx_microfacet.glsl"
-
-// https://fpsunflower.github.io/ckulla/data/s2017_pbs_imageworks_sheen.pdf
-// Equation 2
-float mx_imageworks_sheen_NDF(float NdotH, float roughness)
-{
-    float invRoughness = 1.0 / max(roughness, 0.005);
-    float cos2 = NdotH * NdotH;
-    float sin2 = 1.0 - cos2;
-    return (2.0 + invRoughness) * pow(sin2, invRoughness * 0.5) / (2.0 * M_PI);
-}
-
-float mx_imageworks_sheen_brdf(float NdotL, float NdotV, float NdotH, float roughness)
-{
-    // Microfacet distribution.
-    float D = mx_imageworks_sheen_NDF(NdotH, roughness);
-
-    // Fresnel and geometry terms are ignored.
-    float F = 1.0;
-    float G = 1.0;
-
-    // We use a smoother denominator, as in:
-    // https://blog.selfshadow.com/publications/s2013-shading-course/rad/s2013_pbs_rad_notes.pdf
-    return D * F * G / (4.0 * (NdotL + NdotV - NdotL*NdotV));
-}
-
-// Rational quadratic fit to Monte Carlo data for Imageworks sheen directional albedo.
-float mx_imageworks_sheen_dir_albedo_analytic(float NdotV, float roughness)
-{
-    vec2 r = vec2(13.67300, 1.0) +
-             vec2(-68.78018, 61.57746) * NdotV +
-             vec2(799.08825, 442.78211) * roughness +
-             vec2(-905.00061, 2597.49308) * NdotV * roughness +
-             vec2(60.28956, 121.81241) * mx_square(NdotV) +
-             vec2(1086.96473, 3045.55075) * mx_square(roughness);
-    return r.x / r.y;
-}
-
-float mx_imageworks_sheen_dir_albedo_table_lookup(float NdotV, float roughness)
-{
-#if DIRECTIONAL_ALBEDO_METHOD == 1
-    if (textureSize($albedoTable, 0).x > 1)
-    {
-        return texture($albedoTable, vec2(NdotV, roughness)).b;
-    }
-#endif
-    return 0.0;
-}
-
-float mx_imageworks_sheen_dir_albedo_monte_carlo(float NdotV, float roughness)
-{
-    NdotV = clamp(NdotV, M_FLOAT_EPS, 1.0);
-    vec3 V = vec3(sqrt(1.0f - mx_square(NdotV)), 0, NdotV);
-
-    float radiance = 0.0;
-    const int SAMPLE_COUNT = 64;
-    for (int i = 0; i < SAMPLE_COUNT; i++)
-    {
-        vec2 Xi = mx_spherical_fibonacci(i, SAMPLE_COUNT);
-
-        // Compute the incoming light direction and half vector.
-        vec3 L = mx_uniform_sample_hemisphere(Xi);
-        vec3 H = normalize(L + V);
-        
-        // Compute dot products for this sample.
-        float NdotL = clamp(L.z, M_FLOAT_EPS, 1.0);
-        float NdotH = clamp(H.z, M_FLOAT_EPS, 1.0);
-
-        // Compute sheen reflectance.
-        float reflectance = mx_imageworks_sheen_brdf(NdotL, NdotV, NdotH, roughness);
-
-        // Add the radiance contribution of this sample.
-        //   uniform_pdf = 1 / (2 * PI)
-        //   radiance = reflectance * NdotL / uniform_pdf;
-        radiance += reflectance * NdotL * 2.0 * M_PI;
-    }
-
-    // Return the final directional albedo.
-    return radiance / float(SAMPLE_COUNT);
-}
-
-float mx_imageworks_sheen_dir_albedo(float NdotV, float roughness)
-{
-#if DIRECTIONAL_ALBEDO_METHOD == 0
-    float dirAlbedo = mx_imageworks_sheen_dir_albedo_analytic(NdotV, roughness);
-#elif DIRECTIONAL_ALBEDO_METHOD == 1
-    float dirAlbedo = mx_imageworks_sheen_dir_albedo_table_lookup(NdotV, roughness);
-#else
-    float dirAlbedo = mx_imageworks_sheen_dir_albedo_monte_carlo(NdotV, roughness);
-#endif
-    return clamp(dirAlbedo, 0.0, 1.0);
-}
-
-// The following functions are adapted from https://github.com/tizian/ltc-sheen.
-// "Practical Multiple-Scattering Sheen Using Linearly Transformed Cosines", Zeltner et al.
-
-// Gaussian fit to directional albedo table.
-float mx_zeltner_sheen_dir_albedo(float x, float y)
-{
-    float s = y*(0.0206607 + 1.58491*y)/(0.0379424 + y*(1.32227 + y));
-    float m = y*(-0.193854 + y*(-1.14885 + y*(1.7932 - 0.95943*y*y)))/(0.046391 + y);
-    float o = y*(0.000654023 + (-0.0207818 + 0.119681*y)*y)/(1.26264 + y*(-1.92021 + y));
-    return exp(-0.5*mx_square((x - m)/s))/(s*sqrt(2.0*M_PI)) + o;
-}
-
-// Rational fits to LTC matrix coefficients.
-float mx_zeltner_sheen_ltc_aInv(float x, float y)
-{
-    return (2.58126*x + 0.813703*y)*y/(1.0 + 0.310327*x*x + 2.60994*x*y);
-}
-
-float mx_zeltner_sheen_ltc_bInv(float x, float y)
-{
-    return sqrt(1.0 - x)*(y - 1.0)*y*y*y/(0.0000254053 + 1.71228*x - 1.71506*x*y + 1.34174*y*y);
-}
-
-// V and N are assumed to be unit vectors.
-mat3 mx_orthonormal_basis_ltc(vec3 V, vec3 N, float NdotV)
-{
-    // Generate a tangent vector in the plane of V and N.
-    // This required to correctly orient the LTC lobe.
-    vec3 X = V - N*NdotV;
-    float lenSqr = dot(X, X);
-    if (lenSqr > 0.0)
-    {
-        X *= mx_inversesqrt(lenSqr);
-        vec3 Y = cross(N, X);
-        return mat3(X, Y, N);
-    }
-
-    // If lenSqr == 0, then V == N, so any orthonormal basis will do.
-    return mx_orthonormal_basis(N);
-}
-
-// Multiplication by directional albedo is handled by the calling function.
-float mx_zeltner_sheen_brdf(vec3 L, vec3 V, vec3 N, float NdotV, float roughness)
-{
-    mat3 toLTC = transpose(mx_orthonormal_basis_ltc(V, N, NdotV));
-    vec3 w = toLTC * L;
-
-    float aInv = mx_zeltner_sheen_ltc_aInv(NdotV, roughness);
-    float bInv = mx_zeltner_sheen_ltc_bInv(NdotV, roughness);
-
-    // Transform w to original configuration (clamped cosine).
-    //                 |aInv    0 bInv|
-    // wo = M^-1 . w = |   0 aInv    0| . w
-    //                 |   0    0    1|
-    vec3 wo = vec3(aInv*w.x + bInv*w.z, aInv * w.y, w.z);
-    float lenSqr = dot(wo, wo);
-
-    // D(w) = Do(M^-1.w / ||M^-1.w||) . |M^-1| / ||M^-1.w||^3
-    //      = Do(M^-1.w) . |M^-1| / ||M^-1.w||^4
-    //      = Do(wo) . |M^-1| / dot(wo, wo)^2
-    //      = Do(wo) . aInv^2 / dot(wo, wo)^2
-    //      = Do(wo) . (aInv / dot(wo, wo))^2
-    return max(wo.z, 0.0) * M_PI_INV * mx_square(aInv / lenSqr);
-}
-
-vec3 mx_zeltner_sheen_importance_sample(vec2 Xi, vec3 V, vec3 N, float roughness, out float pdf)
-{
-    float NdotV = clamp(dot(N, V), 0.0, 1.0);
-    roughness = clamp(roughness, 0.01, 1.0); // Clamp to range of original impl.
-
-    vec3 wo = mx_cosine_sample_hemisphere(Xi);
-
-    float aInv = mx_zeltner_sheen_ltc_aInv(NdotV, roughness);
-    float bInv = mx_zeltner_sheen_ltc_bInv(NdotV, roughness);
-
-    // Transform wo from original configuration (clamped cosine).
-    //              |1/aInv      0 -bInv/aInv|
-    // w = M . wo = |     0 1/aInv          0| . wo
-    //              |     0      0          1|    
-    vec3 w = vec3(wo.x/aInv - wo.z*bInv/aInv, wo.y / aInv, wo.z);
-
-    float lenSqr = dot(w, w);
-    w *= mx_inversesqrt(lenSqr);
-
-    // D(w) = Do(wo) . ||M.wo||^3 / |M|
-    //      = Do(wo / ||M.wo||) . ||M.wo||^4 / |M| 
-    //      = Do(w) . ||M.wo||^4 / |M| (possible because M doesn't change z component)
-    //      = Do(w) . dot(w, w)^2 * aInv^2
-    //      = Do(w) . (aInv * dot(w, w))^2
-    pdf = max(w.z, 0.0) * M_PI_INV * mx_square(aInv * lenSqr);
-
-    mat3 fromLTC = mx_orthonormal_basis_ltc(V, N, NdotV);
-    w = fromLTC * w;
-
-    return w;
-}