vapid 0.1.0

data/lib/vapid/vendor/trix/test/src/unit/attachment_test.coffee

@@ -0,0 +1,23 @@
+{assert, test, testGroup} = Trix.TestHelpers
+
+testGroup "Trix.Attachment", ->
+  previewableTypes = "image image/gif image/png image/jpg".split(" ")
+  nonPreviewableTypes = "image/tiff application/foo".split(" ")
+
+  createAttachment = (attributes) ->
+    new Trix.Attachment attributes
+
+  for contentType in previewableTypes then do (contentType) ->
+    test "#{contentType} content type is previewable", ->
+      assert.ok createAttachment({contentType}).isPreviewable()
+
+  for contentType in nonPreviewableTypes then do (contentType) ->
+    test "#{contentType} content type is NOT previewable", ->
+      assert.notOk createAttachment({contentType}).isPreviewable()
+
+  test "'previewable' attribute determines previewability", ->
+    attrs = previewable: true, contentType: nonPreviewableTypes[0]
+    assert.ok createAttachment(attrs).isPreviewable()
+
+    attrs = previewable: false, contentType: previewableTypes[0]
+    assert.notOk createAttachment(attrs).isPreviewable()

data/lib/vapid/vendor/trix/test/src/unit/block_test.coffee

@@ -0,0 +1,22 @@
+{assert, test, testGroup} = Trix.TestHelpers
+
+testGroup "Trix.Block", ->
+  test "consolidating blocks creates text with one blockBreak piece", ->
+    blockA = new Trix.Block Trix.Text.textForStringWithAttributes("a")
+    blockB = new Trix.Block Trix.Text.textForStringWithAttributes("b")
+    consolidatedBlock = blockA.consolidateWith(blockB)
+    pieces = consolidatedBlock.text.getPieces()
+
+    assert.equal pieces.length, 2, JSON.stringify(pieces)
+    assert.deepEqual pieces[0].getAttributes(), {}
+    assert.deepEqual pieces[1].getAttributes(), { blockBreak: true }
+    assert.equal consolidatedBlock.toString(), "a\nb\n"
+
+  test "consolidating empty blocks creates text with one blockBreak piece", ->
+    consolidatedBlock = new Trix.Block().consolidateWith(new Trix.Block)
+    pieces = consolidatedBlock.text.getPieces()
+
+    assert.equal pieces.length, 2, JSON.stringify(pieces)
+    assert.deepEqual pieces[0].getAttributes(), {}
+    assert.deepEqual pieces[1].getAttributes(), { blockBreak: true }
+    assert.equal consolidatedBlock.toString(), "\n\n"

data/lib/vapid/vendor/trix/test/src/unit/composition_test.coffee

@@ -0,0 +1,13 @@
+{assert, test, testGroup} = Trix.TestHelpers
+
+composition = null
+setup = ->
+  composition = new Trix.Composition
+  composition.delegate = new Trix.TestCompositionDelegate
+
+testGroup "Trix.Composition", {setup}, ->
+  test "deleteInDirection respects UTF-16 character boundaries", ->
+    composition.insertString("abc😭")
+    composition.deleteInDirection("backward")
+    composition.insertString("d")
+    assert.equal composition.document.toString(), "abcd\n"

data/lib/vapid/vendor/trix/test/src/unit/document_test.coffee

@@ -0,0 +1,11 @@
+{assert, test, testGroup} = Trix.TestHelpers
+
+testGroup "Trix.Document", ->
+  createDocumentWithAttachment = (attachment) ->
+    text = Trix.Text.textForAttachmentWithAttributes(attachment)
+    new Trix.Document [new Trix.Block text]
+
+  test "documents with different attachments are not assert.equal", ->
+    a = createDocumentWithAttachment(new Trix.Attachment url: "a")
+    b = createDocumentWithAttachment(new Trix.Attachment url: "b")
+    assert.notOk a.isEqualTo(b)

data/lib/vapid/vendor/trix/test/src/unit/document_view_test.coffee

@@ -0,0 +1,6 @@
+{assert, test, testGroup} = Trix.TestHelpers
+
+testGroup "Trix.DocumentView", ->
+  eachFixture (name, details) ->
+    test name, ->
+      assert.documentHTMLEqual details.document, details.html

data/lib/vapid/vendor/trix/test/src/unit/html_parser_test.coffee

@@ -0,0 +1,162 @@
+{after, assert, getHTML, test, testGroup} = Trix.TestHelpers
+
+testGroup "Trix.HTMLParser", ->
+  eachFixture (name, {html, serializedHTML, document}) ->
+    test name, ->
+      parsedDocument = Trix.HTMLParser.parse(html).getDocument()
+      assert.documentHTMLEqual parsedDocument.copyUsingObjectsFromDocument(document), html
+
+  eachFixture (name, {html, serializedHTML, document}) ->
+    if serializedHTML?
+      test "#{name} (serialized)", ->
+        parsedDocument = Trix.HTMLParser.parse(serializedHTML).getDocument()
+        assert.documentHTMLEqual parsedDocument.copyUsingObjectsFromDocument(document), html
+
+  test "parses absolute image URLs", ->
+    src = "#{getOrigin()}/test_helpers/fixtures/logo.png"
+    pattern = ///src="#{src}"///
+    html = """<img src="#{src}">"""
+
+    finalHTML = getHTML(Trix.HTMLParser.parse(html).getDocument())
+    assert.ok pattern.test(finalHTML), "#{pattern} not found in #{JSON.stringify(finalHTML)}"
+
+  test "parses relative image URLs", ->
+    src = "/test_helpers/fixtures/logo.png"
+    pattern = ///src="#{src}"///
+    html = """<img src="#{src}">"""
+
+    finalHTML = getHTML(Trix.HTMLParser.parse(html).getDocument())
+    assert.ok pattern.test(finalHTML), "#{pattern} not found in #{JSON.stringify(finalHTML)}"
+
+  test "parses unfamiliar html", ->
+    html = """<meta charset="UTF-8"><span style="font-style: italic">abc</span><span>d</span><section style="margin:0"><blink>123</blink><a href="http://example.com">45<b>6</b></a>x<br />y</section><p style="margin:0">9</p>"""
+    expectedHTML = """<div><!--block--><em>abc</em>d</div><div><!--block-->123<a href="http://example.com">45<strong>6</strong></a>x<br>y</div><div><!--block-->9</div>"""
+    assert.documentHTMLEqual Trix.HTMLParser.parse(html).getDocument(), expectedHTML
+
+  test "ignores leading whitespace before <meta> tag", ->
+    html = """ \n <meta charset="UTF-8"><pre>abc</pre>"""
+    expectedHTML = """<pre><!--block-->abc</pre>"""
+    assert.documentHTMLEqual Trix.HTMLParser.parse(html).getDocument(), expectedHTML
+
+  test "ignores content after </html>", ->
+    html = """
+    <html xmlns:o="urn:schemas-microsoft-com:office:office" xmlns:w="urn:schemas-microsoft-com:office:word" xmlns:m="http://schemas.microsoft.com/office/2004/12/omml" xmlns="http://www.w3.org/TR/REC-html40">
+    <head>
+    <meta http-equiv=Content-Type content="text/html; charset=utf-8">
+    <meta name=ProgId content=Word.Document>
+    </head>
+
+    <body lang=EN-US link=blue vlink="#954F72" style='tab-interval:.5in'>
+    <!--StartFragment--><span lang=EN style='font-size:12.0pt;font-family:
+    "Arial",sans-serif;mso-fareast-font-family:"Times New Roman";mso-ansi-language:
+    EN;mso-fareast-language:EN-US;mso-bidi-language:AR-SA'>abc</span><!--EndFragment-->
+    </body>
+
+    </html>
+    TAxelFCg��K��
+    """
+    expectedHTML = """<div><!--block-->abc</div>"""
+    assert.documentHTMLEqual Trix.HTMLParser.parse(html).getDocument(), expectedHTML
+
+  test "ignores whitespace between block elements", ->
+    html = """<div>a</div> \n <div>b</div>     <article>c</article>  \n\n <section>d</section> """
+    expectedHTML = """<div><!--block-->a</div><div><!--block-->b</div><div><!--block-->c</div><div><!--block-->d</div>"""
+    assert.documentHTMLEqual Trix.HTMLParser.parse(html).getDocument(), expectedHTML
+
+  test "ingores whitespace between nested block elements", ->
+    html = """<ul> <li>a</li> \n  <li>b</li>  </ul><div>  <div> \n <blockquote>c</blockquote>\n </div>  \n</div>"""
+    expectedHTML = """<ul><li><!--block-->a</li><li><!--block-->b</li></ul><blockquote><!--block-->c</blockquote>"""
+    assert.documentHTMLEqual Trix.HTMLParser.parse(html).getDocument(), expectedHTML
+
+  test "ignores inline whitespace that can't be displayed", ->
+    html = """ a  \n b    <span>c\n</span><span>d  \ne </span> f <span style="white-space: pre">  g\n\n h  </span>"""
+    expectedHTML = """<div><!--block-->a b c d e f &nbsp; g<br><br>&nbsp;h &nbsp;</div>"""
+    assert.documentHTMLEqual Trix.HTMLParser.parse(html).getDocument(), expectedHTML
+
+  test "parses block elements with leading breakable whitespace", ->
+    html = """<blockquote> <span>a</span> <blockquote>\n <strong>b</strong> <pre> <span>c</span></pre></blockquote></blockquote>"""
+    expectedHTML = """<blockquote><!--block-->a<blockquote><!--block--><strong>b</strong><pre><!--block--> c</pre></blockquote></blockquote>"""
+    assert.documentHTMLEqual Trix.HTMLParser.parse(html).getDocument(), expectedHTML
+
+  test "parses block elements with leading non-breaking whitespace", ->
+    html = """<blockquote>&nbsp;<span>a</span></blockquote>"""
+    expectedHTML = """<blockquote><!--block-->&nbsp;a</blockquote>"""
+    assert.documentHTMLEqual Trix.HTMLParser.parse(html).getDocument(), expectedHTML
+
+  test "converts newlines to spaces", ->
+    html = "<div>a\nb \nc \n d \n\ne</div><pre>1\n2</pre>"
+    expectedHTML = """<div><!--block-->a b c d e</div><pre><!--block-->1\n2</pre>"""
+    assert.documentHTMLEqual Trix.HTMLParser.parse(html).getDocument(), expectedHTML
+
+  test "parses entire HTML document", ->
+    html = """<html><head><style>.bold {font-weight: bold}</style></head><body><span class="bold">abc</span></body></html>"""
+    expectedHTML = """<div><!--block--><strong>abc</strong></div>"""
+    assert.documentHTMLEqual Trix.HTMLParser.parse(html).getDocument(), expectedHTML
+
+  test "parses inline element following block element", ->
+    html = """<blockquote>abc</blockquote><strong>123</strong>"""
+    expectedHTML = """<blockquote><!--block-->abc</blockquote><div><!--block--><strong>123</strong></div>"""
+    assert.documentHTMLEqual Trix.HTMLParser.parse(html).getDocument(), expectedHTML
+
+  test "parses whitespace-only text nodes without a containing block element", ->
+    html = """a <strong>b</strong> <em>c</em>"""
+    expectedHTML = """<div><!--block-->a <strong>b</strong> <em>c</em></div>"""
+    assert.documentHTMLEqual Trix.HTMLParser.parse(html).getDocument(), expectedHTML
+
+  test "parses spaces around cursor targets", ->
+    cursorTarget = Trix.selectionElements.create("cursorTarget").outerHTML
+    html = """<div>a #{cursorTarget}<span>b</span>#{cursorTarget} c</div>"""
+    expectedHTML = """<div><!--block-->a b c</div>"""
+    assert.documentHTMLEqual Trix.HTMLParser.parse(html).getDocument(), expectedHTML
+
+  test "parses spanned text elements that don't have a parser function", ->
+    assert.notOk Trix.config.textAttributes.strike.parser
+    html = """<del>a <strong>b</strong></del>"""
+    expectedHTML = """<div><!--block--><del>a </del><strong><del>b</del></strong></div>"""
+    assert.documentHTMLEqual Trix.HTMLParser.parse(html).getDocument(), expectedHTML
+
+  test "translates tables into plain text", ->
+    html = """<table><tr><td>a</td><td>b</td></tr><tr><td>1</td><td><p>2</p></td></tr><table>"""
+    expectedHTML = """<div><!--block-->a | b<br>1 | 2</div>"""
+    assert.documentHTMLEqual Trix.HTMLParser.parse(html).getDocument(), expectedHTML
+
+  test "translates block element margins to newlines", ->
+    html = """<p style="margin: 0 0 1em 0">a</p><p style="margin: 0">b</p><article style="margin: 1em 0 0 0">c</article>"""
+    expectedHTML = """<div><!--block-->a<br><br></div><div><!--block-->b</div><div><!--block--><br>c</div>"""
+    document = Trix.HTMLParser.parse(html).getDocument()
+    assert.documentHTMLEqual document, expectedHTML
+
+  test "ignores text nodes in script elements", ->
+    html = """<div>a<script>alert("b")</script></div>"""
+    expectedHTML = """<div><!--block-->a</div>"""
+    assert.documentHTMLEqual Trix.HTMLParser.parse(html).getDocument(), expectedHTML
+
+  test "sanitizes unsafe html", (done) ->
+    window.unsanitized = []
+    Trix.HTMLParser.parse """
+      <img onload="window.unsanitized.push('img.onload');" src="#{TEST_IMAGE_URL}">
+      <img onerror="window.unsanitized.push('img.onerror');" src="data:image/gif;base64,TOTALLYBOGUS">
+      <script>
+        window.unsanitized.push('script tag');
+      </script>
+    """
+    after 20, ->
+      assert.deepEqual window.unsanitized, []
+      delete window.unsanitized
+      done()
+
+  test "parses attachment caption from large html string", (done) ->
+    html = fixtures["image attachment with edited caption"].html
+
+    for i in [1..30]
+      html += fixtures["image attachment"].html
+
+    for n in [1..3]
+      attachmentPiece = Trix.HTMLParser.parse(html).getDocument().getAttachmentPieces()[0]
+      assert.equal attachmentPiece.getCaption(), "Example"
+
+    done()
+
+getOrigin = ->
+  {protocol, hostname, port} = window.location
+  "#{protocol}//#{hostname}#{if port then ":#{port}" else ""}"

data/lib/vapid/vendor/trix/test/src/unit/location_mapper_test.coffee

@@ -0,0 +1,185 @@
+{assert, test, testGroup} = Trix.TestHelpers
+
+testGroup "Trix.LocationMapper", ->
+  test "findLocationFromContainerAndOffset", ->
+    setDocument [
+      # <trix-editor>
+      # 0 <div>
+      #     0 <!--block-->
+      #     1 <strong>
+      #         0 a
+      #         1 <br>
+      #       </strong>
+      #     2 <br>
+      #   </div>
+      # 1 <blockquote>
+      #     0 <!--block-->
+      #     1 b😭cd
+      #     2 <span data-trix-cursor-target>
+      #         0 (zero-width space)
+      #       </span>
+      #     3 <a href="data:image/png," data-trix-attachment="" ...>
+      #         0 <figure ...>...</figure>
+      #       </a>
+      #     4 <span data-trix-cursor-target>
+      #         0 (zero-width space)
+      #       </span>
+      #     5 e
+      #   </blockquote>
+      # </trix-editor>
+      {"text":[
+        {"type":"string","attributes":{"bold":true},"string":"a\n"},
+        {"type":"string","attributes":{"blockBreak":true},"string":"\n"}
+      ],"attributes":[]},
+      {"text":[
+        {"type":"string","attributes":{},"string":"b😭cd"},
+        {"type":"attachment","attributes":{},"attachment":{"contentType":"image/png","filename":"x.png","filesize":0,"height":13,"href":TEST_IMAGE_URL,"identifier":"1","url":TEST_IMAGE_URL,"width":15}},
+        {"type":"string","attributes":{},"string":"e"},
+        {"type":"string","attributes":{"blockBreak":true},"string":"\n"}
+      ],"attributes":["quote"]}
+    ]
+
+    assertions = [
+      { location: [0, 0],  container: [],         offset: 0 }
+      { location: [0, 0],  container: [0],        offset: 0 }
+      { location: [0, 0],  container: [0],        offset: 1 }
+      { location: [0, 0],  container: [0, 1],     offset: 0 }
+      { location: [0, 0],  container: [0, 1, 0],  offset: 0 }
+      { location: [0, 1],  container: [0, 1, 0],  offset: 1 }
+      { location: [0, 1],  container: [0, 1],     offset: 1 }
+      { location: [0, 2],  container: [0, 1],     offset: 2 }
+      { location: [0, 2],  container: [0],        offset: 2 }
+      { location: [0, 3],  container: [],         offset: 1 }
+      { location: [0, 3],  container: [1],        offset: 0 }
+      { location: [1, 0],  container: [1],        offset: 1 }
+      { location: [1, 0],  container: [1, 1],     offset: 0 }
+      { location: [1, 1],  container: [1, 1],     offset: 1 }
+      { location: [1, 2],  container: [1, 1],     offset: 2 }
+      { location: [1, 3],  container: [1, 1],     offset: 3 }
+      { location: [1, 4],  container: [1, 1],     offset: 4 }
+      { location: [1, 5],  container: [1, 1],     offset: 5 }
+      { location: [1, 6],  container: [1, 1],     offset: 6 }
+      { location: [1, 5],  container: [1],        offset: 2 }
+      { location: [1, 5],  container: [1, 2],     offset: 0 }
+      { location: [1, 5],  container: [1, 2],     offset: 1 }
+      { location: [1, 5],  container: [1],        offset: 3 }
+      { location: [1, 5],  container: [1, 3],     offset: 0 }
+      { location: [1, 5],  container: [1, 3],     offset: 1 }
+      { location: [1, 6],  container: [1],        offset: 4 }
+      { location: [1, 6],  container: [1, 4],     offset: 0 }
+      { location: [1, 6],  container: [1, 4],     offset: 1 }
+      { location: [1, 6],  container: [1],        offset: 5 }
+      { location: [1, 6],  container: [1, 5],     offset: 0 }
+      { location: [1, 7],  container: [1, 5],     offset: 1 }
+      { location: [1, 7],  container: [],         offset: 2 }
+    ]
+
+    for assertion in assertions
+      path = assertion.container
+      container = findContainer(path)
+      offset = assertion.offset
+
+      expectedLocation = index: assertion.location[0], offset: assertion.location[1]
+      actualLocation = mapper.findLocationFromContainerAndOffset(container, offset)
+
+      assert.equal format(actualLocation), format(expectedLocation),
+        "#{describe(container)} at [#{path.join(", ")}], offset #{offset} = #{format(expectedLocation)}"
+
+
+  test "findContainerAndOffsetFromLocation: (0/0)", ->
+    setDocument [
+      # <trix-editor>
+      # 0 <ul>
+      #     0 <li>
+      #         0 <!--block-->
+      #         1 <br>
+      #       </li>
+      #   </ul>
+      # </trix-editor>
+      {"text":[
+        {"type":"string","attributes":{"blockBreak":true},"string":"\n"}
+      ],"attributes":["bulletList","bullet"]},
+    ]
+
+    location = index: 0, offset: 0
+    container = findContainer([0, 0])
+    offset = 1
+
+    assert.deepEqual mapper.findContainerAndOffsetFromLocation(location), [container, offset]
+
+  test "findContainerAndOffsetFromLocation after newline in formatted text", ->
+    setDocument [
+      # <trix-editor>
+      # 0 <div>
+      #     0 <!--block-->
+      #     0 <strong>
+      #         0 a
+      #         1 <br>
+      #       </strong>
+      #   </div>
+      # </trix-editor>
+      {"text":[
+        {"type":"string","attributes":{"bold":true},"string":"a\n"}
+        {"type":"string","attributes":{"blockBreak":true},"string":"\n"}
+      ],"attributes":[]},
+    ]
+
+    location = index: 0, offset: 2
+    container = findContainer([0])
+    offset = 2
+
+    assert.deepEqual mapper.findContainerAndOffsetFromLocation(location), [container, offset]
+
+  test "findContainerAndOffsetFromLocation after nested block", ->
+    setDocument [
+      # <trix-editor>
+      #   <blockquote>
+      #     <ul>
+      #       <li>
+      #         <!--block-->
+      #         a
+      #       </li>
+      #     </ul>
+      #     <!--block-->
+      #     <br>
+      #   </blockquote>
+      # </trix-editor>
+      {
+        "text":[{"type":"string","attributes":{},"string":"a"},{"type":"string","attributes":{"blockBreak":true},"string":"\n"}],
+        "attributes":["quote","bulletList","bullet"]
+      },
+      {
+        "text":[{"type":"string","attributes":{"blockBreak":true},"string":"\n"}],
+        "attributes":["quote"]
+      }
+    ]
+
+    location = index: 1, offset: 0
+    container = findContainer([0])
+    offset = 2
+
+    assert.deepEqual mapper.findContainerAndOffsetFromLocation(location), [container, offset]
+
+# ---
+document = null
+element = null
+mapper = null
+
+setDocument = (json) ->
+  document = Trix.Document.fromJSON(json)
+  element = Trix.DocumentView.render(document)
+  mapper = new Trix.LocationMapper element
+
+findContainer = (path) ->
+  el = element
+  el = el.childNodes[index] for index in path
+  el
+
+format = ({index, offset}) ->
+  "#{index}/#{offset}"
+
+describe = (node) ->
+  if node.nodeType is Node.TEXT_NODE
+    "text node #{JSON.stringify(node.textContent)}"
+  else
+    "container <#{node.tagName.toLowerCase()}>"

data/lib/vapid/vendor/trix/test/src/unit/mutation_observer_test.coffee

@@ -0,0 +1,84 @@
+{assert, defer, test, testGroup} = Trix.TestHelpers
+
+observer = null
+element = null
+summaries = []
+
+install = (html) ->
+  element = document.createElement("div")
+  element.innerHTML = html if html
+  observer = new Trix.MutationObserver element
+  observer.delegate =
+    elementDidMutate: (summary) ->
+      summaries.push(summary)
+
+uninstall = ->
+  observer?.stop()
+  observer = null
+  element = null
+  summaries = []
+
+observerTest = (name, options = {}, callback) ->
+  test name, (done) ->
+    install(options.html)
+    callback ->
+      uninstall()
+      done()
+
+
+testGroup "Trix.MutationObserver", ->
+  observerTest "add character", html: "a", (done) ->
+    element.firstChild.data += "b"
+    defer ->
+      assert.equal summaries.length, 1
+      assert.deepEqual summaries[0], textAdded: "b"
+      done()
+
+  observerTest "remove character", html: "ab", (done) ->
+    element.firstChild.data = "a"
+    defer ->
+      assert.equal summaries.length, 1
+      assert.deepEqual summaries[0], textDeleted: "b"
+      done()
+
+  observerTest "replace character", html: "ab", (done) ->
+    element.firstChild.data = "ac"
+    defer ->
+      assert.equal summaries.length, 1
+      assert.deepEqual summaries[0], textAdded: "c", textDeleted: "b"
+      done()
+
+  observerTest "add <br>", html: "a", (done) ->
+    element.appendChild(document.createElement("br"))
+    defer ->
+      assert.equal summaries.length, 1
+      assert.deepEqual summaries[0], textAdded: "\n"
+      done()
+
+  observerTest "remove <br>", html: "a<br>", (done) ->
+    element.removeChild(element.lastChild)
+    defer ->
+      assert.equal summaries.length, 1
+      assert.deepEqual summaries[0], textDeleted: "\n"
+      done()
+
+  observerTest "remove block comment", html: "<div><!--block-->a</div>", (done) ->
+    element.firstChild.removeChild(element.firstChild.firstChild)
+    defer ->
+      assert.equal summaries.length, 1
+      assert.deepEqual summaries[0], textDeleted: "\n"
+      done()
+
+  observerTest "remove formatted element", html: "a<strong>b</strong>", (done) ->
+    element.removeChild(element.lastChild)
+    defer ->
+      assert.equal summaries.length, 1
+      assert.deepEqual summaries[0], textDeleted: "b"
+      done()
+
+  observerTest "remove nested formatted elements", html: "a<strong>b<em>c</em></strong>", (done) ->
+    element.removeChild(element.lastChild)
+    defer ->
+      assert.equal summaries.length, 1
+      assert.deepEqual summaries[0], textDeleted: "bc"
+      done()