vapid 0.1.0

data/lib/vapid/vendor/trix/src/trix/models/attachment.coffee

@@ -0,0 +1,157 @@
+#= require trix/operations/image_preload_operation
+
+class Trix.Attachment extends Trix.Object
+  @previewablePattern: /^image(\/(gif|png|jpe?g)|$)/
+
+  @attachmentForFile: (file) ->
+    attributes = @attributesForFile(file)
+    attachment = new this attributes
+    attachment.setFile(file)
+    attachment
+
+  @attributesForFile: (file) ->
+    new Trix.Hash
+      filename:    file.name
+      filesize:    file.size
+      contentType: file.type
+
+  @fromJSON: (attachmentJSON) ->
+    new this attachmentJSON
+
+  constructor: (attributes = {}) ->
+    super
+    @attributes = Trix.Hash.box(attributes)
+    @didChangeAttributes()
+
+  getAttribute: (attribute) ->
+    @attributes.get(attribute)
+
+  hasAttribute: (attribute) ->
+    @attributes.has(attribute)
+
+  getAttributes: ->
+    @attributes.toObject()
+
+  setAttributes: (attributes = {}) ->
+    newAttributes = @attributes.merge(attributes)
+    unless @attributes.isEqualTo(newAttributes)
+      @attributes = newAttributes
+      @didChangeAttributes()
+      @delegate?.attachmentDidChangeAttributes?(this)
+
+  didChangeAttributes: ->
+    if @isPreviewable()
+      @preloadURL()
+
+  isPending: ->
+    @file? and not (@getURL() or @getHref())
+
+  isPreviewable: ->
+    if @attributes.has("previewable")
+      @attributes.get("previewable")
+    else
+      @constructor.previewablePattern.test(@getContentType())
+
+  getType: ->
+    if @hasContent()
+      "content"
+    else if @isPreviewable()
+      "preview"
+    else
+      "file"
+
+  getURL: ->
+    @attributes.get("url")
+
+  getHref: ->
+    @attributes.get("href")
+
+  getFilename: ->
+    @attributes.get("filename") ? ""
+
+  getFilesize: ->
+    @attributes.get("filesize")
+
+  getFormattedFilesize: ->
+    filesize = @attributes.get("filesize")
+    if typeof filesize is "number"
+      Trix.config.fileSize.formatter(filesize)
+    else
+      ""
+
+  getExtension: ->
+    @getFilename().match(/\.(\w+)$/)?[1].toLowerCase()
+
+  getContentType: ->
+    @attributes.get("contentType")
+
+  hasContent: ->
+    @attributes.has("content")
+
+  getContent: ->
+    @attributes.get("content")
+
+  getWidth: ->
+    @attributes.get("width")
+
+  getHeight: ->
+    @attributes.get("height")
+
+  getFile: ->
+    @file
+
+  setFile: (@file) ->
+    if @isPreviewable()
+      @preloadFile()
+
+  releaseFile: =>
+    @releasePreloadedFile()
+    @file = null
+
+  getUploadProgress: ->
+    @uploadProgress ? 0
+
+  setUploadProgress: (value) ->
+    unless @uploadProgress is value
+      @uploadProgress = value
+      @uploadProgressDelegate?.attachmentDidChangeUploadProgress?(this)
+
+  toJSON: ->
+    @getAttributes()
+
+  getCacheKey: ->
+    [super, @attributes.getCacheKey(), @getPreviewURL()].join("/")
+
+  # Previewable
+
+  getPreviewURL: ->
+    @previewURL or @preloadingURL
+
+  setPreviewURL: (url) ->
+    unless url is @getPreviewURL()
+      @previewURL = url
+      @previewDelegate?.attachmentDidChangePreviewURL?(this)
+      @delegate?.attachmentDidChangePreviewURL?(this)
+
+  preloadURL: ->
+    @preload(@getURL(), @releaseFile)
+
+  preloadFile: ->
+    if @file
+      @fileObjectURL = URL.createObjectURL(@file)
+      @preload(@fileObjectURL)
+
+  releasePreloadedFile: ->
+    if @fileObjectURL
+      URL.revokeObjectURL(@fileObjectURL)
+      @fileObjectURL = null
+
+  preload: (url, callback) ->
+    if url and url isnt @getPreviewURL()
+      @preloadingURL = url
+      operation = new Trix.ImagePreloadOperation url
+      operation.then ({width, height}) =>
+        @setAttributes({width, height})
+        @preloadingURL = null
+        @setPreviewURL(url)
+        callback?()

data/lib/vapid/vendor/trix/src/trix/models/attachment_manager.coffee

@@ -0,0 +1,24 @@
+#= require trix/models/managed_attachment
+
+class Trix.AttachmentManager extends Trix.BasicObject
+  constructor: (attachments = []) ->
+    @managedAttachments = {}
+    @manageAttachment(attachment) for attachment in attachments
+
+  getAttachments: ->
+    attachment for id, attachment of @managedAttachments
+
+  manageAttachment: (attachment) ->
+    @managedAttachments[attachment.id] ?= new Trix.ManagedAttachment this, attachment
+
+  attachmentIsManaged: (attachment) ->
+    attachment.id of @managedAttachments
+
+  requestRemovalOfAttachment: (attachment) ->
+    if @attachmentIsManaged(attachment)
+      @delegate?.attachmentManagerDidRequestRemovalOfAttachment?(attachment)
+
+  unmanageAttachment: (attachment) ->
+    managedAttachment = @managedAttachments[attachment.id]
+    delete @managedAttachments[attachment.id]
+    managedAttachment

data/lib/vapid/vendor/trix/src/trix/models/attachment_piece.coffee

@@ -0,0 +1,47 @@
+#= require trix/models/attachment
+#= require trix/models/piece
+
+Trix.Piece.registerType "attachment", class Trix.AttachmentPiece extends Trix.Piece
+  @fromJSON: (pieceJSON) ->
+    new this Trix.Attachment.fromJSON(pieceJSON.attachment), pieceJSON.attributes
+
+  constructor: (@attachment) ->
+    super
+    @length = 1
+    @ensureAttachmentExclusivelyHasAttribute("href")
+
+  ensureAttachmentExclusivelyHasAttribute: (attribute) ->
+    if @hasAttribute(attribute) and @attachment.hasAttribute(attribute)
+      @attributes = @attributes.remove(attribute)
+
+  getValue: ->
+    @attachment
+
+  isSerializable: ->
+    not @attachment.isPending()
+
+  getCaption: ->
+    @attributes.get("caption") ? ""
+
+  getAttributesForAttachment: ->
+    @attributes.slice(["caption"])
+
+  canBeGrouped: ->
+    super and not @attachment.hasAttribute("href")
+
+  isEqualTo: (piece) ->
+    super and @attachment.id is piece?.attachment?.id
+
+  toString: ->
+    Trix.OBJECT_REPLACEMENT_CHARACTER
+
+  toJSON: ->
+    json = super
+    json.attachment = @attachment
+    json
+
+  getCacheKey: ->
+    [super, @attachment.getCacheKey()].join("/")
+
+  toConsole: ->
+    JSON.stringify(@toString())

data/lib/vapid/vendor/trix/src/trix/models/block.coffee

@@ -0,0 +1,230 @@
+#= require trix/models/text
+
+{arraysAreEqual, spliceArray, getBlockConfig, getBlockAttributeNames, getListAttributeNames} = Trix
+
+class Trix.Block extends Trix.Object
+  @fromJSON: (blockJSON) ->
+    text = Trix.Text.fromJSON(blockJSON.text)
+    new this text, blockJSON.attributes
+
+  constructor: (text = new Trix.Text, attributes = []) ->
+    super
+    @text = applyBlockBreakToText(text)
+    @attributes = attributes
+
+  isEmpty: ->
+    @text.isBlockBreak()
+
+  isEqualTo: (block) ->
+    super or (
+      @text.isEqualTo(block?.text) and
+      arraysAreEqual(@attributes, block?.attributes)
+    )
+
+  copyWithText: (text) ->
+    new @constructor text, @attributes
+
+  copyWithoutText: ->
+    @copyWithText(null)
+
+  copyWithAttributes: (attributes) ->
+    new @constructor @text, attributes
+
+  copyUsingObjectMap: (objectMap) ->
+    if mappedText = objectMap.find(@text)
+      @copyWithText(mappedText)
+    else
+      @copyWithText(@text.copyUsingObjectMap(objectMap))
+
+  addAttribute: (attribute) ->
+    attributes = @attributes.concat(expandAttribute(attribute))
+    @copyWithAttributes(attributes)
+
+  removeAttribute: (attribute) ->
+    {listAttribute} = getBlockConfig(attribute)
+    attributes = removeLastValue(removeLastValue(@attributes, attribute), listAttribute)
+    @copyWithAttributes(attributes)
+
+  removeLastAttribute: ->
+    @removeAttribute(@getLastAttribute())
+
+  getLastAttribute: ->
+    getLastElement(@attributes)
+
+  getAttributes: ->
+    @attributes.slice(0)
+
+  getAttributeLevel: ->
+    @attributes.length
+
+  getAttributeAtLevel: (level) ->
+    @attributes[level - 1]
+
+  hasAttributes: ->
+    @getAttributeLevel() > 0
+
+  getLastNestableAttribute: ->
+    getLastElement(@getNestableAttributes())
+
+  getNestableAttributes: ->
+    attribute for attribute in @attributes when getBlockConfig(attribute).nestable
+
+  getNestingLevel: ->
+    @getNestableAttributes().length
+
+  decreaseNestingLevel: ->
+    if attribute = @getLastNestableAttribute()
+      @removeAttribute(attribute)
+    else
+      this
+
+  increaseNestingLevel: ->
+    if attribute = @getLastNestableAttribute()
+      index = @attributes.lastIndexOf(attribute)
+      attributes = spliceArray(@attributes, index + 1, 0, expandAttribute(attribute)...)
+      @copyWithAttributes(attributes)
+    else
+      this
+
+  getListItemAttributes: ->
+    attribute for attribute in @attributes when getBlockConfig(attribute).listAttribute
+
+  isListItem: ->
+    getBlockConfig(@getLastAttribute())?.listAttribute
+
+  isTerminalBlock: ->
+    getBlockConfig(@getLastAttribute())?.terminal
+
+  breaksOnReturn: ->
+    getBlockConfig(@getLastAttribute())?.breakOnReturn
+
+  findLineBreakInDirectionFromPosition: (direction, position) ->
+    string = @toString()
+    result = switch direction
+      when "forward"
+        string.indexOf("\n", position)
+      when "backward"
+        string.slice(0, position).lastIndexOf("\n")
+
+    result unless result is -1
+
+  contentsForInspection: ->
+    text: @text.inspect()
+    attributes: @attributes
+
+  toString: ->
+    @text.toString()
+
+  toJSON: ->
+    text: @text
+    attributes: @attributes
+
+  # Splittable
+
+  getLength: ->
+    @text.getLength()
+
+  canBeConsolidatedWith: (block) ->
+    not @hasAttributes() and not block.hasAttributes()
+
+  consolidateWith: (block) ->
+    newlineText = Trix.Text.textForStringWithAttributes("\n")
+    text = @getTextWithoutBlockBreak().appendText(newlineText)
+    @copyWithText(text.appendText(block.text))
+
+  splitAtOffset: (offset) ->
+    if offset is 0
+      left = null
+      right = this
+    else if offset is @getLength()
+      left = this
+      right = null
+    else
+      left = @copyWithText(@text.getTextAtRange([0, offset]))
+      right = @copyWithText(@text.getTextAtRange([offset, @getLength()]))
+    [left, right]
+
+  getBlockBreakPosition: ->
+    @text.getLength() - 1
+
+  getTextWithoutBlockBreak: ->
+    if textEndsInBlockBreak(@text)
+      @text.getTextAtRange([0, @getBlockBreakPosition()])
+    else
+      @text.copy()
+
+  # Grouping
+
+  canBeGrouped: (depth) ->
+    @attributes[depth]
+
+  canBeGroupedWith: (otherBlock, depth) ->
+    otherAttributes = otherBlock.getAttributes()
+    otherAttribute = otherAttributes[depth]
+    attribute = @attributes[depth]
+
+    attribute is otherAttribute and
+      not (getBlockConfig(attribute).group is false and
+           otherAttributes[depth + 1] not in getListAttributeNames())
+
+  # Block breaks
+
+  applyBlockBreakToText = (text) ->
+    text = unmarkExistingInnerBlockBreaksInText(text)
+    text = addBlockBreakToText(text)
+    text
+
+  unmarkExistingInnerBlockBreaksInText = (text) ->
+    modified = false
+    [innerPieces..., lastPiece] = text.getPieces()
+    return text unless lastPiece?
+
+    innerPieces = for piece in innerPieces
+      if piece.isBlockBreak()
+        modified = true
+        unmarkBlockBreakPiece(piece)
+      else
+        piece
+
+    if modified
+      new Trix.Text [innerPieces..., lastPiece]
+    else
+      text
+
+  blockBreakText = Trix.Text.textForStringWithAttributes("\n", blockBreak: true)
+
+  addBlockBreakToText = (text) ->
+    if textEndsInBlockBreak(text)
+      text
+    else
+      text.appendText(blockBreakText)
+
+  textEndsInBlockBreak = (text) ->
+    length = text.getLength()
+    return false if length is 0
+    endText = text.getTextAtRange([length - 1, length])
+    endText.isBlockBreak()
+
+  unmarkBlockBreakPiece = (piece) ->
+    piece.copyWithoutAttribute("blockBreak")
+
+  # Attributes
+
+  expandAttribute = (attribute) ->
+    {listAttribute} = getBlockConfig(attribute)
+    if listAttribute?
+      [listAttribute, attribute]
+    else
+      [attribute]
+
+  # Array helpers
+
+  getLastElement = (array) ->
+    array.slice(-1)[0]
+
+  removeLastValue = (array, value) ->
+    index = array.lastIndexOf(value)
+    if index is -1
+      array
+    else
+      spliceArray(array, index, 1)