vapid 0.1.0

data/lib/vapid/vendor/trix/src/trix/inspector/element.coffee

@@ -0,0 +1,86 @@
+Trix.registerElement "trix-inspector",
+  defaultCSS: """
+    %t {
+      position: fixed;
+      background: #fff;
+      border: 1px solid #444;
+      border-radius: 5px;
+      padding: 10px;
+      font-family: sans-serif;
+      font-size: 12px;
+      overflow: auto;
+      word-wrap: break-word;
+    }
+
+    %t details {
+      margin-bottom: 10px;
+    }
+
+    %t summary:focus {
+      outline: none;
+    }
+
+    %t details .panel {
+      padding: 10px;
+    }
+
+    %t .performance .metrics {
+      margin: 0 0 5px 5px;
+    }
+
+    %t .selection .characters {
+      margin-top: 10px;
+    }
+
+    %t .selection .character {
+      display: inline-block;
+      font-size: 8px;
+      font-family: courier, monospace;
+      line-height: 10px;
+      vertical-align: middle;
+      text-align: center;
+      width: 10px;
+      height: 10px;
+      margin: 0 1px 1px 0;
+      border: 1px solid #333;
+      border-radius: 1px;
+      background: #676666;
+      color: #fff;
+    }
+
+    %t .selection .character.selected {
+      background: yellow;
+      color: #000;
+    }
+  """
+
+  attachedCallback: ->
+    @editorElement = document.querySelector("trix-editor[trix-id='#{@dataset.trixId}']")
+    @views = @createViews()
+
+    for view in @views
+      view.render()
+      @appendChild(view.element)
+
+    @reposition()
+
+    @resizeHandler = @reposition.bind(this)
+    addEventListener("resize", @resizeHandler)
+
+  detachedCallback: ->
+    removeEventListener("resize", @resizeHandler)
+
+  createViews: ->
+    views = for View in Trix.Inspector.views
+      new View @editorElement
+
+    views.sort (a, b) ->
+      a.title.toLowerCase() > b.title.toLowerCase()
+
+  reposition: ->
+    {top, right} = @editorElement.getBoundingClientRect()
+
+    @style.top = "#{top}px"
+    @style.left = "#{right + 10}px"
+    @style.maxWidth = "#{window.innerWidth - right - 40}px"
+    @style.maxHeight = "#{window.innerHeight - top - 30}px"

data/lib/vapid/vendor/trix/src/trix/inspector/index.coffee

@@ -0,0 +1,17 @@
+#= require_tree ./polyfills
+#= require_self
+#= require ./element
+#= require ./control_element
+#= require_tree ./templates
+#= require_tree ./views
+
+Trix.Inspector =
+  views: []
+
+  registerView: (constructor) ->
+    @views.push(constructor)
+
+  install: (@editorElement) ->
+    element = document.createElement("trix-inspector")
+    element.dataset.trixId = @editorElement.trixId
+    document.body.appendChild(element)

data/lib/vapid/vendor/trix/src/trix/inspector/polyfills/vendor/details-element-polyfill.js

@@ -0,0 +1,5 @@
+/*
+Details Element Polyfill 1.0.0
+Copyright © 2016 Javan Makhmali
+ */
+(function(){}).call(this),function(){var t,e,n,r,o,u,i,a,l;i={element:function(){var t,e,n,r,o;return e=document.createElement("details"),"open"in e?(e.innerHTML="<summary>a</summary>b",e.setAttribute("style","position: absolute; left: -9999px"),r=null!=(o=document.body)?o:document.documentElement,r.appendChild(e),t=e.offsetHeight,e.open=!0,n=e.offsetHeight,r.removeChild(e),t!==n):!1}(),toggleEvent:function(){var t;return t=document.createElement("details"),"ontoggle"in t}()},i.element&&i.toggleEvent||(r=function(){return document.head.insertAdjacentHTML("afterbegin",'<style>@charset"UTF-8";details:not([open])>*:not(summary){display:none;}details>summary{display:block;}details>summary::before{content:"\u25ba";padding-right:0.3rem;font-size:0.6rem;cursor:default;}details[open]>summary::before{content:"\u25bc";}</style>')},n=function(){var t,e,n,r,o;return t=document.createElement("details").constructor.prototype,r=t.setAttribute,n=t.removeAttribute,o=null!=(e=Object.getOwnPropertyDescriptor(t,"open"))?e.set:void 0,Object.defineProperties(t,{open:{set:function(t){return"DETAILS"===this.tagName?(t?this.setAttribute("open",""):this.removeAttribute("open"),t):null!=o?o.call(this,t):void 0}},setAttribute:{value:function(t,e){return l(this,function(n){return function(){return r.call(n,t,e)}}(this))}},removeAttribute:{value:function(t){return l(this,function(e){return function(){return n.call(e,t)}}(this))}}})},o=function(){return e(function(t){return t.hasAttribute("open")?t.removeAttribute("open"):t.setAttribute("open","")})},u=function(){var t;return"undefined"!=typeof MutationObserver&&null!==MutationObserver?(t=new MutationObserver(function(t){var e,n,r,o,u,i;for(u=[],n=0,r=t.length;r>n;n++)o=t[n],i=o.target,e=o.attributeName,"DETAILS"===i.tagName&&"open"===e?u.push(a(i)):u.push(void 0);return u}),t.observe(document.documentElement,{attributes:!0,subtree:!0})):e(function(t){var e;return e=t.getAttribute("open"),setTimeout(function(){return t.getAttribute("open")!==e?a(t):void 0},1)})},t=function(t){return!(t.defaultPrevented||t.which>1||t.altKey||t.ctrlKey||t.metaKey||t.shiftKey||t.target.isContentEditable)},e=function(e){return addEventListener("click",function(n){var r,o,u;return t(n)&&(o=n.target,u=o.tagName,r=o.parentElement,"SUMMARY"===u&&"DETAILS"===(null!=r?r.tagName:void 0))?e(r):void 0},!1)},a=function(t){var e;return e=document.createEvent("Events"),e.initEvent("toggle",!0,!1),t.dispatchEvent(e)},l=function(t,e){var n,r;return n=t.getAttribute("open"),r=e(),t.getAttribute("open")!==n&&a(t),r},i.element||(r(),n(),o()),i.element&&!i.toggleEvent&&u())}.call(this),function(){}.call(this);

data/lib/vapid/vendor/trix/src/trix/inspector/templates/debug.jst.eco

@@ -0,0 +1,17 @@
+<p>
+  <label>
+    <input type="checkbox" name="viewCaching" checked="<%= @compositionController.isViewCachingEnabled() %>">
+    Cache views between renders
+  </label>
+</p>
+
+<p>
+  <button data-action="render">Force Render</button> <button data-action="parse">Parse current HTML</button>
+</p>
+
+<p>
+  <label>
+    <input type="checkbox" name="controlElement">
+    Show <code>contenteditable</code> control element
+  </label>
+</p>

data/lib/vapid/vendor/trix/src/trix/inspector/templates/document.jst.eco

@@ -0,0 +1,33 @@
+<% for block, index in @document.getBlocks(): %>
+  <details class="block">
+    <summary class="title">
+      Block <%= block.id %>, Index: <%= index %>
+    </summary>
+    <div class="attributes">
+      Attributes: <%= JSON.stringify(block.attributes) %>
+    </div>
+
+    <div class="text">
+      <% {text} = block %>
+      <% pieces = text.pieceList.toArray() %>
+      <div class="title">
+        Text: <%= text.id %>, Pieces: <%= pieces.length %>, Length: <%= text.getLength() %>
+      </div>
+      <div class="pieces">
+        <% for piece, index in pieces: %>
+          <div class="piece">
+            <div class="title">
+              Piece <%= piece.id %>, Index: <%= index %>
+            </div>
+            <div class="attributes">
+              Attributes: <%= JSON.stringify(piece.attributes) %>
+            </div>
+            <div class="content">
+              <%= JSON.stringify(piece.toString()) %>
+            </div>
+          </div>
+        <% end %>
+      </div>
+    </div>
+  </details>
+<% end %>

data/lib/vapid/vendor/trix/src/trix/inspector/templates/performance.jst.eco

@@ -0,0 +1,10 @@
+<% for name, data of @data: %>
+  <strong><%= name %></strong> (<%= data.calls %>)<br>
+  <% if data.calls > 0: %>
+    <div class="metrics">
+      Mean: <%= @round(data.mean) %>ms<br>
+      Max: <%= @round(data.max) %>ms<br>
+      Last: <%= @round(data.last) %>ms
+    </div>
+  <% end %>
+<% end %>

data/lib/vapid/vendor/trix/src/trix/inspector/templates/render.jst.eco

@@ -0,0 +1 @@
+Syncs: <%= @syncCount %>

data/lib/vapid/vendor/trix/src/trix/inspector/templates/selection.jst.eco

@@ -0,0 +1,5 @@
+Location range: [<%= @locationRange[0].index %>:<%= @locationRange[0].offset %>, <%= @locationRange[1].index %>:<%= @locationRange[1].offset %>]
+
+<div class="characters">
+<% for char in @characters: %><span class="character <%= "selected" if char.selected  %>"><%= char.string %></span><% end %>
+</div>

data/lib/vapid/vendor/trix/src/trix/inspector/templates/undo.jst.eco

@@ -0,0 +1,13 @@
+<h4>Undo stack</h4>
+<ol class="undo-entries">
+  <% for entry in @undoEntries: %>
+    <li><%= entry.description %> <%= JSON.stringify(selectedRange: entry.snapshot.selectedRange, context: entry.context) %></li>
+  <% end %>
+</ol>
+
+<h4>Redo stack</h4>
+<ol class="redo-entries">
+  <% for entry in @redoEntries: %>
+    <li><%= entry.description %> <%= JSON.stringify(selectedRange: entry.snapshot.selectedRange, context: entry.context) %></li>
+  <% end %>
+</ol>

data/lib/vapid/vendor/trix/src/trix/inspector/view.coffee

@@ -0,0 +1,58 @@
+{handleEvent} = Trix
+
+class Trix.Inspector.View
+  constructor: (@editorElement) ->
+    {@editorController, @editor} = @editorElement
+    {@compositionController, @composition} = @editorController
+
+    @element = document.createElement("details")
+    @element.open = true if @getSetting("open") is "true"
+    @element.classList.add(@template)
+
+    @titleElement = document.createElement("summary")
+    @element.appendChild(@titleElement)
+
+    @panelElement = document.createElement("div")
+    @panelElement.classList.add("panel")
+    @element.appendChild(@panelElement)
+
+    @element.addEventListener "toggle", (event) =>
+      if event.target is @element
+        @didToggle()
+
+    @installEventHandlers() if @events
+
+  installEventHandlers: ->
+    for eventName, handler of @events then do (eventName, handler) =>
+      handleEvent eventName, onElement: @editorElement, withCallback: (event) =>
+        requestAnimationFrame =>
+          handler.call(this, event)
+
+  didToggle: (event) ->
+    @saveSetting("open", @isOpen())
+    @render()
+
+  isOpen: ->
+    @element.hasAttribute("open")
+
+  getTitle: ->
+    @title ? ""
+
+  render: ->
+    @renderTitle()
+    if @isOpen()
+      @panelElement.innerHTML = JST["trix/inspector/templates/#{@template}"](this)
+
+  renderTitle: ->
+    @titleElement.innerHTML = @getTitle()
+
+  getSetting: (key) ->
+    key = @getSettingsKey(key)
+    window.sessionStorage?[key]
+
+  saveSetting: (key, value) ->
+    key = @getSettingsKey(key)
+    window.sessionStorage?[key] = value
+
+  getSettingsKey: (key) ->
+    "trix/inspector/#{@template}/#{key}"

data/lib/vapid/vendor/trix/src/trix/inspector/views/debug_view.coffee

@@ -0,0 +1,33 @@
+#= require trix/inspector/view
+
+{handleEvent} = Trix
+
+Trix.Inspector.registerView class extends Trix.Inspector.View
+  title: "Debug"
+  template: "debug"
+
+  constructor: ->
+    super
+    handleEvent "change", onElement: @element, matchingSelector: "input[name=viewCaching]", withCallback: @didToggleViewCaching
+    handleEvent "click", onElement: @element, matchingSelector: "button[data-action=render]", withCallback: @didClickRenderButton
+    handleEvent "click", onElement: @element, matchingSelector: "button[data-action=parse]", withCallback: @didClickParseButton
+    handleEvent "change", onElement: @element, matchingSelector: "input[name=controlElement]", withCallback: @didToggleControlElement
+
+  didToggleViewCaching: ({target}) =>
+    if target.checked
+      @compositionController.enableViewCaching()
+    else
+      @compositionController.disableViewCaching()
+
+  didClickRenderButton: =>
+    @editorController.render()
+
+  didClickParseButton: =>
+    @editorController.reparse()
+
+  didToggleControlElement: ({target}) =>
+    if target.checked
+      @control = new Trix.Inspector.ControlElement @editorElement
+    else
+      @control?.uninstall()
+      @control = null

data/lib/vapid/vendor/trix/src/trix/inspector/views/document_view.coffee

@@ -0,0 +1,12 @@
+#= require trix/inspector/view
+
+Trix.Inspector.registerView class extends Trix.Inspector.View
+  title: "Document"
+  template: "document"
+  events:
+    "trix-change": ->
+      @render()
+
+  render: ->
+    @document = @editor.getDocument()
+    super

data/lib/vapid/vendor/trix/src/trix/inspector/views/performance_view.coffee

@@ -0,0 +1,51 @@
+#= require trix/inspector/view
+
+Trix.Inspector.registerView class extends Trix.Inspector.View
+  title: "Performance"
+  template: "performance"
+
+  constructor: ->
+    super
+    {@documentView} = @compositionController
+
+    @data = {}
+    @track("documentView.render")
+    @track("documentView.sync")
+    @track("documentView.garbageCollectCachedViews")
+    @track("composition.replaceHTML")
+
+    @render()
+
+  track: (methodPath) ->
+    @data[methodPath] = calls: 0, total: 0, mean: 0, max: 0, last: 0
+
+    [propertyNames..., methodName] = methodPath.split(".")
+    object = this
+    for propertyName in propertyNames
+      object = object[propertyName]
+
+    original = object[methodName]
+    object[methodName] = =>
+      started = now()
+      result = original.apply(object, arguments)
+      timing = now() - started
+      @record(methodPath, timing)
+      result
+
+  record: (methodPath, timing) ->
+    data = @data[methodPath]
+    data.calls += 1
+    data.total += timing
+    data.mean = data.total / data.calls
+    data.max = timing if timing > data.max
+    data.last = timing
+    @render()
+
+  round: (ms) ->
+    Math.round(ms * 1000) / 1000
+
+  now =
+    if window.performance?.now?
+      -> performance.now()
+    else
+      -> new Date().getTime()

data/lib/vapid/vendor/trix/src/trix/inspector/views/render_view.coffee

@@ -0,0 +1,21 @@
+#= require trix/inspector/view
+
+Trix.Inspector.registerView class extends Trix.Inspector.View
+  title: "Renders"
+  template: "render"
+  events:
+    "trix-render": ->
+      @renderCount++
+      @render()
+
+    "trix-sync": ->
+      @syncCount++
+      @render()
+
+  constructor: ->
+    @renderCount = 0
+    @syncCount = 0
+    super
+
+  getTitle: ->
+    "#{@title} (#{@renderCount})"

data/lib/vapid/vendor/trix/src/trix/inspector/views/selection_view.coffee

@@ -0,0 +1,33 @@
+#= require trix/inspector/view
+
+Trix.Inspector.registerView class extends Trix.Inspector.View
+  title: "Selection"
+  template: "selection"
+  events:
+    "trix-selection-change": ->
+      @render()
+    "trix-render": ->
+      @render()
+
+  render: ->
+    @document = @editor.getDocument()
+    @range = @editor.getSelectedRange()
+    @locationRange = @composition.getLocationRange()
+    @characters = @getCharacters()
+    super
+
+  getCharacters: ->
+    chars = []
+    utf16string = Trix.UTF16String.box(@document.toString())
+    rangeIsExpanded = @range[0] isnt @range[1]
+    position = 0
+    while position < utf16string.length
+      string = utf16string.charAt(position).toString()
+      string = "⏎" if string is "\n"
+      selected = rangeIsExpanded and (position >= @range[0] and position < @range[1])
+      chars.push({string, selected})
+      position++
+    chars
+
+  getTitle: ->
+    "#{@title} (#{@range.join()})"

data/lib/vapid/vendor/trix/src/trix/inspector/views/undo_view.coffee

@@ -0,0 +1,12 @@
+#= require trix/inspector/view
+
+Trix.Inspector.registerView class extends Trix.Inspector.View
+  title: "Undo"
+  template: "undo"
+  events:
+    "trix-change": ->
+      @render()
+
+  render: ->
+    {@undoEntries, @redoEntries} = @editor.undoManager
+    super

data/lib/vapid/vendor/trix/src/trix/inspector/watchdog/deserializer.coffee

@@ -0,0 +1,55 @@
+class Trix.Watchdog.Deserializer
+  constructor: (@document, @snapshot) ->
+    {@tree, @selection} = @snapshot
+    @deserializeTree()
+    @deserializeSelection()
+
+  deserializeTree: ->
+    @nodes = {}
+    @element = @deserializeNode(@tree)
+
+  deserializeNode: (serializedNode) ->
+    node = switch serializedNode.name
+      when "#text"
+        @deserializeTextNode(serializedNode)
+      when "#comment"
+        @deserializeComment(serializedNode)
+      else
+        @deserializeElement(serializedNode)
+
+    @nodes[serializedNode.id] = node
+    node
+
+  deserializeTextNode: ({value}) ->
+    @document.createTextNode(value)
+
+  deserializeComment: ({value}) ->
+    @document.createComment(value)
+
+  deserializeChildren: (serializedNode) ->
+    for child in serializedNode.children ? []
+      @deserializeNode(child)
+
+  deserializeElement: (serializedNode) ->
+    node = @document.createElement(serializedNode.name)
+    node.setAttribute(name, value) for name, value of serializedNode.attributes ? {}
+    node.removeChild(node.lastChild) while node.lastChild
+    node.appendChild(childNode) for childNode in @deserializeChildren(serializedNode)
+    node
+
+  deserializeSelection: ->
+    return unless @selection
+    {start, end} = @selection
+    startContainer = @nodes[start.id]
+    endContainer = @nodes[end.id]
+
+    @range = @document.createRange()
+    @range.setStart(startContainer, start.offset)
+    @range.setEnd(endContainer, end.offset)
+    @range
+
+  getElement: ->
+    @element
+
+  getRange: ->
+    @range