vapid 0.1.0

data/lib/vapid/vendor/trix/src/trix/core/utilities/operation.coffee

@@ -0,0 +1,37 @@
+class Trix.Operation extends Trix.BasicObject
+  isPerforming: ->
+    @performing is true
+
+  hasPerformed: ->
+    @performed is true
+
+  hasSucceeded: ->
+    @performed and @succeeded
+
+  hasFailed: ->
+    @performed and not @succeeded
+
+  getPromise: ->
+    @promise ?= new Promise (resolve, reject) =>
+      @performing = true
+      @perform (@succeeded, result) =>
+        @performing = false
+        @performed = true
+
+        if @succeeded
+          resolve(result)
+        else
+          reject(result)
+
+  perform: (callback) ->
+    callback(false)
+
+  release: ->
+    @promise?.cancel?()
+    @promise = null
+    @performing = null
+    @performed = null
+    @succeeded = null
+
+  @proxyMethod "getPromise().then"
+  @proxyMethod "getPromise().catch"

data/lib/vapid/vendor/trix/src/trix/core/utilities/utf16_string.coffee

@@ -0,0 +1,93 @@
+class Trix.UTF16String extends Trix.BasicObject
+  @box: (value = "") ->
+    if value instanceof this
+      value
+    else
+      @fromUCS2String(value?.toString())
+
+  @fromUCS2String: (ucs2String) ->
+    new this ucs2String, ucs2decode(ucs2String)
+
+  @fromCodepoints: (codepoints) ->
+    new this ucs2encode(codepoints), codepoints
+
+  constructor: (@ucs2String, @codepoints) ->
+    @length = @codepoints.length
+    @ucs2Length = @ucs2String.length
+
+  offsetToUCS2Offset: (offset) ->
+    ucs2encode(@codepoints.slice(0, Math.max(0, offset))).length
+
+  offsetFromUCS2Offset: (ucs2Offset) ->
+    ucs2decode(@ucs2String.slice(0, Math.max(0, ucs2Offset))).length
+
+  slice: ->
+    @constructor.fromCodepoints(@codepoints.slice(arguments...))
+
+  charAt: (offset) ->
+    @slice(offset, offset + 1)
+
+  isEqualTo: (value) ->
+    @constructor.box(value).ucs2String is @ucs2String
+
+  toJSON: ->
+    @ucs2String
+
+  getCacheKey: ->
+    @ucs2String
+
+  toString: ->
+    @ucs2String
+
+hasArrayFrom = Array.from?("\ud83d\udc7c").length is 1
+hasStringCodePointAt = " ".codePointAt?(0)?
+hasStringFromCodePoint = String.fromCodePoint?(32, 128124) is " \ud83d\udc7c"
+
+# UCS-2 conversion helpers ported from Mathias Bynens' Punycode.js:
+# https://github.com/bestiejs/punycode.js#punycodeucs2
+
+# Creates an array containing the numeric code points of each Unicode
+# character in the string. While JavaScript uses UCS-2 internally,
+# this function will convert a pair of surrogate halves (each of which
+# UCS-2 exposes as separate characters) into a single code point,
+# matching UTF-16.
+if hasArrayFrom and hasStringCodePointAt
+  ucs2decode = (string) ->
+    Array.from(string).map (char) -> char.codePointAt(0)
+else
+  ucs2decode = (string) ->
+    output = []
+    counter = 0
+    length = string.length
+
+    while counter < length
+      value = string.charCodeAt(counter++)
+      if 0xD800 <= value <= 0xDBFF && counter < length
+        # high surrogate, and there is a next character
+        extra = string.charCodeAt(counter++)
+        if (extra & 0xFC00) is 0xDC00
+          # low surrogate
+          value = ((value & 0x3FF) << 10) + (extra & 0x3FF) + 0x10000
+        else
+          # unmatched surrogate; only append this code unit, in case the
+          # next code unit is the high surrogate of a surrogate pair
+          counter--
+      output.push(value)
+
+    output
+
+# Creates a string based on an array of numeric code points.
+if hasStringFromCodePoint
+  ucs2encode = (array) ->
+    String.fromCodePoint(array...)
+else
+  ucs2encode = (array) ->
+    characters = for value in array
+      output = ""
+      if value > 0xFFFF
+        value -= 0x10000
+        output += String.fromCharCode(value >>> 10 & 0x3FF | 0xD800)
+        value = 0xDC00 | value & 0x3FF
+      output + String.fromCharCode(value)
+
+    characters.join("")

data/lib/vapid/vendor/trix/src/trix/elements/trix_editor_element.coffee

@@ -0,0 +1,166 @@
+#= require trix/elements/trix_toolbar_element
+#= require trix/controllers/editor_controller
+
+{makeElement, selectionElements, triggerEvent, handleEvent, handleEventOnce} = Trix
+
+{attachmentSelector} = Trix.AttachmentView
+
+Trix.registerElement "trix-editor", do ->
+  id = 0
+
+  # Contenteditable support helpers
+
+  autofocus = (element) ->
+    unless document.querySelector(":focus")
+      if element.hasAttribute("autofocus") and document.querySelector("[autofocus]") is element
+        element.focus()
+
+  makeEditable = (element) ->
+    return if element.hasAttribute("contenteditable")
+    element.setAttribute("contenteditable", "")
+    handleEventOnce("focus", onElement: element, withCallback: -> configureContentEditable(element))
+
+  configureContentEditable = (element) ->
+    disableObjectResizing(element)
+    setDefaultParagraphSeparator(element)
+
+  disableObjectResizing = (element) ->
+    if document.queryCommandSupported?("enableObjectResizing")
+      document.execCommand("enableObjectResizing", false, false)
+      handleEvent("mscontrolselect", onElement: element, preventDefault: true)
+
+  setDefaultParagraphSeparator = (element) ->
+    if document.queryCommandSupported?("DefaultParagraphSeparator")
+      {tagName} = Trix.config.blockAttributes.default
+      if tagName in ["div", "p"]
+        document.execCommand("DefaultParagraphSeparator", false, tagName)
+
+  # Style
+
+  defaultCSS: """
+    %t:empty:not(:focus)::before {
+      content: attr(placeholder);
+      color: graytext;
+    }
+
+    %t a[contenteditable=false] {
+      cursor: text;
+    }
+
+    %t img {
+      max-width: 100%;
+      height: auto;
+    }
+
+    %t #{attachmentSelector} figcaption textarea {
+      resize: none;
+    }
+
+    %t #{attachmentSelector} figcaption textarea.trix-autoresize-clone {
+      position: absolute;
+      left: -9999px;
+      max-height: 0px;
+    }
+
+    %t #{attachmentSelector}[data-trix-mutable] figcaption:empty::before {
+      content: "#{Trix.config.lang.captionPrompt}";
+      color: graytext;
+    }
+
+    %t #{selectionElements.selector} { #{selectionElements.cssText} }
+  """
+
+  # Properties
+
+  trixId:
+    get: ->
+      if @hasAttribute("trix-id")
+        @getAttribute("trix-id")
+      else
+        @setAttribute("trix-id", ++id)
+        @trixId
+
+  toolbarElement:
+    get: ->
+      if @hasAttribute("toolbar")
+        @ownerDocument?.getElementById(@getAttribute("toolbar"))
+      else if @parentElement
+        toolbarId = "trix-toolbar-#{@trixId}"
+        @setAttribute("toolbar", toolbarId)
+        element = makeElement("trix-toolbar", id: toolbarId)
+        @parentElement.insertBefore(element, this)
+        element
+
+  inputElement:
+    get: ->
+      if @hasAttribute("input")
+        @ownerDocument?.getElementById(@getAttribute("input"))
+      else if @parentElement
+        inputId = "trix-input-#{@trixId}"
+        @setAttribute("input", inputId)
+        element = makeElement("input", type: "hidden", id: inputId)
+        @parentElement.insertBefore(element, @nextElementSibling)
+        element
+
+  editor:
+    get: ->
+      @editorController?.editor
+
+  name:
+    get: ->
+      @inputElement?.name
+
+  value:
+    get: ->
+      @inputElement?.value
+    set: (@defaultValue) ->
+      @editor?.loadHTML(@defaultValue)
+
+  # Controller delegate methods
+
+  notify: (message, data) ->
+    switch message
+      when "document-change"
+        @documentChangedSinceLastRender = true
+      when "render"
+        if @documentChangedSinceLastRender
+          @documentChangedSinceLastRender = false
+          @notify("change")
+      when "change", "attachment-add", "attachment-edit", "attachment-remove"
+        @inputElement?.value = Trix.serializeToContentType(this, "text/html")
+
+    if @editorController
+      triggerEvent("trix-#{message}", onElement: this, attributes: data)
+
+  # Element lifecycle
+
+  createdCallback: ->
+    makeEditable(this)
+
+  attachedCallback: ->
+    unless @hasAttribute("data-trix-internal")
+      @editorController ?= new Trix.EditorController(editorElement: this, html: @defaultValue = @value)
+      @editorController.registerSelectionManager()
+      @registerResetListener()
+      autofocus(this)
+      requestAnimationFrame => @notify("initialize")
+
+  detachedCallback: ->
+    @editorController?.unregisterSelectionManager()
+    @unregisterResetListener()
+
+  # Form reset support
+
+  registerResetListener: ->
+    @resetListener = @resetBubbled.bind(this)
+    window.addEventListener("reset", @resetListener, false)
+
+  unregisterResetListener: ->
+    window.removeEventListener("reset", @resetListener, false)
+
+  resetBubbled: (event) ->
+    if event.target is @inputElement?.form
+      @reset() unless event.defaultPrevented
+
+  reset: ->
+    @value = @defaultValue

data/lib/vapid/vendor/trix/src/trix/elements/trix_toolbar_element.coffee

@@ -0,0 +1,28 @@
+{cloneFragment} = Trix
+
+Trix.registerElement "trix-toolbar",
+  defaultCSS: """
+    %t {
+      white-space: collapse;
+    }
+
+    %t .dialog {
+      display: none;
+    }
+
+    %t .dialog.active {
+      display: block;
+    }
+
+    %t .dialog input.validate:invalid {
+      background-color: #ffdddd;
+    }
+
+    %t[native] {
+      display: none;
+    }
+  """
+
+  createdCallback: ->
+    if @innerHTML is ""
+      @appendChild(cloneFragment(Trix.config.toolbar.content))

data/lib/vapid/vendor/trix/src/trix/index.coffee.erb

@@ -0,0 +1,14 @@
+#= export Trix
+#= require_self
+#= require trix/core
+#= require trix/config
+#= require trix/elements/trix_editor_element
+
+@Trix =
+  VERSION: "<%= depend_on_asset("trix/VERSION").to_s.chomp %>"
+
+  ZERO_WIDTH_SPACE: "\uFEFF"
+  NON_BREAKING_SPACE: "\u00A0"
+  OBJECT_REPLACEMENT_CHARACTER: "\uFFFC"
+
+  config: {}

data/lib/vapid/vendor/trix/src/trix/inspector/control_element.coffee

@@ -0,0 +1,60 @@
+class Trix.Inspector.ControlElement
+  keyEvents = "keydown keypress input".split(" ")
+  compositionEvents = "compositionstart compositionupdate compositionend textInput".split(" ")
+
+  observerOptions =
+    attributes: true
+    childList: true
+    characterData: true
+    characterDataOldValue: true
+    subtree: true
+
+  constructor: (@editorElement) ->
+    @install()
+
+  install: ->
+    @createElement()
+    @logInputEvents()
+    @logMutations()
+
+  uninstall: ->
+    @observer.disconnect()
+    @element.parentNode.removeChild(@element)
+
+  createElement: ->
+    @element = document.createElement("div")
+    @element.setAttribute("contenteditable", "")
+    @element.style.width = getComputedStyle(@editorElement).width
+    @element.style.minHeight = "50px"
+    @element.style.border = "1px solid green"
+    @editorElement.parentNode.insertBefore(@element, @editorElement.nextSibling)
+
+  logInputEvents: ->
+    for eventName in keyEvents
+      @element.addEventListener eventName, (event) ->
+        console.log "#{event.type}: keyCode = #{event.keyCode}"
+
+    for eventName in compositionEvents
+      @element.addEventListener eventName, (event) ->
+        console.log "#{event.type}: data = #{JSON.stringify(event.data)}"
+
+  logMutations: ->
+    @observer = new window.MutationObserver @didMutate
+    @observer.observe(@element, observerOptions)
+
+  didMutate: (mutations) =>
+    console.log "Mutations (#{mutations.length}):"
+    for mutation, index in mutations
+      console.log " #{index + 1}. #{mutation.type}:"
+      switch mutation.type
+        when "characterData"
+          console.log "  oldValue = #{JSON.stringify(mutation.oldValue)}, newValue = #{JSON.stringify(mutation.target.data)}"
+        when "childList"
+          console.log "  node added #{inspectNode(node)}" for node in mutation.addedNodes
+          console.log "  node removed #{inspectNode(node)}" for node in mutation.removedNodes
+
+  inspectNode = (node) ->
+    if node.data?
+      JSON.stringify(node.data)
+    else
+      JSON.stringify(node.outerHTML)

data/lib/vapid/vendor/trix/src/trix/inspector/debugger.coffee

@@ -0,0 +1,104 @@
+# This file is not included in the main Trix bundle and
+# should be explicitly required to enable the debugger.
+
+DEBUG_METHODS =
+  "Trix.AttachmentEditorController": "
+    didClickRemoveButton
+    uninstall
+  "
+
+  "Trix.CompositionController": "
+    didClickAttachment
+  "
+
+  "Trix.EditorController": "
+    setEditor
+    loadDocument
+  "
+
+  "Trix.InputController": "
+    elementDidMutate
+    events.keydown
+    events.keypress
+    events.dragstart
+    events.dragover
+    events.dragend
+    events.drop
+    events.cut
+    events.paste
+    events.compositionstart
+    events.compositionend
+  "
+
+  "Trix.ToolbarController": "
+    didClickActionButton
+    didClickAttributeButton
+    didClickDialogButton
+    didKeyDownDialogInput
+  "
+
+{findClosestElementFromNode} = Trix
+
+errorListeners = []
+
+Trix.Debugger =
+  addErrorListener: (listener) ->
+    unless listener in errorListeners
+      errorListeners.push(listener)
+
+  removeErrorListener: (listener) ->
+    errorListeners = (l for l in errorListeners when l isnt listener)
+
+installMethodDebugger = (className, methodName) ->
+  [objectName, constructorNames...] = className.split(".")
+  [propertyNames..., methodName] = methodName.split(".")
+
+  object = @[objectName]
+  object = object[constructorName] for constructorName in constructorNames
+  object = object.prototype
+  object = object[propertyName] for propertyName in propertyNames
+
+  if typeof object?[methodName] is "function"
+    object[methodName] = wrapFunctionWithErrorHandler(object[methodName])
+  else
+    throw new Error "Can't install on non-function"
+
+wrapFunctionWithErrorHandler = (fn) ->
+  trixDebugWrapper = ->
+    try
+      fn.apply(this, arguments)
+    catch error
+      reportError(error)
+      throw error
+  trixDebugWrapper
+
+reportError = (error) ->
+  Trix.Debugger.lastError = error
+
+  console.error "Trix error!"
+  console.log error.stack
+
+  activeElement = document.activeElement
+  editorElement = findClosestElementFromNode(activeElement, matchingSelector: "trix-editor")
+
+  if editorElement
+    notifyErrorListeners(error, editorElement)
+  else
+    console.warn "Can't find <trix-editor> element. document.activeElement =", activeElement
+
+notifyErrorListeners = (error, element) ->
+  for listener in errorListeners
+    try listener(error, element)
+
+do ->
+  console.groupCollapsed("Trix debugger")
+
+  for className, methodNames of DEBUG_METHODS
+    for methodName in methodNames.split(/\s/)
+      try
+        installMethodDebugger(className, methodName)
+        console.log "✓ #{className}##{methodName}"
+      catch error
+        console.warn "✗ #{className}##{methodName}:", error.message
+
+  console.groupEnd()