vapid 0.1.0

data/lib/vapid/vendor/trix/src/trix/observers/selection_change_observer.coffee

@@ -0,0 +1,56 @@
+{getDOMRange} = Trix
+
+class Trix.SelectionChangeObserver extends Trix.BasicObject
+  constructor: ->
+    @selectionManagers = []
+
+  start: ->
+    unless @started
+      @started = true
+      if "onselectionchange" of document
+        document.addEventListener "selectionchange", @update, true
+      else
+        @run()
+
+  stop: ->
+    if @started
+      @started = false
+      document.removeEventListener "selectionchange", @update, true
+
+  registerSelectionManager: (selectionManager) ->
+    unless selectionManager in @selectionManagers
+      @selectionManagers.push(selectionManager)
+      @start()
+
+  unregisterSelectionManager: (selectionManager) ->
+    @selectionManagers = (s for s in @selectionManagers when s isnt selectionManager)
+    @stop() if @selectionManagers.length is 0
+
+  notifySelectionManagersOfSelectionChange: ->
+    for selectionManager in @selectionManagers
+      selectionManager.selectionDidChange()
+
+  update: =>
+    domRange = getDOMRange()
+    unless domRangesAreEqual(domRange, @domRange)
+      @domRange = domRange
+      @notifySelectionManagersOfSelectionChange()
+
+  reset: ->
+    @domRange = null
+    @update()
+
+  # Private
+
+  run: =>
+    if @started
+      @update()
+      requestAnimationFrame(@run)
+
+  domRangesAreEqual = (left, right) ->
+    left?.startContainer is right?.startContainer and
+      left?.startOffset is right?.startOffset and
+      left?.endContainer is right?.endContainer and
+      left?.endOffset is right?.endOffset
+
+Trix.selectionChangeObserver ?= new Trix.SelectionChangeObserver

data/lib/vapid/vendor/trix/src/trix/operations/file_verification_operation.coffee

@@ -0,0 +1,15 @@
+class Trix.FileVerificationOperation extends Trix.Operation
+  constructor: (@file) ->
+
+  perform: (callback) ->
+    reader = new FileReader
+
+    reader.onerror = ->
+      callback(false)
+
+    reader.onload = =>
+      reader.onerror = null
+      try reader.abort()
+      callback(true, @file)
+
+    reader.readAsArrayBuffer(@file)

data/lib/vapid/vendor/trix/src/trix/operations/image_preload_operation.coffee

@@ -0,0 +1,15 @@
+class Trix.ImagePreloadOperation extends Trix.Operation
+  constructor: (@url) ->
+
+  perform: (callback) ->
+    image = new Image
+
+    image.onload = =>
+      image.width = @width = image.naturalWidth
+      image.height = @height = image.naturalHeight
+      callback(true, image)
+
+    image.onerror = ->
+      callback(false)
+
+    image.src = @url

data/lib/vapid/vendor/trix/src/trix/views/attachment_view.coffee

@@ -0,0 +1,99 @@
+{makeElement, selectionElements} = Trix
+{classNames} = Trix.config.css
+
+class Trix.AttachmentView extends Trix.ObjectView
+  @attachmentSelector: "[data-trix-attachment]"
+
+  constructor: ->
+    super
+    @attachment = @object
+    @attachment.uploadProgressDelegate = this
+    @attachmentPiece = @options.piece
+
+  createContentNodes: ->
+    []
+
+  createNodes: ->
+    figure = makeElement({tagName: "figure", className: @getClassName()})
+
+    if @attachment.hasContent()
+      figure.innerHTML = @attachment.getContent()
+    else
+      figure.appendChild(node) for node in @createContentNodes()
+
+    figure.appendChild(@createCaptionElement())
+
+    data =
+      trixAttachment: JSON.stringify(@attachment)
+      trixContentType: @attachment.getContentType()
+      trixId: @attachment.id
+
+    attributes = @attachmentPiece.getAttributesForAttachment()
+    unless attributes.isEmpty()
+      data.trixAttributes = JSON.stringify(attributes)
+
+    if @attachment.isPending()
+      @progressElement = makeElement
+        tagName: "progress"
+        attributes:
+          class: classNames.attachment.progressBar
+          value: @attachment.getUploadProgress()
+          max: 100
+        data:
+          trixMutable: true
+          trixStoreKey: ["progressElement", @attachment.id].join("/")
+
+      figure.appendChild(@progressElement)
+      data.trixSerialize = false
+
+    if href = @getHref()
+      element = makeElement("a", {href})
+      element.appendChild(figure)
+    else
+      element = figure
+
+    element.dataset[key] = value for key, value of data
+    element.setAttribute("contenteditable", false)
+
+    [selectionElements.create("cursorTarget"), element, selectionElements.create("cursorTarget")]
+
+  createCaptionElement: ->
+    figcaption = makeElement(tagName: "figcaption", className: classNames.attachment.caption)
+
+    if caption = @attachmentPiece.getCaption()
+      figcaption.classList.add(classNames.attachment.captionEdited)
+      figcaption.textContent = caption
+    else
+      if filename = @attachment.getFilename()
+        figcaption.textContent = filename
+
+        if filesize = @attachment.getFormattedFilesize()
+          figcaption.appendChild(document.createTextNode(" "))
+          span = makeElement(tagName: "span", className: classNames.attachment.size, textContent: filesize)
+          figcaption.appendChild(span)
+
+    figcaption
+
+  getClassName: ->
+    names = [classNames.attachment.container, "#{classNames.attachment.typePrefix}#{@attachment.getType()}"]
+    if extension = @attachment.getExtension()
+      names.push(extension)
+    names.join(" ")
+
+  getHref: ->
+    unless htmlContainsTagName(@attachment.getContent(), "a")
+      @attachment.getHref()
+
+  findProgressElement: ->
+    @findElement()?.querySelector("progress")
+
+  # Attachment delegate
+
+  attachmentDidChangeUploadProgress: ->
+    value = @attachment.getUploadProgress()
+    @findProgressElement()?.value = value
+
+htmlContainsTagName = (html, tagName) ->
+  div = makeElement("div")
+  div.innerHTML = html ? ""
+  div.querySelector(tagName)

data/lib/vapid/vendor/trix/src/trix/views/block_view.coffee

@@ -0,0 +1,37 @@
+#= require trix/views/text_view
+
+{makeElement, getBlockConfig} = Trix
+
+class Trix.BlockView extends Trix.ObjectView
+  constructor: ->
+    super
+    @block = @object
+    @attributes = @block.getAttributes()
+
+  createNodes: ->
+    comment = document.createComment("block")
+    nodes = [comment]
+    if @block.isEmpty()
+      nodes.push(makeElement("br"))
+    else
+      textConfig = getBlockConfig(@block.getLastAttribute())?.text
+      textView = @findOrCreateCachedChildView(Trix.TextView, @block.text, {textConfig})
+      nodes.push(textView.getNodes()...)
+      nodes.push(makeElement("br")) if @shouldAddExtraNewlineElement()
+
+    if @attributes.length
+      nodes
+    else
+      element = makeElement(Trix.config.blockAttributes.default.tagName)
+      element.appendChild(node) for node in nodes
+      [element]
+
+  createContainerElement: (depth) ->
+    attribute = @attributes[depth]
+    config = getBlockConfig(attribute)
+    makeElement(config.tagName)
+
+  # A single <br> at the end of a block element has no visual representation
+  # so add an extra one.
+  shouldAddExtraNewlineElement:->
+    /\n\n$/.test(@block.toString())

data/lib/vapid/vendor/trix/src/trix/views/document_view.coffee

@@ -0,0 +1,68 @@
+#= require trix/views/block_view
+
+{defer, makeElement} = Trix
+
+class Trix.DocumentView extends Trix.ObjectView
+  @render: (document) ->
+    element = makeElement("div")
+    view = new this document, {element}
+    view.render()
+    view.sync()
+    element
+
+  constructor: ->
+    super
+    {@element} = @options
+    @elementStore = new Trix.ElementStore
+    @setDocument(@object)
+
+  setDocument: (document) ->
+    unless document.isEqualTo(@document)
+      @document = @object = document
+
+  render: ->
+    @childViews = []
+
+    @shadowElement = makeElement("div")
+
+    unless @document.isEmpty()
+      objects = Trix.ObjectGroup.groupObjects(@document.getBlocks(), asTree: true)
+      for object in objects
+        view = @findOrCreateCachedChildView(Trix.BlockView, object)
+        @shadowElement.appendChild(node) for node in view.getNodes()
+
+  isSynced: ->
+    elementsHaveEqualHTML(@shadowElement, @element)
+
+  sync: ->
+    fragment = @createDocumentFragmentForSync()
+    @element.removeChild(@element.lastChild) while @element.lastChild
+    @element.appendChild(fragment)
+    @didSync()
+
+  # Private
+
+  didSync: ->
+    @elementStore.reset(findStoredElements(@element))
+    defer => @garbageCollectCachedViews()
+
+  createDocumentFragmentForSync: ->
+    fragment = document.createDocumentFragment()
+
+    for node in @shadowElement.childNodes
+      fragment.appendChild(node.cloneNode(true))
+
+    for element in findStoredElements(fragment)
+      if storedElement = @elementStore.remove(element)
+        element.parentNode.replaceChild(storedElement, element)
+
+    fragment
+
+  findStoredElements = (element) ->
+    element.querySelectorAll("[data-trix-store-key]")
+
+  elementsHaveEqualHTML = (element, otherElement) ->
+    ignoreSpaces(element.innerHTML) is ignoreSpaces(otherElement.innerHTML)
+
+  ignoreSpaces = (html) ->
+    html.replace(/ /g, " ")

data/lib/vapid/vendor/trix/src/trix/views/object_group_view.coffee

@@ -0,0 +1,23 @@
+class Trix.ObjectGroupView extends Trix.ObjectView
+  constructor: ->
+    super
+    @objectGroup = @object
+    {@viewClass} = @options
+    delete @options.viewClass
+
+  getChildViews: ->
+    unless @childViews.length
+      for object in @objectGroup.getObjects()
+        @findOrCreateCachedChildView(@viewClass, object, @options)
+    @childViews
+
+  createNodes: ->
+    element = @createContainerElement()
+
+    for view in @getChildViews()
+      element.appendChild(node) for node in view.getNodes()
+
+    [element]
+
+  createContainerElement: (depth = @objectGroup.getDepth()) ->
+    @getChildViews()[0].createContainerElement(depth)

data/lib/vapid/vendor/trix/src/trix/views/object_view.coffee

@@ -0,0 +1,86 @@
+#= require_self
+#= require trix/views/object_group_view
+
+class Trix.ObjectView extends Trix.BasicObject
+  constructor: (@object, @options = {}) ->
+    @childViews = []
+    @rootView = this
+
+  getNodes: ->
+    @nodes ?= @createNodes()
+    node.cloneNode(true) for node in @nodes
+
+  invalidate: ->
+    @nodes = null
+    @parentView?.invalidate()
+
+  invalidateViewForObject: (object) ->
+    @findViewForObject(object)?.invalidate()
+
+  findOrCreateCachedChildView: (viewClass, object, options) ->
+    if view = @getCachedViewForObject(object)
+      @recordChildView(view)
+    else
+      view = @createChildView(arguments...)
+      @cacheViewForObject(view, object)
+    view
+
+  createChildView: (viewClass, object, options = {}) ->
+    if object instanceof Trix.ObjectGroup
+      options.viewClass = viewClass
+      viewClass = Trix.ObjectGroupView
+
+    view = new viewClass object, options
+    @recordChildView(view)
+
+  recordChildView: (view) ->
+    view.parentView = this
+    view.rootView = @rootView
+    unless view in @childViews
+      @childViews.push(view)
+    view
+
+  getAllChildViews: ->
+    views = []
+    for childView in @childViews
+      views.push(childView)
+      views = views.concat(childView.getAllChildViews())
+    views
+
+  findElement: ->
+    @findElementForObject(@object)
+
+  findElementForObject: (object) ->
+    if id = object?.id
+      @rootView.element.querySelector("[data-trix-id='#{id}']")
+
+  findViewForObject: (object) ->
+    return view for view in @getAllChildViews() when view.object is object
+
+  getViewCache: ->
+    if @rootView is this
+      if @isViewCachingEnabled()
+        @viewCache ?= {}
+    else
+      @rootView.getViewCache()
+
+  isViewCachingEnabled: ->
+    @shouldCacheViews isnt false
+
+  enableViewCaching: ->
+    @shouldCacheViews = true
+
+  disableViewCaching: ->
+    @shouldCacheViews = false
+
+  getCachedViewForObject: (object) ->
+    @getViewCache()?[object.getCacheKey()]
+
+  cacheViewForObject: (view, object) ->
+    @getViewCache()?[object.getCacheKey()] = view
+
+  garbageCollectCachedViews: ->
+    if cache = @getViewCache()
+      views = @getAllChildViews().concat(this)
+      objectKeys = (view.object.getCacheKey() for view in views)
+      delete cache[key] for key of cache when key not in objectKeys

data/lib/vapid/vendor/trix/src/trix/views/piece_view.coffee

@@ -0,0 +1,97 @@
+#= require trix/views/attachment_view
+#= require trix/views/previewable_attachment_view
+
+{makeElement, findInnerElement, getTextConfig} = Trix
+
+class Trix.PieceView extends Trix.ObjectView
+  constructor: ->
+    super
+    @piece = @object
+    @attributes = @piece.getAttributes()
+    {@textConfig, @context} = @options
+
+    if @piece.attachment
+      @attachment = @piece.attachment
+    else
+      @string = @piece.toString()
+
+  createNodes: ->
+    nodes = if @attachment
+      @createAttachmentNodes()
+    else
+      @createStringNodes()
+
+    if element = @createElement()
+      innerElement = findInnerElement(element)
+      innerElement.appendChild(node) for node in nodes
+      nodes = [element]
+    nodes
+
+  createAttachmentNodes: ->
+    constructor = if @attachment.isPreviewable()
+      Trix.PreviewableAttachmentView
+    else
+      Trix.AttachmentView
+
+    view = @createChildView(constructor, @piece.attachment, {@piece})
+    view.getNodes()
+
+  createStringNodes: ->
+    if @textConfig?.plaintext
+      [document.createTextNode(@string)]
+    else
+      nodes = []
+      for substring, index in @string.split("\n")
+        if index > 0
+          element = makeElement("br")
+          nodes.push(element)
+
+        if length = substring.length
+          node = document.createTextNode(@preserveSpaces(substring))
+          nodes.push(node)
+      nodes
+
+  createElement: ->
+    for key of @attributes when config = getTextConfig(key)
+      if config.tagName
+        pendingElement = makeElement(config.tagName)
+
+        if innerElement
+          innerElement.appendChild(pendingElement)
+          innerElement = pendingElement
+        else
+          element = innerElement = pendingElement
+
+      if config.style
+        if styles
+          styles[key] = value for key, value of config.style
+        else
+          styles = config.style
+
+    if styles
+      element ?= makeElement("span")
+      element.style[key] = value for key, value of styles
+    element
+
+  createContainerElement: ->
+    for key, value of @attributes when config = getTextConfig(key)
+      if config.groupTagName
+        attributes = {}
+        attributes[key] = value
+        return makeElement(config.groupTagName, attributes)
+
+  nbsp = Trix.NON_BREAKING_SPACE
+
+  preserveSpaces: (string) ->
+    if @context.isLast
+      string = string.replace(/\ $/, nbsp)
+
+    string = string
+      .replace(/(\S)\ {3}(\S)/g, "$1 #{nbsp} $2")
+      .replace(/\ {2}/g, "#{nbsp} ")
+      .replace(/\ {2}/g, " #{nbsp}")
+
+    if @context.isFirst or @context.followsWhitespace
+      string = string.replace(/^\ /, nbsp)
+
+    string