vapid 0.1.0

data/lib/vapid/vendor/trix/src/trix/core/helpers/custom_elements.coffee

@@ -0,0 +1,45 @@
+defaults =
+  extendsTagName: "div"
+  css: "%t { display: block; }"
+
+Trix.registerElement = (tagName, definition = {}) ->
+  tagName = tagName.toLowerCase()
+  properties = rewriteFunctionsAsValues(definition)
+
+  extendsTagName = properties.extendsTagName ? defaults.extendsTagName
+  delete properties.extendsTagName
+
+  defaultCSS = properties.defaultCSS
+  delete properties.defaultCSS
+
+  if defaultCSS? and extendsTagName is defaults.extendsTagName
+    defaultCSS += "\n#{defaults.css}"
+  else
+    defaultCSS = defaults.css
+
+  installDefaultCSSForTagName(defaultCSS, tagName)
+
+  extendedPrototype = Object.getPrototypeOf(document.createElement(extendsTagName))
+  extendedPrototype.__super__ = extendedPrototype
+
+  prototype = Object.create(extendedPrototype, properties)
+  constructor = document.registerElement(tagName, prototype: prototype)
+  Object.defineProperty(prototype, "constructor", value: constructor)
+  constructor
+
+installDefaultCSSForTagName = (defaultCSS, tagName) ->
+  styleElement = insertStyleElementForTagName(tagName)
+  styleElement.textContent = defaultCSS.replace(/%t/g, tagName)
+
+insertStyleElementForTagName = (tagName) ->
+  element = document.createElement("style")
+  element.setAttribute("type", "text/css")
+  element.setAttribute("data-tag-name", tagName.toLowerCase())
+  document.head.insertBefore(element, document.head.firstChild)
+  element
+
+rewriteFunctionsAsValues = (definition) ->
+  object = {}
+  for key, value of definition
+    object[key] = if typeof value is "function" then {value} else value
+  object

data/lib/vapid/vendor/trix/src/trix/core/helpers/dom.coffee

@@ -0,0 +1,185 @@
+#= require_self
+
+html = document.documentElement
+match = html.matchesSelector ? html.webkitMatchesSelector ? html.msMatchesSelector ? html.mozMatchesSelector
+
+Trix.extend
+  handleEvent: (eventName, {onElement, matchingSelector, withCallback, inPhase, preventDefault, times} = {}) ->
+    element = onElement ? html
+    selector = matchingSelector
+    callback = withCallback
+    useCapture = inPhase is "capturing"
+
+    handler = (event) ->
+      handler.destroy() if times? and --times is 0
+      target = Trix.findClosestElementFromNode(event.target, matchingSelector: selector)
+      if target?
+        withCallback?.call(target, event, target)
+        event.preventDefault() if preventDefault
+
+    handler.destroy = ->
+      element.removeEventListener(eventName, handler, useCapture)
+
+    element.addEventListener(eventName, handler, useCapture)
+    handler
+
+  handleEventOnce: (eventName, options = {}) ->
+    options.times = 1
+    Trix.handleEvent(eventName, options)
+
+  triggerEvent: (eventName, {onElement, bubbles, cancelable, attributes} = {}) ->
+    element = onElement ? html
+    bubbles = bubbles isnt false
+    cancelable = cancelable isnt false
+
+    event = document.createEvent("Events")
+    event.initEvent(eventName, bubbles, cancelable)
+    Trix.extend.call(event, attributes) if attributes?
+    element.dispatchEvent(event)
+
+  elementMatchesSelector: (element, selector) ->
+    if element?.nodeType is 1
+      match.call(element, selector)
+
+  findClosestElementFromNode: (node, {matchingSelector, untilNode} = {}) ->
+    node = node.parentNode until not node? or node.nodeType is Node.ELEMENT_NODE
+    return unless node?
+
+    if matchingSelector?
+      if node.closest and not untilNode?
+        node.closest(matchingSelector)
+      else
+        while node and node isnt untilNode
+          return node if Trix.elementMatchesSelector(node, matchingSelector)
+          node = node.parentNode
+    else
+      node
+
+  findInnerElement: (element) ->
+    element = element.firstElementChild while element?.firstElementChild
+    element
+
+  innerElementIsActive: (element) ->
+    document.activeElement isnt element and Trix.elementContainsNode(element, document.activeElement)
+
+  elementContainsNode: (element, node) ->
+    return unless element and node
+    while node
+      return true if node is element
+      node = node.parentNode
+
+  findNodeFromContainerAndOffset: (container, offset) ->
+    return unless container
+    if container.nodeType is Node.TEXT_NODE
+      container
+    else if offset is 0
+      container.firstChild ? container
+    else
+      container.childNodes.item(offset - 1)
+
+  findElementFromContainerAndOffset: (container, offset) ->
+    node = Trix.findNodeFromContainerAndOffset(container, offset)
+    Trix.findClosestElementFromNode(node)
+
+  findChildIndexOfNode: (node) ->
+    return unless node?.parentNode
+    childIndex = 0
+    childIndex++ while node = node.previousSibling
+    childIndex
+
+  walkTree: (tree, {onlyNodesOfType, usingFilter, expandEntityReferences} = {}) ->
+    whatToShow = switch onlyNodesOfType
+      when "element" then NodeFilter.SHOW_ELEMENT
+      when "text"    then NodeFilter.SHOW_TEXT
+      when "comment" then NodeFilter.SHOW_COMMENT
+      else NodeFilter.SHOW_ALL
+
+    document.createTreeWalker(tree, whatToShow, usingFilter ? null, expandEntityReferences is true)
+
+  tagName: (element) ->
+    element?.tagName?.toLowerCase()
+
+  makeElement: (tagName, options = {}) ->
+    if typeof tagName is "object"
+      options = tagName
+      {tagName} = options
+    else
+      options = attributes: options
+
+    element = document.createElement(tagName)
+
+    if options.editable?
+      options.attributes ?= {}
+      options.attributes.contenteditable = options.editable
+
+    if options.attributes
+      for key, value of options.attributes
+        element.setAttribute(key, value)
+
+    if options.style
+      for key, value of options.style
+        element.style[key] = value
+
+    if options.data
+      for key, value of options.data
+        element.dataset[key] = value
+
+    if options.className
+      for className in options.className.split(" ")
+        element.classList.add(className)
+
+    if options.textContent
+      element.textContent = options.textContent
+
+    element
+
+  cloneFragment: (sourceFragment) ->
+    fragment = document.createDocumentFragment()
+    fragment.appendChild(node.cloneNode(true)) for node in sourceFragment.childNodes
+    fragment
+
+  makeFragment: (html = "") ->
+    container = document.createElement("div")
+    container.innerHTML = html
+    fragment = document.createDocumentFragment()
+    fragment.appendChild(node) while node = container.firstChild
+    fragment
+
+  getBlockTagNames: ->
+    Trix.blockTagNames ?= (value.tagName for key, value of Trix.config.blockAttributes)
+
+  nodeIsBlockContainer: (node) ->
+    Trix.nodeIsBlockStartComment(node?.firstChild)
+
+  nodeProbablyIsBlockContainer: (node) ->
+    Trix.tagName(node) in Trix.getBlockTagNames() and
+      Trix.tagName(node.firstChild) not in Trix.getBlockTagNames()
+
+  nodeIsBlockStart: (node, {strict} = strict: true) ->
+    if strict
+      Trix.nodeIsBlockStartComment(node)
+    else
+      Trix.nodeIsBlockStartComment(node) or
+        (not Trix.nodeIsBlockStartComment(node.firstChild) and Trix.nodeProbablyIsBlockContainer(node))
+
+  nodeIsBlockStartComment: (node) ->
+    Trix.nodeIsCommentNode(node) and node?.data is "block"
+
+  nodeIsCommentNode: (node) ->
+    node?.nodeType is Node.COMMENT_NODE
+
+  nodeIsCursorTarget: (node) ->
+    return unless node
+    if Trix.nodeIsTextNode(node)
+      node.data is Trix.ZERO_WIDTH_SPACE
+    else
+      Trix.nodeIsCursorTarget(node.firstChild)
+
+  nodeIsAttachmentElement: (node) ->
+    Trix.elementMatchesSelector(node, Trix.AttachmentView.attachmentSelector)
+
+  nodeIsEmptyTextNode: (node) ->
+    Trix.nodeIsTextNode(node) and node?.data is ""
+
+  nodeIsTextNode: (node) ->
+    node?.nodeType is Node.TEXT_NODE

data/lib/vapid/vendor/trix/src/trix/core/helpers/extend.coffee

@@ -0,0 +1,4 @@
+Trix.extend = (properties) ->
+  for key, value of properties
+    this[key] = value
+  this

data/lib/vapid/vendor/trix/src/trix/core/helpers/functions.coffee

@@ -0,0 +1,3 @@
+Trix.extend
+  defer: (fn) ->
+    setTimeout fn, 1

data/lib/vapid/vendor/trix/src/trix/core/helpers/global.coffee

@@ -0,0 +1,23 @@
+# Explicitly require this file (not included in the main
+# Trix bundle) to install the following global helpers.
+
+@getEditorElement = ->
+  document.querySelector("trix-editor")
+
+@getToolbarElement = ->
+  getEditorElement().toolbarElement
+
+@getEditorController = ->
+  getEditorElement().editorController
+
+@getEditor = ->
+  getEditorController().editor
+
+@getComposition = ->
+  getEditorController().composition
+
+@getDocument = ->
+  getComposition().document
+
+@getSelectionManager = ->
+  getEditorController().selectionManager

data/lib/vapid/vendor/trix/src/trix/core/helpers/index.coffee

@@ -0,0 +1,10 @@
+#= require trix/core/helpers/extend
+#= require trix/core/helpers/functions
+#= require trix/core/helpers/strings
+#= require trix/core/helpers/objects
+#= require trix/core/helpers/arrays
+#= require trix/core/helpers/config
+#= require trix/core/helpers/dom
+#= require trix/core/helpers/ranges
+#= require trix/core/helpers/custom_elements
+#= require trix/core/helpers/selection

data/lib/vapid/vendor/trix/src/trix/core/helpers/objects.coffee

@@ -0,0 +1,11 @@
+Trix.extend
+  copyObject: (object = {}) ->
+    result = {}
+    result[key] = value for key, value of object
+    result
+
+  objectsAreEqual: (a = {}, b = {}) ->
+    return false unless Object.keys(a).length is Object.keys(b).length
+    for key, value of a
+      return false unless value is b[key]
+    true

data/lib/vapid/vendor/trix/src/trix/core/helpers/ranges.coffee

@@ -0,0 +1,33 @@
+#= require trix/core/helpers/objects
+
+{copyObject, objectsAreEqual} = Trix
+
+Trix.extend
+  normalizeRange: normalizeRange = (range) ->
+    return unless range?
+    range = [range, range] unless Array.isArray(range)
+    [copyValue(range[0]), copyValue(range[1] ? range[0])]
+
+  rangeIsCollapsed: (range) ->
+    return unless range?
+    [start, end] = normalizeRange(range)
+    rangeValuesAreEqual(start, end)
+
+  rangesAreEqual: (leftRange, rightRange) ->
+    return unless leftRange? and rightRange?
+    [leftStart, leftEnd] = normalizeRange(leftRange)
+    [rightStart, rightEnd] = normalizeRange(rightRange)
+    rangeValuesAreEqual(leftStart, rightStart) and
+      rangeValuesAreEqual(leftEnd, rightEnd)
+
+copyValue = (value) ->
+  if typeof value is "number"
+    value
+  else
+    copyObject(value)
+
+rangeValuesAreEqual = (left, right) ->
+  if typeof left is "number"
+    left is right
+  else
+    objectsAreEqual(left, right)

data/lib/vapid/vendor/trix/src/trix/core/helpers/selection.coffee

@@ -0,0 +1,25 @@
+Trix.extend
+  getDOMSelection: ->
+    selection = window.getSelection()
+    selection if selection.rangeCount > 0
+
+  getDOMRange: ->
+    if domRange = Trix.getDOMSelection()?.getRangeAt(0)
+      unless domRangeIsPrivate(domRange)
+        domRange
+
+  setDOMRange: (domRange) ->
+    selection = window.getSelection()
+    selection.removeAllRanges()
+    selection.addRange(domRange)
+    Trix.selectionChangeObserver.update()
+
+# In Firefox, clicking certain <input> elements changes the selection to a
+# private element used to draw its UI. Attempting to access properties of those
+# elements throws an error.
+# https://bugzilla.mozilla.org/show_bug.cgi?id=208427
+domRangeIsPrivate = (domRange) ->
+  nodeIsPrivate(domRange.startContainer) or nodeIsPrivate(domRange.endContainer)
+
+nodeIsPrivate = (node) ->
+  not Object.getPrototypeOf(node)

data/lib/vapid/vendor/trix/src/trix/core/helpers/strings.coffee

@@ -0,0 +1,46 @@
+Trix.extend
+  normalizeSpaces: (string) ->
+    string
+      .replace(///#{Trix.ZERO_WIDTH_SPACE}///g, "")
+      .replace(///#{Trix.NON_BREAKING_SPACE}///g, " ")
+
+  summarizeStringChange: (oldString, newString) ->
+    oldString = Trix.UTF16String.box(oldString)
+    newString = Trix.UTF16String.box(newString)
+
+    if newString.length < oldString.length
+      [removed, added] = utf16StringDifferences(oldString, newString)
+    else
+      [added, removed] = utf16StringDifferences(newString, oldString)
+
+    {added, removed}
+
+utf16StringDifferences = (a, b) ->
+  return ["", ""] if a.isEqualTo(b)
+
+  diffA = utf16StringDifference(a, b)
+  {length} = diffA.utf16String
+
+  diffB = if length
+    {offset} = diffA
+    codepoints = a.codepoints.slice(0, offset).concat(a.codepoints.slice(offset + length))
+    utf16StringDifference(b, Trix.UTF16String.fromCodepoints(codepoints))
+  else
+    utf16StringDifference(b, a)
+
+  [diffA.utf16String.toString(), diffB.utf16String.toString()]
+
+utf16StringDifference = (a, b) ->
+  leftIndex = 0
+  rightIndexA = a.length
+  rightIndexB = b.length
+
+  while leftIndex < rightIndexA and a.charAt(leftIndex).isEqualTo(b.charAt(leftIndex))
+    leftIndex++
+
+  while rightIndexA > leftIndex + 1 and a.charAt(rightIndexA - 1).isEqualTo(b.charAt(rightIndexB - 1))
+    rightIndexA--
+    rightIndexB--
+
+  utf16String: a.slice(leftIndex, rightIndexA)
+  offset: leftIndex

data/lib/vapid/vendor/trix/src/trix/core/index.coffee

@@ -0,0 +1,4 @@
+#= require trix/core/object
+#= require trix/core/helpers
+#= require trix/core/collections
+#= require trix/core/utilities

data/lib/vapid/vendor/trix/src/trix/core/object.coffee

@@ -0,0 +1,33 @@
+#= require trix/core/basic_object
+
+class Trix.Object extends Trix.BasicObject
+  id = 0
+
+  @fromJSONString: (jsonString) ->
+    @fromJSON JSON.parse(jsonString)
+
+  constructor: ->
+    @id = ++id
+
+  hasSameConstructorAs: (object) ->
+    @constructor is object?.constructor
+
+  isEqualTo: (object) ->
+    this is object
+
+  inspect: ->
+    contents = for key, value of @contentsForInspection() ? {}
+      "#{key}=#{value}"
+
+    "#<#{@constructor.name}:#{@id}#{if contents.length then " #{contents.join(", ")}" else ""}>"
+
+  contentsForInspection: ->
+
+  toJSONString: ->
+    JSON.stringify(this)
+
+  toUTF16String: ->
+    Trix.UTF16String.box(this)
+
+  getCacheKey: ->
+    @id.toString()

data/lib/vapid/vendor/trix/src/trix/core/utilities/index.coffee

@@ -0,0 +1,2 @@
+#= require trix/core/utilities/operation
+#= require trix/core/utilities/utf16_string