vapid 0.1.0

data/lib/vapid/vendor/trix/src/trix/controllers/toolbar_controller.coffee

@@ -0,0 +1,173 @@
+{handleEvent, triggerEvent, findClosestElementFromNode} = Trix
+
+class Trix.ToolbarController extends Trix.BasicObject
+  actionButtonSelector = "button[data-trix-action]"
+  attributeButtonSelector = "button[data-trix-attribute]"
+  toolbarButtonSelector = [actionButtonSelector, attributeButtonSelector].join(", ")
+  dialogSelector = ".dialog[data-trix-dialog]"
+  activeDialogSelector = "#{dialogSelector}.active"
+  dialogButtonSelector = "#{dialogSelector} input[data-trix-method]"
+  dialogInputSelector = "#{dialogSelector} input[type=text], #{dialogSelector} input[type=url]"
+
+  constructor: (@element) ->
+    @attributes = {}
+    @actions = {}
+    @resetDialogInputs()
+
+    handleEvent "mousedown", onElement: @element, matchingSelector: actionButtonSelector, withCallback: @didClickActionButton
+    handleEvent "mousedown", onElement: @element, matchingSelector: attributeButtonSelector, withCallback: @didClickAttributeButton
+    handleEvent "click", onElement: @element, matchingSelector: toolbarButtonSelector, preventDefault: true
+    handleEvent "click", onElement: @element, matchingSelector: dialogButtonSelector, withCallback: @didClickDialogButton
+    handleEvent "keydown", onElement: @element, matchingSelector: dialogInputSelector, withCallback: @didKeyDownDialogInput
+
+  # Event handlers
+
+  didClickActionButton: (event, element) =>
+    @delegate?.toolbarDidClickButton()
+    event.preventDefault()
+    actionName = getActionName(element)
+
+    if @getDialog(actionName)
+      @toggleDialog(actionName)
+    else
+      @delegate?.toolbarDidInvokeAction(actionName)
+
+  didClickAttributeButton: (event, element) =>
+    @delegate?.toolbarDidClickButton()
+    event.preventDefault()
+    attributeName = getAttributeName(element)
+
+    if @getDialog(attributeName)
+      @toggleDialog(attributeName)
+    else
+      @delegate?.toolbarDidToggleAttribute(attributeName)
+
+    @refreshAttributeButtons()
+
+  didClickDialogButton: (event, element) =>
+    dialogElement = findClosestElementFromNode(element, matchingSelector: dialogSelector)
+    method = element.getAttribute("data-trix-method")
+    @[method].call(this, dialogElement)
+
+  didKeyDownDialogInput: (event, element) =>
+    if event.keyCode is 13 # Enter key
+      event.preventDefault()
+      attribute = element.getAttribute("name")
+      dialog = @getDialog(attribute)
+      @setAttribute(dialog)
+    if event.keyCode is 27 # Escape key
+      event.preventDefault()
+      @hideDialog()
+
+  # Action buttons
+
+  updateActions: (@actions) ->
+    @refreshActionButtons()
+
+  refreshActionButtons: ->
+    @eachActionButton (element, actionName) =>
+      element.disabled = @actions[actionName] is false
+
+  eachActionButton: (callback) ->
+    for element in @element.querySelectorAll(actionButtonSelector)
+      callback(element, getActionName(element))
+
+  # Attribute buttons
+
+  updateAttributes: (@attributes) ->
+    @refreshAttributeButtons()
+
+  refreshAttributeButtons: ->
+    @eachAttributeButton (element, attributeName) =>
+      element.disabled = @attributes[attributeName] is false
+      if @attributes[attributeName] or @dialogIsVisible(attributeName)
+        element.classList.add("active")
+      else
+        element.classList.remove("active")
+
+  eachAttributeButton: (callback) ->
+    for element in @element.querySelectorAll(attributeButtonSelector)
+      callback(element, getAttributeName(element))
+
+  applyKeyboardCommand: (keys) ->
+    keyString = JSON.stringify(keys.sort())
+    for button in @element.querySelectorAll("[data-trix-key]")
+      buttonKeys = button.getAttribute("data-trix-key").split("+")
+      buttonKeyString = JSON.stringify(buttonKeys.sort())
+      if buttonKeyString is keyString
+        triggerEvent("mousedown", onElement: button)
+        return true
+    false
+
+  # Dialogs
+
+  dialogIsVisible: (dialogName) ->
+    if element = @getDialog(dialogName)
+      element.classList.contains("active")
+
+  toggleDialog: (dialogName) ->
+    if @dialogIsVisible(dialogName)
+      @hideDialog()
+    else
+      @showDialog(dialogName)
+
+  showDialog: (dialogName) ->
+    @hideDialog()
+    @delegate?.toolbarWillShowDialog()
+
+    element = @getDialog(dialogName)
+    element.classList.add("active")
+
+    for disabledInput in element.querySelectorAll("input[disabled]")
+      disabledInput.removeAttribute("disabled")
+
+    if attributeName = getAttributeName(element)
+      if input = getInputForDialog(element, dialogName)
+        input.value = @attributes[attributeName] ? ""
+        input.select()
+
+    @delegate?.toolbarDidShowDialog(dialogName)
+
+  setAttribute: (dialogElement) ->
+    attributeName = getAttributeName(dialogElement)
+    input = getInputForDialog(dialogElement, attributeName)
+    if input.willValidate and not input.checkValidity()
+      input.classList.add("validate")
+      input.focus()
+    else
+      @delegate?.toolbarDidUpdateAttribute(attributeName, input.value)
+      @hideDialog()
+
+  removeAttribute: (dialogElement) ->
+    attributeName = getAttributeName(dialogElement)
+    @delegate?.toolbarDidRemoveAttribute(attributeName)
+    @hideDialog()
+
+  hideDialog: ->
+    if element = @element.querySelector(activeDialogSelector)
+      element.classList.remove("active")
+      @resetDialogInputs()
+      @delegate?.toolbarDidHideDialog(getDialogName(element))
+
+  resetDialogInputs: ->
+    for input in @element.querySelectorAll(dialogInputSelector)
+      input.setAttribute("disabled", "disabled")
+      input.classList.remove("validate")
+
+  getDialog: (dialogName) ->
+    @element.querySelector(".dialog[data-trix-dialog=#{dialogName}]")
+
+  getInputForDialog = (element, attributeName) ->
+    attributeName ?= getAttributeName(element)
+    element.querySelector("input[name='#{attributeName}']")
+
+  # General helpers
+
+  getActionName = (element) ->
+    element.getAttribute("data-trix-action")
+
+  getAttributeName = (element) ->
+    element.getAttribute("data-trix-attribute")
+
+  getDialogName = (element) ->
+    element.getAttribute("data-trix-dialog")

data/lib/vapid/vendor/trix/src/trix/core/basic_object.coffee

@@ -0,0 +1,44 @@
+class Trix.BasicObject
+  @proxyMethod: (expression) ->
+    {name, toMethod, toProperty, optional} = parseProxyMethodExpression(expression)
+
+    @::[name] = ->
+      object = if toMethod?
+        if optional then @[toMethod]?() else @[toMethod]()
+      else if toProperty?
+        @[toProperty]
+
+      if optional
+        subject = object?[name]
+        apply.call(subject, object, arguments) if subject?
+      else
+        subject = object[name]
+        apply.call(subject, object, arguments)
+
+  parseProxyMethodExpression = (expression) ->
+    unless match = expression.match(proxyMethodExpressionPattern)
+      throw new Error "can't parse @proxyMethod expression: #{expression}"
+
+    args = name: match[4]
+
+    if match[2]?
+      args.toMethod = match[1]
+    else
+      args.toProperty = match[1]
+
+    if match[3]?
+      args.optional = true
+
+    args
+
+  {apply} = Function.prototype
+
+  proxyMethodExpressionPattern = ///
+    ^
+      (.+?)
+        (\(\))?
+        (\?)?
+      \.
+      (.+?)
+    $
+  ///

data/lib/vapid/vendor/trix/src/trix/core/collections/element_store.coffee

@@ -0,0 +1,21 @@
+class Trix.ElementStore
+  constructor: (elements) ->
+    @reset(elements)
+
+  add: (element) ->
+    key = getKey(element)
+    @elements[key] = element
+
+  remove: (element) ->
+    key = getKey(element)
+    if value = @elements[key]
+      delete @elements[key]
+      value
+
+  reset: (elements = []) ->
+    @elements = {}
+    @add(element) for element in elements
+    elements
+
+  getKey = (element) ->
+    element.dataset.trixStoreKey

data/lib/vapid/vendor/trix/src/trix/core/collections/hash.coffee

@@ -0,0 +1,98 @@
+{arraysAreEqual} = Trix
+
+class Trix.Hash extends Trix.Object
+  @fromCommonAttributesOfObjects: (objects = []) ->
+    return new this unless objects.length
+    hash = box(objects[0])
+    keys = hash.getKeys()
+
+    for object in objects[1..]
+      keys = hash.getKeysCommonToHash(box(object))
+      hash = hash.slice(keys)
+    hash
+
+  @box: (values) ->
+    box(values)
+
+  constructor: (values = {}) ->
+    @values = copy(values)
+    super
+
+  add: (key, value) ->
+    @merge(object(key, value))
+
+  remove: (key) ->
+    new Trix.Hash copy(@values, key)
+
+  get: (key) ->
+    @values[key]
+
+  has: (key) ->
+    key of @values
+
+  merge: (values) ->
+    new Trix.Hash merge(@values, unbox(values))
+
+  slice: (keys) ->
+    values = {}
+    values[key] = @values[key] for key in keys when @has(key)
+    new Trix.Hash values
+
+  getKeys: ->
+    Object.keys(@values)
+
+  getKeysCommonToHash: (hash) ->
+    hash = box(hash)
+    key for key in @getKeys() when @values[key] is hash.values[key]
+
+  isEqualTo: (values) ->
+    arraysAreEqual(@toArray(), box(values).toArray())
+
+  isEmpty: ->
+    @getKeys().length is 0
+
+  toArray: ->
+    (@array ?= (
+      result = []
+      result.push(key, value) for key, value of @values
+      result
+    )).slice(0)
+
+  toObject: ->
+    copy(@values)
+
+  toJSON: ->
+    @toObject()
+
+  contentsForInspection: ->
+    values: JSON.stringify(@values)
+
+  object = (key, value) ->
+    result = {}
+    result[key] = value
+    result
+
+  merge = (object, values) ->
+    result = copy(object)
+    for key, value of values
+      result[key] = value
+    result
+
+  copy = (object, keyToRemove) ->
+    result = {}
+    sortedKeys = Object.keys(object).sort()
+    for key in sortedKeys when key isnt keyToRemove
+      result[key] = object[key]
+    result
+
+  box = (object) ->
+    if object instanceof Trix.Hash
+      object
+    else
+      new Trix.Hash object
+
+  unbox = (object) ->
+    if object instanceof Trix.Hash
+      object.values
+    else
+      object

data/lib/vapid/vendor/trix/src/trix/core/collections/index.coffee

@@ -0,0 +1,4 @@
+#= require trix/core/collections/hash
+#= require trix/core/collections/object_group
+#= require trix/core/collections/object_map
+#= require trix/core/collections/element_store

data/lib/vapid/vendor/trix/src/trix/core/collections/object_group.coffee

@@ -0,0 +1,37 @@
+class Trix.ObjectGroup
+  @groupObjects: (ungroupedObjects = [], {depth, asTree} = {}) ->
+    depth ?= 0 if asTree
+    objects = []
+    for object in ungroupedObjects
+      if group
+        if object.canBeGrouped?(depth) and group[group.length - 1].canBeGroupedWith?(object, depth)
+          group.push(object)
+          continue
+        else
+          objects.push(new this group, {depth, asTree})
+          group = null
+
+      if object.canBeGrouped?(depth)
+        group = [object]
+      else
+        objects.push(object)
+
+    if group
+      objects.push(new this group, {depth, asTree})
+    objects
+
+  constructor: (@objects = [], {depth, asTree}) ->
+    if asTree
+      @depth = depth
+      @objects = @constructor.groupObjects(@objects, {asTree, depth: @depth + 1})
+
+  getObjects: ->
+    @objects
+
+  getDepth: ->
+    @depth
+
+  getCacheKey: ->
+    keys = ["objectGroup"]
+    keys.push(object.getCacheKey()) for object in @getObjects()
+    keys.join("/")

data/lib/vapid/vendor/trix/src/trix/core/collections/object_map.coffee

@@ -0,0 +1,10 @@
+class Trix.ObjectMap extends Trix.BasicObject
+  constructor: (objects = []) ->
+    @objects = {}
+    for object in objects
+      hash = JSON.stringify(object)
+      @objects[hash] ?= object
+
+  find: (object) ->
+    hash = JSON.stringify(object)
+    @objects[hash]

data/lib/vapid/vendor/trix/src/trix/core/helpers/arrays.coffee

@@ -0,0 +1,34 @@
+Trix.extend
+  arraysAreEqual: (a = [], b = []) ->
+    return false unless a.length is b.length
+    for value, index in a
+      return false unless value is b[index]
+    true
+
+  arrayStartsWith: (a = [], b = []) ->
+    Trix.arraysAreEqual(a.slice(0, b.length), b)
+
+  spliceArray: (array, args...) ->
+    result = array.slice(0)
+    result.splice(args...)
+    result
+
+  summarizeArrayChange: (oldArray = [], newArray = []) ->
+    added = []
+    removed = []
+
+    existingValues = new Set
+    for value in oldArray
+      existingValues.add(value)
+
+    currentValues = new Set
+    for value in newArray
+      currentValues.add(value)
+      unless existingValues.has(value)
+        added.push(value)
+
+    for value in oldArray
+      unless currentValues.has(value)
+        removed.push(value)
+
+    {added, removed}

data/lib/vapid/vendor/trix/src/trix/core/helpers/config.coffee

@@ -0,0 +1,23 @@
+allAttributeNames = null
+blockAttributeNames = null
+textAttributeNames = null
+listAttributeNames = null
+
+Trix.extend
+  getAllAttributeNames: ->
+    allAttributeNames ?= Trix.getTextAttributeNames().concat Trix.getBlockAttributeNames()
+
+  getBlockConfig: (attributeName) ->
+    Trix.config.blockAttributes[attributeName]
+
+  getBlockAttributeNames: ->
+    blockAttributeNames ?= Object.keys(Trix.config.blockAttributes)
+
+  getTextConfig: (attributeName) ->
+    Trix.config.textAttributes[attributeName]
+
+  getTextAttributeNames: ->
+    textAttributeNames ?= Object.keys(Trix.config.textAttributes)
+
+  getListAttributeNames: ->
+    listAttributeNames ?= (listAttribute for key, {listAttribute} of Trix.config.blockAttributes when listAttribute?)