vapid 0.1.0

data/lib/vapid/vendor/trix/src/trix/models/line_break_insertion.coffee

@@ -0,0 +1,31 @@
+class Trix.LineBreakInsertion
+  constructor: (@composition) ->
+    {@document} = @composition
+
+    [@startPosition, @endPosition] = @composition.getSelectedRange()
+    @startLocation = @document.locationFromPosition(@startPosition)
+    @endLocation = @document.locationFromPosition(@endPosition)
+
+    @block = @document.getBlockAtIndex(@endLocation.index)
+    @breaksOnReturn = @block.breaksOnReturn()
+    @previousCharacter = @block.text.getStringAtPosition(@endLocation.offset - 1)
+    @nextCharacter = @block.text.getStringAtPosition(@endLocation.offset)
+
+  shouldInsertBlockBreak: ->
+    if @block.hasAttributes() and @block.isListItem() and not @block.isEmpty()
+      @startLocation.offset isnt 0
+    else
+      @breaksOnReturn and @nextCharacter isnt "\n"
+
+  shouldBreakFormattedBlock: ->
+    @block.hasAttributes() and not @block.isListItem() and
+      ((@breaksOnReturn and @nextCharacter is "\n") or @previousCharacter is "\n")
+
+  shouldDecreaseListLevel: ->
+    @block.hasAttributes() and @block.isListItem() and @block.isEmpty()
+
+  shouldPrependListItem: ->
+    @block.isListItem() and @startLocation.offset is 0 and not @block.isEmpty()
+
+  shouldRemoveLastBlockAttribute: ->
+    @block.hasAttributes() and not @block.isListItem() and @block.isEmpty()

data/lib/vapid/vendor/trix/src/trix/models/location_mapper.coffee

@@ -0,0 +1,156 @@
+{elementContainsNode, findChildIndexOfNode, nodeIsBlockStart,
+ nodeIsBlockStartComment, nodeIsBlockContainer, nodeIsCursorTarget,
+ nodeIsEmptyTextNode, nodeIsTextNode, nodeIsAttachmentElement, tagName, walkTree} = Trix
+
+class Trix.LocationMapper
+  constructor: (@element) ->
+
+  findLocationFromContainerAndOffset: (container, offset, {strict} = strict: true) ->
+    childIndex = 0
+    foundBlock = false
+    location = index: 0, offset: 0
+
+    if attachmentElement = @findAttachmentElementParentForNode(container)
+      container = attachmentElement.parentNode
+      offset = findChildIndexOfNode(attachmentElement)
+
+    walker = walkTree(@element, usingFilter: rejectAttachmentContents)
+
+    while walker.nextNode()
+      node = walker.currentNode
+
+      if node is container and nodeIsTextNode(container)
+        unless nodeIsCursorTarget(node)
+          location.offset += offset
+        break
+
+      else
+        if node.parentNode is container
+          break if childIndex++ is offset
+        else unless elementContainsNode(container, node)
+          break if childIndex > 0
+
+        if nodeIsBlockStart(node, {strict})
+          location.index++ if foundBlock
+          location.offset = 0
+          foundBlock = true
+        else
+          location.offset += nodeLength(node)
+
+    location
+
+  findContainerAndOffsetFromLocation: (location) ->
+    if location.index is 0 and location.offset is 0
+      container = @element
+      offset = 0
+
+      while container.firstChild
+        container = container.firstChild
+        if nodeIsBlockContainer(container)
+          offset = 1
+          break
+
+      return [container, offset]
+
+    [node, nodeOffset] = @findNodeAndOffsetFromLocation(location)
+    return unless node
+
+    if nodeIsTextNode(node)
+      container = node
+      string = node.textContent
+      offset = location.offset - nodeOffset
+
+    else
+      container = node.parentNode
+
+      unless nodeIsBlockStart(node.previousSibling)
+        unless nodeIsBlockContainer(container)
+          while node is container.lastChild
+            node = container
+            container = container.parentNode
+            break if nodeIsBlockContainer(container)
+
+      offset = findChildIndexOfNode(node)
+      offset++ unless location.offset is 0
+
+    [container, offset]
+
+  findNodeAndOffsetFromLocation: (location) ->
+    offset = 0
+
+    for currentNode in @getSignificantNodesForIndex(location.index)
+      length = nodeLength(currentNode)
+
+      if location.offset <= offset + length
+        if nodeIsTextNode(currentNode)
+          node = currentNode
+          nodeOffset = offset
+          break if location.offset is nodeOffset and nodeIsCursorTarget(node)
+
+        else if not node
+          node = currentNode
+          nodeOffset = offset
+
+      offset += length
+      break if offset > location.offset
+
+    [node, nodeOffset]
+
+  # Private
+
+  findAttachmentElementParentForNode: (node) ->
+    while node and node isnt @element
+      return node if nodeIsAttachmentElement(node)
+      node = node.parentNode
+
+  getSignificantNodesForIndex: (index) ->
+    nodes = []
+    walker = walkTree(@element, usingFilter: acceptSignificantNodes)
+    recordingNodes = false
+
+    while walker.nextNode()
+      node = walker.currentNode
+      if nodeIsBlockStartComment(node)
+        if blockIndex?
+          blockIndex++
+        else
+          blockIndex = 0
+
+        if blockIndex is index
+          recordingNodes = true
+        else if recordingNodes
+          break
+      else if recordingNodes
+        nodes.push(node)
+
+    nodes
+
+  nodeLength = (node) ->
+    if node.nodeType is Node.TEXT_NODE
+      if nodeIsCursorTarget(node)
+        0
+      else
+        string = node.textContent
+        string.length
+    else if tagName(node) is "br" or nodeIsAttachmentElement(node)
+      1
+    else
+      0
+
+  acceptSignificantNodes = (node) ->
+    if rejectEmptyTextNodes(node) is NodeFilter.FILTER_ACCEPT
+      rejectAttachmentContents(node)
+    else
+      NodeFilter.FILTER_REJECT
+
+  rejectEmptyTextNodes = (node) ->
+    if nodeIsEmptyTextNode(node)
+      NodeFilter.FILTER_REJECT
+    else
+      NodeFilter.FILTER_ACCEPT
+
+  rejectAttachmentContents = (node) ->
+    if nodeIsAttachmentElement(node.parentNode)
+      NodeFilter.FILTER_REJECT
+    else
+      NodeFilter.FILTER_ACCEPT

data/lib/vapid/vendor/trix/src/trix/models/managed_attachment.coffee

@@ -0,0 +1,28 @@
+#= require trix/models/attachment
+
+class Trix.ManagedAttachment extends Trix.BasicObject
+  constructor: (@attachmentManager, @attachment) ->
+    {@id, @file} = @attachment
+
+  remove: ->
+    @attachmentManager.requestRemovalOfAttachment(@attachment)
+
+  @proxyMethod "attachment.getAttribute"
+  @proxyMethod "attachment.hasAttribute"
+  @proxyMethod "attachment.setAttribute"
+  @proxyMethod "attachment.getAttributes"
+  @proxyMethod "attachment.setAttributes"
+  @proxyMethod "attachment.isPending"
+  @proxyMethod "attachment.isPreviewable"
+  @proxyMethod "attachment.getURL"
+  @proxyMethod "attachment.getHref"
+  @proxyMethod "attachment.getFilename"
+  @proxyMethod "attachment.getFilesize"
+  @proxyMethod "attachment.getFormattedFilesize"
+  @proxyMethod "attachment.getExtension"
+  @proxyMethod "attachment.getContentType"
+  @proxyMethod "attachment.getFile"
+  @proxyMethod "attachment.setFile"
+  @proxyMethod "attachment.releaseFile"
+  @proxyMethod "attachment.getUploadProgress"
+  @proxyMethod "attachment.setUploadProgress"

data/lib/vapid/vendor/trix/src/trix/models/piece.coffee

@@ -0,0 +1,95 @@
+class Trix.Piece extends Trix.Object
+  @types: {}
+
+  @registerType: (type, constructor) ->
+    constructor.type = type
+    @types[type] = constructor
+
+  @fromJSON: (pieceJSON) ->
+    if constructor = @types[pieceJSON.type]
+      constructor.fromJSON(pieceJSON)
+
+  constructor: (value, attributes = {}) ->
+    super
+    @attributes = Trix.Hash.box(attributes)
+
+  copyWithAttributes: (attributes) ->
+    new @constructor @getValue(), attributes
+
+  copyWithAdditionalAttributes: (attributes) ->
+    @copyWithAttributes(@attributes.merge(attributes))
+
+  copyWithoutAttribute: (attribute) ->
+    @copyWithAttributes(@attributes.remove(attribute))
+
+  copy: ->
+    @copyWithAttributes(@attributes)
+
+  getAttribute: (attribute) ->
+    @attributes.get(attribute)
+
+  getAttributesHash: ->
+    @attributes
+
+  getAttributes: ->
+    @attributes.toObject()
+
+  getCommonAttributes: ->
+    return {} unless piece = pieceList.getPieceAtIndex(0)
+    attributes = piece.attributes
+    keys = attributes.getKeys()
+
+    pieceList.eachPiece (piece) ->
+      keys = attributes.getKeysCommonToHash(piece.attributes)
+      attributes = attributes.slice(keys)
+
+    attributes.toObject()
+
+  hasAttribute: (attribute) ->
+    @attributes.has(attribute)
+
+  hasSameStringValueAsPiece: (piece) ->
+    piece? and @toString() is piece.toString()
+
+  hasSameAttributesAsPiece: (piece) ->
+    piece? and (@attributes is piece.attributes or @attributes.isEqualTo(piece.attributes))
+
+  isBlockBreak: ->
+    false
+
+  isEqualTo: (piece) ->
+    super or (
+      @hasSameConstructorAs(piece) and
+      @hasSameStringValueAsPiece(piece) and
+      @hasSameAttributesAsPiece(piece)
+    )
+
+  isEmpty: ->
+    @length is 0
+
+  isSerializable: ->
+    true
+
+  toJSON: ->
+    type: @constructor.type
+    attributes: @getAttributes()
+
+  contentsForInspection: ->
+    type: @constructor.type
+    attributes: @attributes.inspect()
+
+  # Grouping
+
+  canBeGrouped: ->
+    @hasAttribute("href")
+
+  canBeGroupedWith: (piece) ->
+    @getAttribute("href") is piece.getAttribute("href")
+
+  # Splittable
+
+  getLength: ->
+    @length
+
+  canBeConsolidatedWith: (piece) ->
+    false

data/lib/vapid/vendor/trix/src/trix/models/point_mapper.coffee

@@ -0,0 +1,28 @@
+{getDOMRange, setDOMRange} = Trix
+
+class Trix.PointMapper
+  createDOMRangeFromPoint: ({x, y}) ->
+    if document.caretPositionFromPoint
+      {offsetNode, offset} = document.caretPositionFromPoint(x, y)
+      domRange = document.createRange()
+      domRange.setStart(offsetNode, offset)
+      domRange
+
+    else if document.caretRangeFromPoint
+      document.caretRangeFromPoint(x, y)
+
+    else if document.body.createTextRange
+      originalDOMRange = getDOMRange()
+      try
+        # IE 11 throws "Unspecified error" when using moveToPoint
+        # during a drag-and-drop operation.
+        textRange = document.body.createTextRange()
+        textRange.moveToPoint(x, y)
+        textRange.select()
+      domRange = getDOMRange()
+      setDOMRange(originalDOMRange)
+      domRange
+
+  getClientRectsForDOMRange: (domRange) ->
+    [start, ..., end] = [domRange.getClientRects()...]
+    [start, end]

data/lib/vapid/vendor/trix/src/trix/models/selection_manager.coffee

@@ -0,0 +1,129 @@
+#= require trix/models/location_mapper
+#= require trix/models/point_mapper
+#= require trix/observers/selection_change_observer
+
+{getDOMSelection, getDOMRange, setDOMRange, elementContainsNode,
+ nodeIsCursorTarget, innerElementIsActive, handleEvent, normalizeRange,
+ rangeIsCollapsed, rangesAreEqual} = Trix
+
+class Trix.SelectionManager extends Trix.BasicObject
+  constructor: (@element) ->
+    @locationMapper = new Trix.LocationMapper @element
+    @pointMapper = new Trix.PointMapper
+    @lockCount = 0
+    handleEvent("mousedown", onElement: @element, withCallback: @didMouseDown)
+
+  getLocationRange: (options = {}) ->
+    locationRange =
+      if options.strict is false
+        @createLocationRangeFromDOMRange(getDOMRange(), strict: false)
+      else if options.ignoreLock
+        @currentLocationRange
+      else
+        @lockedLocationRange ? @currentLocationRange
+
+  setLocationRange: (locationRange) ->
+    return if @lockedLocationRange
+    locationRange = normalizeRange(locationRange)
+    if domRange = @createDOMRangeFromLocationRange(locationRange)
+      setDOMRange(domRange)
+      @updateCurrentLocationRange(locationRange)
+
+  setLocationRangeFromPointRange: (pointRange) ->
+    pointRange = normalizeRange(pointRange)
+    startLocation = @getLocationAtPoint(pointRange[0])
+    endLocation = @getLocationAtPoint(pointRange[1])
+    @setLocationRange([startLocation, endLocation])
+
+  getClientRectAtLocationRange: (locationRange) ->
+    if domRange = @createDOMRangeFromLocationRange(locationRange)
+      @getClientRectsForDOMRange(domRange)[1]
+
+  locationIsCursorTarget: (location) ->
+    [node, offset] = @findNodeAndOffsetFromLocation(location)
+    nodeIsCursorTarget(node)
+
+  lock: ->
+    if @lockCount++ is 0
+      @updateCurrentLocationRange()
+      @lockedLocationRange = @getLocationRange()
+
+  unlock: ->
+    if --@lockCount is 0
+      lockedLocationRange = @lockedLocationRange
+      @lockedLocationRange = null
+      @setLocationRange(lockedLocationRange) if lockedLocationRange?
+
+  clearSelection: ->
+    getDOMSelection()?.removeAllRanges()
+
+  selectionIsCollapsed: ->
+    getDOMRange()?.collapsed is true
+
+  selectionIsExpanded: ->
+    not @selectionIsCollapsed()
+
+  # Private
+
+  @proxyMethod "locationMapper.findLocationFromContainerAndOffset"
+  @proxyMethod "locationMapper.findContainerAndOffsetFromLocation"
+  @proxyMethod "locationMapper.findNodeAndOffsetFromLocation"
+  @proxyMethod "pointMapper.createDOMRangeFromPoint"
+  @proxyMethod "pointMapper.getClientRectsForDOMRange"
+
+  didMouseDown: =>
+    @pauseTemporarily()
+
+  pauseTemporarily: ->
+    @paused = true
+
+    resume = =>
+      @paused = false
+      clearTimeout(resumeTimeout)
+      for handler in resumeHandlers
+        handler.destroy()
+      if elementContainsNode(document, @element)
+        @selectionDidChange()
+
+    resumeTimeout = setTimeout(resume, 200)
+    resumeHandlers = for eventName in ["mousemove", "keydown"]
+      handleEvent(eventName, onElement: document, withCallback: resume)
+
+  selectionDidChange: =>
+    unless @paused or innerElementIsActive(@element)
+      @updateCurrentLocationRange()
+
+  updateCurrentLocationRange: (locationRange) ->
+    if locationRange ?= @createLocationRangeFromDOMRange(getDOMRange())
+      if not rangesAreEqual(locationRange, @currentLocationRange)
+        @currentLocationRange = locationRange
+        @delegate?.locationRangeDidChange?(@currentLocationRange.slice(0))
+
+  createDOMRangeFromLocationRange: (locationRange) ->
+    rangeStart = @findContainerAndOffsetFromLocation(locationRange[0])
+    rangeEnd = if rangeIsCollapsed(locationRange)
+      rangeStart
+    else
+      @findContainerAndOffsetFromLocation(locationRange[1]) ? rangeStart
+
+    if rangeStart? and rangeEnd?
+      domRange = document.createRange()
+      domRange.setStart(rangeStart...)
+      domRange.setEnd(rangeEnd...)
+      domRange
+
+  createLocationRangeFromDOMRange: (domRange, options) ->
+    return unless domRange? and @domRangeWithinElement(domRange)
+    return unless start = @findLocationFromContainerAndOffset(domRange.startContainer, domRange.startOffset, options)
+    end = @findLocationFromContainerAndOffset(domRange.endContainer, domRange.endOffset, options) unless domRange.collapsed
+    normalizeRange([start, end])
+
+  getLocationAtPoint: (point) ->
+    if domRange = @createDOMRangeFromPoint(point)
+      @createLocationRangeFromDOMRange(domRange)?[0]
+
+  domRangeWithinElement: (domRange) ->
+    if domRange.collapsed
+      elementContainsNode(@element, domRange.startContainer)
+    else
+      elementContainsNode(@element, domRange.startContainer) and elementContainsNode(@element, domRange.endContainer)